Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 #
   5 # For each of the libraries we build, we define the following
   6 # substituted variables:
   7 #
   8 # foo_PACKAGES:     pkg-config packages this library requires
   9 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  10 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  11 # foo_DEP_LIBS:     All libraries this module requires
  12 # foo_DEP_CFLAGS:   All cflags this module requires
  13
  14
  15 ## We could have pkg-config uniquify the ldflags and cflags by calling
  16 ## it once with both the GLib and Pango package names, but we don't,
  17 ## someone should fix that.
  18
  19
  20 # Save this value here, since automake will set cflags later
  21 cflags_set=${CFLAGS+set}
  22
  23 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  24 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  25 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  26 #
  27 # Making releases:
  28 #   GTK_MICRO_VERSION += 1;
  29 #   GTK_INTERFACE_AGE += 1;
  30 #   GTK_BINARY_AGE += 1;
  31 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  32 # if backwards compatibility has been broken,
  33 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  34 #
  35 GTK_MAJOR_VERSION=1
  36 GTK_MINOR_VERSION=3
  37 GTK_MICRO_VERSION=5
  38 GTK_INTERFACE_AGE=0
  39 GTK_BINARY_AGE=0
  40 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  41 dnl
  42 AC_DIVERT_POP()dnl
  43
  44 AC_SUBST(GTK_MAJOR_VERSION)
  45 AC_SUBST(GTK_MINOR_VERSION)
  46 AC_SUBST(GTK_MICRO_VERSION)
  47 AC_SUBST(GTK_INTERFACE_AGE)
  48 AC_SUBST(GTK_BINARY_AGE)
  49 AC_SUBST(GTK_VERSION)
  50
  51 # libtool versioning
  52 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  53 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  54 LT_REVISION=$GTK_INTERFACE_AGE
  55 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  56 AC_SUBST(LT_RELEASE)
  57 AC_SUBST(LT_CURRENT)
  58 AC_SUBST(LT_REVISION)
  59 AC_SUBST(LT_AGE)
  60
  61 #
  62 # gdk-pixbuf gets versioned separately, and for now, using standard
  63 # libtool versioning, not GTK+-style versioning
  64 #
  65 GDK_PIXBUF_MAJOR=0
  66 GDK_PIXBUF_MINOR=8
  67 GDK_PIXBUF_MICRO=0
  68 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
  69 AC_SUBST(GDK_PIXBUF_MAJOR)
  70 AC_SUBST(GDK_PIXBUF_MINOR)
  71 AC_SUBST(GDK_PIXBUF_MICRO)
  72 AC_SUBST(GDK_PIXBUF_VERSION)
  73
  74 # For automake.
  75 VERSION=$GTK_VERSION
  76 PACKAGE=gtk+
  77
  78 GETTEXT_PACKAGE=gtk20
  79 AC_SUBST(GETTEXT_PACKAGE)
  80 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
  81
  82 # Save this value here, since automake will set cflags later
  83 cflags_set=${CFLAGS+set}
  84
  85 dnl Initialize automake stuff
  86 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  87
  88 # Specify a configuration file
  89 AM_CONFIG_HEADER(config.h)
  90
  91 dnl Initialize libtool
  92 AM_PROG_LIBTOOL
  93
  94 dnl Initialize maintainer mode
  95 AM_MAINTAINER_MODE
  96
  97 AC_CANONICAL_HOST
  98
  99 dnl figure debugging default, prior to $ac_help setup
 100 dnl
 101 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
 102 if test `expr $GTK_MINOR_VERSION \% 2` = 1 ; then
 103         debug_default=yes
 104 else
 105         debug_default=minimum
 106 fi
 107 AC_DIVERT_POP()dnl
 108
 109 dnl declare --enable-* args and collect ac_help strings
 110 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 111 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
 112                    echo $enable_shm, enable_shm="yes")
 113 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 114                     , enable_ansi=no)
 115 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
 116                         , enable_xim="yes")
 117 AC_ARG_ENABLE(xim_inst, [  --disable-xim-inst      does not use xim instantiate callback],
 118                         , enable_xim_inst="maybe")
 119 AC_ARG_ENABLE(xkb, [  --enable-xkb            support XKB [default=maybe]],
 120                         , enable_xkb="maybe")
 121 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 122
 123 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
 124
 125 gdktarget=x11
 126 gdktargetlib=libgdk-x11-1.3.la
 127 gtktargetlib=libgtk-x11-1.3.la
 128 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[x11/nanox/linux-fb] select GDK target [default=x11] ],
 129         gdktarget=$with_gdktarget)
 130
 131 AC_SUBST(gdktarget)
 132 case $gdktarget in
 133   x11|nanox|linux-fb) ;;
 134   *) AC_MSG_ERROR([Invalid target for GDK: use x11, nanox or linux-fb.]);;
 135 esac
 136
 137 AC_ARG_ENABLE(shadowfb, [  --disable-shadowfb      disable shadowfb support for linux-fb],,enable_shadowfb=yes)
 138
 139 if test "x$enable_debug" = "xyes"; then
 140   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 141   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 142 else
 143   if test "x$enable_debug" = "xno"; then
 144     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 145   else
 146     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 147   fi
 148 fi
 149
 150 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 151
 152
 153 # Build time sanity check...
 154 AM_SANITY_CHECK
 155
 156 # Checks for programs.
 157 AC_PROG_CC
 158 AC_ISC_POSIX
 159 AM_PROG_CC_STDC
 160 AC_PROG_INSTALL
 161 AC_PROG_MAKE_SET
 162
 163 changequote(,)dnl
 164 if test "x$GCC" = "xyes"; then
 165   case " $CFLAGS " in
 166   *[\ \ ]-Wall[\ \      ]*) ;;
 167   *) CFLAGS="$CFLAGS -Wall" ;;
 168   esac
 169
 170   if test "x$enable_ansi" = "xyes"; then
 171     case " $CFLAGS " in
 172     *[\ \       ]-ansi[\ \      ]*) ;;
 173     *) CFLAGS="$CFLAGS -ansi" ;;
 174     esac
 175
 176     case " $CFLAGS " in
 177     *[\ \       ]-pedantic[\ \  ]*) ;;
 178     *) CFLAGS="$CFLAGS -pedantic" ;;
 179     esac
 180   fi
 181 fi
 182 changequote([,])dnl
 183
 184 # Honor aclocal flags
 185 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 186
 187 # libtool option to control which symbols are exported
 188 # right now, symbols starting with _ are not exported
 189 LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 190 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 191
 192 # define a MAINT-like variable REBUILD which is set if Perl
 193 # and awk are found, so autogenerated sources can be rebuilt
 194
 195 AC_PROG_AWK
 196 AC_CHECK_PROGS(PERL, perl5 perl)
 197
 198 # We would like indent, but don't require it.
 199 AC_CHECK_PROG(INDENT, indent, indent)
 200
 201 REBUILD=\#
 202 if test "x$enable_rebuilds" = "xyes" && \
 203      test -n "$PERL" && \
 204      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 205      test -n "$AWK" ; then
 206   REBUILD=
 207 fi
 208 AC_SUBST(REBUILD)
 209
 210 AC_CHECK_FUNCS(lstat mkstemp sigsetjmp bind_textdomain_codeset)
 211
 212 AC_MSG_CHECKING(whether make is GNU Make)
 213 STRIP_BEGIN=
 214 STRIP_END=
 215 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 216         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 217         STRIP_END=')'
 218         AC_MSG_RESULT(yes)
 219 else
 220         AC_MSG_RESULT(no)
 221 fi
 222 STRIP_DUMMY=
 223 AC_SUBST(STRIP_DUMMY)
 224 AC_SUBST(STRIP_BEGIN)
 225 AC_SUBST(STRIP_END)
 226
 227 # i18n stuff
 228 ALL_LINGUAS="az ca cs da de el en_GB en@IPA es et eu fa fi fr ga gl he hr hu ia it ja ko lt nl nn no pl pt pt_BR ro ru sk sl sp sr sv tr uk vi wa zh_TW zh_CN"
 229 AM_GLIB_GNU_GETTEXT
 230 LIBS="$LIBS $INTLLIBS"
 231
 232 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 233 # this is the directory where the *.{mo,gmo} files are installed
 234 gtklocaledir='${prefix}/${DATADIRNAME}/locale'
 235 AC_SUBST(gtklocaledir)
 236
 237 dnl The DU4 header files don't provide library prototypes unless
 238 dnl -std1 is given to the native cc.
 239 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 240
 241 gtk_save_LIBS=$LIBS
 242 LIBS="$LIBS -lm"
 243 AC_TRY_RUN([#include <math.h>
 244              int main (void) { return (log(1) != log(1.)); }],
 245      AC_MSG_RESULT(none needed),
 246      gtk_save_CFLAGS="$CFLAGS"
 247      CFLAGS="$CFLAGS -std1"
 248      AC_TRY_RUN([#include <math.h>
 249                  int main (void) { return (log(1) != log(1.)); }],
 250          AC_MSG_RESULT(-std1),
 251          AC_MSG_RESULT()
 252          CFLAGS="$gtk_save_CFLAGS"
 253          AC_MSG_WARN(
 254                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 255          true
 256      ),
 257      AC_MSG_RESULT(none needed)
 258 )
 259 LIBS=$gtk_save_LIBS
 260
 261 MATH_LIB=-lm
 262 AC_MSG_CHECKING(for the BeOS)
 263 case $host in
 264   *-*-beos*)
 265     AC_MSG_RESULT(yes)
 266     MATH_LIB=
 267   ;;
 268   *)
 269     AC_MSG_RESULT(no)
 270   ;;
 271 esac
 272
 273 dnl NeXTStep cc seems to need this
 274 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 275 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 276   AC_MSG_RESULT(none needed),
 277   gtk_save_CFLAGS="$CFLAGS"
 278   CFLAGS="$CFLAGS -posix"
 279   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 280     AC_MSG_RESULT(-posix),
 281     AC_MSG_RESULT()
 282     CFLAGS="$gtk_save_CFLAGS"
 283     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 284
 285 #
 286 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 287 #
 288
 289 GLIB_PACKAGES="gobject-2.0 gmodule-2.0"
 290 GLIB_REQUIRED_VERSION=1.3.4
 291
 292 AM_PATH_GLIB_2_0($GLIB_REQUIRED_VERSION, :,
 293   AC_MSG_ERROR([
 294 *** GLIB $GLIB_REQUIRED_VERSION or better is required. The latest version of
 295 *** GLIB is always available from ftp://ftp.gtk.org/.]),
 296   gobject gmodule gthread)
 297
 298 AC_CHECK_HEADERS(dirent.h, AC_DEFINE(HAVE_DIRENT_H))
 299 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 300 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 301 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 302
 303 saved_cflags="$CFLAGS"
 304 saved_ldflags="$LDFLAGS"
 305
 306
 307 # Checks for header files.
 308 AC_HEADER_STDC
 309
 310 # Checks for typedefs, structures, and compiler characteristics.
 311 AC_C_CONST
 312
 313 # Checks for library functions.
 314 AC_TYPE_SIGNAL
 315 AC_FUNC_MMAP
 316
 317 AC_CHECK_FUNCS(getresuid)
 318 AC_TYPE_UID_T
 319
 320 # Check if <sys/select.h> needs to be included for fd_set
 321 AC_MSG_CHECKING([for fd_set])
 322 AC_TRY_COMPILE([#include <sys/types.h>],
 323         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 324 if test $gtk_ok = yes; then
 325     AC_MSG_RESULT([yes, found in sys/types.h])
 326 else
 327     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 328     if test $gtk_ok = yes; then
 329         AC_DEFINE(HAVE_SYS_SELECT_H)
 330         AC_MSG_RESULT([yes, found in sys/select.h])
 331     else
 332         AC_DEFINE(NO_FD_SET)
 333         AC_MSG_RESULT(no)
 334     fi
 335 fi
 336
 337 # `widechar' tests for gdki18n.h
 338 AC_MSG_CHECKING(for wchar.h)
 339 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 340 if test $gdk_wchar_h = yes; then
 341    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 342 fi
 343 AC_MSG_RESULT($gdk_wchar_h)
 344
 345 # Check for wctype.h (for iswalnum)
 346 AC_MSG_CHECKING(for wctype.h)
 347 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 348 if test $gdk_wctype_h = yes; then
 349    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 350 fi
 351 AC_MSG_RESULT($gdk_wctype_h)
 352
 353 # in Solaris 2.5, `iswalnum' is in -lw
 354 GDK_WLIBS=
 355 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 356
 357 oLIBS="$LIBS"
 358 LIBS="$LIBS $GDK_WLIBS"
 359 # The following is necessary for Linux libc-5.4.38
 360 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 361 AC_TRY_LINK([#include <stdlib.h>],[
 362 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 363 #  ifdef HAVE_WCTYPE_H
 364 #    include <wctype.h>
 365 #  else
 366 #    ifdef HAVE_WCHAR_H
 367 #      include <wchar.h>
 368 #    endif
 369 #  endif
 370 #else
 371 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 372 #endif
 373 iswalnum((wchar_t) 0);
 374 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 375 LIBS="$oLIBS"
 376
 377 if test $gdk_working_wctype = no; then
 378    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 379    GDK_WLIBS=
 380 fi
 381 AC_MSG_RESULT($gdk_working_wctype)
 382 AC_SUBST(GDK_WLIBS)
 383
 384
 385
 386 ##################################################
 387 # Checks for gdk-pixbuf
 388 ##################################################
 389
 390 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 391
 392 AC_ARG_ENABLE(modules, [  --disable-modules       Disables dynamic module loading],[
 393         if test x$withval = xyes; then
 394             with_modules=yes
 395         else
 396             with_modules=no
 397         fi
 398 ])
 399
 400 dynworks=false
 401 deps=
 402 if test x$with_modules = xno; then
 403     AC_MSG_RESULT(no)
 404 else
 405     AC_MSG_RESULT(yes)
 406     AC_MSG_CHECKING(whether dynamic modules work)
 407     oLIBS="$LIBS"
 408     oCFLAGS="$CFLAGS"
 409     CFLAGS="$GLIB_CFLAGS"
 410     LIBS="$GLIB_LIBS"
 411     AC_TRY_RUN([
 412     #include <glib.h>
 413     #include <gmodule.h>
 414     main ()
 415     {
 416         if (g_module_supported ())
 417             exit (0);
 418         else
 419             exit (1);
 420     }
 421     ], dynworks=true)
 422     LIBS="$oLIBS"
 423     CFLAGS="$oCFLAGS"
 424 fi
 425
 426 dnl Now we check to see if our libtool supports shared lib deps
 427 dnl (in a rather ugly way even)
 428 if $dynworks; then
 429    pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} libtool --config"
 430    pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 431       grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 432       sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 433    if test "x$pixbuf_deplibs_check" = "xnone" || \
 434       test "x$pixbuf_deplibs_check" = "xunknown" || \
 435       test "x$pixbuf_deplibs_check" = "x"; then
 436       dynworks=false
 437    fi
 438 fi
 439
 440 if $dynworks; then
 441    AC_DEFINE(USE_GMODULE)
 442    AC_MSG_RESULT(yes)
 443 else
 444    AC_MSG_RESULT(no)
 445 fi
 446
 447 dnl Test for libtiff
 448   if test -z "$LIBTIFF"; then
 449     AC_CHECK_LIB(tiff, TIFFReadScanline,
 450       AC_CHECK_HEADER(tiffio.h,
 451         TIFF='tiff'; LIBTIFF='-ltiff',
 452         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 453       AC_CHECK_LIB(tiff, TIFFWriteScanline,
 454         AC_CHECK_HEADER(tiffio.h,
 455           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 456           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 457         AC_CHECK_LIB(tiff34, TIFFFlushData,
 458           AC_CHECK_HEADER(tiffio.h,
 459             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 460             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 461         AC_MSG_WARN(*** TIFF plug-in will not be built (TIFF library not found) ***), -ljpeg -lz -lm), -ljpeg -lz -lm), -lm)
 462   fi
 463
 464 dnl Test for libjpeg
 465   if test -z "$LIBJPEG"; then
 466     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 467       jpeg_ok=yes,
 468       jpeg_ok=no
 469       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 470     if test "$jpeg_ok" = yes; then
 471       AC_MSG_CHECKING([for jpeglib.h])
 472       AC_TRY_CPP(
 473 [#include <stdio.h>
 474 #undef PACKAGE
 475 #undef VERSION
 476 #include <jpeglib.h>],
 477         jpeg_ok=yes,
 478         jpeg_ok=no)
 479       AC_MSG_RESULT($jpeg_ok)
 480       if test "$jpeg_ok" = yes; then
 481         LIBJPEG='-ljpeg'
 482         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 483           AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
 484           AC_MSG_WARN(JPEG library does not support progressive saving.))
 485       else
 486           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 487       fi
 488     fi
 489   fi
 490
 491 dnl Test for libpng
 492   if test -z "$LIBPNG"; then
 493     AC_CHECK_LIB(png, png_read_info,
 494       AC_CHECK_HEADER(png.h,
 495         png_ok=yes,
 496         png_ok=no),
 497       AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 498     if test "$png_ok" = yes; then
 499       AC_MSG_CHECKING([for png_structp in png.h])
 500       AC_TRY_COMPILE([#include <png.h>],
 501         [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 502         png_ok=yes,
 503         png_ok=no)
 504       AC_MSG_RESULT($png_ok)
 505       if test "$png_ok" = yes; then
 506         PNG='png'; LIBPNG='-lpng -lz'
 507       else
 508         AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 509       fi
 510     else
 511      AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 512     fi
 513   fi
 514
 515 AC_SUBST(LIBTIFF)
 516 AC_SUBST(LIBJPEG)
 517 AC_SUBST(LIBPNG)
 518
 519 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 520
 521 #
 522 # Allow building some or all gdk-pixbuf loaders included
 523 #
 524 AC_MSG_CHECKING(pixbuf loaders to build)
 525
 526 AC_ARG_WITH(included_loaders, [  --with-included-loaders=LOADER1,LOADER2,... Build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
 527
 528 all_loaders="png,bmp,wbmp,gif,ico,jpeg,pnm,ras,tiff,xpm"
 529 included_loaders=""
 530 # If no loaders specified, include all
 531 if test "x$with_included_loaders" = xyes ; then
 532   included_loaders="$all_loaders"
 533 else
 534   included_loaders="$with_included_loaders"
 535 fi
 536
 537 AC_MSG_RESULT($included_loaders)
 538
 539 INCLUDED_LOADER_OBJ=
 540 INCLUDED_LOADER_DEFINE=
 541
 542 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 543 for loader in $included_loaders; do
 544  if echo "$all_loaders" | grep "\(^\|\,\)$loader\(\$\|\,\)" > /dev/null; then
 545    :
 546  else
 547    AC_MSG_ERROR([the specified loader $loader does not exist])
 548  fi
 549
 550  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
 551  INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
 552 done
 553 IFS="$gtk_save_ifs"
 554 AC_SUBST(INCLUDED_LOADER_OBJ)
 555 AC_SUBST(INCLUDED_LOADER_DEFINE)
 556
 557 AC_HEADER_DIRENT
 558 AC_HEADER_SYS_WAIT
 559
 560 AC_TYPE_SIGNAL
 561
 562 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
 563 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
 564 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
 565
 566 if $dynworks ; then
 567   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
 568 else
 569   STATIC_LIB_DEPS=
 570   if echo "$included_loaders" | grep "\(^\|\,\)tiff\(\$\|\,\)" > /dev/null; then
 571     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
 572   fi
 573   if echo "$included_loaders" | grep "\(^\|\,\)jpeg\(\$\|\,\)" > /dev/null; then
 574     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
 575   fi
 576   if echo "$included_loaders" | grep "\(^\|\,\)png\(\$\|\,\)" > /dev/null; then
 577     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
 578   fi
 579 fi
 580
 581 # Checks to see if we should compile in MMX support (there will be
 582 # a runtime test when the code is actually run to see if it should
 583 # be used - this just checks if we can compile it.)
 584 #
 585 # This code is partially taken from Mesa
 586 #
 587 AC_MSG_CHECKING(for x86 platform)
 588 case $host_cpu in
 589   i386|i486|i586|i686|i786|k6|k7)
 590         use_x86_asm=yes
 591         ;;
 592    *)
 593         use_x86_asm=no
 594 esac
 595 AC_MSG_RESULT($use_x86_asm)
 596
 597 use_mmx_asm=no
 598 if test $use_x86_asm = yes; then
 599     save_ac_ext=$ac_ext
 600     ac_ext=S
 601
 602     AC_MSG_CHECKING(compiler support for MMX)
 603     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
 604     if AC_TRY_EVAL(ac_compile); then
 605         use_mmx_asm=yes
 606     fi
 607
 608     rm -rf conftest*
 609
 610     ac_ext=$save_ac_ext
 611     if test $use_mmx_asm = yes; then
 612       AC_DEFINE(USE_MMX)
 613       AC_MSG_RESULT(yes)
 614     else
 615       AC_MSG_RESULT(no)
 616     fi
 617 fi
 618
 619 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 620
 621
 622 GDK_PIXBUF_PACKAGES=gmodule-2.0
 623 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB"
 624 GDK_PIXBUF_EXTRA_CFLAGS=
 625 GDK_PIXBUF_DEP_LIBS="`pkg-config --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
 626 GDK_PIXBUF_DEP_CFLAGS="`pkg-config --cflags $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
 627
 628 AC_SUBST(GDK_PIXBUF_PACKAGES)
 629 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
 630 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
 631 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
 632 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
 633
 634
 635 ########################################
 636 # Windowing system checks
 637 ########################################
 638
 639 GDK_EXTRA_LIBS=$GDK_WLIBS
 640 GDK_EXTRA_CFLAGS=
 641
 642 if test "x$gdktarget" = "xx11"; then
 643   # Find the X11 include and library directories
 644   AC_PATH_X
 645   AC_PATH_XTRA
 646
 647   if test "x$x_includes" = "x"; then
 648     x_includes="/usr/include"
 649   fi
 650
 651   CFLAGS="$CFLAGS $X_CFLAGS"
 652   LDFLAGS="$LDFLAGS $X_LDFLAGS $X_LIBS"
 653
 654   if test "x$no_x" = "xyes"; then
 655     AC_MSG_ERROR([
 656 *** X libraries or include files not found. Check 'config.log' for
 657 *** more details.])
 658   fi
 659
 660   # Checks for libraries.
 661   # Check for the X11 library
 662   AC_CHECK_LIB(X11, XOpenDisplay, x_libs="-lX11 $X_EXTRA_LIBS",
 663     AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 664     $X_EXTRA_LIBS)
 665
 666   if test "x$enable_shm" = "xyes"; then
 667     # Check for the Xext library (needed for XShm extention)
 668     AC_CHECK_LIB(Xext, XShmAttach,
 669         x_libs="-lXext $x_libs",
 670         # On AIX, it is in XextSam instead, but we still need -lXext
 671         AC_CHECK_LIB(XextSam, XShmAttach,
 672             x_libs="-lXextSam -lXext $x_libs",
 673             no_xext_lib=yes, $x_libs),
 674         $x_libs)
 675   fi
 676
 677   GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
 678   GDK_PIXBUF_XLIB_EXTRA_LIBS="$x_ldflags $x_libs"
 679
 680   # Check for shaped window extension
 681
 682   AC_CHECK_LIB(Xext, XShapeCombineMask,
 683       if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 684            x_libs="-lXext $x_libs"
 685       fi
 686       AC_DEFINE(HAVE_SHAPE_EXT),
 687       ,
 688       $x_libs)
 689
 690   # Check for XConvertCase (X11R6 specific)
 691
 692   AC_CHECK_LIB(X11, XConvertCase,
 693       AC_DEFINE(HAVE_XCONVERTCASE),
 694       ,
 695       $x_libs)
 696
 697   #
 698   # Checks for FreeType
 699   #
 700   FREETYPE_LIBS=
 701   FREETYPE_CFLAGS=
 702   have_freetype=false
 703   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 704   if test "x$FREETYPE_CONFIG" != "xno" ; then
 705     FREETYPE_CFLAGS=`freetype-config --cflags`
 706     FREETYPE_LIBS=`freetype-config --libs`
 707
 708     AC_CHECK_LIB(freetype, FT_New_Face, have_freetype=true
 709                  ,:,$FREETYPE_LIBS)
 710   fi
 711
 712   #
 713   # Checks for Xft/XRender
 714   #
 715   have_xft=false
 716   if test $have_freetype = true ; then
 717     AC_CHECK_LIB(Xrender, XRenderFindFormat,
 718       AC_CHECK_LIB(Xft, XftFontOpen, have_xft=true, :, -lXrender -lXext $X_LIBS $FREETYPE_LIBS)
 719     ,:,-lXext $X_LIBS)
 720
 721     ## be sure we also have Pango built with xft support
 722     if ! $PKG_CONFIG --exists pangoxft ; then
 723         have_xft=false
 724         AC_MSG_WARN([X render extension found, but Pango lacks Xft support])
 725     fi
 726
 727     if $have_xft = 'true' ; then
 728       X_LIBS="-lXft -lXrender -lXext $FREETYPE_LIBS $X_LIBS"
 729       AC_DEFINE(HAVE_XFT)
 730     fi
 731   fi
 732
 733   AM_CONDITIONAL(HAVE_XFT, $have_xft)
 734
 735   # Check for XIM support.
 736
 737   AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 738             : ,
 739             enable_xim_inst="no",
 740             $x_libs)
 741
 742   # On Solaris, calling XRegisterIMInstantiateCallback seems to
 743   # cause an immediate segfault, so we disable it, unless
 744   # the user specifically forces it to be on.
 745
 746   if test x$enable_xim_inst = xmaybe ; then
 747     case host in
 748           *-*-solaris*)
 749             enable_xim_inst="no"
 750             ;;
 751           *)
 752             enable_xim_inst="yes"
 753             ;;
 754     esac
 755   fi
 756
 757   if test "x$enable_xim" = "xyes"; then
 758     GTK_XIM_FLAGS="-DUSE_XIM"
 759     if test "x$enable_xim_inst" = "xyes"; then
 760       AC_DEFINE(USE_X11R6_XIM)
 761     fi
 762   fi
 763
 764   # Check for XKB support.
 765
 766   if test "x$enable_xkb" = "xyes"; then
 767         AC_MSG_WARN(XKB support explicitly enabled)
 768         AC_DEFINE(HAVE_XKB)
 769   elif test "x$enable_xkb" = "xmaybe"; then
 770         AC_CHECK_LIB(X11, XkbQueryExtension,
 771                      AC_DEFINE(HAVE_XKB),
 772                      ,
 773                      $x_libs)
 774   else
 775         AC_MSG_WARN(XKB support explicitly disabled)
 776   fi
 777
 778   x_cflags="$X_CFLAGS"
 779   x_ldflags="$X_LDFLAGS"
 780
 781   # set up things for XInput
 782
 783   if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 784     AC_DEFINE(XINPUT_GXI)
 785     xinput_progs=gxid
 786     x_libs="-lXi $x_libs"
 787   elif test "x$with_xinput" = "xxfree"; then
 788     AC_DEFINE(XINPUT_XFREE)
 789     x_libs="-lXi $x_libs"
 790   else
 791     AC_DEFINE(XINPUT_NONE)
 792   fi
 793
 794   AM_CONDITIONAL(XINPUT_GXI, test x$with_xinput = xgxi)
 795   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree)
 796
 797   if test "x$enable_shm" = "xyes"; then
 798     # Check for shared memory
 799     AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 800     AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 801
 802     # Check for the X shared memory extension header file
 803     AC_MSG_CHECKING(X11/extensions/XShm.h)
 804     if test "x$no_xext_lib" = "xyes"; then
 805       AC_MSG_RESULT(no)
 806       no_xshm=yes
 807     else
 808       if test -f "$x_includes/X11/extensions/XShm.h"; then
 809         AC_MSG_RESULT(yes)
 810         AC_DEFINE(HAVE_XSHM_H)
 811       else
 812         AC_MSG_RESULT(no)
 813         no_xshm=yes
 814       fi
 815     fi
 816   fi
 817
 818   GDK_EXTRA_CFLAGS="$GDK_EXTRA_CFLAGS $x_cflags"
 819   GDK_EXTRA_LIBS="$x_ldflags $x_libs $GDK_EXTRA_LIBS"
 820
 821   # these are already defined above
 822   #gdktargetlib = "libgdk-x11-1.3.la"
 823   #gtktargetlib = "libgtk-x11-1.3.la"
 824
 825   AM_CONDITIONAL(USE_X11, true)
 826 else
 827   AM_CONDITIONAL(USE_X11, false)
 828 fi
 829
 830 AC_SUBST(xinput_progs)
 831
 832 GDK_PIXBUF_XLIB_PACKAGES=
 833 GDK_PIXBUF_XLIB_DEP_LIBS="`pkg-config --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
 834 GDK_PIXBUF_XLIB_DEP_CFLAGS="`pkg-config --cflags  $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
 835
 836 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
 837 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
 838 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
 839 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
 840 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
 841
 842 if test "x$gdktarget" = "xnanox"; then
 843   AC_CHECK_LIB(nano-X, GrOpen,,AC_MSG_ERROR([nano-X libraries not found.]))
 844   # nano-X may require additional libraries
 845   GDK_EXTRA_LIBS="-lnano-X $GDK_EXTRA_LIBS"
 846
 847   gdktargetlib="libgdk-nanox-1.3.la"
 848   gtktargetlib="libgtk-nanox-1.3.la"
 849
 850   AM_CONDITIONAL(USE_NANOX, true)
 851 else
 852   AM_CONDITIONAL(USE_NANOX, false)
 853 fi
 854
 855 if test "x$gdktarget" = "xlinux-fb"; then
 856   gdktargetlib="libgdk-linux-fb-1.3.la"
 857   gtktargetlib="libgtk-linux-fb-1.3.la"
 858
 859   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 860   if test x$FREETYPE_CONFIG = xno ; then
 861     AC_MSG_ERROR([*** freetype-config not found])
 862   fi
 863
 864   FREETYPE_CFLAGS="`$FREETYPE_CONFIG --cflags`"
 865   FREETYPE_LIBS="`$FREETYPE_CONFIG --libs`"
 866   CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 867
 868   if test x$enable_shadowfb = xyes ; then
 869     AC_DEFINE(ENABLE_SHADOW_FB)
 870   fi
 871
 872   GDK_EXTRA_CFLAGS="$FREETYPE_CFLAGS"
 873   GDK_EXTRA_LIBS="$FREETYPE_LIBS $GDK_EXTRA_LIBS"
 874
 875   AM_CONDITIONAL(USE_LINUX_FB, true)
 876 else
 877   AM_CONDITIONAL(USE_LINUX_FB, false)
 878 fi
 879
 880 AC_SUBST(gdktargetlib)
 881 AC_SUBST(gtktargetlib)
 882
 883 #
 884 # Pick correct Pango packages to use
 885 #
 886
 887 if test "x$gdktarget" = "xx11"; then
 888         if $have_xft = true ; then
 889             PANGO_PACKAGES="pangox pangoxft"
 890         else
 891             PANGO_PACKAGES=pangox
 892         fi
 893 elif test "x$gdktarget" = "xlinux-fb"; then
 894         PANGO_PACKAGES=pangoft2
 895 else
 896         PANGO_PACKAGES=pango
 897 fi
 898
 899 # Check for Pango flags
 900
 901 AC_MSG_CHECKING(Pango flags)
 902 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
 903         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
 904         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
 905
 906         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
 907 else
 908         AC_MSG_ERROR([
 909 *** Pango not found. Pango is required to build GTK+.
 910 *** See http://www.pango.org for Pango information.
 911 *** For the framebuffer target, you will need to build
 912 *** Pango with freetype support.
 913 ])
 914 fi
 915
 916 CFLAGS="$CFLAGS $PANGO_CFLAGS"
 917
 918 AC_CHECK_LIB(pango, pango_context_new, :, AC_MSG_ERROR([
 919 *** Can't link to Pango. Pango is required to build
 920 *** GTK+. For more information see http://www.pango.org]), $PANGO_LIBS $x_ldflags $x_libs)
 921
 922 CFLAGS="$saved_cflags"
 923 LDFLAGS="$saved_ldflags"
 924
 925 GDK_PACKAGES=$PANGO_PACKAGES
 926 GDK_DEP_LIBS="`pkg-config --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
 927 GDK_DEP_CFLAGS="`pkg-config --cflags  $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
 928
 929 AC_SUBST(GDK_PACKAGES)
 930 AC_SUBST(GDK_EXTRA_LIBS)
 931 AC_SUBST(GDK_EXTRA_CFLAGS)
 932 AC_SUBST(GDK_DEP_LIBS)
 933 AC_SUBST(GDK_DEP_CFLAGS)
 934
 935
 936 ########################################
 937 # Check for Accessibility Toolkit flags
 938 ########################################
 939
 940 ATK_PACKAGES=atk
 941 AC_MSG_CHECKING(ATK flags)
 942 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
 943         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
 944         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
 945
 946         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
 947 else
 948         AC_MSG_ERROR([
 949 *** Accessibility Toolkit not found. Accessibility Toolkit is required
 950 *** to build GTK+.
 951 ])
 952 fi
 953
 954 AC_CHECK_LIB(atk, atk_object_get_type, : , AC_MSG_ERROR([
 955 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
 956 *** to build GTK+]), $ATK_LIBS $GLIB_LIBS)
 957
 958
 959 GTK_PACKAGES=atk
 960 GTK_EXTRA_LIBS=
 961 GTK_EXTRA_CFLAGS=
 962 GTK_DEP_LIBS="`pkg-config --libs $GTK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
 963 GTK_DEP_CFLAGS="`pkg-config --cflags  $GTK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
 964
 965 AC_SUBST(GTK_PACKAGES)
 966 AC_SUBST(GTK_EXTRA_LIBS)
 967 AC_SUBST(GTK_EXTRA_CFLAGS)
 968 AC_SUBST(GTK_DEP_LIBS)
 969 AC_SUBST(GTK_DEP_CFLAGS)
 970
 971
 972 AC_SUBST(GTK_DEBUG_FLAGS)
 973 AC_SUBST(GTK_XIM_FLAGS)
 974
 975 ##################################################
 976 # Checks for gtk-doc and docbook-tools
 977 ##################################################
 978
 979 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
 980
 981 if test "x$with_html_dir" = "x" ; then
 982   HTML_DIR='${datadir}/gtk-doc/html'
 983 else
 984   HTML_DIR=$with_html_dir
 985 fi
 986
 987 AC_SUBST(HTML_DIR)
 988
 989 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
 990
 991 gtk_doc_min_version=0.6
 992 if $GTKDOC ; then
 993     gtk_doc_version=`gtkdoc-mkdb --version`
 994     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
 995     if perl <<EOF ; then
 996       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
 997             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
 998 EOF
 999       AC_MSG_RESULT(yes)
1000    else
1001       AC_MSG_RESULT(no)
1002       GTKDOC=false
1003    fi
1004 fi
1005
1006 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1007 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1008
1009 dnl Let people disable the gtk-doc stuff.
1010 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1011
1012 if test x$enable_gtk_doc = xauto ; then
1013   if test x$GTKDOC = xtrue ; then
1014     enable_gtk_doc=yes
1015   else
1016     enable_gtk_doc=no
1017   fi
1018 fi
1019
1020 dnl NOTE: We need to use a separate automake conditional for this
1021 dnl       to make this work with the tarballs.
1022 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1023
1024
1025 ##################################################
1026 # Output commands
1027 ##################################################
1028
1029 AC_OUTPUT_COMMANDS([
1030
1031 ## Generate `gdk/gdkconfig.h' in two cases
1032 ## 1. `config.status' is run either explicitly, or via configure.
1033 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1034 ##     config.h
1035 ## 2. CONFIG_OTHER is set explicitly
1036 ##
1037 ## Case 1 is difficult.  We know that `automake' sets one of
1038 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1039 ## only when AM_CONFIG_HEADER is set, however.
1040
1041 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1042   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1043   CONFIG_OTHER=${CONFIG_OTHER:-gdk/gdkconfig.h}
1044 fi
1045 case "$CONFIG_OTHER" in
1046 *gdk/gdkconfig.h*)
1047         echo creating gdk/gdkconfig.h
1048         outfile=gdkconfig.h-tmp
1049         cat > $outfile <<\_______EOF
1050 /* gdkconfig.h
1051  *
1052  * This is a generated file.  Please modify `configure.in'
1053  */
1054
1055 #ifndef GDKCONFIG_H
1056 #define GDKCONFIG_H
1057
1058 #ifdef __cplusplus
1059 extern "C" {
1060 #endif /* __cplusplus */
1061
1062 _______EOF
1063
1064         cat >>$outfile <<_______EOF
1065 $gdk_windowing
1066 $gdk_wc
1067 _______EOF
1068
1069         cat >>$outfile <<_______EOF
1070
1071 #ifdef __cplusplus
1072 }
1073 #endif /* __cplusplus */
1074
1075 #endif /* GDKCONFIG_H */
1076 _______EOF
1077
1078
1079         if cmp -s $outfile gdk/gdkconfig.h; then
1080           echo gdk/gdkconfig.h is unchanged
1081           rm -f $outfile
1082         else
1083           mv $outfile gdk/gdkconfig.h
1084         fi ;;
1085 esac
1086 ],[
1087 if test "x$gdktarget" = "xx11" ; then
1088   gdk_windowing='
1089 #define GDK_WINDOWING_X11'
1090 elif test "x$gdktarget" = "xnanox" ; then
1091   gdk_windowing='
1092 #define GDK_WINDOWING_NANOX'
1093 elif test "x$gdktarget" = "xlinux-fb" ; then
1094   gdk_windowing='
1095 #define GDK_WINDOWING_FB
1096 #define GDK_NATIVE_WINDOW_POINTER'
1097 fi
1098
1099 if test x$gdk_wchar_h = xyes; then
1100   gdk_wc='
1101 #define GDK_HAVE_WCHAR_H 1'
1102 fi
1103 if test x$gdk_wctype_h = xyes; then
1104   gdk_wc="\$gdk_wc
1105 #define GDK_HAVE_WCTYPE_H 1"
1106 fi
1107 if test x$gdk_working_wctype = xno; then
1108   gdk_wc="\$gdk_wc
1109 #define GDK_HAVE_BROKEN_WCTYPE 1"
1110 fi
1111
1112
1113 ])
1114
1115 AC_PATH_PROG(SGML2HTML, sgml2html, no)
1116 AM_CONDITIONAL(HAVE_SGML2HTML, ! test x$SGML2HTML = xno)
1117
1118 AC_OUTPUT([
1119 config.h.win32
1120 gtk+.spec
1121 docs/gtk-config.1
1122 Makefile
1123 gdk-pixbuf-2.0.pc
1124 gdk-2.0.pc
1125 gtk+-2.0.pc
1126 po/Makefile.in
1127 build/Makefile
1128 build/win32/Makefile
1129 demos/Makefile
1130 demos/gtk-demo/Makefile
1131 tests/Makefile
1132 docs/Makefile
1133 docs/reference/Makefile
1134 docs/reference/gdk-pixbuf/Makefile
1135 docs/reference/gdk/Makefile
1136 docs/reference/gtk/Makefile
1137 docs/faq/Makefile
1138 docs/tutorial/Makefile
1139 gdk-pixbuf/Makefile
1140 gdk-pixbuf/makefile.mingw
1141 gdk-pixbuf/gdk-pixbuf-features.h
1142 gdk-pixbuf/pixops/Makefile
1143 gdk-pixbuf/pixops/makefile.mingw
1144 gdk/Makefile
1145 gdk/makefile.mingw
1146 gdk/x11/Makefile
1147 gdk/win32/Makefile
1148 gdk/win32/makefile.mingw
1149 gdk/win32/rc/Makefile
1150 gdk/win32/rc/gdk.rc
1151 gdk/nanox/Makefile
1152 gdk/linux-fb/Makefile
1153 gtk/Makefile
1154 gtk/makefile.mingw
1155 gtk/makefile.msc
1156 gtk/gtkcompat.h
1157 gtk/gtk-win32.rc
1158 gtk/stock-icons/Makefile
1159 modules/Makefile
1160 modules/input/Makefile
1161 contrib/Makefile
1162 contrib/gdk-pixbuf-xlib/Makefile
1163 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
1164 ])