Pileus Git - ~andy/sunrise/blob - x11-wm/qlwm/qlwm-4.3.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="1"
   6
   7 DESCRIPTION="A Qt based window manager"
   8 HOMEPAGE="http://www.mynetcologne.de/~nc-lindenal/qlwm/
   9         http://www.alinden.mynetcologne.de/qlwm/"
  10 SRC_URI="http://www.alinden.mynetcologne.de/${PN}/${P}.tar.gz"
  11 LICENSE="GPL-2"
  12
  13 SLOT="4"
  14 KEYWORDS="~x86"
  15 IUSE=""
  16
  17 DEPEND="dev-libs/qtgui:4
  18         x11-libs/libX11
  19         x11-libs/libXext"
  20 RDEPEND="${DEPEND}"
  21
  22 src_unpack() {
  23         unpack ${A}
  24         cd "${S}"
  25
  26         # fix path to shared files
  27         sed -i -e 's!^DEST .*$!DEST = /usr/share/'"${PN}-${SLOT}"'!' "Makefile" \
  28            || die "Cannot fix DEST variable for shared files"
  29         # fix path to Qt4's qmake
  30         sed -i -e 's!^QMAKE .*$!QMAKE = /usr/bin/qmake!' "Makefile" \
  31            || die "Cannot fix Makefile variable for qmake"
  32         # fixing path/filename to qtconfig
  33         sed -i -e 's!qtconfig-qt4!/usr/bin/qtconfig!' "files/menuconfig" \
  34            || die "Cannot fix menu entry for qtconfig"
  35         # in the source code, fix path to config files and images
  36         sed -i -e 's!\bCONFDIR ".*$!CONFDIR "/usr/share/'"${PN}-${SLOT}"'/files/"!' \
  37            "src/conf.h" || die "Cannot change CONFDIR in src/conf.h"
  38 }
  39
  40 src_install() {
  41         # install binaries with slotted filenames
  42         newbin src/qlwm qlwm-${SLOT} || die "Cannot install binary qlwm"
  43         newbin dclock/dclock dclock-${SLOT} || die "Cannot install binary dclock"
  44         newbin mail/biff biff-${SLOT} || die "Cannot install binary biff"
  45
  46         # install man page with slotted filename
  47         newman qlwm.1 qlwm-${SLOT}.1 || die "Cannot install manual file"
  48
  49         # renaming defaults file
  50         mv files/defaults.in files/defaults || die "Cannot rename default config"
  51         # disable font name entries in default config file
  52         sed -i -e 's!^\(\S*FontName\S*\)\b!# \1!g;
  53                    s!^\(Style \)!# \1!g' \
  54            files/defaults || die "Cannot fix font names in default configuration"
  55         # rename entries for dclock and biff to match $SLOT
  56         sed -i -e 's!\S*\(dclock\|biff\)\b!/usr/bin/\1-'${SLOT}'!g' \
  57            files/defaults || die "Cannot fix font names in default configuration"
  58
  59         # install config files and images
  60         insinto /usr/share/${PN}-${SLOT}
  61         doins -r files/ || die "Cannot install shared files"
  62
  63         # install documentation
  64         dodoc README CHANGES || die "Cannot install documentation"
  65 }