Pileus Git - ~andy/rhawk/blob - rhawk

   1 #!awk -f
   2
   3 @include "irc.awk"
   4 @include "json.awk"
   5 @include "spades.awk"
   6 #@include "email.awk"
   7
   8 # Initialization
   9 BEGIN {
  10         json_load("var/login.json",     login);
  11         json_load("var/nounicode.json", nounicode);
  12         json_load("var/nocolor.json",   nocolors);
  13
  14         OWNER = login["owner"];
  15
  16         connect(login["server"],  \
  17                 login["nick"],    \
  18                 login["channel"], \
  19                 login["auth"],    \
  20                 login["pass"])
  21
  22         delete login
  23
  24         if (FIRST) {
  25                 join("#rhnoise")
  26                 join("#rhspades")
  27                 join("#sfvlug")
  28         }
  29 }
  30
  31 # Admin
  32 AUTH == OWNER && TO == NICK && /^die in a fire/ {
  33         say("Ack, argh, barasdjf..")
  34         quit()
  35 }
  36
  37 AUTH == OWNER && TO == NICK && /^reload/ {
  38         say("Reloading..")
  39         reload()
  40 }
  41
  42 AUTH == OWNER && TO == NICK && /^rejoin/ {
  43         reply("joining..")
  44         join("#rhnoise")
  45         next
  46 }
  47
  48 AUTH == OWNER && TO == NICK && /^(join|part)/ {
  49         if (match(MSG, /(join|part) +(#+\w+)/, arr)) {
  50                 if (arr[1] == "join") join(arr[2]);
  51                 if (arr[1] == "part") part(arr[2]);
  52                 next
  53         }
  54 }
  55
  56 AUTH == OWNER && TO == NICK && /^\.msg/ {
  57         match(MSG, /.*\.msg +(#*\w+) +(.*)/, arr)
  58         send("PRIVMSG " arr[1] " :" arr[2])
  59 }
  60
  61 # Kick handling
  62 CMD == "KICK" && ARG[2] == NICK {
  63         kick_delay = (kick_delay + 2) * 2
  64         system("sleep " kick_delay)
  65         join(DST)
  66         reply("I feel happy!")
  67 }
  68
  69 # Identify bots
  70 FROM ~ /bo+t$|rhnoise/ {
  71         bots[FROM] = 1
  72 }
  73
  74 CMD == "NICK" && FROM in bots {
  75         bots[MSG] = FROM
  76 }
  77
  78
  79 # Fancy output
  80 /[Uu]nicode :-?\(/ {
  81         nounicode[FROM] = 1
  82         json_save("var/nounicode.json", nounicode);
  83 }
  84
  85 /[Uu]nicode :-?\)/ {
  86         delete nounicode[FROM]
  87         json_save("var/nounicode.json", nounicode);
  88 }
  89
  90 /[Cc]olors :-?\(/ {
  91         nocolor[FROM] = 1
  92         json_save("var/nocolor.json", nocolor);
  93 }
  94
  95 /[Cc]olors :-?\)/ {
  96         delete nocolor[FROM]
  97         json_save("var/nocolor.json", nocolor);
  98 }
  99
 100 # SFV Lug
 101 function email(to, from, subj, body, sendmail)
 102 {
 103         from     = NICK "<andy@pileus.org>"
 104         subj     = "Update sfvlug.org!"
 105         body     = "The next SFVLUG meeting is TBA!"
 106         sendmail = "/usr/sbin/sendmail '" to "'"
 107         print "To: " to        | sendmail
 108         print "From: " from    | sendmail
 109         print "Subject: " subj | sendmail
 110         print ""               | sendmail
 111         print body             | sendmail
 112         say("Topic out of date, emailing " to);
 113         close(sendmail)
 114 }
 115
 116 BEGIN { pollchan = "#sfvlug" }
 117 (CMD == "PING"    && systime()-lastpoll > 60*60*24) ||
 118 (CMD == "PRIVMSG" && /^\.poll/) {
 119         if (!TOPICS[pollchan]) {
 120                 debug("Unknown topic for " pollchan);
 121                 send("TOPIC " pollchan)
 122                 next
 123         }
 124         _curl     = "curl -s http://sfvlug.org/"
 125         _day      = "(Sun|Mon|Tue|Wed|Thu|Fri|Sat)"
 126         _web_tba  = "next meeting is: TBA"
 127         _web_ptrn = "next meeting.*" _day "\\w+[, ]+([A-Z]\\w+) +([0-9]+)[, ]+([0-9]+)"
 128         _irc_ptrn = _day "\\w*[, ]+([A-Z]\\w+) +([0-9]+)"
 129         while (_curl | getline _line) {
 130                 #if (match(_line, _web_tba))
 131                 #       email("Brian <brian@zimage.com>");
 132                 if (match(_line, _web_ptrn, _parts)) {
 133                         _date  = _parts[1] " " _parts[2] " " _parts[3]
 134                         _topic = TOPICS[pollchan]
 135                         sub(_irc_ptrn, _date, _topic)
 136                         if (_topic != TOPICS[pollchan])
 137                                 topic(pollchan, TOPICS[pollchan] = _topic)
 138                         else
 139                                 debug("topic is already correct")
 140                         break
 141                 }
 142         }
 143         lastpoll = systime()
 144         close(_curl)
 145 }
 146
 147 # Versin/Uptime
 148 function head(cmd, var) {
 149         cmd | getline var
 150         close(cmd)
 151         return var
 152 }
 153 function uptime(time,  fmt) {
 154         fmt = "%d:%02d:%02d:%02d"
 155         fmt = "%d days %02d:%02d:%02d"
 156         return sprintf(fmt,
 157                 time / (60*60*24),
 158                 time / (60*60   ) % 24,
 159                 time / (60      ) % 60,
 160                 time / (1       ) % 60)
 161 }
 162 BEGIN {
 163         up_version = head("git describe --always --dirty")
 164         up_author  = head("git log -n1 --format=format:%an")
 165         up_message = head("git log -n1 --format=format:%s")
 166         up_reload  = systime();
 167 }
 168 /^\.(version|rev)/ {
 169         say("version: " up_version " - " up_author " - " up_message)
 170 }
 171 /^\.uptime/ {
 172         _now = systime();
 173         say("uptime: " uptime(_now - START) ", " \
 174             "reload: " uptime(_now - up_reload))
 175 }
 176
 177 # Auth info
 178 /^\.auth/ {
 179         _who = $2 ? $2 : FROM
 180         if (_who in USERS)
 181                 say("nick=" USERS[_who]["nick"] " " \
 182                     "user=" USERS[_who]["user"] " " \
 183                     "auth=" USERS[_who]["auth"] " " \
 184                     "real=" USERS[_who]["real"] " " \
 185                     "host=" USERS[_who]["host"])
 186         else
 187                 say("no auth info for " _who)
 188 }
 189
 190 # Fortune
 191 TO == NICK && /^/               { extra = ""   }
 192 TO == NICK && /^\.?fortune.*-o/ { extra = "-o" }
 193 TO == NICK && /^\.?fortune/     {
 194         gsub(/.*\.?fortune *|-[a-z]* *|[^a-zA-Z0-9 ]/, "", MSG)
 195         cmd = "fortune " extra " " (MSG ? "-m '" MSG "'" : "-s")
 196         _lines = 0
 197         while (cmd | getline _fortune && _lines < 5) {
 198                 say(_fortune)
 199                 _lines++
 200         }
 201         close(cmd)
 202         next
 203 }
 204
 205 # Morse code
 206 BEGIN {
 207         morse["/"      ] = " "
 208         morse[".-.-.-" ] = "."
 209         morse["--..--" ] = ","
 210         morse["..--.." ] = "?"
 211         morse[".----." ] = "'"
 212         morse["-.-.--" ] = "!"
 213         morse["-..-."  ] = "/"
 214         morse["-.--."  ] = "("
 215         morse["-.--.-" ] = ")"
 216         morse[".-..."  ] = "&"
 217         morse["---..." ] = ":"
 218         morse["-.-.-." ] = ";"
 219         morse["-...-"  ] = "="
 220         morse[".-.-."  ] = "+"
 221         morse["-....-" ] = "-"
 222         morse["..--.-" ] = "_"
 223         morse[".-..-." ] = "\""
 224         morse["...-..-"] = "$"
 225         morse[".--.-." ] = "@"
 226         morse[".-"     ] = "a"
 227         morse["-..."   ] = "b"
 228         morse["-.-."   ] = "c"
 229         morse["-.."    ] = "d"
 230         morse["."      ] = "e"
 231         morse["..-."   ] = "f"
 232         morse["--."    ] = "g"
 233         morse["...."   ] = "h"
 234         morse[".."     ] = "i"
 235         morse[".---"   ] = "j"
 236         morse["-.-"    ] = "k"
 237         morse[".-.."   ] = "l"
 238         morse["--"     ] = "m"
 239         morse["-."     ] = "n"
 240         morse["---"    ] = "o"
 241         morse[".--."   ] = "p"
 242         morse["--.-"   ] = "q"
 243         morse[".-."    ] = "r"
 244         morse["..."    ] = "s"
 245         morse["-"      ] = "t"
 246         morse["..-"    ] = "u"
 247         morse["...-"   ] = "v"
 248         morse[".--"    ] = "w"
 249         morse["-..-"   ] = "x"
 250         morse["-.--"   ] = "y"
 251         morse["--.."   ] = "z"
 252         morse["-----"  ] = "0"
 253         morse[".----"  ] = "1"
 254         morse["..---"  ] = "2"
 255         morse["...--"  ] = "3"
 256         morse["....-"  ] = "4"
 257         morse["....."  ] = "5"
 258         morse["-...."  ] = "6"
 259         morse["--..."  ] = "7"
 260         morse["---.."  ] = "8"
 261         morse["----."  ] = "9"
 262 }
 263
 264 /^\.morse/ {
 265         gsub(/[^.\-\/]/, " ")
 266         _str = ""
 267         for (i=2; i<=NF; i++)
 268                 if ($i in morse)
 269                         _str = _str morse[$i]
 270         if (_str)
 271                 reply(_str)
 272         else
 273                 reply("hush it, you pile of bologna")
 274 }
 275
 276 # Noise
 277 AUTH == OWNER && /^go go gadget woop/ {
 278         for (i=20; i>0; i--)
 279                 say(".delay " i " seconds; .woop " i)
 280 }
 281
 282 function woop(msg) {
 283         gsub(/[^Oo]/, "", $1)
 284         _len = length($1)
 285         if (_len == 2)
 286                 _len = 10
 287         if ($2)
 288                 _len = $2
 289         _woop = msg
 290         for (i=1; i<_len; i++)
 291                 _woop = _woop " " msg
 292         say(_woop)
 293 }
 294
 295 TO == NICK && /^[Ww][Oo]+[Pp] *([0-9]*)/ {
 296         woop("WOOP")
 297 }
 298
 299 /^~WOOP *([0-9]*)/ {
 300         woop("(00/")
 301 }
 302
 303 /^~woop *([0-9]*)/ {
 304         woop("^H^P^P^O")
 305 }
 306
 307 TO == NICK && DST ~ /^#/ {
 308         #say("Hello, " FROM)
 309 }
 310
 311 #DST != "#sfvlug" &&
 312 !(FROM in bots) &&
 313 CMD == "PRIVMSG" &&
 314 MSG !~ /^\./ &&
 315 /awk/ {
 316         say("Awk, awk, awk! I'm a bird!")
 317 }
 318
 319 !(FROM in bots) &&
 320 ((TO == NICK && /(help|halp)/) ||
 321  /^[^.](help|halp)/) {
 322         reply("Nothing can help you now..")
 323 }
 324
 325 /(\<[Hh][Oo]\>.*){3}/ {
 326         say("\00309Merry \00304Christmas!")
 327 }
 328
 329 !(FROM in bots) &&
 330 tolower($0) ~ /\<cloud\>/ {
 331         _cmd = "shuf clouds.txt"
 332         _cmd | getline _cloud
 333         close(_cmd)
 334         say(_cloud)
 335 }
 336
 337 /^headshot [Cc]hristmas/ {
 338         say(".load Christmas")
 339         say(".jingle")
 340         say(".unload Christmas")
 341 }
 342
 343 FROM == "rhnoise" && $2 == "slaps" && $3 == NICK {
 344         say(".spin")
 345 }
 346
 347 /^[Aa]nd now[.,]/ {
 348         say("And now...");
 349         say("THE LARCH");
 350 }
 351
 352 /(for what|that for)\?$/ {
 353         say("For great justice!");
 354 }
 355
 356 /\<nazi/ {
 357         say("And now it's...");
 358         say("Springtime for Hitler and Germany!");
 359 }
 360
 361 # God damn commands
 362 FROM == "rhnoise" && load_mod {
 363         say(".load " load_mod)
 364         say("rhnoise: You slag!")
 365 }
 366 // {
 367         load_mod = ""
 368 }
 369 (TO  ==  "rhnoise" && /^load \w+/) ||
 370 (DST == "#rhniose" && /^\.load [a-z]\w+/) {
 371         gsub(/[^a-zA-Z0-9_]/, " ")
 372         load_mod = toupper(substr($2,1,1)) substr($2,2);
 373 }
 374
 375 (DST == "#rhnoise" && /^\.line /) {
 376         sub(/\./, "!");
 377         say($0);
 378         say("scalawag: You slag!")
 379 }
 380
 381 (DST == "#rhnoise" && /^\.qdb 268$/) {
 382         say(".diediedie");
 383         next
 384 }
 385 (DST == "#rhnoise" && /\.qdb *268/) {
 386         say(".slap " FROM);
 387         next
 388 }
 389
 390 # Decrementer
 391 BEGIN {
 392         user_scores[0] = 1;
 393 }
 394
 395 /^\.(scores|scoreboard)$/ {
 396         delete user_scores
 397 }
 398
 399 FROM == "rhnoise" && !length(user_scores) {
 400         if (split(MSG, _parts, /, /)) {
 401                 for (_i=1; _i<=length(_parts); _i++) {
 402                         split(_parts[_i], _tmp, ": ");
 403                         user_scores[_i]["user"]  = _tmp[1];
 404                         user_scores[_i]["score"] = _tmp[2];
 405                 }
 406         }
 407 }
 408
 409 length(user_scores) &&
 410 tolower($0) ~ /\<nuclear launch detected\>/ {
 411         _count = 0;
 412         for (_i=1; _i<=length(user_scores); _i++) {
 413                 _user  = user_scores[_i]["user"];
 414                 _score = user_scores[_i]["score"];
 415                 if (_user in USERS) continue
 416                 if (_score ==  1) { say(_user "--"); _count++; }
 417                 if (_score == -1) { say(_user "++"); _count++; }
 418         }
 419         if (_count) {
 420                 delete user_scores;
 421                 say(".scores");
 422         } else {
 423                 say("looks like you're safe.. for now..");
 424         }
 425 }
 426
 427 # Misc
 428 { fflush("") }
 429
 430 # vim: ft=awk