Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 # In the following, there are a the following variants
   5 # of GLib cflags and libs variables
   6 #
   7 # GLIB_CFLAGS:  cflags for compiling libraries and example progs
   8 # GLIB_LIBS:    libraries for linking example programs
   9 # GLIB_DEPLIBS: libraries for linking libraries against
  10 # glib_cflags:  cflags to store in gtk-config
  11 # glib_libs:    libs to store in gtk-config
  12 # glib_thread_cflags: cflags to store in gtk-config for gtk-config gthread
  13 # glib_thread_libs:   libs to store in gtk-config for gtk-config gthread
  14
  15 # Save this value here, since automake will set cflags later
  16 cflags_set=${CFLAGS+set}
  17
  18 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  19 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  20 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  21 #
  22 # Making releases:
  23 #   GTK_MICRO_VERSION += 1;
  24 #   GTK_INTERFACE_AGE += 1;
  25 #   GTK_BINARY_AGE += 1;
  26 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  27 # if backwards compatibility has been broken,
  28 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  29 #
  30 GTK_MAJOR_VERSION=1
  31 GTK_MINOR_VERSION=3
  32 GTK_MICRO_VERSION=0
  33 GTK_INTERFACE_AGE=0
  34 GTK_BINARY_AGE=0
  35 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  36 dnl
  37 AC_DIVERT_POP()dnl
  38
  39 AC_SUBST(GTK_MAJOR_VERSION)
  40 AC_SUBST(GTK_MINOR_VERSION)
  41 AC_SUBST(GTK_MICRO_VERSION)
  42 AC_SUBST(GTK_INTERFACE_AGE)
  43 AC_SUBST(GTK_BINARY_AGE)
  44 AC_SUBST(GTK_VERSION)
  45
  46 # libtool versioning
  47 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  48 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  49 LT_REVISION=$GTK_INTERFACE_AGE
  50 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  51 AC_SUBST(LT_RELEASE)
  52 AC_SUBST(LT_CURRENT)
  53 AC_SUBST(LT_REVISION)
  54 AC_SUBST(LT_AGE)
  55
  56 # For automake.
  57 VERSION=$GTK_VERSION
  58 PACKAGE=gtk+
  59
  60 # Save this value here, since automake will set cflags later
  61 cflags_set=${CFLAGS+set}
  62
  63 dnl Initialize automake stuff
  64 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  65
  66 # Specify a configuration file
  67 AM_CONFIG_HEADER(config.h)
  68
  69 dnl Initialize libtool
  70 AM_PROG_LIBTOOL
  71
  72 dnl Initialize maintainer mode
  73 AM_MAINTAINER_MODE
  74
  75 AC_CANONICAL_HOST
  76
  77 dnl figure debugging default, prior to $ac_help setup
  78 dnl
  79 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  80 if test `expr $GTK_MINOR_VERSION \% 2` = 1 ; then
  81         debug_default=yes
  82 else
  83         debug_default=minimum
  84 fi
  85 AC_DIVERT_POP()dnl
  86
  87 dnl declare --enable-* args and collect ac_help strings
  88 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
  89 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
  90                    echo $enable_shm, enable_shm="yes")
  91 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  92                     , enable_ansi=no)
  93 AC_ARG_WITH(glib, [  --with-glib=DIR         Use uninstalled copy of glib])
  94 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
  95                         , enable_xim="yes")
  96 AC_ARG_ENABLE(xim_inst, [  --disable-xim-inst      does not use xim instantiate callback],
  97                         , enable_xim_inst="maybe")
  98 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
  99 AC_ARG_WITH(locale, [  --with-locale=LOCALE    locale name you want to use ])
 100
 101 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
 102
 103 if test "x$enable_debug" = "xyes"; then
 104   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 105   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 106 else
 107   if test "x$enable_debug" = "xno"; then
 108     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DGTK_NO_CHECK_CASTS"
 109   else
 110     GTK_DEBUG_FLAGS="-DGTK_NO_CHECK_CASTS"
 111   fi
 112 fi
 113
 114 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 115
 116 # Build time sanity check...
 117 AM_SANITY_CHECK
 118
 119 # Checks for programs.
 120 AC_PROG_CC
 121 AC_ISC_POSIX
 122 AM_PROG_CC_STDC
 123 AC_PROG_INSTALL
 124 AC_PROG_MAKE_SET
 125
 126 changequote(,)dnl
 127 if test "x$GCC" = "xyes"; then
 128   case " $CFLAGS " in
 129   *[\ \ ]-Wall[\ \      ]*) ;;
 130   *) CFLAGS="$CFLAGS -Wall" ;;
 131   esac
 132
 133   if test "x$enable_ansi" = "xyes"; then
 134     case " $CFLAGS " in
 135     *[\ \       ]-ansi[\ \      ]*) ;;
 136     *) CFLAGS="$CFLAGS -ansi" ;;
 137     esac
 138
 139     case " $CFLAGS " in
 140     *[\ \       ]-pedantic[\ \  ]*) ;;
 141     *) CFLAGS="$CFLAGS -pedantic" ;;
 142     esac
 143   fi
 144 fi
 145 changequote([,])dnl
 146
 147 # Honor aclocal flags
 148 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 149
 150 # define a MAINT-like variable REBUILD which is set if Perl
 151 # and awk are found, so autogenerated sources can be rebuilt
 152
 153 AC_PROG_AWK
 154 AC_CHECK_PROGS(PERL, perl5 perl)
 155
 156 # We would like indent, but don't require it.
 157 AC_CHECK_PROG(INDENT, indent, indent)
 158
 159 REBUILD=\#
 160 if test "x$enable_rebuilds" = "xyes" && \
 161      test -n "$PERL" && \
 162      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 163      test -n "$AWK" ; then
 164   REBUILD=
 165 fi
 166 AC_SUBST(REBUILD)
 167
 168 AC_CHECK_FUNCS(lstat)
 169
 170 AC_MSG_CHECKING(whether make is GNU Make)
 171 STRIP_BEGIN=
 172 STRIP_END=
 173 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 174         STRIP_BEGIN='$(strip'
 175         STRIP_END=')'
 176         AC_MSG_RESULT(yes)
 177 else
 178         AC_MSG_RESULT(no)
 179 fi
 180 AC_SUBST(STRIP_BEGIN)
 181 AC_SUBST(STRIP_END)
 182
 183 # i18n stuff
 184 ALL_LINGUAS="ca cs da de el es et eu fi fr ga gl hr hu it ja ko nl no pl pt pt_BR ru sk sl sv uk wa zh_TW.Big5"
 185 AM_GTK_GNU_GETTEXT
 186 LIBS="$LIBS $INTLLIBS"
 187
 188 # AM_GTK_GNU_GETTEXT above substs $DATADIRNAME
 189 # this is the directory where the *.{mo,gmo} files are installed
 190 gtklocaledir='${prefix}/${DATADIRNAME}/locale'
 191 AC_SUBST(gtklocaledir)
 192
 193 dnl The DU4 header files don't provide library prototypes unless
 194 dnl -std1 is given to the native cc.
 195 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 196
 197 gtk_save_LIBS=$LIBS
 198 LIBS="$LIBS -lm"
 199 AC_TRY_RUN([#include <math.h>
 200              int main (void) { return (log(1) != log(1.)); }],
 201      AC_MSG_RESULT(none needed),
 202      gtk_save_CFLAGS=$CFLAGS
 203      CFLAGS="$CFLAGS -std1"
 204      AC_TRY_RUN([#include <math.h>
 205                  int main (void) { return (log(1) != log(1.)); }],
 206          AC_MSG_RESULT(-std1),
 207          AC_MSG_RESULT()
 208          CFLAGS=$gtk_save_CFLAGS
 209          AC_MSG_WARN(
 210                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 211          true
 212      ),
 213      AC_MSG_RESULT(none needed)
 214 )
 215 LIBS=$gtk_save_LIBS
 216
 217 MATH_LIB=-lm
 218 GTK_LIBS_EXTRA=
 219 AC_MSG_CHECKING(for the BeOS)
 220 case $host in
 221   *-*-beos*)
 222     AC_MSG_RESULT(yes)
 223     GTK_LIBS_EXTRA="-L\$(top_builddir_full)/gdk/.libs -lgdk"
 224     MATH_LIB=
 225   ;;
 226   *)
 227     AC_MSG_RESULT(no)
 228   ;;
 229 esac
 230 AC_SUBST(MATH_LIB)
 231 AC_SUBST(GTK_LIBS_EXTRA)
 232
 233 dnl NeXTStep cc seems to need this
 234 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 235 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 236   AC_MSG_RESULT(none needed),
 237   gtk_save_CFLAGS=$CFLAGS
 238   CFLAGS="$CFLAGS -posix"
 239   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 240     AC_MSG_RESULT(-posix),
 241     AC_MSG_RESULT()
 242     CFLAGS=$gtk_save_CFLAGS
 243     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 244
 245 if test x$with_glib = xyes ; then
 246   AC_MSG_ERROR([
 247 *** Directory must be specified for --with-glib])
 248 fi
 249
 250 if test x$with_glib = x ; then
 251   # Look for separately installed glib
 252
 253   AM_PATH_GLIB(1.3.0,,
 254     AC_MSG_ERROR([
 255 *** GLIB 1.3.0 or better is required. The latest version of GLIB
 256 *** is always available from ftp://ftp.gtk.org/.]),
 257     gmodule gthread)
 258
 259   # we do not want to make all gtk progs to link to thread libraries.
 260   glib_cflags=`$GLIB_CONFIG glib gmodule --cflags`
 261   glib_thread_cflags="$GLIB_CFLAGS"
 262   glib_libs=`$GLIB_CONFIG glib gmodule --libs`
 263   glib_thread_libs="$GLIB_LIBS"
 264   GLIB_LIBS="$glib_libs"
 265   GLIB_DEPLIBS="$glib_libs"
 266 else
 267   # Use uninstalled glib (assume they got the version right)
 268
 269   GLIB_CONFIG=$with_glib/glib-config
 270   if test -x $GLIB_CONFIG ; then
 271     :
 272   else
 273     AC_MSG_ERROR([GLIB directory ($with_glib) not present or not configured])
 274   fi
 275
 276   # For use in gtk-config
 277   glib_cflags=`$GLIB_CONFIG --cflags gmodule`
 278   glib_thread_cflags=`$GLIB_CONFIG --cflags gmodule gthread`
 279   glib_libs=`$GLIB_CONFIG --libs gmodule`
 280   glib_thread_libs=`$GLIB_CONFIG --libs gmodule gthread`
 281
 282   glib_release=`$GLIB_CONFIG --version | sed 's%\\.[[0-9]]*$%%'`
 283
 284   # canonicalize relative paths
 285   case $with_glib in
 286     /*)
 287       glib_dir=$with_glib
 288       ;;
 289     *)
 290       glib_dir="\$(top_builddir)/$with_glib"
 291       ;;
 292   esac
 293
 294   GLIB_CFLAGS="-I$glib_dir -I$glib_dir/gmodule"
 295   GLIB_LIBS="$glib_dir/libglib.la $glib_dir/gmodule/libgmodule.la"
 296   GLIB_DEPLIBS=
 297
 298   AC_SUBST(GLIB_CFLAGS)
 299   AC_SUBST(GLIB_LIBS)
 300 fi
 301
 302 AC_SUBST(glib_cflags)
 303 AC_SUBST(glib_libs)
 304 AC_SUBST(glib_thread_cflags)
 305 AC_SUBST(glib_thread_libs)
 306 AC_SUBST(GLIB_DEPLIBS)
 307
 308 AC_CHECK_HEADERS(dirent.h, AC_DEFINE(HAVE_DIRENT_H))
 309 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 310 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 311
 312 # Find the X11 include and library directories
 313 AC_PATH_X
 314 AC_PATH_XTRA
 315
 316 if test "x$x_includes" = "x"; then
 317   x_includes="/usr/include"
 318 fi
 319
 320 saved_cflags="$CFLAGS"
 321 saved_ldflags="$LDFLAGS"
 322
 323 CFLAGS="$CFLAGS $X_CFLAGS"
 324 LDFLAGS="$LDFLAGS $X_LDFLAGS $X_LIBS"
 325
 326 if test "x$no_x" = "xyes"; then
 327   AC_MSG_ERROR([
 328 *** X libraries or include files not found. Check 'config.log' for
 329 *** more details.])
 330 fi
 331
 332 # Checks for libraries.
 333 # Check for the X11 library
 334 AC_CHECK_LIB(X11, XOpenDisplay, x_libs="-lX11 $X_EXTRA_LIBS",
 335   AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 336   $X_EXTRA_LIBS)
 337
 338 if test "x$enable_shm" = "xyes"; then
 339   # Check for the Xext library (needed for XShm extention)
 340   AC_CHECK_LIB(Xext, XShmAttach,
 341       x_libs="-lXext $x_libs",
 342       # On AIX, it is in XextSam instead, but we still need -lXext
 343       AC_CHECK_LIB(XextSam, XShmAttach,
 344           x_libs="-lXextSam -lXext $x_libs",
 345           no_xext_lib=yes, $x_libs),
 346       $x_libs)
 347 fi
 348
 349 # Check for shaped window extension
 350
 351 AC_CHECK_LIB(Xext, XShapeCombineMask,
 352       if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 353            x_libs="-lXext $x_libs"
 354       fi
 355       AC_DEFINE(HAVE_SHAPE_EXT),
 356       ,
 357       $x_libs)
 358
 359 # Check for XConvertCase (X11R6 specific)
 360
 361 AC_CHECK_LIB(X11, XConvertCase,
 362       AC_DEFINE(HAVE_XCONVERTCASE),
 363       ,
 364       $x_libs)
 365
 366 # Check for XIM support.
 367
 368 AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 369             : ,
 370             enable_xim_inst="no",
 371             $x_libs)
 372
 373 # On Solaris, calling XRegisterIMInstantiateCallback seems to
 374 # cause an immediate segfault, so we disable it, unless
 375 # the user specifically forces it to be on.
 376
 377 if test x$enable_xim_inst = xmaybe ; then
 378   case host in
 379         *-*-solaris*)
 380             enable_xim_inst="no"
 381             ;;
 382         *)
 383             enable_xim_inst="yes"
 384             ;;
 385   esac
 386 fi
 387
 388 if test "x$enable_xim" = "xyes"; then
 389   GTK_XIM_FLAGS="-DUSE_XIM"
 390   if test "x$enable_xim_inst" = "xyes"; then
 391     AC_DEFINE(USE_X11R6_XIM)
 392   fi
 393 fi
 394
 395 x_cflags="$X_CFLAGS"
 396 x_ldflags="$X_LDFLAGS $X_LIBS"
 397
 398 # set up things for XInput
 399
 400 if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 401   AC_DEFINE(XINPUT_GXI)
 402   xinput_progs=gxid
 403   x_libs="-lXi $x_libs"
 404 elif test "x$with_xinput" = "xxfree"; then
 405   AC_DEFINE(XINPUT_XFREE)
 406   x_libs="-lXi $x_libs"
 407 else
 408   AC_DEFINE(XINPUT_NONE)
 409 fi
 410
 411 AM_CONDITIONAL(XINPUT_GXI, test x$with_xinput = xgxi)
 412 AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree)
 413
 414 CFLAGS="$saved_cflags"
 415 LDFLAGS="$saved_ldflags"
 416
 417 AC_SUBST(x_cflags)
 418 AC_SUBST(x_includes)
 419 AC_SUBST(x_ldflags)
 420 AC_SUBST(x_libs)
 421 AC_SUBST(xinput_progs)
 422
 423 if test "x$enable_shm" = "xyes"; then
 424   # Check for shared memory
 425   AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 426   AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 427
 428   # Check for the X shared memory extension header file
 429   AC_MSG_CHECKING(X11/extensions/XShm.h)
 430   if test "x$no_xext_lib" = "xyes"; then
 431     AC_MSG_RESULT(no)
 432     no_xshm=yes
 433   else
 434     if test -f "$x_includes/X11/extensions/XShm.h"; then
 435       AC_MSG_RESULT(yes)
 436       AC_DEFINE(HAVE_XSHM_H)
 437     else
 438       AC_MSG_RESULT(no)
 439       no_xshm=yes
 440     fi
 441   fi
 442 fi
 443
 444 # Check if X_LOCALE definition is necessary
 445
 446 AC_MSG_CHECKING(need -DX_LOCALE)
 447
 448 AC_TRY_RUN([
 449 #include <stdio.h>
 450 #include <locale.h>
 451
 452 int
 453 main ()
 454 {
 455   return setlocale (LC_ALL, "${with_locale}") == NULL;
 456 }],
 457 need_x_locale=no,
 458 need_x_locale=yes,
 459 need_x_locale=no)
 460 AC_MSG_RESULT($need_x_locale)
 461
 462 if test $need_x_locale = yes; then
 463   GTK_LOCALE_FLAGS="-DX_LOCALE"
 464 fi
 465
 466 # Checks for header files.
 467 AC_HEADER_STDC
 468
 469 # Checks for typedefs, structures, and compiler characteristics.
 470 AC_C_CONST
 471
 472 # Checks for library functions.
 473 AC_TYPE_SIGNAL
 474 AC_FUNC_MMAP
 475
 476 # Check if <sys/select.h> needs to be included for fd_set
 477 AC_MSG_CHECKING([for fd_set])
 478 AC_TRY_COMPILE([#include <sys/types.h>],
 479         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 480 if test $gtk_ok = yes; then
 481     AC_MSG_RESULT([yes, found in sys/types.h])
 482 else
 483     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 484     if test $gtk_ok = yes; then
 485         AC_DEFINE(HAVE_SYS_SELECT_H)
 486         AC_MSG_RESULT([yes, found in sys/select.h])
 487     else
 488         AC_DEFINE(NO_FD_SET)
 489         AC_MSG_RESULT(no)
 490     fi
 491 fi
 492
 493 # `widechar' tests for gdki18n.h
 494 AC_MSG_CHECKING(for wchar.h)
 495 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 496 if test $gdk_wchar_h = yes; then
 497    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 498 fi
 499 AC_MSG_RESULT($gdk_wchar_h)
 500
 501 # Check for wctype.h (for iswalnum)
 502 AC_MSG_CHECKING(for wctype.h)
 503 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 504 if test $gdk_wctype_h = yes; then
 505    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 506 fi
 507 AC_MSG_RESULT($gdk_wctype_h)
 508
 509 # in Solaris 2.5, `iswalnum' is in -lw
 510 GDK_WLIBS=
 511 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 512
 513 oLIBS="$LIBS"
 514 LIBS="$LIBS $GDK_WLIBS"
 515 # The following is necessary for Linux libc-5.4.38
 516 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 517 AC_TRY_LINK([#include <stdlib.h>],[
 518 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 519 #  ifdef HAVE_WCTYPE_H
 520 #    include <wctype.h>
 521 #  else
 522 #    ifdef HAVE_WCHAR_H
 523 #      include <wchar.h>
 524 #    endif
 525 #  endif
 526 #else
 527 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 528 #endif
 529 iswalnum((wchar_t) 0);
 530 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 531 LIBS="$oLIBS"
 532
 533 if test $gdk_working_wctype = no; then
 534    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 535    GDK_WLIBS=
 536 fi
 537 AC_MSG_RESULT($gdk_working_wctype)
 538 AC_SUBST(GDK_WLIBS)
 539
 540 AC_SUBST(GTK_DEBUG_FLAGS)
 541 AC_SUBST(GTK_XIM_FLAGS)
 542 AC_SUBST(GTK_LOCALE_FLAGS)
 543
 544 AC_OUTPUT_COMMANDS([
 545
 546 ## Generate `gdk/gdkconfig.h' in two cases
 547 ## 1. `config.status' is run either explicitly, or via configure.
 548 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 549 ##     config.h
 550 ## 2. CONFIG_OTHER is set explicitly
 551 ##
 552 ## Case 1 is difficult.  We know that `automake' sets one of
 553 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 554 ## only when AM_CONFIG_HEADER is set, however.
 555
 556 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 557   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 558   CONFIG_OTHER=${CONFIG_OTHER:-gdk/gdkconfig.h}
 559 fi
 560 case "$CONFIG_OTHER" in
 561 *gdk/gdkconfig.h*)
 562         echo creating gdk/gdkconfig.h
 563         outfile=gdkconfig.h-tmp
 564         cat > $outfile <<\_______EOF
 565 /* gdkconfig.h
 566  *
 567  * This is a generated file.  Please modify `configure.in'
 568  */
 569
 570 #ifndef GDKCONFIG_H
 571 #define GDKCONFIG_H
 572
 573 #ifdef __cplusplus
 574 extern "C" {
 575 #endif /* __cplusplus */
 576
 577 _______EOF
 578
 579         cat >>$outfile <<_______EOF
 580 $gdk_windowing
 581 $gdk_wc
 582 _______EOF
 583
 584         cat >>$outfile <<_______EOF
 585
 586 #ifdef __cplusplus
 587 }
 588 #endif /* __cplusplus */
 589
 590 #endif /* GDKCONFIG_H */
 591 _______EOF
 592
 593
 594         if cmp -s $outfile gdk/gdkconfig.h; then
 595           echo gdk/gdkconfig.h is unchanged
 596           rm -f $outfile
 597         else
 598           mv $outfile gdk/gdkconfig.h
 599         fi ;;
 600 esac
 601 ],[
 602 # Currently we always use X11 on those systems where we run configure...
 603 gdk_windowing='
 604 #define GDK_WINDOWING_X11'
 605 if test x$gdk_wchar_h = xyes; then
 606   gdk_wc='
 607 #define GDK_HAVE_WCHAR_H 1'
 608 fi
 609 if test x$gdk_wctype_h = xyes; then
 610   gdk_wc="\$gdk_wc
 611 #define GDK_HAVE_WCTYPE_H 1"
 612 fi
 613 if test x$gdk_working_wctype = xno; then
 614   gdk_wc="\$gdk_wc
 615 #define GDK_HAVE_BROKEN_WCTYPE 1"
 616 fi
 617
 618
 619 ])
 620
 621 AC_OUTPUT([
 622 gtk+.spec
 623 docs/gtk-config.1
 624 Makefile
 625 gtk-config
 626 po/Makefile.in
 627 docs/Makefile
 628 gdk/Makefile
 629 gdk/x11/Makefile
 630 gtk/Makefile
 631 gtk/gtkfeatures.h
 632 gtk/gtkcompat.h
 633 ], [chmod +x gtk-config])