Pileus Git - ~andy/rhawk/blob - rhawk

   1 #!awk -f
   2
   3 @include "irc.awk"
   4 @include "json.awk"
   5 @include "spades.awk"
   6 #@include "email.awk"
   7
   8 # Initialization
   9 BEGIN {
  10         json_load("var/login.json",     login);
  11         json_load("var/nounicode.json", nounicode);
  12         json_load("var/nocolor.json",   nocolor);
  13
  14         OWNER = login["owner"];
  15
  16         connect(login["server"],  \
  17                 login["nick"],    \
  18                 login["channel"], \
  19                 login["auth"],    \
  20                 login["pass"])
  21
  22         delete login
  23
  24         if (FIRST) {
  25                 join("#rhtest")
  26                 join("#rhspades")
  27                 join("#sfvlug")
  28         }
  29 }
  30
  31 # Admin
  32 AUTH == OWNER && TO == NICK && /^die in a fire/ {
  33         say("Ack, argh, barasdjf..")
  34         quit()
  35 }
  36
  37 AUTH == OWNER && TO == NICK && /^reload/ {
  38         say("Reloading..")
  39         reload()
  40 }
  41
  42 AUTH == OWNER && TO == NICK && /^rejoin/ {
  43         reply("joining..")
  44         join("#rhnoise")
  45         next
  46 }
  47
  48 AUTH == OWNER && TO == NICK && /^(join|part)/ {
  49         if (match(MSG, /(join|part) +(#+\w+)/, arr)) {
  50                 if (arr[1] == "join") join(arr[2]);
  51                 if (arr[1] == "part") part(arr[2]);
  52                 next
  53         }
  54 }
  55
  56 AUTH == OWNER && TO == NICK && /^\.msg/ {
  57         match(MSG, /.*\.msg +(#*\w+) +(.*)/, arr)
  58         send("PRIVMSG " arr[1] " :" arr[2])
  59 }
  60
  61 # Kick handling
  62 CMD == "KICK" && ARG[2] == NICK {
  63         kick_delay = (kick_delay + 2) * 2
  64         system("sleep " kick_delay)
  65         join(DST)
  66         reply("I feel happy!")
  67 }
  68
  69 # Identify bots
  70 FROM ~ /bo+t$|rhnoise/ {
  71         bots[FROM] = 1
  72 }
  73
  74 CMD == "NICK" && FROM in bots {
  75         bots[MSG] = FROM
  76 }
  77
  78
  79 # Fancy output
  80 /[Uu]nicode :-?\(/ {
  81         nounicode[FROM] = 1
  82         json_save("var/nounicode.json", nounicode);
  83 }
  84
  85 /[Uu]nicode :-?\)/ {
  86         delete nounicode[FROM]
  87         json_save("var/nounicode.json", nounicode);
  88 }
  89
  90 /[Cc]olors :-?\(/ {
  91         nocolor[FROM] = 1
  92         json_save("var/nocolor.json", nocolor);
  93 }
  94
  95 /[Cc]olors :-?\)/ {
  96         delete nocolor[FROM]
  97         json_save("var/nocolor.json", nocolor);
  98 }
  99
 100 # SFV Lug
 101 function email(to, from, subj, body, sendmail)
 102 {
 103         from     = NICK "<andy@pileus.org>"
 104         subj     = "Update sfvlug.org!"
 105         body     = "The next SFVLUG meeting is TBA!"
 106         sendmail = "/usr/sbin/sendmail '" to "'"
 107         print "To: " to        | sendmail
 108         print "From: " from    | sendmail
 109         print "Subject: " subj | sendmail
 110         print ""               | sendmail
 111         print body             | sendmail
 112         say("Topic out of date, emailing " to);
 113         close(sendmail)
 114 }
 115
 116 BEGIN { pollchan = "#sfvlug" }
 117 (CMD == "PING"    && systime()-lastpoll > 60*60*24) ||
 118 (CMD == "PRIVMSG" && /^\.poll/) {
 119         if (!TOPICS[pollchan]) {
 120                 debug("Unknown topic for " pollchan);
 121                 send("TOPIC " pollchan)
 122                 next
 123         }
 124         _curl     = "curl -s http://sfvlug.org/"
 125         _day      = "(Sun|Mon|Tue|Wed|Thu|Fri|Sat)"
 126         _web_tba  = "next meeting is: TBA"
 127         _web_ptrn = "next meeting.*" _day "\\w+[, ]+([A-Z]\\w+) +([0-9]+)[, ]+([0-9]+)"
 128         _irc_ptrn = _day "\\w*[, ]+([A-Z]\\w+) +([0-9]+)"
 129         while (_curl | getline _line) {
 130                 #if (match(_line, _web_tba))
 131                 #       email("Brian <brian@zimage.com>");
 132                 if (match(_line, _web_ptrn, _parts)) {
 133                         _date  = _parts[1] " " _parts[2] " " _parts[3]
 134                         _topic = TOPICS[pollchan]
 135                         sub(_irc_ptrn, _date, _topic)
 136                         if (_topic != TOPICS[pollchan])
 137                                 topic(pollchan, TOPICS[pollchan] = _topic)
 138                         else
 139                                 debug("topic is already correct")
 140                         break
 141                 }
 142         }
 143         lastpoll = systime()
 144         close(_curl)
 145 }
 146
 147 # Versin/Uptime
 148 function head(cmd, var) {
 149         cmd | getline var
 150         close(cmd)
 151         return var
 152 }
 153 function uptime(time,  fmt) {
 154         fmt = "%d:%02d:%02d:%02d"
 155         fmt = "%d days %02d:%02d:%02d"
 156         return sprintf(fmt,
 157                 time / (60*60*24),
 158                 time / (60*60   ) % 24,
 159                 time / (60      ) % 60,
 160                 time / (1       ) % 60)
 161 }
 162 BEGIN {
 163         up_version = head("git describe --always --dirty")
 164         up_author  = head("git log -n1 --format=format:%an")
 165         up_message = head("git log -n1 --format=format:%s")
 166         up_reload  = systime();
 167 }
 168 /^\.(version|rev)/ {
 169         say("version: " up_version " - " up_author " - " up_message)
 170 }
 171 /^\.uptime/ {
 172         _now = systime();
 173         say("uptime: " uptime(_now - START) ", " \
 174             "reload: " uptime(_now - up_reload))
 175 }
 176
 177 # Auth info
 178 /^\.auth/ {
 179         _who = $2 ? $2 : FROM
 180         if (_who in USERS)
 181                 say("nick=" USERS[_who]["nick"] " " \
 182                     "user=" USERS[_who]["user"] " " \
 183                     "auth=" USERS[_who]["auth"] " " \
 184                     "real=" USERS[_who]["real"] " " \
 185                     "host=" USERS[_who]["host"])
 186         else
 187                 say("no auth info for " _who)
 188 }
 189
 190 # Fortune
 191 TO == NICK && /^/               { extra = ""   }
 192 TO == NICK && /^\.?fortune.*-o/ { extra = "-o" }
 193 TO == NICK && /^\.?fortune/     {
 194         gsub(/.*\.?fortune *|-[a-z]* *|[^a-zA-Z0-9 ]/, "", MSG)
 195         cmd = "fortune " extra " " (MSG ? "-m '" MSG "'" : "-s")
 196         _lines = 0
 197         while (cmd | getline _fortune && _lines < 5) {
 198                 say(_fortune)
 199                 _lines++
 200         }
 201         close(cmd)
 202         next
 203 }
 204
 205 /\<[Bb][Oo][Ff][Hh]\>/ {
 206         _cmd = "fortune bofh-excuses"
 207         _cmd | getline _fortune
 208         _cmd | getline _fortune
 209         _cmd | getline _fortune
 210         close(_cmd)
 211         say(_fortune)
 212         next
 213 }
 214
 215 # Morse code
 216 BEGIN {
 217         morse["/"      ] = " "
 218         morse[".-.-.-" ] = "."
 219         morse["--..--" ] = ","
 220         morse["..--.." ] = "?"
 221         morse[".----." ] = "'"
 222         morse["-.-.--" ] = "!"
 223         morse["-..-."  ] = "/"
 224         morse["-.--."  ] = "("
 225         morse["-.--.-" ] = ")"
 226         morse[".-..."  ] = "&"
 227         morse["---..." ] = ":"
 228         morse["-.-.-." ] = ";"
 229         morse["-...-"  ] = "="
 230         morse[".-.-."  ] = "+"
 231         morse["-....-" ] = "-"
 232         morse["..--.-" ] = "_"
 233         morse[".-..-." ] = "\""
 234         morse["...-..-"] = "$"
 235         morse[".--.-." ] = "@"
 236         morse[".-"     ] = "a"
 237         morse["-..."   ] = "b"
 238         morse["-.-."   ] = "c"
 239         morse["-.."    ] = "d"
 240         morse["."      ] = "e"
 241         morse["..-."   ] = "f"
 242         morse["--."    ] = "g"
 243         morse["...."   ] = "h"
 244         morse[".."     ] = "i"
 245         morse[".---"   ] = "j"
 246         morse["-.-"    ] = "k"
 247         morse[".-.."   ] = "l"
 248         morse["--"     ] = "m"
 249         morse["-."     ] = "n"
 250         morse["---"    ] = "o"
 251         morse[".--."   ] = "p"
 252         morse["--.-"   ] = "q"
 253         morse[".-."    ] = "r"
 254         morse["..."    ] = "s"
 255         morse["-"      ] = "t"
 256         morse["..-"    ] = "u"
 257         morse["...-"   ] = "v"
 258         morse[".--"    ] = "w"
 259         morse["-..-"   ] = "x"
 260         morse["-.--"   ] = "y"
 261         morse["--.."   ] = "z"
 262         morse["-----"  ] = "0"
 263         morse[".----"  ] = "1"
 264         morse["..---"  ] = "2"
 265         morse["...--"  ] = "3"
 266         morse["....-"  ] = "4"
 267         morse["....."  ] = "5"
 268         morse["-...."  ] = "6"
 269         morse["--..."  ] = "7"
 270         morse["---.."  ] = "8"
 271         morse["----."  ] = "9"
 272 }
 273
 274 /^\.morse/ {
 275         gsub(/[^.\-\/]/, " ")
 276         _str = ""
 277         for (i=2; i<=NF; i++)
 278                 if ($i in morse)
 279                         _str = _str morse[$i]
 280         if (_str)
 281                 reply(_str)
 282         else
 283                 reply("hush it, you pile of bologna")
 284 }
 285
 286 # Noise
 287 AUTH == OWNER && /^go go gadget woop/ {
 288         for (i=20; i>0; i--)
 289                 say(".delay " i " seconds; .woop " i)
 290 }
 291
 292 function woop(msg) {
 293         gsub(/[^Oo]/, "", $1)
 294         _len = length($1)
 295         if (_len == 2)
 296                 _len = 10
 297         if ($2)
 298                 _len = $2
 299         _woop = msg
 300         for (i=1; i<_len; i++)
 301                 _woop = _woop " " msg
 302         say(_woop)
 303 }
 304
 305 TO == NICK && /^[Ww][Oo]+[Pp] *([0-9]*)/ {
 306         woop("WOOP")
 307 }
 308
 309 /^~WOOP *([0-9]*)/ {
 310         woop("(00/")
 311 }
 312
 313 /^~woop *([0-9]*)/ {
 314         woop("^H^P^P^O")
 315 }
 316
 317 TO == NICK && DST ~ /^#/ {
 318         #say("Hello, " FROM)
 319 }
 320
 321 #DST != "#sfvlug" &&
 322 !(FROM in bots) &&
 323 CMD == "PRIVMSG" &&
 324 MSG !~ /^\./ &&
 325 /awk/ {
 326         say("Awk, awk, awk! I'm a bird!")
 327 }
 328
 329 !(FROM in bots) &&
 330 ((TO == NICK && /(help|halp)/) ||
 331  /^[^.](help|halp)/) {
 332         reply("Nothing can help you now..")
 333 }
 334
 335 /(\<[Hh][Oo]\>.*){3}/ {
 336         say("\00309Merry \00304Christmas!")
 337 }
 338
 339 !(FROM in bots) &&
 340 tolower($0) ~ /\<cloud\>/ {
 341         _cmd = "shuf clouds.txt"
 342         _cmd | getline _cloud
 343         close(_cmd)
 344         say(_cloud)
 345 }
 346
 347 /^headshot [Cc]hristmas/ {
 348         say(".load Christmas")
 349         say(".jingle")
 350         say(".unload Christmas")
 351 }
 352
 353 FROM == "rhnoise" && $2 == "slaps" && $3 == NICK {
 354         say(".spin")
 355 }
 356
 357 /^[Aa]nd now[.,]/ {
 358         say("And now...");
 359         say("THE LARCH");
 360 }
 361
 362 /(for what|that for)\?$/ {
 363         say("For great justice!");
 364 }
 365
 366 /\<nazi/ {
 367         say("And now it's...");
 368         say("Springtime for Hitler and Germany!");
 369 }
 370
 371 # God damn commands
 372 FROM == "rhnoise" && load_mod {
 373         say(".load " load_mod)
 374         say("rhnoise: You slag!")
 375 }
 376 // {
 377         load_mod = ""
 378 }
 379 (TO  ==  "rhnoise" && /^load \w+/) ||
 380 (DST == "#rhniose" && /^\.load [a-z]\w+/) {
 381         gsub(/[^a-zA-Z0-9_]/, " ")
 382         load_mod = toupper(substr($2,1,1)) substr($2,2);
 383 }
 384
 385 (DST == "#rhnoise" && /^\.line /) {
 386         sub(/\./, "!");
 387         say($0);
 388         say("scalawag: You slag!")
 389 }
 390
 391 (DST == "#rhnoise" && /^\.qdb 268$/) {
 392         say(".diediedie");
 393         next
 394 }
 395 (DST == "#rhnoise" && /\.qdb *268/) {
 396         say(".slap " FROM);
 397         next
 398 }
 399
 400 # Decrementer
 401 BEGIN {
 402         user_scores[0] = 1;
 403 }
 404
 405 /^\.(scores|scoreboard)$/ {
 406         delete user_scores
 407 }
 408
 409 FROM == "rhnoise" && !length(user_scores) {
 410         if (split(MSG, _parts, /, /)) {
 411                 for (_i=1; _i<=length(_parts); _i++) {
 412                         split(_parts[_i], _tmp, ": ");
 413                         user_scores[_i]["user"]  = _tmp[1];
 414                         user_scores[_i]["score"] = _tmp[2];
 415                 }
 416         }
 417 }
 418
 419 length(user_scores) &&
 420 tolower($0) ~ /\<nuclear launch detected\>/ {
 421         _count = 0;
 422         for (_i=1; _i<=length(user_scores); _i++) {
 423                 _user  = user_scores[_i]["user"];
 424                 _score = user_scores[_i]["score"];
 425                 if (_user in USERS) continue
 426                 if (_score ==  1) { say(_user "--"); _count++; }
 427                 if (_score == -1) { say(_user "++"); _count++; }
 428         }
 429         if (_count) {
 430                 delete user_scores;
 431                 say(".scores");
 432         } else {
 433                 say("looks like you're safe.. for now..");
 434         }
 435 }
 436
 437 # Misc
 438 { fflush("") }
 439
 440 # vim: ft=awk