Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 # In the following, there are a the following variants
   5 # of GLib cflags and libs variables
   6 #
   7 # GLIB_CFLAGS:  cflags for compiling libraries and example progs
   8 # GLIB_LIBS:    libraries for linking example programs
   9 # GLIB_DEPLIBS: libraries for linking libraries against
  10 # glib_cflags:  cflags to store in gtk-config
  11 # glib_libs:    libs to store in gtk-config
  12 # glib_thread_cflags: cflags to store in gtk-config for gtk-config gthread
  13 # glib_thread_libs:   libs to store in gtk-config for gtk-config gthread
  14
  15 # Save this value here, since automake will set cflags later
  16 cflags_set=${CFLAGS+set}
  17
  18 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  19 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  20 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  21 #
  22 # Making releases:
  23 #   GTK_MICRO_VERSION += 1;
  24 #   GTK_INTERFACE_AGE += 1;
  25 #   GTK_BINARY_AGE += 1;
  26 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  27 # if backwards compatibility has been broken,
  28 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  29 #
  30 GTK_MAJOR_VERSION=1
  31 GTK_MINOR_VERSION=2
  32 GTK_MICRO_VERSION=0
  33 GTK_INTERFACE_AGE=0
  34 GTK_BINARY_AGE=0
  35 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  36 dnl
  37 AC_DIVERT_POP()dnl
  38
  39 AC_SUBST(GTK_MAJOR_VERSION)
  40 AC_SUBST(GTK_MINOR_VERSION)
  41 AC_SUBST(GTK_MICRO_VERSION)
  42 AC_SUBST(GTK_INTERFACE_AGE)
  43 AC_SUBST(GTK_BINARY_AGE)
  44 AC_SUBST(GTK_VERSION)
  45
  46 # libtool versioning
  47 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  48 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  49 LT_REVISION=$GTK_INTERFACE_AGE
  50 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  51 AC_SUBST(LT_RELEASE)
  52 AC_SUBST(LT_CURRENT)
  53 AC_SUBST(LT_REVISION)
  54 AC_SUBST(LT_AGE)
  55
  56 # For automake.
  57 VERSION=$GTK_VERSION
  58 PACKAGE=gtk+
  59
  60 # Save this value here, since automake will set cflags later
  61 cflags_set=${CFLAGS+set}
  62
  63 dnl Initialize automake stuff
  64 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  65
  66 # Specify a configuration file
  67 AM_CONFIG_HEADER(config.h)
  68
  69 dnl Initialize libtool
  70 AM_PROG_LIBTOOL
  71
  72 dnl Initialize maintainer mode
  73 AM_MAINTAINER_MODE
  74
  75 AC_CANONICAL_HOST
  76
  77 dnl figure debugging default, prior to $ac_help setup
  78 dnl
  79 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  80 if test `expr $GTK_MINOR_VERSION \% 2` = 1 ; then
  81         debug_default=yes
  82 else
  83         debug_default=minimum
  84 fi
  85 AC_DIVERT_POP()dnl
  86
  87 dnl declare --enable-* args and collect ac_help strings
  88 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
  89 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
  90                    echo $enable_shm, enable_shm="yes")
  91 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  92                     , enable_ansi=no)
  93 AC_ARG_WITH(glib, [  --with-glib=DIR         Use uninstalled copy of glib])
  94 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
  95                         , enable_xim="yes")
  96 AC_ARG_ENABLE(xim_inst, [  --disable-xim-inst      does not use xim instantiate callback],
  97                         , enable_xim_inst="maybe")
  98 AC_ARG_WITH(locale, [  --with-locale=LOCALE    locale name you want to use ])
  99
 100 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
 101
 102 if test "x$enable_debug" = "xyes"; then
 103   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 104   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 105 else
 106   if test "x$enable_debug" = "xno"; then
 107     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DGTK_NO_CHECK_CASTS"
 108   else
 109     GTK_DEBUG_FLAGS="-DGTK_NO_CHECK_CASTS"
 110   fi
 111 fi
 112
 113 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 114
 115 # Build time sanity check...
 116 AM_SANITY_CHECK
 117
 118 # Checks for programs.
 119 AC_PROG_CC
 120 AC_ISC_POSIX
 121 AM_PROG_CC_STDC
 122 AC_PROG_INSTALL
 123 AC_PROG_MAKE_SET
 124
 125 changequote(,)dnl
 126 if test "x$GCC" = "xyes"; then
 127   case " $CFLAGS " in
 128   *[\ \ ]-Wall[\ \      ]*) ;;
 129   *) CFLAGS="$CFLAGS -Wall" ;;
 130   esac
 131
 132   if test "x$enable_ansi" = "xyes"; then
 133     case " $CFLAGS " in
 134     *[\ \       ]-ansi[\ \      ]*) ;;
 135     *) CFLAGS="$CFLAGS -ansi" ;;
 136     esac
 137
 138     case " $CFLAGS " in
 139     *[\ \       ]-pedantic[\ \  ]*) ;;
 140     *) CFLAGS="$CFLAGS -pedantic" ;;
 141     esac
 142   fi
 143 fi
 144 changequote([,])dnl
 145
 146 # define a MAINT-like variable REBUILD which is set if Perl
 147 # and awk are found, so autogenerated sources can be rebuilt
 148
 149 AC_PROG_AWK
 150 AC_CHECK_PROGS(PERL, perl5 perl)
 151
 152 # We would like indent, but don't require it.
 153 AC_CHECK_PROG(INDENT, indent, indent)
 154
 155 REBUILD=\#
 156 if test -n "$PERL" && perl -v | grep 'version 5.' > /dev/null ; then
 157   if test -n "$AWK" ; then
 158     REBUILD=
 159   fi
 160 fi
 161 AC_SUBST(REBUILD)
 162
 163 # i18n stuff
 164 ALL_LINGUAS="cs de es fr hu it ja ko nl no pl pt ru sv"
 165 AM_GTK_GNU_GETTEXT
 166 AC_CHECK_FUNC(gettext,
 167         ,
 168         AC_CHECK_LIB(intl, gettext)
 169 )
 170 # AM_GTK_GNU_GETTEXT above substs $DATADIRNAME
 171 # this is the directory where the *.{mo,gmo} files are installed
 172 gtklocaledir='${prefix}/${DATADIRNAME}/locale'
 173 AC_SUBST(gtklocaledir)
 174
 175 dnl The DU4 header files don't provide library prototypes unless
 176 dnl -std1 is given to the native cc.
 177 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 178
 179 gtk_save_LIBS=$LIBS
 180 LIBS="$LIBS -lm"
 181 AC_TRY_RUN([#include <math.h>
 182              int main (void) { return (log(1) != log(1.)); }],
 183      AC_MSG_RESULT(none needed),
 184      gtk_save_CFLAGS=$CFLAGS
 185      CFLAGS="$CFLAGS -std1"
 186      AC_TRY_RUN([#include <math.h>
 187                  int main (void) { return (log(1) != log(1.)); }],
 188          AC_MSG_RESULT(-std1),
 189          AC_MSG_RESULT()
 190          CFLAGS=$gtk_save_CFLAGS
 191          AC_MSG_WARN(
 192                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 193      )
 194 )
 195 LIBS=$gtk_save_LIBS
 196
 197 dnl NeXTStep cc seems to need this
 198 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 199 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 200   AC_MSG_RESULT(none needed),
 201   gtk_save_CFLAGS=$CFLAGS
 202   CFLAGS="$CFLAGS -posix"
 203   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 204     AC_MSG_RESULT(-posix),
 205     AC_MSG_RESULT()
 206     CFLAGS=$gtk_save_CFLAGS
 207     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 208
 209 if test x$with_glib = xyes ; then
 210   AC_MSG_ERROR([
 211 *** Directory must be specified for --with-glib])
 212 fi
 213
 214 if test x$with_glib = x ; then
 215   # Look for separately installed glib
 216
 217   AM_PATH_GLIB(1.2.0,,
 218     AC_MSG_ERROR([
 219 *** GLIB 1.2.0 or better is required. The latest version of GLIB
 220 *** is always available from ftp://ftp.gtk.org/.]),
 221     gmodule gthread)
 222
 223   # we do not want to make all gtk progs to link to thread libraries.
 224   glib_cflags=`$GLIB_CONFIG glib gmodule --cflags`
 225   glib_thread_cflags="$GLIB_CFLAGS"
 226   glib_libs=`$GLIB_CONFIG glib gmodule --libs`
 227   glib_thread_libs="$GLIB_LIBS"
 228   GLIB_LIBS="$glib_libs"
 229   GLIB_DEPLIBS="$glib_libs"
 230 else
 231   # Use uninstalled glib (assume they got the version right)
 232
 233   GLIB_CONFIG=$with_glib/glib-config
 234   if test -x $GLIB_CONFIG ; then
 235     :
 236   else
 237     AC_MSG_ERROR([GLIB directory ($with_glib) not present or not configured])
 238   fi
 239
 240   # For use in gtk-config
 241   glib_cflags=`$GLIB_CONFIG --cflags gmodule`
 242   glib_thread_cflags=`$GLIB_CONFIG --cflags gmodule gthread`
 243   glib_libs=`$GLIB_CONFIG --libs gmodule`
 244   glib_thread_libs=`$GLIB_CONFIG --libs gmodule gthread`
 245
 246   glib_release=`$GLIB_CONFIG --version | sed 's%\\.[[0-9]]*$%%'`
 247
 248   # canonicalize relative paths
 249   case $with_glib in
 250     /*)
 251       glib_dir=$with_glib
 252       ;;
 253     *)
 254       glib_dir="\$(top_builddir)/$with_glib"
 255       ;;
 256   esac
 257
 258   GLIB_CFLAGS="-I$glib_dir -I$glib_dir/gmodule"
 259   GLIB_LIBS="$glib_dir/libglib.la $glib_dir/gmodule.la"
 260   GLIB_DEPLIBS=
 261
 262   AC_SUBST(GLIB_CFLAGS)
 263   AC_SUBST(GLIB_LIBS)
 264 fi
 265
 266 AC_SUBST(glib_cflags)
 267 AC_SUBST(glib_libs)
 268 AC_SUBST(glib_thread_cflags)
 269 AC_SUBST(glib_thread_libs)
 270 AC_SUBST(GLIB_DEPLIBS)
 271
 272 # Find the X11 include and library directories
 273 AC_PATH_X
 274 AC_PATH_XTRA
 275
 276 if test "x$x_includes" = "x"; then
 277   x_includes="/usr/include"
 278 fi
 279
 280 saved_cflags="$CFLAGS"
 281 saved_ldflags="$LDFLAGS"
 282
 283 CFLAGS="$CFLAGS $X_CFLAGS"
 284 LDFLAGS="$LDFLAGS $X_LDFLAGS $X_LIBS"
 285
 286 if test "x$no_x" = "xyes"; then
 287   AC_MSG_ERROR([
 288 *** X libraries or include files not found. Check 'config.log' for
 289 *** more details.])
 290 fi
 291
 292 # Checks for libraries.
 293 # Check for the X11 library
 294 AC_CHECK_LIB(X11, XOpenDisplay, x_libs="-lX11 $X_EXTRA_LIBS",
 295   AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 296   $X_EXTRA_LIBS)
 297
 298 if test "x$enable_shm" = "xyes"; then
 299   # Check for the Xext library (needed for XShm extention)
 300   AC_CHECK_LIB(Xext, XShmAttach,
 301       x_libs="-lXext $x_libs",
 302       # On AIX, it is in XextSam instead, but we still need -lXext
 303       AC_CHECK_LIB(XextSam, XShmAttach,
 304           x_libs="-lXextSam -lXext $x_libs",
 305           no_xext_lib=yes, $x_libs),
 306       $x_libs)
 307 fi
 308
 309 # Check for shaped window extension
 310
 311 AC_CHECK_LIB(Xext, XShapeCombineMask,
 312       if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 313            x_libs="-lXext $x_libs"
 314       fi
 315       AC_DEFINE(HAVE_SHAPE_EXT),
 316       ,
 317       $x_libs)
 318
 319 # Check for XConvertCase (X11R6 specific)
 320
 321 AC_CHECK_LIB(X11, XConvertCase,
 322       AC_DEFINE(HAVE_XCONVERTCASE),
 323       ,
 324       $x_libs)
 325
 326 # Check for XIM support.
 327
 328 AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 329             : ,
 330             enable_xim_inst="no",
 331             $x_libs)
 332
 333 # On Solaris, calling XRegisterIMInstantiateCallback seems to
 334 # cause an immediate segfault, so we disable it, unless
 335 # the user specifically forces it to be on.
 336
 337 if test x$enable_xim_inst = xmaybe ; then
 338   case host in
 339         *-*-solaris*)
 340             enable_xim_inst="no"
 341             ;;
 342         *)
 343             enable_xim_inst="yes"
 344             ;;
 345   esac
 346 fi
 347
 348 if test "x$enable_xim" = "xyes"; then
 349   GTK_XIM_FLAGS="-DUSE_XIM"
 350   if test "x$enable_xim_inst" = "xyes"; then
 351     AC_DEFINE(USE_X11R6_XIM)
 352   fi
 353 fi
 354
 355 x_cflags="$X_CFLAGS"
 356 x_ldflags="$X_LDFLAGS $X_LIBS"
 357
 358 # set up things for XInput
 359
 360 if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 361   AC_DEFINE(XINPUT_GXI)
 362   xinput_progs=gxid
 363   x_libs="-lXi $x_libs"
 364 elif test "x$with_xinput" = "xxfree"; then
 365   AC_DEFINE(XINPUT_XFREE)
 366   x_libs="-lXi $x_libs"
 367 else
 368   AC_DEFINE(XINPUT_NONE)
 369 fi
 370
 371 CFLAGS="$saved_cflags"
 372 LDFLAGS="$saved_ldflags"
 373
 374 AC_SUBST(x_cflags)
 375 AC_SUBST(x_includes)
 376 AC_SUBST(x_ldflags)
 377 AC_SUBST(x_libs)
 378 AC_SUBST(xinput_progs)
 379
 380 if test "x$enable_shm" = "xyes"; then
 381   # Check for shared memory
 382   AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 383   AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 384
 385   # Check for the X shared memory extension header file
 386   AC_MSG_CHECKING(X11/extensions/XShm.h)
 387   if test "x$no_xext_lib" = "xyes"; then
 388     AC_MSG_RESULT(no)
 389     no_xshm=yes
 390   else
 391     if test -f "$x_includes/X11/extensions/XShm.h"; then
 392       AC_MSG_RESULT(yes)
 393       AC_DEFINE(HAVE_XSHM_H)
 394     else
 395       AC_MSG_RESULT(no)
 396       no_xshm=yes
 397     fi
 398   fi
 399 fi
 400
 401 # Check if X_LOCALE definition is necessary
 402
 403 AC_MSG_CHECKING(need -DX_LOCALE)
 404
 405 AC_TRY_RUN([
 406 #include <stdio.h>
 407 #include <locale.h>
 408
 409 int
 410 main ()
 411 {
 412   return setlocale (LC_ALL, "${with_locale}") == NULL;
 413 }],
 414 need_x_locale=no,
 415 need_x_locale=yes)
 416 AC_MSG_RESULT($need_x_locale)
 417
 418 if test $need_x_locale = yes; then
 419   GTK_LOCALE_CFLAGS="-DX_LOCALE"
 420 fi
 421
 422 # Checks for header files.
 423 AC_HEADER_STDC
 424
 425 # Checks for typedefs, structures, and compiler characteristics.
 426 AC_C_CONST
 427
 428 # Checks for library functions.
 429 AC_TYPE_SIGNAL
 430 AC_FUNC_MMAP
 431
 432 # Check if <sys/select.h> needs to be included for fd_set
 433 AC_MSG_CHECKING([for fd_set])
 434 AC_TRY_COMPILE([#include <sys/types.h>],
 435         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 436 if test $gtk_ok = yes; then
 437     AC_MSG_RESULT([yes, found in sys/types.h])
 438 else
 439     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 440     if test $gtk_ok = yes; then
 441         AC_DEFINE(HAVE_SYS_SELECT_H)
 442         AC_MSG_RESULT([yes, found in sys/select.h])
 443     else
 444         AC_DEFINE(NO_FD_SET)
 445         AC_MSG_RESULT(no)
 446     fi
 447 fi
 448
 449 # Duplicate `widechar' tests from `glib'.
 450 # Check for wchar.h
 451 if test x = y; then
 452   # will not be executed
 453   # hack so as not to update `acconfig.h'
 454   AC_CHECK_HEADERS(wchar.h wctype.h)
 455   AC_CHECK_FUNCS(broken_wctype)
 456 fi
 457
 458 AC_MSG_CHECKING(for wchar.h)
 459 AC_TRY_CPP([#include <wchar.h>], gtk_ok=yes, gtk_ok=no)
 460 if test $gtk_ok = yes; then
 461    ac_kludge=HAVE_WCHAR_H
 462    AC_DEFINE($ac_kludge)
 463 fi
 464 AC_MSG_RESULT($gtk_ok)
 465
 466 # Check for wctype.h (for iswalnum)
 467
 468 AC_MSG_CHECKING(for wctype.h)
 469 AC_TRY_CPP([#include <wctype.h>], gtk_ok=yes, gtk_ok=no)
 470 if test $gtk_ok = yes; then
 471    ac_kludge=HAVE_WCTYPE_H
 472    AC_DEFINE($ac_kludge)
 473 fi
 474 AC_MSG_RESULT($gtk_ok)
 475
 476 # in Solaris 2.5, `iswalnum' is in -lw
 477 GDK_WLIBS=
 478 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 479
 480 # The following is necessary for Linux libc-5.4.38
 481 oLIBS="$LIBS"
 482 LIBS="$LIBS $GDK_WLIBS"
 483 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 484 AC_TRY_LINK([#include <stdlib.h>],[
 485 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 486 #  ifdef HAVE_WCTYPE_H
 487 #    include <wctype.h>
 488 #  else
 489 #    ifdef HAVE_WCHAR_H
 490 #      include <wchar.h>
 491 #    endif
 492 #  endif
 493 #else
 494 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 495 #endif
 496 iswalnum((wchar_t) 0);
 497 ], gtk_ok=yes, gtk_ok=no)
 498 LIBS="$oLIBS"
 499
 500 if test $gtk_ok = no; then
 501    ac_kludge=HAVE_BROKEN_WCTYPE
 502    AC_DEFINE($ac_kludge)
 503    GDK_WLIBS=
 504 fi
 505 AC_MSG_RESULT($gtk_ok)
 506 AC_SUBST(GDK_WLIBS)
 507
 508 AC_SUBST(GTK_DEBUG_FLAGS)
 509 AC_SUBST(GTK_XIM_FLAGS)
 510 AC_SUBST(GTK_LOCALE_FLAGS)
 511
 512 AC_OUTPUT([
 513 gtk+.spec
 514 Makefile
 515 gtk-config
 516 po/Makefile.in
 517 docs/Makefile
 518 gdk/Makefile
 519 gtk/Makefile
 520 gtk/gtkfeatures.h
 521 ], [chmod +x gtk-config])