Pileus Git - ~andy/rhawk/blob - rhawk

   1 #!awk -f
   2
   3 @include "irc.awk"
   4 @include "spades.awk"
   5 #@include "email.awk"
   6
   7 # Initialization
   8 BEGIN {
   9         OWNER = "andy753421"
  10         connect("localhost", "rhawk", "#rhtest");
  11         if (FIRST) {
  12                 join("#rhnoise")
  13                 join("#rhspades")
  14                 join("#sfvlug")
  15         }
  16 }
  17
  18 # Admin
  19 FROM == OWNER && TO == NICK && /^die in a fire/ {
  20         say("Ack, argh, barasdjf..")
  21         quit()
  22 }
  23
  24 FROM == OWNER && TO == NICK && /^reload/ {
  25         say("Reloading..")
  26         reload()
  27 }
  28
  29 FROM == OWNER && TO == NICK && /^rejoin/ {
  30         reply("joining..")
  31         join("#rhnoise")
  32         next
  33 }
  34
  35 FROM == OWNER && TO == NICK && /^(join|part)/ {
  36         match(MSG, /(join|part) +(#+\w+)/, arr)
  37         if (arr[1] && arr[2]) {
  38                 send(toupper(arr[1]) " " arr[2]);
  39                 next
  40         }
  41 }
  42
  43 FROM == OWNER && TO == NICK && /^\.msg/ {
  44         match(MSG, /.*\.msg +(#*\w+) +(.*)/, arr)
  45         send("PRIVMSG " arr[1] " :" arr[2])
  46 }
  47
  48 # Kick handling
  49 CMD == "KICK" && ARG == NICK {
  50         kick_delay = (kick_delay + 2) * 2
  51         system("sleep " kick_delay)
  52         join(DST)
  53         reply("I feel happy!")
  54 }
  55
  56 # Identify bots
  57 FROM ~ /bo+t$|rhnoise/ {
  58         bots[FROM] = 1
  59 }
  60
  61 CMD == "NICK" && FROM in bots {
  62         bots[MSG] = FROM
  63 }
  64
  65
  66 # Unicode
  67 /[Uu]nicode :-?\(/ {
  68         plain[FROM] = 1
  69 }
  70
  71 /[Uu]nicode :-?\)/ {
  72         plain[FROM] = 0
  73 }
  74
  75 # SFV Lug
  76 function email(to, from, subj, body, sendmail)
  77 {
  78         from     = NICK "<andy@pileus.org>"
  79         subj     = "Update sfvlug.org!"
  80         body     = "The next SFVLUG meeting is TBA!"
  81         sendmail = "/usr/sbin/sendmail '" to "'"
  82         print "To: " to        | sendmail
  83         print "From: " from    | sendmail
  84         print "Subject: " subj | sendmail
  85         print ""               | sendmail
  86         print body             | sendmail
  87         say("Topic out of date, emailing " to);
  88         close(sendmail)
  89 }
  90
  91 BEGIN { pollchan = "#sfvlug" }
  92 #(CMD == "TOPIC"   && systime()-lastpoll > 60*60*24) ||
  93 (CMD == "PING"    && systime()-lastpoll > 60*60*24) ||
  94 (CMD == "PRIVMSG" && /^\.poll/) {
  95         if (!topics[pollchan]) {
  96                 debug("Unknown topic for " pollchan);
  97                 send("TOPIC " pollchan)
  98                 next
  99         }
 100         _curl     = "curl -s http://sfvlug.org/"
 101         _day      = "(Sun|Mon|Tue|Wed|Thu|Fri|Sat)"
 102         _web_tba  = "next meeting is: TBA"
 103         _web_ptrn = "next meeting.*" _day "\\w+[, ]+([A-Z]\\w+) +([0-9]+)[, ]+([0-9]+)"
 104         _irc_ptrn = _day "\\w*[, ]+([A-Z]\\w+) +([0-9]+)"
 105         while (_curl | getline _line) {
 106                 if (match(_line, _web_tba))
 107                         email("Brian <brian@zimage.com>");
 108                 if (match(_line, _web_ptrn, _parts)) {
 109                         _date  = _parts[1] " " _parts[2] " " _parts[3]
 110                         _topic = topics[pollchan]
 111                         sub(_irc_ptrn, _date, _topic)
 112                         if (_topic != topics[pollchan])
 113                                 topic(pollchan, topics[pollchan] = _topic)
 114                         else
 115                                 debug("topic is already correct")
 116                         break
 117                 }
 118         }
 119         lastpoll = systime()
 120         close(cmd)
 121 }
 122
 123 # Uptime
 124 function uptime(time,  fmt) {
 125         fmt = "%d:%02d:%02d:%02d"
 126         fmt = "%d days %02d:%02d:%02d"
 127         return sprintf(fmt,
 128                 time / (60*60*24),
 129                 time / (60*60   ) % 24,
 130                 time / (60      ) % 60,
 131                 time / (1       ) % 60)
 132 }
 133 BEGIN {
 134         up_reload = systime();
 135 }
 136 /^\.uptime/ {
 137         _now = systime();
 138         say("uptime: " uptime(_now - START) ", " \
 139             "reload: " uptime(_now - up_reload))
 140 }
 141
 142 # Fortune
 143 TO == NICK && /^/               { extra = ""   }
 144 TO == NICK && /^\.?fortune.*-o/ { extra = "-o" }
 145 TO == NICK && /^\.?fortune/     {
 146         gsub(/.*\.?fortune *|-[a-z]* *|[^a-zA-Z0-9 ]/, "", MSG)
 147         cmd = "fortune " extra " " (MSG ? "-m '" MSG "'" : "-s")
 148         _lines = 0
 149         while (cmd | getline _fortune && _lines < 5) {
 150                 say(_fortune)
 151                 _lines++
 152         }
 153         close(cmd)
 154         next
 155 }
 156
 157 # Noise
 158 FROM ~ OWNER && /^go go gadget woop/ {
 159         for (i=20; i>0; i--)
 160                 say(".delay " i " seconds; .woop " i)
 161 }
 162
 163 function woop(msg) {
 164         gsub(/[^Oo]/, "", $1)
 165         _len = length($1)
 166         if (_len == 2)
 167                 _len = 10
 168         if ($2)
 169                 _len = $2
 170         _woop = msg
 171         for (i=1; i<_len; i++)
 172                 _woop = _woop " " msg
 173         say(_woop)
 174 }
 175
 176 TO == NICK && /^[Ww][Oo]+[Pp] *([0-9]*)/ {
 177         woop("WOOP")
 178 }
 179
 180 /^~WOOP *([0-9]*)/ {
 181         woop("(00/")
 182 }
 183
 184 /^~woop *([0-9]*)/ {
 185         woop("^H^P^P^O")
 186 }
 187
 188 TO == NICK && DST ~ /^#/ {
 189         #say("Hello, " FROM)
 190 }
 191
 192 #DST != "#sfvlug" &&
 193 !(FROM in bots) &&
 194 MSG !~ /^\./ &&
 195 /awk/ {
 196         say("Awk, awk, awk! I'm a bird!")
 197 }
 198
 199 !(FROM in bots) &&
 200 ((TO == NICK && /(help|halp)/) ||
 201  /^[^.](help|halp)/) {
 202         reply("Nothing can help you now..")
 203 }
 204
 205 /(\<[Hh][Oo]\>.*){3}/ {
 206         say("\00309Merry \00304Christmas!")
 207 }
 208
 209 !(FROM in bots) &&
 210 tolower($0) ~ /\<cloud\>/ {
 211         _cmd = "shuf clouds.txt"
 212         _cmd | getline _cloud
 213         close(_cmd)
 214         say(_cloud)
 215 }
 216
 217 /^headshot [Cc]hristmas/ {
 218         say(".load Christmas")
 219         say(".jingle")
 220         say(".unload Christmas")
 221 }
 222
 223 FROM == "rhnoise" && $2 == "slaps" && $3 == NICK {
 224         say(".spin")
 225 }
 226
 227 /^[Aa]nd now[.,]/ {
 228         say("And now...");
 229         say("THE LARCH");
 230 }
 231
 232 # God damn commands
 233 FROM == "rhnoise" && load_mod {
 234         say(".load " load_mod)
 235         say("rhnoise: You slag!")
 236 }
 237 // {
 238         load_mod = ""
 239 }
 240 (TO  ==  "rhnoise" && /^load \w+/) ||
 241 (DST == "#rhniose" && /^\.load [a-z]\w+/) {
 242         gsub(/[^a-zA-Z0-9_]/, " ")
 243         load_mod = toupper(substr($2,1,1)) substr($2,2);
 244 }
 245
 246 (DST == "#rhnoise" && /^\.line /) {
 247         sub(/\./, "!");
 248         say($0);
 249         say("scalawag: You slag!")
 250 }
 251
 252 (DST == "#rhnoise" && /^\.qdb 268$/) {
 253         say(".diediedie");
 254         next
 255 }
 256 (DST == "#rhnoise" && /\.qdb *268/) {
 257         say(".slap " FROM);
 258         next
 259 }
 260
 261 # Misc
 262 { fflush("") }
 263
 264 # vim: ft=awk