Pileus Git - ~andy/sunrise/blob - dev-util/nvidia-texture-tools/nvidia-texture-tools-2.0.8-r1.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=4
   6
   7 inherit cmake-utils eutils multilib toolchain-funcs
   8
   9 DESCRIPTION="A set of cuda-enabled texture tools and compressors"
  10 HOMEPAGE="http://developer.nvidia.com/object/texture_tools.html"
  11 SRC_URI="http://${PN}.googlecode.com/files/${P}-1.tar.gz"
  12
  13 LICENSE="MIT"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="cg cuda glew glut openexr static-libs"
  17
  18 DEPEND="media-libs/libpng:0
  19         media-libs/ilmbase
  20         media-libs/tiff
  21         sys-libs/zlib
  22         virtual/jpeg
  23         virtual/opengl
  24         x11-libs/libX11
  25         cg? ( media-gfx/nvidia-cg-toolkit )
  26         cuda? ( dev-util/nvidia-cuda-toolkit )
  27         glew? ( media-libs/glew )
  28         glut? ( media-libs/freeglut )
  29         openexr? ( media-libs/openexr )
  30         "
  31 RDEPEND="${DEPEND}"
  32
  33 S=${WORKDIR}/${PN}
  34
  35 pkg_setup() {
  36         if use cuda; then
  37                 if [[ $(( $(gcc-major-version) * 10 + $(gcc-minor-version) )) -gt 44 ]] ; then
  38                         eerror "gcc 4.5 and up are not supported for useflag cuda!"
  39                         die "gcc 4.5 and up are not supported for useflag cuda!"
  40                 fi
  41         fi
  42 }
  43
  44 src_prepare() {
  45         epatch "${FILESDIR}"/gcc4.4.4-aliasing.patch \
  46                 "${FILESDIR}"/libpng1.5-build.patch \
  47                 "${FILESDIR}"/valgrind.patch \
  48                 "${FILESDIR}"/cuda.patch \
  49                 "${FILESDIR}"/libtiff4.patch \
  50                 "${FILESDIR}"/${PF}-cmake.patch
  51 }
  52
  53 src_configure() {
  54         local mycmakeargs=(
  55                 -DLIBDIR=$(get_libdir)
  56                 $(cmake-utils_use cg CG)
  57                 $(cmake-utils_use cuda CUDA)
  58                 $(cmake-utils_use glew GLEW)
  59                 $(cmake-utils_use glut GLUT)
  60                 $(cmake-utils_use openexr OPENEXR)
  61                 $(cmake-utils_use !static-libs NVTT_SHARED)
  62                 )
  63
  64         cmake-utils_src_configure
  65 }
  66
  67 src_install() {
  68         cmake-utils_src_install
  69
  70         dodoc ChangeLog
  71 }