Pileus Git - ~andy/sunrise/blob - media-gfx/xaralx/xaralx-0.7_p1785.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="4"
   6
   7 WX_GTK_VER="2.8"
   8
   9 inherit eutils wxwidgets autotools gnome2
  10
  11 MY_P=XaraLX-${PV/_p/r}
  12
  13 DESCRIPTION="General purpose vector graphics program"
  14 HOMEPAGE="http://www.xaraxtreme.org/"
  15 SRC_URI="
  16         http://downloads.xara.com/opensource/${MY_P}.tar.bz2
  17         http://dev.gentoo.org/~jlec/distfiles/60_launchpad_translations.xz
  18         http://ompldr.org/vOWptaQ/${P}-pragma.patch"
  19
  20 LICENSE="GPL-2"
  21 SLOT="0"
  22 KEYWORDS="~amd64 ~x86"
  23 IUSE=""
  24
  25 RDEPEND="
  26         x11-libs/gtk+:2
  27         x11-libs/wxGTK:2.8[X]
  28         virtual/libintl
  29         media-libs/libpng
  30         virtual/jpeg
  31         app-arch/zip
  32         dev-lang/perl
  33         dev-libs/libxml2"
  34 DEPEND="${RDEPEND}
  35         dev-util/pkgconfig
  36         >=sys-devel/gettext-0.14.3"
  37
  38 S=${WORKDIR}/${MY_P/Src/}
  39
  40 src_prepare() {
  41         epatch \
  42                 "${WORKDIR}"/60_launchpad_translations \
  43                 "${DISTDIR}"/${P}-pragma.patch \
  44                 "${FILESDIR}"/{3,4,5}0*
  45         sed -i -e "s/CXFTreeDlg:://" Kernel/cxftree.h
  46         sed -i -e "s:XaraLX:xaralx:g" Makefile.am
  47         sed -i '/info_ptr->trans/s:trans:trans_alpha:' wxOil/outptpng.cpp
  48         AT_M4DIR=". ${S}/m4" eautoreconf
  49 }
  50
  51 src_configure() {
  52         econf \
  53                 --with-wx-config=${WX_CONFIG} \
  54                 --with-wx-base-config=${WX_CONFIG} \
  55                 --enable-xarlib \
  56                 --enable-filters
  57 }
  58
  59 src_install() {
  60         default
  61
  62         dodoc doc/{gifutil.txt,mtrand.txt,XSVG.txt}
  63
  64         insinto /usr/share/${PN}
  65         doins -r Designs Templates
  66
  67         doicon ${PN}.png
  68         domenu ${PN}.desktop
  69
  70         insinto /usr/share/icons/hicolor/48x48/mimetypes
  71         newins xaralx.png gnome-mime-application-vnd.xara.png
  72         insinto /usr/share/mime/packages
  73         doins Mime/xaralx.xml
  74         insinto /usr/share/application-registry
  75         doins Mime/mime-storage/gnome/xaralx.applications
  76         insinto /usr/share/mime-info
  77         doins Mime/mime-storage/gnome/xaralx.{keys,mime}
  78
  79         doman doc/xaralx.1
  80         newdoc doc/en/LICENSE LICENSE-docs
  81         dodir /usr/share/doc/${PF}/html
  82         tar xzf doc/en/xaralxHelp.tar.gz -C "${D}"/usr/share/doc/${PF}/html
  83 }