Pileus Git - ~andy/sunrise/blob - media-video/qnapi/qnapi-0.1.6_rc2.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="2"
   6 KDE_REQUIRED="optional"
   7 WANT_CMAKE="no"
   8
   9 inherit eutils gnome2-utils kde4-base qt4
  10
  11 MY_P=${P/_rc/-rc}
  12
  13 DESCRIPTION="Automatic subtitle downloader using Napiprojekt database"
  14 HOMEPAGE="http://krzemin.iglu.cz/software/qnapi"
  15 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
  16
  17 LICENSE="GPL-2"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE="gnome kde3"
  21
  22 S=${WORKDIR}/${MY_P}
  23
  24 DEPEND="x11-libs/qt-core
  25         x11-libs/qt-gui
  26         gnome? ( gnome-base/gconf )
  27         kde3? ( <kde-base/kdelibs-4 )"
  28 RDEPEND="${DEPEND}
  29         app-arch/p7zip"
  30
  31 # fix install paths, remove unneeded files, general cleanup
  32 PATCHES=( "${FILESDIR}/${P}-gentoo.diff" )
  33
  34 pkg_setup() {
  35         use kde && kde4-base_pkg_setup # get KDEDIR for KDE4
  36         qt4_pkg_setup
  37 }
  38
  39 src_configure() {
  40         local integr
  41
  42         use gnome && integr="gnome_integration"
  43         use kde && integr="${integr} kde4_integration"
  44         use kde3 && integr="${integr} konqueror_integration"
  45         # Dolphin for KDE3 is being dropped (bug #280633),
  46         # d3lphin isn't yet in portage.
  47
  48         KDE4DIR="${KDEDIR}" INTEGRATION_TARGETS="${integr}" eqmake4
  49 }
  50
  51 src_compile() {
  52         emake || die "emake failed."
  53 }
  54
  55 src_install() {
  56         emake INSTALL_ROOT="${D}" install || die "emake install failed."
  57
  58         prepalldocs || die "prepalldocs failed."
  59 }
  60
  61 pkg_preinst() {
  62         use gnome && gnome2_gconf_savelist
  63 }
  64
  65 pkg_postinst() {
  66         use gnome && gnome2_gconf_install
  67         use kde || use kde3 && kde4-base_pkg_postinst
  68 }
  69
  70 pkg_postrm() {
  71         use kde || use kde3 && kde4-base_pkg_postrm
  72 }