Pileus Git - ~andy/rsl/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(rsl, 1.42)
   3 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability foreign])
   4
   5 AM_INIT_AUTOMAKE
   6 AM_CONFIG_HEADER(config.h)
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 # Checks for programs.
  10 AC_PROG_CC
  11 AM_PROG_LIBTOOL
  12 AM_PROG_LEX
  13 AC_PROG_YACC
  14 AC_PROG_LN_S
  15
  16 # Checks for header files.
  17 AC_HEADER_STDC
  18 AC_HEADER_SYS_WAIT
  19 AC_CHECK_HEADERS(fcntl.h malloc.h strings.h unistd.h)
  20
  21 # Checks for typedefs, structures, and compiler characteristics.
  22 AC_C_CONST
  23 AC_TYPE_SIZE_T
  24 AC_STRUCT_TM
  25
  26 # Checks for library functions.
  27 # AC_FUNC_SETVBUF_REVERSED
  28 AC_CHECK_FUNCS(mktime strdup strstr)
  29
  30 # I would like lassen to be defined.  Override this in config.h.
  31 AC_DEFINE(HAVE_LASSEN, 1,
  32     [For LASSEN capability.  Change this to '#undef HAVE_LASSEN', if you
  33      dont want LASSEN.])
  34
  35 # Checks for libraries.
  36 if test $prefix = NONE; then
  37   prefix=$ac_default_prefix
  38 fi
  39 LIBDIR="-L$prefix/lib"
  40 LIBS="-lz -lm"
  41
  42 # The order of the libraries is important.
  43 # This works:
  44 #   -lrsl -limplode -ltsdistk -lmfhdf -ldf -ljpeg -lz -lm
  45 #
  46 # If mounting with shared libraries we may have to specify all possible libraries.
  47 # First check with simple LIBS list, if it fails, then expand the list.
  48
  49 AC_CHECK_LIB(implode,  _implode,           ,,$LIBDIR)
  50 AC_CHECK_LIB(jpeg,     jpeg_CreateCompress,,,$LIBDIR)
  51 AC_CHECK_LIB(df,       DFopen,             ,,$LIBDIR)
  52 AC_CHECK_LIB(mfhdf,    SDstart,            ,,$LIBDIR)
  53 AC_CHECK_LIB(tsdistk,  TKopen,             ,,$LIBDIR)
  54
  55 # Check if yywrap is defined in toolkit, and add $LEXLIB to LIBS if not.
  56 YYWRAP=""
  57 AC_CHECK_LIB(tsdistk,  yywrap, YYWRAP="yes",,$LIBDIR)
  58 if test "$YYWRAP" = ""; then
  59         LIBS="$LIBS $LEXLIB"
  60 fi
  61
  62 # Test for Windows vs. Unix
  63 case "${host}" in
  64         *mingw32*) SYS="WIN"  ;;
  65         *cygwin*)  SYS="WIN"  ;;
  66         *)         SYS="UNIX" ;;
  67 esac
  68 AC_SUBST([SYS])
  69 AM_CONDITIONAL([SYS_WIN],  test "$SYS" = "WIN")
  70 AM_CONDITIONAL([SYS_UNIX], test "$SYS" = "UNIX")
  71
  72 # Check for relative build
  73 AC_ARG_ENABLE(relative, [AS_HELP_STRING([--enable-relative],
  74         [enable runtime search paths @<:@default=no@:>@])],
  75         [DOTS=".."; ac_default_prefix="/"])
  76 AC_SUBST([DOTS])
  77
  78 AC_MSG_RESULT(LIBS = $LIBS)
  79 AC_CONFIG_FILES([Makefile doc/Makefile data/Makefile examples/Makefile src/Makefile])
  80 AC_OUTPUT