Pileus Git - ~andy/rhawk/blob - rhawk

   1 #!awk -f
   2
   3 @include "irc.awk"
   4 @include "json.awk"
   5 @include "spades.awk"
   6 #@include "email.awk"
   7
   8 # Initialization
   9 BEGIN {
  10         json_load("var/login.json",     login);
  11         json_load("var/nounicode.json", nounicode);
  12         json_load("var/nocolor.json",   nocolor);
  13
  14         OWNER = login["owner"];
  15
  16         connect(login["server"],  \
  17                 login["nick"],    \
  18                 login["channel"], \
  19                 login["auth"],    \
  20                 login["pass"])
  21
  22         delete login
  23
  24         if (FIRST) {
  25                 join("#rhtest")
  26                 join("#rhspades")
  27                 join("#sfvlug")
  28         }
  29 }
  30
  31 # Admin
  32 AUTH == OWNER && TO == NICK && /^die in a fire/ {
  33         say("Ack, argh, barasdjf..")
  34         quit()
  35 }
  36
  37 AUTH == OWNER && TO == NICK && /^reload/ {
  38         say("Reloading..")
  39         reload()
  40 }
  41
  42 AUTH == OWNER && TO == NICK && /^rejoin/ {
  43         reply("joining..")
  44         join("#rhnoise")
  45         next
  46 }
  47
  48 AUTH == OWNER && TO == NICK && /^(join|part)/ {
  49         if (match(MSG, /(join|part) +(#+\w+)/, arr)) {
  50                 if (arr[1] == "join") join(arr[2]);
  51                 if (arr[1] == "part") part(arr[2]);
  52                 next
  53         }
  54 }
  55
  56 AUTH == OWNER && TO == NICK && /^\.msg/ {
  57         match(MSG, /.*\.msg +(#*\w+) +(.*)/, arr)
  58         send("PRIVMSG " arr[1] " :" arr[2])
  59 }
  60
  61 # Kick handling
  62 CMD == "KICK" && ARG[2] == NICK {
  63         kick_delay = (kick_delay + 2) * 2
  64         system("sleep " kick_delay)
  65         join(DST)
  66         reply("I feel happy!")
  67 }
  68
  69 # Identify bots
  70 FROM ~ /bo+t$|rhnoise/ {
  71         bots[FROM] = 1
  72 }
  73
  74 CMD == "NICK" && FROM in bots {
  75         bots[MSG] = FROM
  76 }
  77
  78
  79 # Fancy output
  80 /[Uu]nicode :-?\(/ {
  81         nounicode[FROM] = 1
  82         json_save("var/nounicode.json", nounicode);
  83 }
  84
  85 /[Uu]nicode :-?\)/ {
  86         delete nounicode[FROM]
  87         json_save("var/nounicode.json", nounicode);
  88 }
  89
  90 /[Cc]olors :-?\(/ {
  91         nocolor[FROM] = 1
  92         json_save("var/nocolor.json", nocolor);
  93 }
  94
  95 /[Cc]olors :-?\)/ {
  96         delete nocolor[FROM]
  97         json_save("var/nocolor.json", nocolor);
  98 }
  99
 100 # SFV Lug
 101 function email(to, from, subj, body, sendmail)
 102 {
 103         from     = NICK "<andy@pileus.org>"
 104         subj     = "Update sfvlug.org!"
 105         body     = "The next SFVLUG meeting is TBA!"
 106         sendmail = "/usr/sbin/sendmail '" to "'"
 107         print "To: " to        | sendmail
 108         print "From: " from    | sendmail
 109         print "Subject: " subj | sendmail
 110         print ""               | sendmail
 111         print body             | sendmail
 112         say("Topic out of date, emailing " to);
 113         close(sendmail)
 114 }
 115
 116 BEGIN { pollchan = "#sfvlug" }
 117 (CMD == "PING"    && systime()-lastpoll > 60*60*24) ||
 118 (CMD == "PRIVMSG" && /^\.poll/) {
 119         if (!TOPICS[pollchan]) {
 120                 debug("Unknown topic for " pollchan);
 121                 send("TOPIC " pollchan)
 122                 next
 123         }
 124         _curl     = "curl -s http://sfvlug.org/"
 125         _day      = "(Sun|Mon|Tue|Wed|Thu|Fri|Sat)"
 126         _web_tba  = "next meeting is: TBA"
 127         _web_ptrn = "next meeting.*" _day "\\w+[, ]+([A-Z]\\w+) +([0-9]+)[, ]+([0-9]+)"
 128         _irc_ptrn = _day "\\w*[, ]+([A-Z]\\w+) +([0-9]+)"
 129         while (_curl | getline _line) {
 130                 #if (match(_line, _web_tba))
 131                 #       email("Brian <brian@zimage.com>");
 132                 if (match(_line, _web_ptrn, _parts)) {
 133                         _date  = _parts[1] " " _parts[2] " " _parts[3]
 134                         _topic = TOPICS[pollchan]
 135                         sub(_irc_ptrn, _date, _topic)
 136                         if (_topic != TOPICS[pollchan])
 137                                 topic(pollchan, TOPICS[pollchan] = _topic)
 138                         else
 139                                 debug("topic is already correct")
 140                         break
 141                 }
 142         }
 143         lastpoll = systime()
 144         close(_curl)
 145 }
 146
 147 # Versin/Uptime
 148 function head(cmd, var) {
 149         cmd | getline var
 150         close(cmd)
 151         return var
 152 }
 153 function uptime(time,  fmt) {
 154         fmt = "%d:%02d:%02d:%02d"
 155         fmt = "%d days %02d:%02d:%02d"
 156         return sprintf(fmt,
 157                 time / (60*60*24),
 158                 time / (60*60   ) % 24,
 159                 time / (60      ) % 60,
 160                 time / (1       ) % 60)
 161 }
 162 BEGIN {
 163         up_version = head("git describe --always --dirty")
 164         up_author  = head("git log -n1 --format=format:%an")
 165         up_message = head("git log -n1 --format=format:%s")
 166         up_reload  = systime();
 167 }
 168 /^\.(version|rev)/ {
 169         say("version: " up_version " - " up_author " - " up_message)
 170 }
 171 /^\.uptime/ {
 172         _now = systime();
 173         say("uptime: " uptime(_now - START) ", " \
 174             "reload: " uptime(_now - up_reload))
 175 }
 176
 177 # Auth info
 178 /^\.auth/ {
 179         _who = $2 ? $2 : FROM
 180         if (_who in USERS)
 181                 say("nick=" USERS[_who]["nick"] " " \
 182                     "user=" USERS[_who]["user"] " " \
 183                     "auth=" USERS[_who]["auth"] " " \
 184                     "real=" USERS[_who]["real"] " " \
 185                     "host=" USERS[_who]["host"])
 186         else
 187                 say("no auth info for " _who)
 188 }
 189
 190 # GeoIP Lookup
 191 function geoip(ip,  dat, cmd, line, parts) {
 192         dat = "/usr/share/GeoIP/GeoIPCity.dat"
 193
 194         cmd = "geoiplookup -f " dat " " ip
 195         cmd | getline line
 196         close(cmd)
 197
 198         if (split(line, parts, /[:,] /) >= 9)
 199                 return parts[8] ","  parts[9] " -- " \
 200                        parts[6] ", " parts[4] ", " parts[3] " -- " ip
 201         else
 202                 return "not found -- " ip
 203 }
 204
 205 /^\.geoip (([0-9a-zA-Z_.-]+) *)*$/ {
 206         for (_i=2; _i<=NF; _i++)
 207                 say(geoip($_i))
 208 }
 209
 210 # Fortune
 211 TO == NICK && /^/               { extra = ""   }
 212 TO == NICK && /^\.?fortune.*-o/ { extra = "-o" }
 213 TO == NICK && /^\.?fortune/     {
 214         gsub(/.*\.?fortune *|-[a-z]* *|[^a-zA-Z0-9 ]/, "", MSG)
 215         cmd = "fortune " extra " " (MSG ? "-m '" MSG "'" : "-s")
 216         _lines = 0
 217         while (cmd | getline _fortune && _lines < 5) {
 218                 say(_fortune)
 219                 _lines++
 220         }
 221         close(cmd)
 222         next
 223 }
 224
 225 /\<[Bb][Oo][Ff][Hh]\>/ {
 226         _cmd = "fortune bofh-excuses"
 227         _cmd | getline _fortune
 228         _cmd | getline _fortune
 229         _cmd | getline _fortune
 230         close(_cmd)
 231         say(_fortune)
 232         next
 233 }
 234
 235 # Morse code
 236 BEGIN {
 237         morse["/"      ] = " "
 238         morse[".-.-.-" ] = "."
 239         morse["--..--" ] = ","
 240         morse["..--.." ] = "?"
 241         morse[".----." ] = "'"
 242         morse["-.-.--" ] = "!"
 243         morse["-..-."  ] = "/"
 244         morse["-.--."  ] = "("
 245         morse["-.--.-" ] = ")"
 246         morse[".-..."  ] = "&"
 247         morse["---..." ] = ":"
 248         morse["-.-.-." ] = ";"
 249         morse["-...-"  ] = "="
 250         morse[".-.-."  ] = "+"
 251         morse["-....-" ] = "-"
 252         morse["..--.-" ] = "_"
 253         morse[".-..-." ] = "\""
 254         morse["...-..-"] = "$"
 255         morse[".--.-." ] = "@"
 256         morse[".-"     ] = "a"
 257         morse["-..."   ] = "b"
 258         morse["-.-."   ] = "c"
 259         morse["-.."    ] = "d"
 260         morse["."      ] = "e"
 261         morse["..-."   ] = "f"
 262         morse["--."    ] = "g"
 263         morse["...."   ] = "h"
 264         morse[".."     ] = "i"
 265         morse[".---"   ] = "j"
 266         morse["-.-"    ] = "k"
 267         morse[".-.."   ] = "l"
 268         morse["--"     ] = "m"
 269         morse["-."     ] = "n"
 270         morse["---"    ] = "o"
 271         morse[".--."   ] = "p"
 272         morse["--.-"   ] = "q"
 273         morse[".-."    ] = "r"
 274         morse["..."    ] = "s"
 275         morse["-"      ] = "t"
 276         morse["..-"    ] = "u"
 277         morse["...-"   ] = "v"
 278         morse[".--"    ] = "w"
 279         morse["-..-"   ] = "x"
 280         morse["-.--"   ] = "y"
 281         morse["--.."   ] = "z"
 282         morse["-----"  ] = "0"
 283         morse[".----"  ] = "1"
 284         morse["..---"  ] = "2"
 285         morse["...--"  ] = "3"
 286         morse["....-"  ] = "4"
 287         morse["....."  ] = "5"
 288         morse["-...."  ] = "6"
 289         morse["--..."  ] = "7"
 290         morse["---.."  ] = "8"
 291         morse["----."  ] = "9"
 292 }
 293
 294 /^\.morse/ {
 295         gsub(/[^.\-\/]/, " ")
 296         _str = ""
 297         for (i=2; i<=NF; i++)
 298                 if ($i in morse)
 299                         _str = _str morse[$i]
 300         if (_str)
 301                 reply(_str)
 302         else
 303                 reply("hush it, you pile of bologna")
 304 }
 305
 306 # Noise
 307 AUTH == OWNER && /^go go gadget woop/ {
 308         for (i=20; i>0; i--)
 309                 say(".delay " i " seconds; .woop " i)
 310 }
 311
 312 function woop(msg) {
 313         gsub(/[^Oo]/, "", $1)
 314         _len = length($1)
 315         if (_len == 2)
 316                 _len = 10
 317         if ($2)
 318                 _len = $2
 319         _woop = msg
 320         for (i=1; i<_len; i++)
 321                 _woop = _woop " " msg
 322         say(_woop)
 323 }
 324
 325 TO == NICK && /^[Ww][Oo]+[Pp] *([0-9]*)/ {
 326         woop("WOOP")
 327 }
 328
 329 /^~WOOP *([0-9]*)/ {
 330         woop("(00/")
 331 }
 332
 333 /^~woop *([0-9]*)/ {
 334         woop("^H^P^P^O")
 335 }
 336
 337 TO == NICK && DST ~ /^#/ {
 338         #say("Hello, " FROM)
 339 }
 340
 341 /^\.nestroyeti/ {
 342         say(sprintf("Temperature: %4.1f F Humidity: %2d%%",
 343                 rand()*20+65, rand()*20+40))
 344 }
 345
 346 #DST != "#sfvlug" &&
 347 !(FROM in bots) &&
 348 CMD == "PRIVMSG" &&
 349 MSG !~ /^\./ &&
 350 /awk/ {
 351         say("Awk, awk, awk! I'm a bird!")
 352 }
 353
 354 !(FROM in bots) &&
 355 ((TO == NICK && /(help|halp)/) ||
 356  /^[^.](help|halp)/) {
 357         reply("Nothing can help you now..")
 358 }
 359
 360 /(\<[Hh][Oo]\>.*){3}/ {
 361         say("\00309Merry \00304Christmas!")
 362 }
 363
 364 !(FROM in bots) &&
 365 tolower($0) ~ /\<cloud\>/ {
 366         _cmd = "shuf clouds.txt"
 367         _cmd | getline _cloud
 368         close(_cmd)
 369         say(_cloud)
 370 }
 371
 372 /^headshot [Cc]hristmas/ {
 373         say(".load Christmas")
 374         say(".jingle")
 375         say(".unload Christmas")
 376 }
 377
 378 FROM == "rhnoise" && $2 == "slaps" && $3 == NICK {
 379         say(".spin")
 380 }
 381
 382 /^[Aa]nd now[.,]/ {
 383         say("And now...");
 384         say("THE LARCH");
 385 }
 386
 387 /(for what|that for)\?$/ {
 388         say("For great justice!");
 389 }
 390
 391 /\<nazi/ {
 392         say("And now it's...");
 393         say("Springtime for Hitler and Germany!");
 394 }
 395
 396 # God damn commands
 397 FROM == "rhnoise" && load_mod {
 398         say(".load " load_mod)
 399         say("rhnoise: You slag!")
 400 }
 401 // {
 402         load_mod = ""
 403 }
 404 (TO  ==  "rhnoise" && /^load \w+/) ||
 405 (DST == "#rhniose" && /^\.load [a-z]\w+/) {
 406         gsub(/[^a-zA-Z0-9_]/, " ")
 407         load_mod = toupper(substr($2,1,1)) substr($2,2);
 408 }
 409
 410 (DST == "#rhnoise" && /^\.line /) {
 411         sub(/\./, "!");
 412         say($0);
 413         say("scalawag: You slag!")
 414 }
 415
 416 (DST == "#rhnoise" && /^\.qdb 268$/) {
 417         say(".diediedie");
 418         next
 419 }
 420 (DST == "#rhnoise" && /\.qdb *268/) {
 421         say(".slap " FROM);
 422         next
 423 }
 424
 425 # Decrementer
 426 BEGIN {
 427         user_scores[0] = 1;
 428         delete user_scores
 429 }
 430
 431 /^\.(scores|scoreboard)$/ {
 432         delete user_scores
 433 }
 434
 435 FROM == "rhnoise" && !length(user_scores) {
 436         if (split(MSG, _parts, /, /)) {
 437                 for (_i=1; _i<=length(_parts); _i++) {
 438                         split(_parts[_i], _tmp, ": ");
 439                         user_scores[_i]["user"]  = _tmp[1];
 440                         user_scores[_i]["score"] = _tmp[2];
 441                 }
 442         }
 443 }
 444
 445 length(user_scores) &&
 446 tolower($0) ~ /\<nuclear launch detected\>/ {
 447         _count = 0;
 448         for (_i=1; _i<=length(user_scores); _i++) {
 449                 _user  = user_scores[_i]["user"];
 450                 _score = user_scores[_i]["score"];
 451                 if (_user in USERS) continue
 452                 if (_score ==  1) { say(_user "--"); _count++; }
 453                 if (_score == -1) { say(_user "++"); _count++; }
 454         }
 455         if (_count) {
 456                 delete user_scores;
 457                 say(".scores");
 458         } else {
 459                 say("looks like you're safe.. for now..");
 460         }
 461 }
 462
 463 # Vote relay
 464 DST != "#rhnoise" && /\<[a-zA-Z0-9_]{3,16}(\+\+|--)/ {
 465         say("#rhnoise", "(" DST ") " FROM ": " MSG);
 466 }
 467
 468 # Misc
 469 { fflush("") }
 470
 471 # vim: ft=awk