Pileus Git - ~andy/linux/blob - arch/powerpc/kernel/entry_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Adapted for Power Macintosh by Paul Mackerras.
   7  *  Low-level exception handlers and MMU support
   8  *  rewritten by Paul Mackerras.
   9  *    Copyright (C) 1996 Paul Mackerras.
  10  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains the system call entry code, context switch
  13  *  code, and exception/interrupt return code for PowerPC.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  */
  20
  21 #include <linux/errno.h>
  22 #include <asm/unistd.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/thread_info.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/cputable.h>
  30 #include <asm/firmware.h>
  31 #include <asm/bug.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/irqflags.h>
  34 #include <asm/ftrace.h>
  35 #include <asm/hw_irq.h>
  36 #include <asm/context_tracking.h>
  37
  38 /*
  39  * System calls.
  40  */
  41         .section        ".toc","aw"
  42 .SYS_CALL_TABLE:
  43         .tc .sys_call_table[TC],.sys_call_table
  44
  45 /* This value is used to mark exception frames on the stack. */
  46 exception_marker:
  47         .tc     ID_EXC_MARKER[TC],STACK_FRAME_REGS_MARKER
  48
  49         .section        ".text"
  50         .align 7
  51
  52 #undef SHOW_SYSCALLS
  53
  54         .globl system_call_common
  55 system_call_common:
  56         andi.   r10,r12,MSR_PR
  57         mr      r10,r1
  58         addi    r1,r1,-INT_FRAME_SIZE
  59         beq-    1f
  60         ld      r1,PACAKSAVE(r13)
  61 1:      std     r10,0(r1)
  62         std     r11,_NIP(r1)
  63         std     r12,_MSR(r1)
  64         std     r0,GPR0(r1)
  65         std     r10,GPR1(r1)
  66         beq     2f                      /* if from kernel mode */
  67         ACCOUNT_CPU_USER_ENTRY(r10, r11)
  68 2:      std     r2,GPR2(r1)
  69         std     r3,GPR3(r1)
  70         mfcr    r2
  71         std     r4,GPR4(r1)
  72         std     r5,GPR5(r1)
  73         std     r6,GPR6(r1)
  74         std     r7,GPR7(r1)
  75         std     r8,GPR8(r1)
  76         li      r11,0
  77         std     r11,GPR9(r1)
  78         std     r11,GPR10(r1)
  79         std     r11,GPR11(r1)
  80         std     r11,GPR12(r1)
  81         std     r11,_XER(r1)
  82         std     r11,_CTR(r1)
  83         std     r9,GPR13(r1)
  84         mflr    r10
  85         /*
  86          * This clears CR0.SO (bit 28), which is the error indication on
  87          * return from this system call.
  88          */
  89         rldimi  r2,r11,28,(63-28)
  90         li      r11,0xc01
  91         std     r10,_LINK(r1)
  92         std     r11,_TRAP(r1)
  93         std     r3,ORIG_GPR3(r1)
  94         std     r2,_CCR(r1)
  95         ld      r2,PACATOC(r13)
  96         addi    r9,r1,STACK_FRAME_OVERHEAD
  97         ld      r11,exception_marker@toc(r2)
  98         std     r11,-16(r9)             /* "regshere" marker */
  99 #if defined(CONFIG_VIRT_CPU_ACCOUNTING_NATIVE) && defined(CONFIG_PPC_SPLPAR)
 100 BEGIN_FW_FTR_SECTION
 101         beq     33f
 102         /* if from user, see if there are any DTL entries to process */
 103         ld      r10,PACALPPACAPTR(r13)  /* get ptr to VPA */
 104         ld      r11,PACA_DTL_RIDX(r13)  /* get log read index */
 105         addi    r10,r10,LPPACA_DTLIDX
 106         LDX_BE  r10,0,r10               /* get log write index */
 107         cmpd    cr1,r11,r10
 108         beq+    cr1,33f
 109         bl      .accumulate_stolen_time
 110         REST_GPR(0,r1)
 111         REST_4GPRS(3,r1)
 112         REST_2GPRS(7,r1)
 113         addi    r9,r1,STACK_FRAME_OVERHEAD
 114 33:
 115 END_FW_FTR_SECTION_IFSET(FW_FEATURE_SPLPAR)
 116 #endif /* CONFIG_VIRT_CPU_ACCOUNTING_NATIVE && CONFIG_PPC_SPLPAR */
 117
 118         /*
 119          * A syscall should always be called with interrupts enabled
 120          * so we just unconditionally hard-enable here. When some kind
 121          * of irq tracing is used, we additionally check that condition
 122          * is correct
 123          */
 124 #if defined(CONFIG_TRACE_IRQFLAGS) && defined(CONFIG_BUG)
 125         lbz     r10,PACASOFTIRQEN(r13)
 126         xori    r10,r10,1
 127 1:      tdnei   r10,0
 128         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 129 #endif
 130
 131 #ifdef CONFIG_PPC_BOOK3E
 132         wrteei  1
 133 #else
 134         ld      r11,PACAKMSR(r13)
 135         ori     r11,r11,MSR_EE
 136         mtmsrd  r11,1
 137 #endif /* CONFIG_PPC_BOOK3E */
 138
 139         /* We do need to set SOFTE in the stack frame or the return
 140          * from interrupt will be painful
 141          */
 142         li      r10,1
 143         std     r10,SOFTE(r1)
 144
 145 #ifdef SHOW_SYSCALLS
 146         bl      .do_show_syscall
 147         REST_GPR(0,r1)
 148         REST_4GPRS(3,r1)
 149         REST_2GPRS(7,r1)
 150         addi    r9,r1,STACK_FRAME_OVERHEAD
 151 #endif
 152         CURRENT_THREAD_INFO(r11, r1)
 153         ld      r10,TI_FLAGS(r11)
 154         andi.   r11,r10,_TIF_SYSCALL_T_OR_A
 155         bne     syscall_dotrace
 156 .Lsyscall_dotrace_cont:
 157         cmpldi  0,r0,NR_syscalls
 158         bge-    syscall_enosys
 159
 160 system_call:                    /* label this so stack traces look sane */
 161 /*
 162  * Need to vector to 32 Bit or default sys_call_table here,
 163  * based on caller's run-mode / personality.
 164  */
 165         ld      r11,.SYS_CALL_TABLE@toc(2)
 166         andi.   r10,r10,_TIF_32BIT
 167         beq     15f
 168         addi    r11,r11,8       /* use 32-bit syscall entries */
 169         clrldi  r3,r3,32
 170         clrldi  r4,r4,32
 171         clrldi  r5,r5,32
 172         clrldi  r6,r6,32
 173         clrldi  r7,r7,32
 174         clrldi  r8,r8,32
 175 15:
 176         slwi    r0,r0,4
 177         ldx     r10,r11,r0      /* Fetch system call handler [ptr] */
 178         mtctr   r10
 179         bctrl                   /* Call handler */
 180
 181 syscall_exit:
 182         std     r3,RESULT(r1)
 183 #ifdef SHOW_SYSCALLS
 184         bl      .do_show_syscall_exit
 185         ld      r3,RESULT(r1)
 186 #endif
 187         CURRENT_THREAD_INFO(r12, r1)
 188
 189         ld      r8,_MSR(r1)
 190 #ifdef CONFIG_PPC_BOOK3S
 191         /* No MSR:RI on BookE */
 192         andi.   r10,r8,MSR_RI
 193         beq-    unrecov_restore
 194 #endif
 195         /*
 196          * Disable interrupts so current_thread_info()->flags can't change,
 197          * and so that we don't get interrupted after loading SRR0/1.
 198          */
 199 #ifdef CONFIG_PPC_BOOK3E
 200         wrteei  0
 201 #else
 202         ld      r10,PACAKMSR(r13)
 203         /*
 204          * For performance reasons we clear RI the same time that we
 205          * clear EE. We only need to clear RI just before we restore r13
 206          * below, but batching it with EE saves us one expensive mtmsrd call.
 207          * We have to be careful to restore RI if we branch anywhere from
 208          * here (eg syscall_exit_work).
 209          */
 210         li      r9,MSR_RI
 211         andc    r11,r10,r9
 212         mtmsrd  r11,1
 213 #endif /* CONFIG_PPC_BOOK3E */
 214
 215         ld      r9,TI_FLAGS(r12)
 216         li      r11,-_LAST_ERRNO
 217         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
 218         bne-    syscall_exit_work
 219         cmpld   r3,r11
 220         ld      r5,_CCR(r1)
 221         bge-    syscall_error
 222 .Lsyscall_error_cont:
 223         ld      r7,_NIP(r1)
 224 BEGIN_FTR_SECTION
 225         stdcx.  r0,0,r1                 /* to clear the reservation */
 226 END_FTR_SECTION_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 227         andi.   r6,r8,MSR_PR
 228         ld      r4,_LINK(r1)
 229
 230         beq-    1f
 231         ACCOUNT_CPU_USER_EXIT(r11, r12)
 232         HMT_MEDIUM_LOW_HAS_PPR
 233         ld      r13,GPR13(r1)   /* only restore r13 if returning to usermode */
 234 1:      ld      r2,GPR2(r1)
 235         ld      r1,GPR1(r1)
 236         mtlr    r4
 237         mtcr    r5
 238         mtspr   SPRN_SRR0,r7
 239         mtspr   SPRN_SRR1,r8
 240         RFI
 241         b       .       /* prevent speculative execution */
 242
 243 syscall_error:
 244         oris    r5,r5,0x1000    /* Set SO bit in CR */
 245         neg     r3,r3
 246         std     r5,_CCR(r1)
 247         b       .Lsyscall_error_cont
 248
 249 /* Traced system call support */
 250 syscall_dotrace:
 251         bl      .save_nvgprs
 252         addi    r3,r1,STACK_FRAME_OVERHEAD
 253         bl      .do_syscall_trace_enter
 254         /*
 255          * Restore argument registers possibly just changed.
 256          * We use the return value of do_syscall_trace_enter
 257          * for the call number to look up in the table (r0).
 258          */
 259         mr      r0,r3
 260         ld      r3,GPR3(r1)
 261         ld      r4,GPR4(r1)
 262         ld      r5,GPR5(r1)
 263         ld      r6,GPR6(r1)
 264         ld      r7,GPR7(r1)
 265         ld      r8,GPR8(r1)
 266         addi    r9,r1,STACK_FRAME_OVERHEAD
 267         CURRENT_THREAD_INFO(r10, r1)
 268         ld      r10,TI_FLAGS(r10)
 269         b       .Lsyscall_dotrace_cont
 270
 271 syscall_enosys:
 272         li      r3,-ENOSYS
 273         b       syscall_exit
 274
 275 syscall_exit_work:
 276 #ifdef CONFIG_PPC_BOOK3S
 277         mtmsrd  r10,1           /* Restore RI */
 278 #endif
 279         /* If TIF_RESTOREALL is set, don't scribble on either r3 or ccr.
 280          If TIF_NOERROR is set, just save r3 as it is. */
 281
 282         andi.   r0,r9,_TIF_RESTOREALL
 283         beq+    0f
 284         REST_NVGPRS(r1)
 285         b       2f
 286 0:      cmpld   r3,r11          /* r10 is -LAST_ERRNO */
 287         blt+    1f
 288         andi.   r0,r9,_TIF_NOERROR
 289         bne-    1f
 290         ld      r5,_CCR(r1)
 291         neg     r3,r3
 292         oris    r5,r5,0x1000    /* Set SO bit in CR */
 293         std     r5,_CCR(r1)
 294 1:      std     r3,GPR3(r1)
 295 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
 296         beq     4f
 297
 298         /* Clear per-syscall TIF flags if any are set.  */
 299
 300         li      r11,_TIF_PERSYSCALL_MASK
 301         addi    r12,r12,TI_FLAGS
 302 3:      ldarx   r10,0,r12
 303         andc    r10,r10,r11
 304         stdcx.  r10,0,r12
 305         bne-    3b
 306         subi    r12,r12,TI_FLAGS
 307
 308 4:      /* Anything else left to do? */
 309         SET_DEFAULT_THREAD_PPR(r3, r10)         /* Set thread.ppr = 3 */
 310         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
 311         beq     .ret_from_except_lite
 312
 313         /* Re-enable interrupts */
 314 #ifdef CONFIG_PPC_BOOK3E
 315         wrteei  1
 316 #else
 317         ld      r10,PACAKMSR(r13)
 318         ori     r10,r10,MSR_EE
 319         mtmsrd  r10,1
 320 #endif /* CONFIG_PPC_BOOK3E */
 321
 322         bl      .save_nvgprs
 323         addi    r3,r1,STACK_FRAME_OVERHEAD
 324         bl      .do_syscall_trace_leave
 325         b       .ret_from_except
 326
 327 /* Save non-volatile GPRs, if not already saved. */
 328 _GLOBAL(save_nvgprs)
 329         ld      r11,_TRAP(r1)
 330         andi.   r0,r11,1
 331         beqlr-
 332         SAVE_NVGPRS(r1)
 333         clrrdi  r0,r11,1
 334         std     r0,_TRAP(r1)
 335         blr
 336
 337
 338 /*
 339  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 340  * and thus put the process into the stopped state where we might
 341  * want to examine its user state with ptrace.  Therefore we need
 342  * to save all the nonvolatile registers (r14 - r31) before calling
 343  * the C code.  Similarly, fork, vfork and clone need the full
 344  * register state on the stack so that it can be copied to the child.
 345  */
 346
 347 _GLOBAL(ppc_fork)
 348         bl      .save_nvgprs
 349         bl      .sys_fork
 350         b       syscall_exit
 351
 352 _GLOBAL(ppc_vfork)
 353         bl      .save_nvgprs
 354         bl      .sys_vfork
 355         b       syscall_exit
 356
 357 _GLOBAL(ppc_clone)
 358         bl      .save_nvgprs
 359         bl      .sys_clone
 360         b       syscall_exit
 361
 362 _GLOBAL(ppc32_swapcontext)
 363         bl      .save_nvgprs
 364         bl      .compat_sys_swapcontext
 365         b       syscall_exit
 366
 367 _GLOBAL(ppc64_swapcontext)
 368         bl      .save_nvgprs
 369         bl      .sys_swapcontext
 370         b       syscall_exit
 371
 372 _GLOBAL(ret_from_fork)
 373         bl      .schedule_tail
 374         REST_NVGPRS(r1)
 375         li      r3,0
 376         b       syscall_exit
 377
 378 _GLOBAL(ret_from_kernel_thread)
 379         bl      .schedule_tail
 380         REST_NVGPRS(r1)
 381         ld      r14, 0(r14)
 382         mtlr    r14
 383         mr      r3,r15
 384         blrl
 385         li      r3,0
 386         b       syscall_exit
 387
 388         .section        ".toc","aw"
 389 DSCR_DEFAULT:
 390         .tc dscr_default[TC],dscr_default
 391
 392         .section        ".text"
 393
 394 /*
 395  * This routine switches between two different tasks.  The process
 396  * state of one is saved on its kernel stack.  Then the state
 397  * of the other is restored from its kernel stack.  The memory
 398  * management hardware is updated to the second process's state.
 399  * Finally, we can return to the second process, via ret_from_except.
 400  * On entry, r3 points to the THREAD for the current task, r4
 401  * points to the THREAD for the new task.
 402  *
 403  * Note: there are two ways to get to the "going out" portion
 404  * of this code; either by coming in via the entry (_switch)
 405  * or via "fork" which must set up an environment equivalent
 406  * to the "_switch" path.  If you change this you'll have to change
 407  * the fork code also.
 408  *
 409  * The code which creates the new task context is in 'copy_thread'
 410  * in arch/powerpc/kernel/process.c
 411  */
 412         .align  7
 413 _GLOBAL(_switch)
 414         mflr    r0
 415         std     r0,16(r1)
 416         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 417         /* r3-r13 are caller saved -- Cort */
 418         SAVE_8GPRS(14, r1)
 419         SAVE_10GPRS(22, r1)
 420         mflr    r20             /* Return to switch caller */
 421         mfmsr   r22
 422         li      r0, MSR_FP
 423 #ifdef CONFIG_VSX
 424 BEGIN_FTR_SECTION
 425         oris    r0,r0,MSR_VSX@h /* Disable VSX */
 426 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 427 #endif /* CONFIG_VSX */
 428 #ifdef CONFIG_ALTIVEC
 429 BEGIN_FTR_SECTION
 430         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 431         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 432         std     r24,THREAD_VRSAVE(r3)
 433 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 434 #endif /* CONFIG_ALTIVEC */
 435 #ifdef CONFIG_PPC64
 436 BEGIN_FTR_SECTION
 437         mfspr   r25,SPRN_DSCR
 438         std     r25,THREAD_DSCR(r3)
 439 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 440 #endif
 441         and.    r0,r0,r22
 442         beq+    1f
 443         andc    r22,r22,r0
 444         MTMSRD(r22)
 445         isync
 446 1:      std     r20,_NIP(r1)
 447         mfcr    r23
 448         std     r23,_CCR(r1)
 449         std     r1,KSP(r3)      /* Set old stack pointer */
 450
 451 #ifdef CONFIG_PPC_BOOK3S_64
 452 BEGIN_FTR_SECTION
 453         /* Event based branch registers */
 454         mfspr   r0, SPRN_BESCR
 455         std     r0, THREAD_BESCR(r3)
 456         mfspr   r0, SPRN_EBBHR
 457         std     r0, THREAD_EBBHR(r3)
 458         mfspr   r0, SPRN_EBBRR
 459         std     r0, THREAD_EBBRR(r3)
 460 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 461 #endif
 462
 463 #ifdef CONFIG_SMP
 464         /* We need a sync somewhere here to make sure that if the
 465          * previous task gets rescheduled on another CPU, it sees all
 466          * stores it has performed on this one.
 467          */
 468         sync
 469 #endif /* CONFIG_SMP */
 470
 471         /*
 472          * If we optimise away the clear of the reservation in system
 473          * calls because we know the CPU tracks the address of the
 474          * reservation, then we need to clear it here to cover the
 475          * case that the kernel context switch path has no larx
 476          * instructions.
 477          */
 478 BEGIN_FTR_SECTION
 479         ldarx   r6,0,r1
 480 END_FTR_SECTION_IFSET(CPU_FTR_STCX_CHECKS_ADDRESS)
 481
 482 #ifdef CONFIG_PPC_BOOK3S
 483 /* Cancel all explict user streams as they will have no use after context
 484  * switch and will stop the HW from creating streams itself
 485  */
 486         DCBT_STOP_ALL_STREAM_IDS(r6)
 487 #endif
 488
 489         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 490         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 491
 492         ld      r8,KSP(r4)      /* new stack pointer */
 493 #ifdef CONFIG_PPC_BOOK3S
 494 BEGIN_FTR_SECTION
 495   BEGIN_FTR_SECTION_NESTED(95)
 496         clrrdi  r6,r8,28        /* get its ESID */
 497         clrrdi  r9,r1,28        /* get current sp ESID */
 498   FTR_SECTION_ELSE_NESTED(95)
 499         clrrdi  r6,r8,40        /* get its 1T ESID */
 500         clrrdi  r9,r1,40        /* get current sp 1T ESID */
 501   ALT_MMU_FTR_SECTION_END_NESTED_IFCLR(MMU_FTR_1T_SEGMENT, 95)
 502 FTR_SECTION_ELSE
 503         b       2f
 504 ALT_MMU_FTR_SECTION_END_IFSET(MMU_FTR_SLB)
 505         clrldi. r0,r6,2         /* is new ESID c00000000? */
 506         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 507         cror    eq,4*cr1+eq,eq
 508         beq     2f              /* if yes, don't slbie it */
 509
 510         /* Bolt in the new stack SLB entry */
 511         ld      r7,KSP_VSID(r4) /* Get new stack's VSID */
 512         oris    r0,r6,(SLB_ESID_V)@h
 513         ori     r0,r0,(SLB_NUM_BOLTED-1)@l
 514 BEGIN_FTR_SECTION
 515         li      r9,MMU_SEGSIZE_1T       /* insert B field */
 516         oris    r6,r6,(MMU_SEGSIZE_1T << SLBIE_SSIZE_SHIFT)@h
 517         rldimi  r7,r9,SLB_VSID_SSIZE_SHIFT,0
 518 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 519
 520         /* Update the last bolted SLB.  No write barriers are needed
 521          * here, provided we only update the current CPU's SLB shadow
 522          * buffer.
 523          */
 524         ld      r9,PACA_SLBSHADOWPTR(r13)
 525         li      r12,0
 526         std     r12,SLBSHADOW_STACKESID(r9)     /* Clear ESID */
 527         li      r12,SLBSHADOW_STACKVSID
 528         STDX_BE r7,r12,r9                       /* Save VSID */
 529         li      r12,SLBSHADOW_STACKESID
 530         STDX_BE r0,r12,r9                       /* Save ESID */
 531
 532         /* No need to check for MMU_FTR_NO_SLBIE_B here, since when
 533          * we have 1TB segments, the only CPUs known to have the errata
 534          * only support less than 1TB of system memory and we'll never
 535          * actually hit this code path.
 536          */
 537
 538         slbie   r6
 539         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 540         slbmte  r7,r0
 541         isync
 542 2:
 543 #endif /* !CONFIG_PPC_BOOK3S */
 544
 545         CURRENT_THREAD_INFO(r7, r8)  /* base of new stack */
 546         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 547            because we don't need to leave the 288-byte ABI gap at the
 548            top of the kernel stack. */
 549         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 550
 551         mr      r1,r8           /* start using new stack pointer */
 552         std     r7,PACAKSAVE(r13)
 553
 554 #ifdef CONFIG_PPC_BOOK3S_64
 555 BEGIN_FTR_SECTION
 556         /* Event based branch registers */
 557         ld      r0, THREAD_BESCR(r4)
 558         mtspr   SPRN_BESCR, r0
 559         ld      r0, THREAD_EBBHR(r4)
 560         mtspr   SPRN_EBBHR, r0
 561         ld      r0, THREAD_EBBRR(r4)
 562         mtspr   SPRN_EBBRR, r0
 563
 564         ld      r0,THREAD_TAR(r4)
 565         mtspr   SPRN_TAR,r0
 566 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 567 #endif
 568
 569 #ifdef CONFIG_ALTIVEC
 570 BEGIN_FTR_SECTION
 571         ld      r0,THREAD_VRSAVE(r4)
 572         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 573 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 574 #endif /* CONFIG_ALTIVEC */
 575 #ifdef CONFIG_PPC64
 576 BEGIN_FTR_SECTION
 577         lwz     r6,THREAD_DSCR_INHERIT(r4)
 578         ld      r7,DSCR_DEFAULT@toc(2)
 579         ld      r0,THREAD_DSCR(r4)
 580         cmpwi   r6,0
 581         li      r8, FSCR_DSCR
 582         bne     1f
 583         ld      r0,0(r7)
 584         b       3f
 585 1:
 586   BEGIN_FTR_SECTION_NESTED(70)
 587         mfspr   r6, SPRN_FSCR
 588         or      r6, r6, r8
 589         mtspr   SPRN_FSCR, r6
 590     BEGIN_FTR_SECTION_NESTED(69)
 591         mfspr   r6, SPRN_HFSCR
 592         or      r6, r6, r8
 593         mtspr   SPRN_HFSCR, r6
 594     END_FTR_SECTION_NESTED(CPU_FTR_HVMODE, CPU_FTR_HVMODE, 69)
 595         b       4f
 596   END_FTR_SECTION_NESTED(CPU_FTR_ARCH_207S, CPU_FTR_ARCH_207S, 70)
 597 3:
 598   BEGIN_FTR_SECTION_NESTED(70)
 599         mfspr   r6, SPRN_FSCR
 600         andc    r6, r6, r8
 601         mtspr   SPRN_FSCR, r6
 602     BEGIN_FTR_SECTION_NESTED(69)
 603         mfspr   r6, SPRN_HFSCR
 604         andc    r6, r6, r8
 605         mtspr   SPRN_HFSCR, r6
 606     END_FTR_SECTION_NESTED(CPU_FTR_HVMODE, CPU_FTR_HVMODE, 69)
 607   END_FTR_SECTION_NESTED(CPU_FTR_ARCH_207S, CPU_FTR_ARCH_207S, 70)
 608 4:      cmpd    r0,r25
 609         beq     2f
 610         mtspr   SPRN_DSCR,r0
 611 2:
 612 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 613 #endif
 614
 615         ld      r6,_CCR(r1)
 616         mtcrf   0xFF,r6
 617
 618         /* r3-r13 are destroyed -- Cort */
 619         REST_8GPRS(14, r1)
 620         REST_10GPRS(22, r1)
 621
 622         /* convert old thread to its task_struct for return value */
 623         addi    r3,r3,-THREAD
 624         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 625         mtlr    r7
 626         addi    r1,r1,SWITCH_FRAME_SIZE
 627         blr
 628
 629         .align  7
 630 _GLOBAL(ret_from_except)
 631         ld      r11,_TRAP(r1)
 632         andi.   r0,r11,1
 633         bne     .ret_from_except_lite
 634         REST_NVGPRS(r1)
 635
 636 _GLOBAL(ret_from_except_lite)
 637         /*
 638          * Disable interrupts so that current_thread_info()->flags
 639          * can't change between when we test it and when we return
 640          * from the interrupt.
 641          */
 642 #ifdef CONFIG_PPC_BOOK3E
 643         wrteei  0
 644 #else
 645         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 646         mtmsrd  r10,1             /* Update machine state */
 647 #endif /* CONFIG_PPC_BOOK3E */
 648
 649         CURRENT_THREAD_INFO(r9, r1)
 650         ld      r3,_MSR(r1)
 651 #ifdef CONFIG_PPC_BOOK3E
 652         ld      r10,PACACURRENT(r13)
 653 #endif /* CONFIG_PPC_BOOK3E */
 654         ld      r4,TI_FLAGS(r9)
 655         andi.   r3,r3,MSR_PR
 656         beq     resume_kernel
 657 #ifdef CONFIG_PPC_BOOK3E
 658         lwz     r3,(THREAD+THREAD_DBCR0)(r10)
 659 #endif /* CONFIG_PPC_BOOK3E */
 660
 661         /* Check current_thread_info()->flags */
 662         andi.   r0,r4,_TIF_USER_WORK_MASK
 663 #ifdef CONFIG_PPC_BOOK3E
 664         bne     1f
 665         /*
 666          * Check to see if the dbcr0 register is set up to debug.
 667          * Use the internal debug mode bit to do this.
 668          */
 669         andis.  r0,r3,DBCR0_IDM@h
 670         beq     restore
 671         mfmsr   r0
 672         rlwinm  r0,r0,0,~MSR_DE /* Clear MSR.DE */
 673         mtmsr   r0
 674         mtspr   SPRN_DBCR0,r3
 675         li      r10, -1
 676         mtspr   SPRN_DBSR,r10
 677         b       restore
 678 #else
 679         beq     restore
 680 #endif
 681 1:      andi.   r0,r4,_TIF_NEED_RESCHED
 682         beq     2f
 683         bl      .restore_interrupts
 684         SCHEDULE_USER
 685         b       .ret_from_except_lite
 686
 687 2:      bl      .save_nvgprs
 688         bl      .restore_interrupts
 689         addi    r3,r1,STACK_FRAME_OVERHEAD
 690         bl      .do_notify_resume
 691         b       .ret_from_except
 692
 693 resume_kernel:
 694         /* check current_thread_info, _TIF_EMULATE_STACK_STORE */
 695         CURRENT_THREAD_INFO(r9, r1)
 696         ld      r8,TI_FLAGS(r9)
 697         andis.  r8,r8,_TIF_EMULATE_STACK_STORE@h
 698         beq+    1f
 699
 700         addi    r8,r1,INT_FRAME_SIZE    /* Get the kprobed function entry */
 701
 702         lwz     r3,GPR1(r1)
 703         subi    r3,r3,INT_FRAME_SIZE    /* dst: Allocate a trampoline exception frame */
 704         mr      r4,r1                   /* src:  current exception frame */
 705         mr      r1,r3                   /* Reroute the trampoline frame to r1 */
 706
 707         /* Copy from the original to the trampoline. */
 708         li      r5,INT_FRAME_SIZE/8     /* size: INT_FRAME_SIZE */
 709         li      r6,0                    /* start offset: 0 */
 710         mtctr   r5
 711 2:      ldx     r0,r6,r4
 712         stdx    r0,r6,r3
 713         addi    r6,r6,8
 714         bdnz    2b
 715
 716         /* Do real store operation to complete stwu */
 717         lwz     r5,GPR1(r1)
 718         std     r8,0(r5)
 719
 720         /* Clear _TIF_EMULATE_STACK_STORE flag */
 721         lis     r11,_TIF_EMULATE_STACK_STORE@h
 722         addi    r5,r9,TI_FLAGS
 723 0:      ldarx   r4,0,r5
 724         andc    r4,r4,r11
 725         stdcx.  r4,0,r5
 726         bne-    0b
 727 1:
 728
 729 #ifdef CONFIG_PREEMPT
 730         /* Check if we need to preempt */
 731         andi.   r0,r4,_TIF_NEED_RESCHED
 732         beq+    restore
 733         /* Check that preempt_count() == 0 and interrupts are enabled */
 734         lwz     r8,TI_PREEMPT(r9)
 735         cmpwi   cr1,r8,0
 736         ld      r0,SOFTE(r1)
 737         cmpdi   r0,0
 738         crandc  eq,cr1*4+eq,eq
 739         bne     restore
 740
 741         /*
 742          * Here we are preempting the current task. We want to make
 743          * sure we are soft-disabled first and reconcile irq state.
 744          */
 745         RECONCILE_IRQ_STATE(r3,r4)
 746 1:      bl      .preempt_schedule_irq
 747
 748         /* Re-test flags and eventually loop */
 749         CURRENT_THREAD_INFO(r9, r1)
 750         ld      r4,TI_FLAGS(r9)
 751         andi.   r0,r4,_TIF_NEED_RESCHED
 752         bne     1b
 753
 754         /*
 755          * arch_local_irq_restore() from preempt_schedule_irq above may
 756          * enable hard interrupt but we really should disable interrupts
 757          * when we return from the interrupt, and so that we don't get
 758          * interrupted after loading SRR0/1.
 759          */
 760 #ifdef CONFIG_PPC_BOOK3E
 761         wrteei  0
 762 #else
 763         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 764         mtmsrd  r10,1             /* Update machine state */
 765 #endif /* CONFIG_PPC_BOOK3E */
 766 #endif /* CONFIG_PREEMPT */
 767
 768         .globl  fast_exc_return_irq
 769 fast_exc_return_irq:
 770 restore:
 771         /*
 772          * This is the main kernel exit path. First we check if we
 773          * are about to re-enable interrupts
 774          */
 775         ld      r5,SOFTE(r1)
 776         lbz     r6,PACASOFTIRQEN(r13)
 777         cmpwi   cr0,r5,0
 778         beq     restore_irq_off
 779
 780         /* We are enabling, were we already enabled ? Yes, just return */
 781         cmpwi   cr0,r6,1
 782         beq     cr0,do_restore
 783
 784         /*
 785          * We are about to soft-enable interrupts (we are hard disabled
 786          * at this point). We check if there's anything that needs to
 787          * be replayed first.
 788          */
 789         lbz     r0,PACAIRQHAPPENED(r13)
 790         cmpwi   cr0,r0,0
 791         bne-    restore_check_irq_replay
 792
 793         /*
 794          * Get here when nothing happened while soft-disabled, just
 795          * soft-enable and move-on. We will hard-enable as a side
 796          * effect of rfi
 797          */
 798 restore_no_replay:
 799         TRACE_ENABLE_INTS
 800         li      r0,1
 801         stb     r0,PACASOFTIRQEN(r13);
 802
 803         /*
 804          * Final return path. BookE is handled in a different file
 805          */
 806 do_restore:
 807 #ifdef CONFIG_PPC_BOOK3E
 808         b       .exception_return_book3e
 809 #else
 810         /*
 811          * Clear the reservation. If we know the CPU tracks the address of
 812          * the reservation then we can potentially save some cycles and use
 813          * a larx. On POWER6 and POWER7 this is significantly faster.
 814          */
 815 BEGIN_FTR_SECTION
 816         stdcx.  r0,0,r1         /* to clear the reservation */
 817 FTR_SECTION_ELSE
 818         ldarx   r4,0,r1
 819 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 820
 821         /*
 822          * Some code path such as load_up_fpu or altivec return directly
 823          * here. They run entirely hard disabled and do not alter the
 824          * interrupt state. They also don't use lwarx/stwcx. and thus
 825          * are known not to leave dangling reservations.
 826          */
 827         .globl  fast_exception_return
 828 fast_exception_return:
 829         ld      r3,_MSR(r1)
 830         ld      r4,_CTR(r1)
 831         ld      r0,_LINK(r1)
 832         mtctr   r4
 833         mtlr    r0
 834         ld      r4,_XER(r1)
 835         mtspr   SPRN_XER,r4
 836
 837         REST_8GPRS(5, r1)
 838
 839         andi.   r0,r3,MSR_RI
 840         beq-    unrecov_restore
 841
 842         /*
 843          * Clear RI before restoring r13.  If we are returning to
 844          * userspace and we take an exception after restoring r13,
 845          * we end up corrupting the userspace r13 value.
 846          */
 847         ld      r4,PACAKMSR(r13) /* Get kernel MSR without EE */
 848         andc    r4,r4,r0         /* r0 contains MSR_RI here */
 849         mtmsrd  r4,1
 850
 851 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 852         /* TM debug */
 853         std     r3, PACATMSCRATCH(r13) /* Stash returned-to MSR */
 854 #endif
 855         /*
 856          * r13 is our per cpu area, only restore it if we are returning to
 857          * userspace the value stored in the stack frame may belong to
 858          * another CPU.
 859          */
 860         andi.   r0,r3,MSR_PR
 861         beq     1f
 862         ACCOUNT_CPU_USER_EXIT(r2, r4)
 863         RESTORE_PPR(r2, r4)
 864         REST_GPR(13, r1)
 865 1:
 866         mtspr   SPRN_SRR1,r3
 867
 868         ld      r2,_CCR(r1)
 869         mtcrf   0xFF,r2
 870         ld      r2,_NIP(r1)
 871         mtspr   SPRN_SRR0,r2
 872
 873         ld      r0,GPR0(r1)
 874         ld      r2,GPR2(r1)
 875         ld      r3,GPR3(r1)
 876         ld      r4,GPR4(r1)
 877         ld      r1,GPR1(r1)
 878
 879         rfid
 880         b       .       /* prevent speculative execution */
 881
 882 #endif /* CONFIG_PPC_BOOK3E */
 883
 884         /*
 885          * We are returning to a context with interrupts soft disabled.
 886          *
 887          * However, we may also about to hard enable, so we need to
 888          * make sure that in this case, we also clear PACA_IRQ_HARD_DIS
 889          * or that bit can get out of sync and bad things will happen
 890          */
 891 restore_irq_off:
 892         ld      r3,_MSR(r1)
 893         lbz     r7,PACAIRQHAPPENED(r13)
 894         andi.   r0,r3,MSR_EE
 895         beq     1f
 896         rlwinm  r7,r7,0,~PACA_IRQ_HARD_DIS
 897         stb     r7,PACAIRQHAPPENED(r13)
 898 1:      li      r0,0
 899         stb     r0,PACASOFTIRQEN(r13);
 900         TRACE_DISABLE_INTS
 901         b       do_restore
 902
 903         /*
 904          * Something did happen, check if a re-emit is needed
 905          * (this also clears paca->irq_happened)
 906          */
 907 restore_check_irq_replay:
 908         /* XXX: We could implement a fast path here where we check
 909          * for irq_happened being just 0x01, in which case we can
 910          * clear it and return. That means that we would potentially
 911          * miss a decrementer having wrapped all the way around.
 912          *
 913          * Still, this might be useful for things like hash_page
 914          */
 915         bl      .__check_irq_replay
 916         cmpwi   cr0,r3,0
 917         beq     restore_no_replay
 918
 919         /*
 920          * We need to re-emit an interrupt. We do so by re-using our
 921          * existing exception frame. We first change the trap value,
 922          * but we need to ensure we preserve the low nibble of it
 923          */
 924         ld      r4,_TRAP(r1)
 925         clrldi  r4,r4,60
 926         or      r4,r4,r3
 927         std     r4,_TRAP(r1)
 928
 929         /*
 930          * Then find the right handler and call it. Interrupts are
 931          * still soft-disabled and we keep them that way.
 932         */
 933         cmpwi   cr0,r3,0x500
 934         bne     1f
 935         addi    r3,r1,STACK_FRAME_OVERHEAD;
 936         bl      .do_IRQ
 937         b       .ret_from_except
 938 1:      cmpwi   cr0,r3,0x900
 939         bne     1f
 940         addi    r3,r1,STACK_FRAME_OVERHEAD;
 941         bl      .timer_interrupt
 942         b       .ret_from_except
 943 #ifdef CONFIG_PPC_DOORBELL
 944 1:
 945 #ifdef CONFIG_PPC_BOOK3E
 946         cmpwi   cr0,r3,0x280
 947 #else
 948         BEGIN_FTR_SECTION
 949                 cmpwi   cr0,r3,0xe80
 950         FTR_SECTION_ELSE
 951                 cmpwi   cr0,r3,0xa00
 952         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE)
 953 #endif /* CONFIG_PPC_BOOK3E */
 954         bne     1f
 955         addi    r3,r1,STACK_FRAME_OVERHEAD;
 956         bl      .doorbell_exception
 957         b       .ret_from_except
 958 #endif /* CONFIG_PPC_DOORBELL */
 959 1:      b       .ret_from_except /* What else to do here ? */
 960
 961 unrecov_restore:
 962         addi    r3,r1,STACK_FRAME_OVERHEAD
 963         bl      .unrecoverable_exception
 964         b       unrecov_restore
 965
 966 #ifdef CONFIG_PPC_RTAS
 967 /*
 968  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 969  * called with the MMU off.
 970  *
 971  * In addition, we need to be in 32b mode, at least for now.
 972  *
 973  * Note: r3 is an input parameter to rtas, so don't trash it...
 974  */
 975 _GLOBAL(enter_rtas)
 976         mflr    r0
 977         std     r0,16(r1)
 978         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 979
 980         /* Because RTAS is running in 32b mode, it clobbers the high order half
 981          * of all registers that it saves.  We therefore save those registers
 982          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 983          */
 984         SAVE_GPR(2, r1)                 /* Save the TOC */
 985         SAVE_GPR(13, r1)                /* Save paca */
 986         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 987         SAVE_10GPRS(22, r1)             /* ditto */
 988
 989         mfcr    r4
 990         std     r4,_CCR(r1)
 991         mfctr   r5
 992         std     r5,_CTR(r1)
 993         mfspr   r6,SPRN_XER
 994         std     r6,_XER(r1)
 995         mfdar   r7
 996         std     r7,_DAR(r1)
 997         mfdsisr r8
 998         std     r8,_DSISR(r1)
 999
