Pileus Git - ~andy/sunrise/blob - sys-power/acpi-support/acpi-support-0.109.ebuild

   1 # Copyright 1999-2008 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 inherit eutils
   6
   7 DESCRIPTION="Ubuntu scripts and events for acpid, power management, and vendor-specific laptop configuration"
   8 HOMEPAGE="http://packages.ubuntu.com/feisty/admin/acpi-support"
   9 SRC_URI="mirror://ubuntu/pool/main/a/acpi-support/${PN}_${PV}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="X hibernate-script video_cards_radeon"
  15
  16 RDEPEND="sys-power/acpid
  17         sys-apps/kbd
  18         sys-apps/dmidecode
  19         sys-apps/vbetool
  20         sys-apps/ethtool
  21         sys-power/powermgmt-base
  22         hibernate-script? ( sys-power/hibernate-script )
  23         X? ( x11-apps/xset )
  24         video_cards_radeon? ( app-laptop/radeontool )"
  25
  26 src_unpack() {
  27         unpack ${A}
  28         epatch "${FILESDIR}/${P}-gentoo.patch"
  29         use hibernate-script && sed -i '/USE_HIBERNATE_SCRIPT=true/ s/# //' "${S}/acpi-support"
  30         use video_cards_radeon && sed -i '/RADEON_LIGHT=true/ s/# //' "${S}/acpi-support"
  31         use X || sed -i '/xset/ s/\(.*\)/#\1/' "${S}/"{lid.sh,lib/screenblank}
  32         sed -i "s!/etc/default/acpi-support!/etc/conf.d/${PN}!" "${S}/"{*.sh,vbesave} || die "sed failed"
  33 }
  34
  35 src_compile() {
  36         sed -i 's/strip acpi_fakekey//' Makefile
  37         emake || die "emake failed"
  38 }
  39
  40 src_install() {
  41         dobin acpi_fakekey
  42
  43         insinto /usr/share/${PN}
  44         doins key-constants lib/*
  45
  46         insinto /etc/acpi
  47         insopts -m755
  48         doins *.sh
  49         doins -r *.d events
  50
  51         doconfd ${PN}
  52         newinitd debian/init.d ${PN}
  53
  54         keepdir /etc/acpi/{local,{resume,battery,events,suspend,start,ac}.d} /var/lib/${PN}
  55         dodoc README
  56 }
  57
  58 pkg_postinst() {
  59         elog "You may wish to read the Gentoo Linux Power Management Guide,"
  60         elog "which can be found online at:"
  61         elog
  62         elog "http://www.gentoo.org/doc/en/power-management-guide.xml"
  63         elog
  64         elog "The following packages provide additional functionality:"
  65         elog
  66         elog "app-laptop/laptop-mode-tools"
  67         elog "app-laptop/toshset"
  68         elog "sys-power/kpowersave"
  69         elog "sys-power/powersave"
  70         elog "sys-apps/855resolution"
  71         elog "sys-apps/pcmciautils"
  72         elog
  73         elog "To initialize power management options for your devices at"
  74         elog "system startup, please run the following:"
  75         elog
  76         elog "rc-update add ${PN} default"
  77         elog
  78         elog "This package will not work until you restart acpid. Please run the following:"
  79         elog
  80         elog "/etc/init.d/acpid restart"
  81 }