Pileus Git - ~andy/sunrise/blob - dev-dotnet/f-sharp/f-sharp-2.0.0.0.ebuild

   1 # Copyright 1999-2010 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6
   7 inherit eutils mono
   8
   9 DESCRIPTION="The F# programming language and tools"
  10 HOMEPAGE="http://fsharp.net/"
  11 SRC_URI="http://download.microsoft.com/download/B/8/6/B869DF5B-B2C7-4125-8A1E-23CA77235048/fsharp.zip -> ${P}.zip"
  12
  13 LICENSE="MSR-SSLA"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE=""
  17
  18 RDEPEND=">=dev-lang/mono-2.6"
  19 DEPEND="app-arch/unzip
  20                 ${RDEPEND}"
  21
  22 S=${WORKDIR}/FSharp-${PV}
  23
  24 create_exe_wrappers() {
  25         ebegin "creating compiler wrappers"
  26
  27         for exe in fsi fsc; do
  28                 make_wrapper ${exe} "mono /usr/$(get_libdir)/${PN}/${exe}.exe" \
  29                         || die "couldn't create wrapper for ${exe}.exe"
  30         done
  31
  32         eend $?
  33 }
  34
  35 src_install() {
  36         insinto "/usr/$(get_libdir)/${PN}"
  37         doins bin/* || die "installing libraries failed"
  38
  39         local libname=bin/FSharp.Core.dll
  40
  41         # Sign $libname with the Mono key, per the instructions
  42         # in install-mono.sh.
  43         sn -q -R "${S}/${libname}" "${FILESDIR}/mono.snk" \
  44                 || die "couldn't sign the ${libname} assembly"
  45
  46         # After signing, this should work.
  47         egacinstall "${libname}" \
  48                 || die "couldn't install ${libname} in the global assembly cache"
  49
  50         create_exe_wrappers
  51 }