1000         /* Temporary workaround to clear CR until RTAS can be modified to
1001          * ignore all bits.
1002          */
1003         li      r0,0
1004         mtcr    r0
1005
1006 #ifdef CONFIG_BUG
1007         /* There is no way it is acceptable to get here with interrupts enabled,
1008          * check it with the asm equivalent of WARN_ON
1009          */
1010         lbz     r0,PACASOFTIRQEN(r13)
1011 1:      tdnei   r0,0
1012         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
1013 #endif
1014
1015         /* Hard-disable interrupts */
1016         mfmsr   r6
1017         rldicl  r7,r6,48,1
1018         rotldi  r7,r7,16
1019         mtmsrd  r7,1
1020
1021         /* Unfortunately, the stack pointer and the MSR are also clobbered,
1022          * so they are saved in the PACA which allows us to restore
1023          * our original state after RTAS returns.
1024          */
1025         std     r1,PACAR1(r13)
1026         std     r6,PACASAVEDMSR(r13)
1027
1028         /* Setup our real return addr */
1029         LOAD_REG_ADDR(r4,.rtas_return_loc)
1030         clrldi  r4,r4,2                 /* convert to realmode address */
1031         mtlr    r4
1032
1033         li      r0,0
1034         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
1035         andc    r0,r6,r0
1036
1037         li      r9,1
1038         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
1039         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP|MSR_RI
1040         andc    r6,r0,r9
1041         sync                            /* disable interrupts so SRR0/1 */
1042         mtmsrd  r0                      /* don't get trashed */
1043
1044         LOAD_REG_ADDR(r4, rtas)
1045         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
1046         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
1047
1048         mtspr   SPRN_SRR0,r5
1049         mtspr   SPRN_SRR1,r6
1050         rfid
1051         b       .       /* prevent speculative execution */
1052
1053 _STATIC(rtas_return_loc)
1054         /* relocation is off at this point */
1055         GET_PACA(r4)
1056         clrldi  r4,r4,2                 /* convert to realmode address */
1057
1058         bcl     20,31,$+4
1059 0:      mflr    r3
1060         ld      r3,(1f-0b)(r3)          /* get &.rtas_restore_regs */
1061
1062         mfmsr   r6
1063         li      r0,MSR_RI
1064         andc    r6,r6,r0
1065         sync
1066         mtmsrd  r6
1067
1068         ld      r1,PACAR1(r4)           /* Restore our SP */
1069         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
1070
1071         mtspr   SPRN_SRR0,r3
1072         mtspr   SPRN_SRR1,r4
1073         rfid
1074         b       .       /* prevent speculative execution */
1075
1076         .align  3
1077 1:      .llong  .rtas_restore_regs
1078
1079 _STATIC(rtas_restore_regs)
1080         /* relocation is on at this point */
1081         REST_GPR(2, r1)                 /* Restore the TOC */
1082         REST_GPR(13, r1)                /* Restore paca */
1083         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
1084         REST_10GPRS(22, r1)             /* ditto */
1085
1086         GET_PACA(r13)
1087
1088         ld      r4,_CCR(r1)
1089         mtcr    r4
1090         ld      r5,_CTR(r1)
1091         mtctr   r5
1092         ld      r6,_XER(r1)
1093         mtspr   SPRN_XER,r6
1094         ld      r7,_DAR(r1)
1095         mtdar   r7
1096         ld      r8,_DSISR(r1)
1097         mtdsisr r8
1098
1099         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
1100         ld      r0,16(r1)               /* get return address */
1101
1102         mtlr    r0
1103         blr                             /* return to caller */
1104
1105 #endif /* CONFIG_PPC_RTAS */
1106
1107 _GLOBAL(enter_prom)
1108         mflr    r0
1109         std     r0,16(r1)
1110         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
1111
1112         /* Because PROM is running in 32b mode, it clobbers the high order half
1113          * of all registers that it saves.  We therefore save those registers
1114          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
1115          */
1116         SAVE_GPR(2, r1)
1117         SAVE_GPR(13, r1)
1118         SAVE_8GPRS(14, r1)
1119         SAVE_10GPRS(22, r1)
1120         mfcr    r10
1121         mfmsr   r11
1122         std     r10,_CCR(r1)
1123         std     r11,_MSR(r1)
1124
1125         /* Get the PROM entrypoint */
1126         mtlr    r4
1127
1128         /* Switch MSR to 32 bits mode
1129          */
1130 #ifdef CONFIG_PPC_BOOK3E
1131         rlwinm  r11,r11,0,1,31
1132         mtmsr   r11
1133 #else /* CONFIG_PPC_BOOK3E */
1134         mfmsr   r11
1135         li      r12,1
1136         rldicr  r12,r12,MSR_SF_LG,(63-MSR_SF_LG)
1137         andc    r11,r11,r12
1138         li      r12,1
1139         rldicr  r12,r12,MSR_ISF_LG,(63-MSR_ISF_LG)
1140         andc    r11,r11,r12
1141         mtmsrd  r11
1142 #endif /* CONFIG_PPC_BOOK3E */
1143         isync
1144
1145         /* Enter PROM here... */
1146         blrl
1147
1148         /* Just make sure that r1 top 32 bits didn't get
1149          * corrupt by OF
1150          */
1151         rldicl  r1,r1,0,32
1152
1153         /* Restore the MSR (back to 64 bits) */
1154         ld      r0,_MSR(r1)
1155         MTMSRD(r0)
1156         isync
1157
1158         /* Restore other registers */
1159         REST_GPR(2, r1)
1160         REST_GPR(13, r1)
1161         REST_8GPRS(14, r1)
1162         REST_10GPRS(22, r1)
1163         ld      r4,_CCR(r1)
1164         mtcr    r4
1165
1166         addi    r1,r1,PROM_FRAME_SIZE
1167         ld      r0,16(r1)
1168         mtlr    r0
1169         blr
1170
1171 #ifdef CONFIG_FUNCTION_TRACER
1172 #ifdef CONFIG_DYNAMIC_FTRACE
1173 _GLOBAL(mcount)
1174 _GLOBAL(_mcount)
1175         blr
1176
1177 _GLOBAL(ftrace_caller)
1178         /* Taken from output of objdump from lib64/glibc */
1179         mflr    r3
1180         ld      r11, 0(r1)
1181         stdu    r1, -112(r1)
1182         std     r3, 128(r1)
1183         ld      r4, 16(r11)
1184         subi    r3, r3, MCOUNT_INSN_SIZE
1185 .globl ftrace_call
1186 ftrace_call:
1187         bl      ftrace_stub
1188         nop
1189 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1190 .globl ftrace_graph_call
1191 ftrace_graph_call:
1192         b       ftrace_graph_stub
1193 _GLOBAL(ftrace_graph_stub)
1194 #endif
1195         ld      r0, 128(r1)
1196         mtlr    r0
1197         addi    r1, r1, 112
1198 _GLOBAL(ftrace_stub)
1199         blr
1200 #else
1201 _GLOBAL(mcount)
1202         blr
1203
1204 _GLOBAL(_mcount)
1205         /* Taken from output of objdump from lib64/glibc */
1206         mflr    r3
1207         ld      r11, 0(r1)
1208         stdu    r1, -112(r1)
1209         std     r3, 128(r1)
1210         ld      r4, 16(r11)
1211
1212         subi    r3, r3, MCOUNT_INSN_SIZE
1213         LOAD_REG_ADDR(r5,ftrace_trace_function)
1214         ld      r5,0(r5)
1215         ld      r5,0(r5)
1216         mtctr   r5
1217         bctrl
1218         nop
1219
1220
1221 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1222         b       ftrace_graph_caller
1223 #endif
1224         ld      r0, 128(r1)
1225         mtlr    r0
1226         addi    r1, r1, 112
1227 _GLOBAL(ftrace_stub)
1228         blr
1229
1230 #endif /* CONFIG_DYNAMIC_FTRACE */
1231
1232 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1233 _GLOBAL(ftrace_graph_caller)
1234         /* load r4 with local address */
1235         ld      r4, 128(r1)
1236         subi    r4, r4, MCOUNT_INSN_SIZE
1237
1238         /* get the parent address */
1239         ld      r11, 112(r1)
1240         addi    r3, r11, 16
1241
1242         bl      .prepare_ftrace_return
1243         nop
1244
1245         ld      r0, 128(r1)
1246         mtlr    r0
1247         addi    r1, r1, 112
1248         blr
1249
1250 _GLOBAL(return_to_handler)
1251         /* need to save return values */
1252         std     r4,  -24(r1)
1253         std     r3,  -16(r1)
1254         std     r31, -8(r1)
1255         mr      r31, r1
1256         stdu    r1, -112(r1)
1257
1258         bl      .ftrace_return_to_handler
1259         nop
1260
1261         /* return value has real return address */
1262         mtlr    r3
1263
1264         ld      r1, 0(r1)
1265         ld      r4,  -24(r1)
1266         ld      r3,  -16(r1)
1267         ld      r31, -8(r1)
1268
1269         /* Jump back to real return address */
1270         blr
1271
1272 _GLOBAL(mod_return_to_handler)
1273         /* need to save return values */
1274         std     r4,  -32(r1)
1275         std     r3,  -24(r1)
1276         /* save TOC */
1277         std     r2,  -16(r1)
1278         std     r31, -8(r1)
1279         mr      r31, r1
1280         stdu    r1, -112(r1)
1281
1282         /*
1283          * We are in a module using the module's TOC.
1284          * Switch to our TOC to run inside the core kernel.
1285          */
1286         ld      r2, PACATOC(r13)
1287
1288         bl      .ftrace_return_to_handler
1289         nop
1290
1291         /* return value has real return address */
1292         mtlr    r3
1293
1294         ld      r1, 0(r1)
1295         ld      r4,  -32(r1)
1296         ld      r3,  -24(r1)
1297         ld      r2,  -16(r1)
1298         ld      r31, -8(r1)
1299
1300         /* Jump back to real return address */
1301         blr
1302 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
1303 #endif /* CONFIG_FUNCTION_TRACER */