Pileus Git - ~andy/sunrise/blob - sys-fs/cromfs/cromfs-1.2.5.ebuild

   1 # Copyright 1999-2007 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 inherit toolchain-funcs
   6
   7 DESCRIPTION="a FUSE-based compressed read-only filesystem"
   8 HOMEPAGE="http://bisqwit.iki.fi/source/cromfs.html"
   9 SRC_URI="http://bisqwit.iki.fi/src/arch/${P}.tar.bz2"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~x86"
  14 IUSE="static"
  15
  16 DEPEND=">=sys-fs/fuse-2.5.2"
  17 RDEPEND="${DEPEND}"
  18
  19 src_unpack() {
  20         unpack ${A}
  21         cd "${S}"
  22         sed -i -e '/upx/d' -e '/strip/d' Makefile \
  23                 || die "sed failed in Makefile"
  24         for i in Makefile util/Makefile ; do
  25                 sed -i -e "/^CXXFLAGS +=/s:-O3::" \
  26                         -e "/OPTIM +=/s:-O3::" ${i} \
  27                 || die "sed failed in ${i}"
  28         done
  29         for i in Makefile.sets util/Makefile.sets ; do
  30                 sed -i -e "/^CC=/s:gcc:$(tc-getCC):" \
  31                         -e "/^CPP=/s:g++:$(tc-getCPP):" \
  32                         -e "/^CXX=/s:g++:$(tc-getCXX):" \
  33                         -e "/^CPPFLAGS=/s:-pipe -g::" \
  34                         -e "/^OPTIM/s:=.*:=${CXXFLAGS}:" \
  35                         -e "/^LDFLAGS/s:=.*:+=:" ${i} \
  36                 || die "sed failed in ${i}"
  37         done
  38 }
  39
  40 src_compile() {
  41         emake -j1 || die "emake failed"
  42 }
  43
  44 src_install() {
  45         use static && dobin cromfs-driver-static
  46         dobin cromfs-driver util/{mkcromfs,unmkcromfs,cvcromfs}
  47
  48         dodoc doc/*.txt doc/{FORMAT,ChangeLog}
  49         dohtml doc/*.{html,png}
  50 }