Pileus Git - ~andy/rhawk/blob - rhawk

   1 #!awk -f
   2
   3 @include "irc.awk"
   4 @include "spades.awk"
   5 @include "email.awk"
   6
   7 # Initialization
   8 BEGIN {
   9         OWNER = "andy753421"
  10         connect("localhost", "rhawk", "#rhtest");
  11         if (FIRST) {
  12                 join("#rhnoise")
  13                 join("#rhspades")
  14                 join("#sfvlug")
  15         }
  16 }
  17
  18 # Admin
  19 FROM == OWNER && TO == NICK && /^die in a fire/ {
  20         say("Ack, argh, barasdjf..")
  21         quit()
  22 }
  23
  24 FROM == OWNER && TO == NICK && /^reload/ {
  25         say("Reloading..")
  26         reload()
  27 }
  28
  29 FROM == OWNER && TO == NICK && /^rejoin/ {
  30         reply("joining..")
  31         join("#rhnoise")
  32         next
  33 }
  34
  35 FROM == OWNER && TO == NICK && /^(join|part)/ {
  36         match(MSG, /(join|part) +(#+\w+)/, arr)
  37         if (arr[1] && arr[2]) {
  38                 send(toupper(arr[1]) " " arr[2]);
  39                 next
  40         }
  41 }
  42
  43 FROM == OWNER && TO == NICK && /^\.msg/ {
  44         match(MSG, /.*\.msg +(#*\w+) +(.*)/, arr)
  45         send("PRIVMSG " arr[1] " :" arr[2])
  46 }
  47
  48 # Kick handling
  49 CMD == "KICK" && ARG == NICK {
  50         kick_delay = (kick_delay + 2) * 2
  51         system("sleep " kick_delay)
  52         join(DST)
  53         reply("I feel happy!")
  54 }
  55
  56 # Identify bots
  57 FROM ~ /bo+t$|rhnoise/ {
  58         bots[FROM] = 1
  59 }
  60
  61 CMD == "NICK" && FROM in bots {
  62         bots[MSG] = FROM
  63 }
  64
  65
  66 # Unicode
  67 /[Uu]nicode :-?\(/ {
  68         plain[FROM] = 1
  69 }
  70
  71 /[Uu]nicode :-?\)/ {
  72         plain[FROM] = 0
  73 }
  74
  75 # SFV Lug
  76 BEGIN { pollchan = "#sfvlug" }
  77 (CMD == "PING"    && systime()-lastpoll > 60*60*24) ||
  78 (CMD == "PRIVMSG" && DST == pollchan && /^\.poll/) {
  79         if (!topics[pollchan]) {
  80                 debug("Unknown topic for " pollchan);
  81                 next
  82         }
  83         _curl     = "curl -s http://sfvlug.org/"
  84         _day      = "(Sun|Mon|Tue|Wed|Thu|Fri|Sat)"
  85         _web_ptrn = "next meeting.*" _day "\\w+[, ]+([A-Z]\\w+) +([0-9]+)[, ]+([0-9]+)"
  86         _irc_ptrn = _day "\\w*[, ]+([A-Z]\\w+) +([0-9]+)"
  87         while (_curl | getline _line) {
  88                 if (match(_line, _web_ptrn, _parts)) {
  89                         _date  = _parts[1] " " _parts[2] " " _parts[3]
  90                         _topic = topics[pollchan]
  91                         sub(_irc_ptrn, _date, _topic)
  92                         if (_topic != topics[pollchan])
  93                                 topic(pollchan, topics[pollchan] = _topic)
  94                         else
  95                                 debug("topic is already correct")
  96                         break
  97                 }
  98         }
  99         lastpoll = systime()
 100         close(cmd)
 101 }
 102
 103 # Fortune
 104 TO == NICK && /^/               { extra = ""   }
 105 TO == NICK && /^\.?fortune.*-o/ { extra = "-o" }
 106 TO == NICK && /^\.?fortune/     {
 107         gsub(/.*\.?fortune *|-[a-z]* *|[^a-zA-Z0-9 ]/, "", MSG)
 108         cmd = "fortune " extra " " (MSG ? "-m '" MSG "'" : "-s")
 109         _lines = 0
 110         while (cmd | getline _fortune && _lines < 5) {
 111                 say(_fortune)
 112                 _lines++
 113         }
 114         close(cmd)
 115         next
 116 }
 117
 118 # Noise
 119 FROM ~ OWNER && /^go go gadget woop/ {
 120         for (i=20; i>0; i--)
 121                 say(".delay " i " seconds; .woop " i)
 122 }
 123
 124 TO == NICK && /^[Ww][Oo]+[Pp]/ {
 125         gsub(/[^Oo]/, "", $1)
 126         _len = length($1)
 127         if (_len == 2)
 128                 _len = 10
 129         _woop = "WOOP"
 130         for (i=1; i<_len; i++)
 131                 _woop = _woop " WOOP"
 132         say(_woop)
 133 }
 134
 135 TO == NICK && DST ~ /^#/ {
 136         #say("Hello, " FROM)
 137 }
 138
 139 !(FROM in bots) &&
 140 MSG !~ /^\./ &&
 141 /awk/ {
 142         say("Awk, awk, awk! I'm a bird!")
 143 }
 144
 145 !(FROM in bots) &&
 146 /^[^.](help|halp)/ {
 147         reply("Nothing can help you now..")
 148 }
 149
 150 /Ho.*Ho.*Ho/ {
 151         say("\00309Merry \00304Christmas!")
 152 }
 153
 154 { fflush("") }
 155
 156 # vim: ft=awk