Pileus Git - ~andy/sunrise/blob - app-cdr/acetoneiso/acetoneiso-2.0.3_rc1.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6
   7 inherit eutils qt4
   8
   9 MY_P="${PN}_${PV/_rc/RC}"
  10
  11 DESCRIPTION="Graphical tool to do a lot things with image files like extracting, mounting, encrypting."
  12 HOMEPAGE="http://www.acetoneteam.org/"
  13 # switch back to the sf.net mirror later, if the tarball is also vailable there
  14 #SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
  15 SRC_URI="http://www.acetoneteam.org/download/${MY_P}.tar.gz"
  16
  17 LICENSE="GPL-3"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE="doc"
  21
  22 # remove the blocker after some time
  23 DEPEND="x11-libs/qt-gui
  24         x11-libs/qt-webkit
  25         !app-cdr/acetoneiso2"
  26 RDEPEND="${DEPEND}"
  27
  28 S="${WORKDIR}/${MY_P}/acetoneiso/"
  29
  30 src_prepare() {
  31         # Fix prestripping bug 221745
  32         epatch "${FILESDIR}/${PN}-nostrip.patch"
  33
  34         # unrar is called unrar-nonfree there
  35         sed -i -e 's:unrar-nonfree:unrar:g' sources/compress.h locale/*.ts \
  36                 || die "sed failed"
  37 }
  38
  39 src_configure() {
  40         eqmake4
  41 }
  42
  43 src_install() {
  44         emake INSTALL_ROOT="${D}" install || die "emake install failed"
  45
  46         dodoc ../{AUTHORS,CHANGELOG,FEATURES,README} || die "dodoc failed"
  47
  48         if use doc; then
  49                 dohtml -r manual/* || die "dohtml failed"
  50         fi
  51 }
  52
  53 pkg_postinst() {
  54         elog
  55         elog "The following packages will give ${PN} extended functionality:"
  56
  57         elog "Filemanager:"
  58         elog "\tkde-base/dolphin"
  59         elog "\tkde-base/konqueror"
  60         elog "\tgnome-base/nautilus"
  61
  62         elog "Video player:"
  63         elog "\tmedia-video/mplayer"
  64         elog "\tmedia-video/smplayer"
  65         elog "\tmedia-video/kaffeine"
  66         elog "\tmedia-video/vlc"
  67
  68         elog "Image mounting:"
  69         elog "\tsys-fs/fuse"
  70         elog "\tsys-fs/fuseiso"
  71
  72         elog "Image encryption:"
  73         elog "\t>=app-crypt/gnupg-2"
  74
  75         elog "Image compression:"
  76         elog "\tapp-arch/p7zip"
  77         elog "\tapp-arch/unrar"
  78
  79         elog "Encoding:"
  80         elog "\tmedia-video/ffmpeg"
  81         elog "\tmedia-sound/lame"
  82         elog "\tmedia-video/mplayer (mencoder)"
  83
  84         elog "Device info:"
  85         elog "\tsys-apps/hal"
  86
  87         elog "CD/DVD burning, image creation etc.:"
  88         elog "\tapp-cdr/cdrkit"
  89         elog "\tapp-cdr/cdrdao"
  90         elog "\tmedia-sound/cdparanoia"
  91
  92         elog "Additional tools which are not in the portage tree:"
  93         elog "\tgeteltorito - http://www.uni-koblenz.de/~krienke/ftp/noarch/geteltorito/"
  94         elog "\tciso - http://ciso.tenshu.fr/"
  95
  96         elog
  97         elog "for further informations see README"
  98         elog
  99 }