Pileus Git - ~andy/sunrise/blob - games-engines/openmw/openmw-0.13.0.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=3
   6
   7 inherit eutils cmake-utils flag-o-matic games
   8
   9 DESCRIPTION="An open source reimplementation of TES III: Morrowind"
  10 HOMEPAGE="http://openmw.org/"
  11 SRC_URI="http://${PN}.googlecode.com/files/${P}-source.tar.bz2"
  12
  13 LICENSE="GPL-3"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="mp3 ffmpeg"
  17
  18 RDEPEND=">=dev-games/ogre-1.7.0[cg,ois]
  19         dev-games/ois
  20         >=dev-libs/boost-1.46.0
  21         media-gfx/nvidia-cg-toolkit
  22         media-libs/freetype:2
  23         media-libs/openal
  24         sci-physics/bullet
  25         >=dev-qt/qtgui-4.7.0:4
  26         mp3? (
  27                 ffmpeg? ( media-video/ffmpeg[mp3] )
  28                 !ffmpeg? ( media-libs/libsndfile
  29                         media-sound/mpg123 )
  30         )"
  31 DEPEND="${RDEPEND}
  32         virtual/pkgconfig"
  33
  34 S=${WORKDIR}/${P}-source
  35
  36 src_prepare() {
  37         epatch "${FILESDIR}"/${P}-cmake.patch
  38
  39         sed \
  40                 -e "s#globalPath(\"/etc/\")#globalPath(\"${GAMES_SYSCONFDIR}\")#" \
  41                 -i components/files/linuxpath.cpp || die
  42 }
  43
  44 src_configure() {
  45         # QA
  46         append-flags -fno-strict-aliasing
  47
  48         local mycmakeargs
  49         if use mp3 ; then
  50                 use ffmpeg && mycmakeargs="-DUSE_FFMPEG=ON" || \
  51                         mycmakeargs="-DUSE_MPG123=ON"
  52         fi
  53
  54         mycmakeargs+=(
  55                 -DBINDIR="${GAMES_BINDIR}"
  56                 -DDATADIR="${GAMES_DATADIR}"/${PN}
  57                 -DSYSCONFDIR="${GAMES_SYSCONFDIR}"/${PN}
  58                 -DUSE_AUDIERE=OFF
  59         )
  60
  61         cmake-utils_src_configure
  62 }
  63
  64 src_install() {
  65         cmake-utils_src_install
  66         dodoc readme.txt || die
  67         prepgamesdirs
  68 }