Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 # Making releases:
   6 #   GTK_MICRO_VERSION += 1;
   7 #   GTK_INTERFACE_AGE += 1;
   8 #   GTK_BINARY_AGE += 1;
   9 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  10 # if backwards compatibility has been broken,
  11 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  12
  13 m4_define([gtk_major_version], [2])
  14 m4_define([gtk_minor_version], [14])
  15 m4_define([gtk_micro_version], [3])
  16 m4_define([gtk_interface_age], [3])
  17 m4_define([gtk_binary_age],
  18           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  19 m4_define([gtk_version],
  20           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  21 # This is the X.Y used in -lgtk-FOO-X.Y
  22 m4_define([gtk_api_version], [2.0])
  23
  24 # Define a string for the earliest version that this release has
  25 # backwards binary compatibility with for all interfaces a module
  26 # might. Unless we add module-only API with lower stability
  27 # guarantees, this should be unchanged until we break binary compat
  28 # for GTK+.
  29 #
  30 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  31 m4_define([gtk_binary_version], [2.10.0])
  32
  33 # required versions of other packages
  34 m4_define([glib_required_version], [2.17.6])
  35 m4_define([pango_required_version], [1.20])
  36 m4_define([atk_required_version], [1.13.0])
  37 m4_define([cairo_required_version], [1.6])
  38
  39
  40 AC_INIT([gtk+], [gtk_version],
  41         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  42         [gtk+])
  43
  44 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  45
  46 # Save this value here, since automake will set cflags later
  47 cflags_set=${CFLAGS+set}
  48
  49 AM_INIT_AUTOMAKE(no-define)
  50 AM_CONFIG_HEADER(config.h)
  51
  52 #
  53 # For each of the libraries we build, we define the following
  54
  55 # substituted variables:
  56 #
  57 # foo_PACKAGES:     pkg-config packages this library requires
  58 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  59 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  60 # foo_DEP_LIBS:     All libraries this module requires
  61 # foo_DEP_CFLAGS:   All cflags this module requires
  62
  63
  64 GTK_MAJOR_VERSION=gtk_major_version
  65 GTK_MINOR_VERSION=gtk_minor_version
  66 GTK_MICRO_VERSION=gtk_micro_version
  67 GTK_INTERFACE_AGE=gtk_interface_age
  68 GTK_BINARY_AGE=gtk_binary_age
  69 GTK_VERSION=gtk_version
  70 GTK_API_VERSION=gtk_api_version
  71 GTK_BINARY_VERSION=gtk_binary_version
  72 AC_SUBST(GTK_MAJOR_VERSION)
  73 AC_SUBST(GTK_MINOR_VERSION)
  74 AC_SUBST(GTK_MICRO_VERSION)
  75 AC_SUBST(GTK_INTERFACE_AGE)
  76 AC_SUBST(GTK_BINARY_AGE)
  77 AC_SUBST(GTK_API_VERSION)
  78 AC_SUBST(GTK_VERSION)
  79 AC_SUBST(GTK_BINARY_VERSION)
  80
  81 # libtool versioning
  82 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  83 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  84 #LT_REVISION=$GTK_INTERFACE_AGE
  85 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  86 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  87
  88 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
  89 m4_define([lt_revision], [gtk_interface_age])
  90 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
  91 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  92 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
  93 AC_SUBST(LT_VERSION_INFO)
  94 AC_SUBST(LT_CURRENT_MINUS_AGE)
  95
  96 m4_define([gail_lt_current],[18])
  97 m4_define([gail_lt_revision],[1])
  98 m4_define([gail_lt_age],[0])
  99 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 100 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 101 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 102 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 103
 104 #
 105 # gdk-pixbuf gets versioned separately, and for now, using standard
 106 # libtool versioning, not GTK+-style versioning
 107 #
 108 GDK_PIXBUF_MAJOR=gtk_major_version
 109 GDK_PIXBUF_MINOR=gtk_minor_version
 110 GDK_PIXBUF_MICRO=gtk_micro_version
 111 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
 112 AC_SUBST(GDK_PIXBUF_MAJOR)
 113 AC_SUBST(GDK_PIXBUF_MINOR)
 114 AC_SUBST(GDK_PIXBUF_MICRO)
 115 AC_SUBST(GDK_PIXBUF_VERSION)
 116
 117 GETTEXT_PACKAGE=gtk20
 118 AC_SUBST(GETTEXT_PACKAGE)
 119 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 120                    [The prefix for our gettext translation domains.])
 121
 122 AC_CANONICAL_HOST
 123
 124 MATH_LIB=-lm
 125 AC_MSG_CHECKING([for native Win32])
 126 LIB_EXE_MACHINE_FLAG=X86
 127 case "$host" in
 128   *-*-mingw*)
 129     os_win32=yes
 130     gio_can_sniff=no
 131     MATH_LIB=
 132     case "$host" in
 133     x86_64-*-*)
 134       LIB_EXE_MACHINE_FLAG=X64
 135       ;;
 136     esac
 137     ;;
 138   *)
 139     os_win32=no
 140     ;;
 141 esac
 142 AC_MSG_RESULT([$os_win32])
 143
 144 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 145
 146 case $host in
 147   *-*-linux*)
 148     os_linux=yes
 149     ;;
 150 esac
 151
 152 dnl Initialize libtool
 153 AC_PROG_CC
 154 AM_DISABLE_STATIC
 155
 156 dnl
 157 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 158 dnl We use this for an automated test for C++ header correctness.
 159 dnl
 160 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 161 AC_LANG_SAVE
 162 AC_LANG_CPLUSPLUS
 163
 164 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 165 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 166
 167 gtk_save_cxxflags="$CXXFLAGS"
 168 CXXFLAGS="$CXXFLAGS -x objective-c++"
 169 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 170 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 171 CXXFLAGS="$gtk_save_cxxflags"
 172 AC_LANG_RESTORE
 173
 174 if test "$os_win32" = "yes"; then
 175   if test x$enable_static = xyes -o x$enable_static = x; then
 176     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 177     enable_static=no
 178   fi
 179   if test x$enable_shared = xno; then
 180     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 181   fi
 182   enable_shared=yes
 183 fi
 184
 185 AC_LIBTOOL_WIN32_DLL
 186 AM_PROG_LIBTOOL
 187 dnl when using libtool 2.x create libtool early, because it's used in configure
 188 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 189
 190
 191 # Make sure we use 64-bit versions of various file stuff.
 192 AC_SYS_LARGEFILE
 193
 194 AM_PROG_AS
 195 AC_PATH_PROG(NM, nm, nm)
 196
 197 dnl Initialize maintainer mode
 198 AM_MAINTAINER_MODE
 199
 200 AC_MSG_CHECKING([for some Win32 platform])
 201 case "$host" in
 202   *-*-mingw*|*-*-cygwin*)
 203     platform_win32=yes
 204     ;;
 205   *)
 206     platform_win32=no
 207     ;;
 208 esac
 209 AC_MSG_RESULT([$platform_win32])
 210 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 211
 212 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 213 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 214 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 215
 216 if test "$os_win32" = "yes"; then
 217   AC_CHECK_TOOL(WINDRES, windres, no)
 218   if test "$WINDRES" = no; then
 219     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 220   fi
 221   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 222 fi
 223 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 224
 225 m4_define([debug_default],
 226           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 227
 228 dnl declare --enable-* args and collect ac_help strings
 229 AC_ARG_ENABLE(debug,
 230               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 231                              [turn on debugging @<:@default=debug_default@:>@]),,
 232               enable_debug=debug_default)
 233 AC_ARG_ENABLE(shm,
 234               [AC_HELP_STRING([--enable-shm],
 235                               [support shared memory if available [default=yes]])],,
 236               [enable_shm="yes"])
 237 AC_ARG_ENABLE(xkb,
 238               [AC_HELP_STRING([--enable-xkb],
 239                               [support XKB [default=maybe]])],,
 240               [enable_xkb="maybe"])
 241 AC_ARG_ENABLE(xinerama,
 242               [AC_HELP_STRING([--enable-xinerama],
 243                               [support xinerama extension if available [default=yes]])],,
 244               [enable_xinerama="yes"])
 245 AC_ARG_ENABLE(rebuilds,
 246               [AC_HELP_STRING([--disable-rebuilds],
 247                               [disable all source autogeneration rules])],,
 248               [enable_rebuilds=yes])
 249 AC_ARG_ENABLE(visibility,
 250               [AC_HELP_STRING([--disable-visibility],
 251                               [don't use ELF visibility attributes])],,
 252               [enable_visibility=yes])
 253
 254 AC_ARG_WITH(xinput,
 255             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 256
 257 if test "$platform_win32" = yes; then
 258   gdktarget=win32
 259 else
 260   gdktarget=x11
 261 fi
 262
 263 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/win32/quartz/directfb]] select non-default GDK target],
 264         gdktarget=$with_gdktarget)
 265
 266 AC_SUBST(gdktarget)
 267 case $gdktarget in
 268   x11|win32|quartz|directfb) ;;
 269   *) AC_MSG_ERROR([Invalid target for GDK: use x11, quartz, directfb or win32.]);;
 270 esac
 271
 272 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 273 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 274
 275 AC_SUBST(gdktargetlib)
 276 AC_SUBST(gtktargetlib)
 277
 278 if test "x$enable_debug" = "xyes"; then
 279   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 280   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 281 else
 282   if test "x$enable_debug" = "xno"; then
 283     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 284   else
 285     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 286   fi
 287 fi
 288
 289
 290 if test "x$enable_visibility" = "xno"; then
 291   GTK_DEBUG_FLAGS="$GTK_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 292 fi
 293
 294
 295 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 296                    [Define if debugging is enabled])
 297
 298
 299 # Build time sanity check...
 300 AM_SANITY_CHECK
 301
 302 # Checks for programs.
 303 AC_ISC_POSIX
 304 AM_PROG_CC_STDC
 305 AC_PROG_INSTALL
 306 AC_PROG_MAKE_SET
 307
 308 changequote(,)dnl
 309 if test "x$GCC" = "xyes"; then
 310   case " $CFLAGS " in
 311   *[\ \ ]-Wall[\ \      ]*) ;;
 312   *) CFLAGS="$CFLAGS -Wall" ;;
 313   esac
 314
 315   if test "x$enable_ansi" = "xyes"; then
 316     case " $CFLAGS " in
 317     *[\ \       ]-ansi[\ \      ]*) ;;
 318     *) CFLAGS="$CFLAGS -ansi" ;;
 319     esac
 320
 321     case " $CFLAGS " in
 322     *[\ \       ]-pedantic[\ \  ]*) ;;
 323     *) CFLAGS="$CFLAGS -pedantic" ;;
 324     esac
 325   fi
 326 fi
 327 changequote([,])dnl
 328
 329 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES -DGDK_PIXBUF_DISABLE_SINGLE_INCLUDES -DGTK_DISABLE_SINGLE_INCLUDES"
 330
 331 # Ensure MSVC-compatible struct packing convention is used when
 332 # compiling for Win32 with gcc.
 333 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 334 # gcc2 uses "-fnative-struct".
 335 if test x"$os_win32" = xyes; then
 336   if test x"$GCC" = xyes; then
 337     msnative_struct=''
 338     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 339     if test -z "$ac_cv_prog_CC"; then
 340       our_gcc="$CC"
 341     else
 342       our_gcc="$ac_cv_prog_CC"
 343     fi
 344     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 345       2.)
 346         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 347           msnative_struct='-fnative-struct'
 348         fi
 349         ;;
 350       *)
 351         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 352           msnative_struct='-mms-bitfields'
 353         fi
 354         ;;
 355     esac
 356     if test x"$msnative_struct" = x ; then
 357       AC_MSG_RESULT([no way])
 358       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 359     else
 360       CFLAGS="$CFLAGS $msnative_struct"
 361       AC_MSG_RESULT([${msnative_struct}])
 362     fi
 363   fi
 364 fi
 365
 366 # Honor aclocal flags
 367 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 368
 369 ## Initial sanity check, done here so that users get told they
 370 ## have the wrong dependencies as early in the process as possible.
 371 ## Later on we actually use the cflags/libs from separate pkg-config
 372 ## calls. Oh, also the later pkg-config calls don't include
 373 ## the version requirements since those make the module lists
 374 ## annoying to construct
 375 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 376   [glib-2.0 >= glib_required_version dnl
 377    atk >= atk_required_version dnl
 378    pango >= pango_required_version dnl
 379    cairo >= cairo_required_version])
 380
 381 if test "$os_win32" != yes; then
 382     # libtool option to control which symbols are exported
 383     # right now, symbols starting with _ are not exported
 384     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 385 else
 386     # We currently use .def files on Windows (for gdk-pixbuf, gdk and gtk)
 387     LIBTOOL_EXPORT_OPTIONS=
 388 fi
 389 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 390
 391 dnl ******************************************************
 392 dnl * See whether to include shared library dependencies *
 393 dnl ******************************************************
 394
 395 AC_ARG_ENABLE(explicit-deps,
 396               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 397                               [use explicit dependencies in .pc files [default=auto]])],,
 398               [enable_explicit_deps=auto])
 399
 400 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 401 case $enable_explicit_deps in
 402   auto)
 403     export SED
 404     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 405     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 406       enable_explicit_deps=yes
 407     else
 408       enable_explicit_deps=no
 409     fi
 410   ;;
 411   yes|no)
 412   ;;
 413   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 414   ;;
 415 esac
 416 AC_MSG_RESULT($enable_explicit_deps)
 417
 418 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 419
 420 # define a MAINT-like variable REBUILD which is set if Perl
 421 # and awk are found, so autogenerated sources can be rebuilt
 422
 423 AC_PATH_PROGS(PERL, perl5 perl)
 424
 425 # We would like indent, but don't require it.
 426 AC_CHECK_PROG(INDENT, indent, indent)
 427
 428 REBUILD=\#
 429 if test "x$enable_rebuilds" = "xyes" && \
 430      test -n "$PERL" && \
 431      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 432   REBUILD=
 433 fi
 434 AC_SUBST(REBUILD)
 435
 436 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 437 AC_CHECK_FUNCS(localtime_r)
 438
 439 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 440 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 441 AC_TRY_LINK([#include <langinfo.h>], [
 442 char c;
 443 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 444 ], gtk_ok=yes, gtk_ok=no)
 445 AC_MSG_RESULT($gtk_ok)
 446 if test "$gtk_ok" = "yes"; then
 447   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 448             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 449 fi
 450
 451 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 452 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 453 AC_TRY_LINK([#include <langinfo.h>], [
 454 char c;
 455 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 456 ], gtk_ok=yes, gtk_ok=no)
 457 AC_MSG_RESULT($gtk_ok)
 458 if test "$gtk_ok" = "yes"; then
 459   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 460             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 461 fi
 462
 463 # _NL_PAPER_HEIGHT is an enum and not a define
 464 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 465 AC_TRY_LINK([#include <langinfo.h>], [
 466 char c;
 467 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 468 ], gtk_ok=yes, gtk_ok=no)
 469 AC_MSG_RESULT($gtk_ok)
 470 if test "$gtk_ok" = "yes"; then
 471   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 472             [Define if _NL_PAPER_HEIGHT is available])
 473 fi
 474
 475 # _NL_PAPER_WIDTH is an enum and not a define
 476 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 477 AC_TRY_LINK([#include <langinfo.h>], [
 478 char c;
 479 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 480 ], gtk_ok=yes, gtk_ok=no)
 481 AC_MSG_RESULT($gtk_ok)
 482 if test "$gtk_ok" = "yes"; then
 483   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 484             [Define if _NL_PAPER_WIDTH is available])
 485 fi
 486
 487 # sigsetjmp is a macro on some platforms, so AC_CHECK_FUNCS is not reliable
 488 AC_MSG_CHECKING(for sigsetjmp)
 489 AC_TRY_LINK([#include <setjmp.h>], [
 490 sigjmp_buf env;
 491 sigsetjmp(env, 0);
 492 ], gtk_ok=yes, gtk_ok=no)
 493 AC_MSG_RESULT($gtk_ok)
 494 if test "$gtk_ok" = "yes"; then
 495   AC_DEFINE(HAVE_SIGSETJMP, 1,
 496             [Define to 1 if sigsetjmp is available])
 497 fi
 498
 499 # i18n stuff
 500 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 501 AM_GLIB_GNU_GETTEXT
 502 LIBS="$LIBS $INTLLIBS"
 503 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 504         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 505       esac])
 506
 507 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 508
 509 dnl The DU4 header files don't provide library prototypes unless
 510 dnl -std1 is given to the native cc.
 511 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 512
 513 gtk_save_LIBS=$LIBS
 514 LIBS="$LIBS -lm"
 515 AC_TRY_RUN([#include <math.h>
 516              int main (void) { return (log(1) != log(1.)); }],
 517      AC_MSG_RESULT(none needed),
 518      gtk_save_CFLAGS="$CFLAGS"
 519      CFLAGS="$CFLAGS -std1"
 520      AC_TRY_RUN([#include <math.h>
 521                  int main (void) { return (log(1) != log(1.)); }],
 522          AC_MSG_RESULT(-std1),
 523          AC_MSG_RESULT()
 524          CFLAGS="$gtk_save_CFLAGS"
 525          AC_MSG_WARN(
 526                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 527          true
 528      ),
 529      AC_MSG_RESULT(none needed)
 530 )
 531 LIBS=$gtk_save_LIBS
 532
 533 AC_MSG_CHECKING(for the BeOS)
 534 case $host in
 535   *-*-beos*)
 536     AC_MSG_RESULT(yes)
 537     MATH_LIB=
 538   ;;
 539   *)
 540     AC_MSG_RESULT(no)
 541   ;;
 542 esac
 543
 544 #
 545 # see bug 162979
 546 #
 547 AC_MSG_CHECKING(for HP-UX)
 548 case $host_os in
 549   hpux9* | hpux10* | hpux11*)
 550     AC_MSG_RESULT(yes)
 551     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 552   ;;
 553   *)
 554     AC_MSG_RESULT(no)
 555   ;;
 556 esac
 557
 558 dnl NeXTStep cc seems to need this
 559 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 560 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 561   AC_MSG_RESULT(none needed),
 562   gtk_save_CFLAGS="$CFLAGS"
 563   CFLAGS="$CFLAGS -posix"
 564   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 565     AC_MSG_RESULT(-posix),
 566     AC_MSG_RESULT()
 567     CFLAGS="$gtk_save_CFLAGS"
 568     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 569
 570 #
 571 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 572 #
 573
 574 GLIB_PACKAGES="gobject-2.0 gmodule-no-export-2.0"
 575
 576 AM_PATH_GLIB_2_0(glib_required_version, :,
 577   AC_MSG_ERROR([
 578 *** GLIB glib_required_version or better is required. The latest version of
 579 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 580   gobject gmodule-no-export gthread)
 581
 582 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 583 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 584 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 585 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 586   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 587 fi
 588
 589 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 590
 591
 592 dnl
 593 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 594 dnl
 595 gtk_save_LIBS=$LIBS
 596 LIBS="$LIBS $GLIB_LIBS"
 597 AC_CHECK_FUNCS(bind_textdomain_codeset)
 598 LIBS=$gtk_save_LIBS
 599
 600 AC_CHECK_HEADERS(pwd.h,
 601                  AC_DEFINE(HAVE_PWD_H, 1,
 602                            [Define to 1 if pwd.h is available]))
 603 AC_CHECK_HEADERS(sys/time.h,
 604                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 605                            [Define to 1 if time.h is available]))
 606 AC_CHECK_HEADERS(unistd.h,
 607                  AC_DEFINE(HAVE_UNISTD_H, 1,
 608                            [Define to 1 if unistd.h is available]))
 609 AC_CHECK_HEADERS(ftw.h,
 610                  AC_DEFINE(HAVE_FTW_H, 1,
 611                            [Define to 1 if ftw.h is available]))
 612
 613 AC_MSG_CHECKING([for GNU ftw extensions])
 614 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 615 #define _GNU_SOURCE
 616 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 617 if test $gtk_ok = yes; then
 618     AC_MSG_RESULT([yes])
 619     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 620 else
 621     AC_MSG_RESULT([no])
 622 fi
 623
 624 saved_cflags="$CFLAGS"
 625 saved_ldflags="$LDFLAGS"
 626
 627
 628 # Checks for header files.
 629 AC_HEADER_STDC
 630
 631 # Checks for typedefs, structures, and compiler characteristics.
 632 AC_C_CONST
 633
 634 # Checks for library functions.
 635 AC_TYPE_SIGNAL
 636 AC_FUNC_MMAP
 637
 638 AC_CHECK_FUNCS(mallinfo)
 639 AC_CHECK_FUNCS(getresuid)
 640 AC_TYPE_UID_T
 641
 642 # Check if <sys/select.h> needs to be included for fd_set
 643 AC_MSG_CHECKING([for fd_set])
 644 AC_TRY_COMPILE([#include <sys/types.h>],
 645         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 646 if test $gtk_ok = yes; then
 647     AC_MSG_RESULT([yes, found in sys/types.h])
 648 else
 649     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 650     if test $gtk_ok = yes; then
 651         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 652                   [Define to 1 if sys/select.h is available])
 653         AC_MSG_RESULT([yes, found in sys/select.h])
 654     else
 655         AC_DEFINE(NO_FD_SET, 1,
 656                   [Define to 1 if fd_set is not available])
 657         AC_MSG_RESULT(no)
 658     fi
 659 fi
 660
 661 # `widechar' tests for gdki18n.h
 662 AC_MSG_CHECKING(for wchar.h)
 663 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 664 if test $gdk_wchar_h = yes; then
 665    AC_DEFINE(HAVE_WCHAR_H, 1, [Have wchar.h include file])
 666 fi
 667 AC_MSG_RESULT($gdk_wchar_h)
 668
 669 # Check for wctype.h (for iswalnum)
 670 AC_MSG_CHECKING(for wctype.h)
 671 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 672 if test $gdk_wctype_h = yes; then
 673    AC_DEFINE(HAVE_WCTYPE_H, 1, [Have wctype.h include file])
 674 fi
 675 AC_MSG_RESULT($gdk_wctype_h)
 676
 677 # in Solaris 2.5, `iswalnum' is in -lw
 678 GDK_WLIBS=
 679 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 680
 681 oLIBS="$LIBS"
 682 LIBS="$LIBS $GDK_WLIBS"
 683 # The following is necessary for Linux libc-5.4.38
 684 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 685 AC_TRY_LINK([#include <stdlib.h>],[
 686 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 687 #  ifdef HAVE_WCTYPE_H
 688 #    include <wctype.h>
 689 #  else
 690 #    ifdef HAVE_WCHAR_H
 691 #      include <wchar.h>
 692 #    endif
 693 #  endif
 694 #else
 695 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 696 #endif
 697 iswalnum((wchar_t) 0);
 698 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 699 LIBS="$oLIBS"
 700
 701 if test $gdk_working_wctype = no; then
 702    AC_DEFINE(HAVE_BROKEN_WCTYPE, 1, [Is the wctype implementation broken])
 703    GDK_WLIBS=
 704 fi
 705 AC_MSG_RESULT($gdk_working_wctype)
 706 AC_SUBST(GDK_WLIBS)
 707
 708 # Check for uxtheme.h (for MS-Windows Engine)
 709 AC_MSG_CHECKING(for uxtheme.h)
 710 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 711 if test $gtk_uxtheme_h = yes; then
 712    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 713 fi
 714 AC_MSG_RESULT($gtk_uxtheme_h)
 715
 716 # Checks for gdkspawn
 717 AC_CHECK_HEADERS(crt_externs.h)
 718 AC_CHECK_FUNCS(_NSGetEnviron)
 719
 720
 721 ##################################################
 722 # Checks for gdk-pixbuf
 723 ##################################################
 724
 725 dnl ********************************************************
 726 dnl * See whether we need to load our modules as .la files *
 727 dnl ********************************************************
 728
 729 use_la_modules=false
 730 case $host in
 731   *-aix*) use_la_modules=true
 732 esac
 733
 734 if $use_la_modules ; then
 735    AC_DEFINE(USE_LA_MODULES, 1,
 736              [Whether to load modules via .la files rather than directly])
 737 fi
 738
 739
 740 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 741
 742 AC_ARG_ENABLE(modules,
 743               [AC_HELP_STRING([--disable-modules],
 744                               [disable dynamic module loading])])
 745
 746 dynworks=false
 747 deps=
 748 if test x$enable_modules = xno; then
 749     AC_MSG_RESULT(no)
 750 else
 751     AC_MSG_RESULT(yes)
 752     AC_MSG_CHECKING(whether dynamic modules work)
 753     ## for loop is to strip newline
 754     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 755     for I in $tmp; do
 756         dynworks=$I
 757     done
 758
 759     dnl Now we check to see if our libtool supports shared lib deps
 760     dnl (in a rather ugly way even)
 761     if $dynworks; then
 762         pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 763         pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 764             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 765             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 766         if test "x$pixbuf_deplibs_check" = "xnone" || \
 767            test "x$pixbuf_deplibs_check" = "xunknown" || \
 768            test "x$pixbuf_deplibs_check" = "x"; then
 769             dynworks=false
 770         fi
 771     fi
 772
 773     if $dynworks; then
 774         AC_DEFINE(USE_GMODULE, 1,
 775                   [Define to 1 if gmodule works and should be used])
 776         AC_MSG_RESULT(yes)
 777     else
 778         AC_MSG_RESULT(no)
 779     fi
 780 fi
 781
 782 dnl We allow people to disable image loaders explicitely, but if they don't we error
 783 dnl out so that people don't accidentally build without them.
 784
 785 AC_ARG_WITH(libpng,
 786             [AC_HELP_STRING([--without-libpng],
 787                             [disable PNG loader for gdk-pixbuf])])
 788 AC_ARG_WITH(libjpeg,
 789             [AC_HELP_STRING([--without-libjpeg],
 790                             [disable JPEG loader for gdk-pixbuf])])
 791 AC_ARG_WITH(libtiff,
 792             [AC_HELP_STRING([--without-libtiff],
 793                             [disable TIFF loader for gdk-pixbuf])])
 794 AC_ARG_WITH(libjasper,
 795             [AC_HELP_STRING([--without-libjasper],
 796                             [disable JPEG2000 loader for gdk-pixbuf])])
 797
 798 AC_ARG_ENABLE(gdiplus,
 799             [AC_HELP_STRING([--disable-gdiplus],
 800                             [disable GDI+ loaders for gdk-pixbuf])])
 801
 802 AM_CONDITIONAL(BUILD_GDIPLUS_LOADERS, [ test x$os_win32 = xyes && test x$enable_gdiplus != xno ])
 803
 804 dnl Test for libtiff
 805 if test x$os_win32 = xno || test x$enable_gdiplus = xno; then
 806   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 807     AC_CHECK_LIB(tiff, TIFFReadRGBAImageOriented,
 808       [AC_CHECK_HEADER(tiffio.h,
 809         TIFF='tiff'; LIBTIFF='-ltiff',
 810         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 811       [AC_CHECK_LIB(tiff, TIFFWriteScanline,
 812         [AC_CHECK_HEADER(tiffio.h,
 813           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 814           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 815         [AC_CHECK_LIB(tiff34, TIFFFlushData,
 816           [AC_CHECK_HEADER(tiffio.h,
 817             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 818             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 819         AC_MSG_WARN(*** TIFF loader will not be built (TIFF library not found) ***), -ljpeg -lz -lm)], -ljpeg -lz -lm)], -lm)
 820   fi
 821
 822   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 823      AC_MSG_ERROR([
 824 *** Checks for TIFF loader failed. You can build without it by passing
 825 *** --without-libtiff to configure but some programs using GTK+ may
 826 *** not work properly])
 827   fi
 828 fi
 829
 830 dnl Test for libjpeg
 831 if test x$os_win32 = xno || test x$enable_gdiplus = xno; then
 832   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 833     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 834       jpeg_ok=yes,
 835       jpeg_ok=no
 836       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 837     if test "$jpeg_ok" = yes; then
 838       AC_MSG_CHECKING([for jpeglib.h])
 839       AC_TRY_CPP(
 840 [#include <stdio.h>
 841 #undef PACKAGE
 842 #undef VERSION
 843 #undef HAVE_STDLIB_H
 844 #include <jpeglib.h>],
 845         jpeg_ok=yes,
 846         jpeg_ok=no)
 847       AC_MSG_RESULT($jpeg_ok)
 848       if test "$jpeg_ok" = yes; then
 849         LIBJPEG='-ljpeg'
 850         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 851           AC_DEFINE(HAVE_PROGRESSIVE_JPEG, 1,
 852                     [Define to 1 is libjpeg supports progressive JPEG]),
 853           AC_MSG_WARN(JPEG library does not support progressive saving.))
 854       else
 855           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 856       fi
 857     fi
 858   fi
 859
 860   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 861      AC_MSG_ERROR([
 862 *** Checks for JPEG loader failed. You can build without it by passing
 863 *** --without-libjpeg to configure but some programs using GTK+ may
 864 *** not work properly])
 865   fi
 866 fi
 867
 868 dnl Test for libpng
 869   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 870     AC_MSG_CHECKING(for libpng12)
 871     if $PKG_CONFIG --exists libpng12 ; then
 872         AC_MSG_RESULT(yes)
 873         PNG='png'
 874         PNG_DEP_CFLAGS_PACKAGES=libpng12
 875         LIBPNG=`$PKG_CONFIG --libs libpng12`
 876     else
 877       AC_MSG_RESULT(no)
 878       AC_CHECK_LIB(png, png_read_info,
 879         [AC_CHECK_HEADER(png.h,
 880           png_ok=yes,
 881           png_ok=no)],
 882         AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 883       if test "$png_ok" = yes; then
 884         AC_MSG_CHECKING([for png_structp in png.h])
 885         AC_TRY_COMPILE([#include <png.h>],
 886           [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 887           png_ok=yes,
 888           png_ok=no)
 889         AC_MSG_RESULT($png_ok)
 890         if test "$png_ok" = yes; then
 891           PNG='png'; LIBPNG='-lpng -lz'
 892         else
 893           AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 894         fi
 895       else
 896        AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 897       fi
 898     fi
 899   fi
 900
 901   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 902      AC_MSG_ERROR([
 903 *** Checks for PNG loader failed. You can build without it by passing
 904 *** --without-libpng to configure but many programs using GTK+ will
 905 *** not work properly. The PNG loader is also needed if you are compiling
 906 *** from CVS.])
 907   fi
 908
 909 dnl Test for libjasper
 910   if test x$with_libjasper != xno && test -z "$LIBJASPER"; then
 911     AC_CHECK_LIB(jasper, jas_init, LIBJASPER=-ljasper, [], -ljpeg)
 912   fi
 913
 914   if test x$with_libjasper != xno && test -z "$LIBJASPER"; then
 915      AC_MSG_ERROR([
 916 *** Checks for JPEG2000 loader failed. You can build without it by passing
 917 *** --without-libjasper to configure])
 918   fi
 919
 920 AC_SUBST(LIBTIFF)
 921 AC_SUBST(LIBJPEG)
 922 AC_SUBST(LIBPNG)
 923 AC_SUBST(LIBJASPER)
 924
 925 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 926
 927 #
 928 # Allow building some or all gdk-pixbuf loaders included
 929 #
 930 AC_MSG_CHECKING(pixbuf loaders to build)
 931
 932 dnl due to an autoconf bug, commas in the first arg to
 933 dnl AC_HELP_STRING cause problems.
 934 dnl AC_HELP_STRING([--with-included-loaders=LOADER1 LOADER2 ...],
 935 dnl                [build the specified loaders into gdk-pixbuf])
 936 AC_ARG_WITH(included_loaders,
 937 [  --with-included-loaders=LOADER1,LOADER2,...
 938                           build the specified loaders into gdk-pixbuf])
 939
 940 if $dynworks; then
 941    :
 942 else
 943    ## if the option was specified, leave it; otherwise disable included loaders
 944    if test x$with_included_loaders = xno; then
 945            with_included_loaders=yes
 946    fi
 947 fi
 948
 949 # Use the traditional png loader instead of the GDI+ one on Windows,
 950 # because some important apps like GIMP need to read and write
 951 # arbitrary tEXt chunks which doesn't seem to be possible through GDI+
 952
 953 all_loaders="ani,icns,pcx,ras,tga,png,pnm,wbmp,xbm,xpm"
 954 if test x$with_libjasper != xno; then
 955   all_loaders="$all_loaders,jasper"
 956 fi
 957 if test x$os_win32 = xyes && test x$enable_gdiplus != xno; then
 958   # Skip PNG, see comment above
 959   gdip_formats="bmp emf gif ico jpeg tiff wmf"
 960   for f in $gdip_formats; do
 961     all_loaders="$all_loaders,gdip-$f"
 962   done
 963 else
 964   all_loaders="$all_loaders,bmp,gif,ico,jpeg,tiff"
 965 fi
 966 included_loaders=""
 967 # If no loaders specified, include all
 968 if test "x$with_included_loaders" = xyes ; then
 969   included_loaders="$all_loaders"
 970 else
 971   included_loaders="$with_included_loaders"
 972 fi
 973
 974 AC_MSG_RESULT($included_loaders)
 975
 976 INCLUDED_LOADER_OBJ=
 977 INCLUDED_LOADER_DEFINE=
 978
 979 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 980 for loader in $included_loaders; do
 981  if echo "$all_loaders" | egrep "(^|,)$loader(\$|,)" > /dev/null; then
 982    :
 983  else
 984    AC_MSG_ERROR([the specified loader $loader does not exist])
 985  fi
 986
 987  loader_underscores=`echo $loader | sed -e 's/-/_/g'`
 988  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libstatic-pixbufloader-$loader.la"
 989
 990  # Don't bother defining separate -DINCLUDE_gdip_foo for each gdip-foo loader
 991  case $loader in
 992    gdip-*) ;;
 993    *) INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader_underscores";;
 994  esac
 995  eval INCLUDE_$loader_underscores=yes
 996 done
 997
 998 # Just define one -DINCLUDE_gdiplus for all the gdip-foo loaders
 999 # (except gdip-png, which isn't built at all)
1000 if test x"$INCLUDE_gdip_ico" = xyes; then
1001   INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_gdiplus"
1002 fi
1003
1004 IFS="$gtk_save_ifs"
1005 AC_SUBST(INCLUDED_LOADER_OBJ)
1006 AC_SUBST(INCLUDED_LOADER_DEFINE)
1007
1008 AM_CONDITIONAL(INCLUDE_PNG, [test x"$INCLUDE_png" = xyes])
1009 AM_CONDITIONAL(INCLUDE_BMP, [test x"$INCLUDE_bmp" = xyes])
1010 AM_CONDITIONAL(INCLUDE_WBMP, [test x"$INCLUDE_wbmp" = xyes])
1011 AM_CONDITIONAL(INCLUDE_GIF, [test x"$INCLUDE_gif" = xyes])
1012 AM_CONDITIONAL(INCLUDE_ICO, [test x"$INCLUDE_ico" = xyes])
1013 AM_CONDITIONAL(INCLUDE_ANI, [test x"$INCLUDE_ani" = xyes])
1014 AM_CONDITIONAL(INCLUDE_JPEG, [test x"$INCLUDE_jpeg" = xyes])
1015 AM_CONDITIONAL(INCLUDE_PNM, [test x"$INCLUDE_pnm" = xyes])
1016 AM_CONDITIONAL(INCLUDE_RAS, [test x"$INCLUDE_ras" = xyes])
1017 AM_CONDITIONAL(INCLUDE_TIFF, [test x"$INCLUDE_tiff" = xyes])
1018 AM_CONDITIONAL(INCLUDE_XPM, [test x"$INCLUDE_xpm" = xyes])
1019 AM_CONDITIONAL(INCLUDE_XBM, [test x"$INCLUDE_xbm" = xyes])
1020 AM_CONDITIONAL(INCLUDE_TGA, [test x"$INCLUDE_tga" = xyes])
1021 AM_CONDITIONAL(INCLUDE_PCX, [test x"$INCLUDE_pcx" = xyes])
1022 AM_CONDITIONAL(INCLUDE_ICNS, [test x"$INCLUDE_icns" = xyes])
1023 AM_CONDITIONAL(INCLUDE_JASPER, [test x"$INCLUDE_jasper" = xyes])
1024 # As all GDI+ loaders are either built-in or not, arbitrarily just
1025 # check one of the variables here
1026 AM_CONDITIONAL(INCLUDE_GDIPLUS, [test x"$INCLUDE_gdip_ico" = xyes])
1027
1028 if test x$gio_can_sniff = x; then
1029   AC_MSG_CHECKING([if gio can sniff png])
1030   gtk_save_LIBS="$LIBS"
1031   gtk_save_CFLAGS="$CFLAGS"
1032   LIBS="`$PKG_CONFIG --libs gio-2.0`"
1033   CFLAGS="`$PKG_CONFIG --cflags gio-2.0`"
1034   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1035   #include <gio/gio.h>
1036   static const gsize data_size = 159;
1037   static const guint8 data[] =
1038   {
1039     0x89, 0x50, 0x4e, 0x47, 0x0d, 0x0a, 0x1a, 0x0a, 0x00, 0x00, 0x00, 0x0d,
1040     0x49, 0x48, 0x44, 0x52, 0x00, 0x00, 0x00, 0x01, 0x00, 0x00, 0x00, 0x01,
1041     0x08, 0x02, 0x00, 0x00, 0x00, 0x90, 0x77, 0x53, 0xde, 0x00, 0x00, 0x00,
1042     0x01, 0x73, 0x52, 0x47, 0x42, 0x00, 0xae, 0xce, 0x1c, 0xe9, 0x00, 0x00,
1043     0x00, 0x09, 0x70, 0x48, 0x59, 0x73, 0x00, 0x00, 0x0b, 0x13, 0x00, 0x00,
1044     0x0b, 0x13, 0x01, 0x00, 0x9a, 0x9c, 0x18, 0x00, 0x00, 0x00, 0x07, 0x74,
1045     0x49, 0x4d, 0x45, 0x07, 0xd8, 0x07, 0x0f, 0x10, 0x08, 0x15, 0x61, 0xd8,
1046     0x35, 0x37, 0x00, 0x00, 0x00, 0x19, 0x74, 0x45, 0x58, 0x74, 0x43, 0x6f,
1047     0x6d, 0x6d, 0x65, 0x6e, 0x74, 0x00, 0x43, 0x72, 0x65, 0x61, 0x74, 0x65,
1048     0x64, 0x20, 0x77, 0x69, 0x74, 0x68, 0x20, 0x47, 0x49, 0x4d, 0x50, 0x57,
1049     0x81, 0x0e, 0x17, 0x00, 0x00, 0x00, 0x0c, 0x49, 0x44, 0x41, 0x54, 0x08,
1050     0xd7, 0x63, 0xf8, 0xff, 0xff, 0x3f, 0x00, 0x05, 0xfe, 0x02, 0xfe, 0xdc,
1051     0xcc, 0x59, 0xe7, 0x00, 0x00, 0x00, 0x00, 0x49, 0x45, 0x4e, 0x44, 0xae,
1052     0x42, 0x60, 0x82
1053   };
1054   int
1055   main (int argc, char **argv)
1056   {
1057     char *content_type;
1058     char *image_png;
1059     content_type = g_content_type_guess (NULL, data, data_size, NULL);
1060     image_png = g_content_type_from_mime_type ("image/png");
1061     return !!strcmp (content_type, image_png);
1062   }]])],
1063     [gio_can_sniff=yes
1064      AC_DEFINE(GDK_PIXBUF_USE_GIO_MIME, 1, [Define if gio can sniff image data])],
1065     [gio_can_sniff=no])
1066   AC_MSG_RESULT($gio_can_sniff)
1067   LIBS="$gtk_save_LIBS"
1068   CFLAGS="$gtk_save_CFLAGS"
1069 fi
1070
1071 #
1072 # Allow building some or all immodules included
1073 #
1074 AC_MSG_CHECKING(immodules to build)
1075
1076 dnl due to an autoconf bug, commas in the first arg to
1077 dnl AC_HELP_STRING cause problems.
1078 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
1079 dnl                [build the specified input method modules into gtk])
1080 AC_ARG_WITH(included_immodules,
1081 [  --with-included-immodules=MODULE1,MODULE2,...
1082                           build the specified input methods into gtk])
1083
1084 if $dynworks; then
1085    :
1086 else
1087    ## if the option was specified, leave it; otherwise disable included immodules
1088    if test x$with_included_immodules = xno; then
1089            with_included_immodules=yes
1090    fi
1091 fi
1092
1093 all_immodules="am-et,cedilla,cyrillic-translit"
1094 if test "$gdktarget" = "win32"; then
1095    all_immodules="${all_immodules},ime"
1096 fi
1097 all_immodules="${all_immodules},inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr"
1098 if test "$gdktarget" = "x11"; then
1099    all_immodules="${all_immodules},xim"
1100 fi
1101
1102 included_immodules=""
1103 # If the switch specified without listing any specific ones, include all
1104 if test "x$with_included_immodules" = xyes ; then
1105   included_immodules="$all_immodules"
1106 else
1107   included_immodules="$with_included_immodules"
1108 fi
1109
1110 AC_MSG_RESULT($included_immodules)
1111 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
1112
1113 INCLUDED_IMMODULE_OBJ=
1114 INCLUDED_IMMODULE_DEFINE=
1115
1116 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
1117 for immodule in $included_immodules; do
1118  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
1119  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
1120    :
1121  else
1122    AC_MSG_ERROR([the specified input method $immodule does not exist])
1123  fi
1124
1125  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
1126  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
1127  eval INCLUDE_$immodule_underscores=yes
1128 done
1129 IFS="$gtk_save_ifs"
1130 AC_SUBST(INCLUDED_IMMODULE_OBJ)
1131 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
1132
1133 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
1134 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
1135 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
1136 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
1137 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
1138 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
1139 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
1140 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
1141 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
1142 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
1143 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
1144 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
1145
1146 AC_HEADER_SYS_WAIT
1147
1148 AC_TYPE_SIGNAL
1149
1150 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
1151 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
1152 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
1153 AM_CONDITIONAL(HAVE_JASPER, test "x$LIBJASPER" != x)
1154
1155 if $dynworks ; then
1156   STATIC_LIB_DEPS=
1157   if echo "$included_loaders" | egrep '(^|,)tiff($|,)' > /dev/null; then
1158     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
1159   fi
1160   if echo "$included_loaders" | egrep '(^|,)jpeg($|,)' > /dev/null; then
1161     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
1162   fi
1163   if echo "$included_loaders" | egrep '(^|,)png($|,)' > /dev/null; then
1164     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
1165   fi
1166 else
1167   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
1168 fi
1169
1170 # Checks to see whether we should include mediaLib
1171 # support.
1172 #
1173 AC_CHECK_HEADER(sys/systeminfo.h,
1174                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
1175                           [Define to 1 if sys/systeminfo.h is available]))
1176 AC_CHECK_HEADER(sys/sysinfo.h,
1177                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
1178                           [Define to 1 if sys/sysinfo.h is available]))
1179
1180 AC_MSG_CHECKING(for mediaLib 2.3)
1181 use_mlib25=no
1182 # Check for a mediaLib 2.3 function since that is what the GTK+ mediaLib
1183 # patch requires.
1184 AC_CHECK_LIB(mlib, mlib_ImageSetStruct, use_mlib=yes, use_mlib=no)
1185 if test $use_mlib = yes; then
1186     AC_DEFINE(USE_MEDIALIB, 1,
1187               [Define to 1 if medialib is available and should be used])
1188     MEDIA_LIB=-lmlib
1189
1190     AC_MSG_CHECKING(for mediaLib 2.5)
1191     # Check for a mediaLib 2.5 function since that is what is needed for
1192     # gdk_rgb_convert integration.
1193     AC_CHECK_LIB(mlib, mlib_VideoColorRGBint_to_BGRAint, use_mlib25=yes, use_mlib25=no)
1194     if test $use_mlib25 = yes; then
1195         AC_DEFINE(USE_MEDIALIB25, 1,
1196                   [Define to 1 if medialib 2.5 is available])
1197     fi
1198 fi
1199 AM_CONDITIONAL(USE_MEDIALIB, test $use_mlib = yes)
1200 AM_CONDITIONAL(USE_MEDIALIB25, test $use_mlib25 = yes)
1201
1202 # Checks to see if we should compile in MMX support (there will be
1203 # a runtime test when the code is actually run to see if it should
1204 # be used - this just checks if we can compile it.)
1205 #
1206 # This code is partially taken from Mesa
1207 #
1208 AC_MSG_CHECKING(for x86 platform)
1209 case $host_cpu in
1210   i386|i486|i586|i686|i786|k6|k7)
1211         use_x86_asm=yes
1212         ;;
1213    *)
1214         use_x86_asm=no
1215 esac
1216 AC_MSG_RESULT($use_x86_asm)
1217
1218 use_mmx_asm=no
1219 if test $use_x86_asm = yes; then
1220     save_ac_ext=$ac_ext
1221     ac_ext=S
1222
1223     AC_MSG_CHECKING(compiler support for MMX)
1224     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
1225     if AC_TRY_EVAL(ac_compile); then
1226         use_mmx_asm=yes
1227     fi
1228
1229     rm -rf conftest*
1230
1231     ac_ext=$save_ac_ext
1232     if test $use_mmx_asm = yes; then
1233       AC_DEFINE(USE_MMX, 1,
1234                 [Define to 1 if XXM is available and should be used])
1235       AC_MSG_RESULT(yes)
1236     else
1237       AC_MSG_RESULT(no)
1238     fi
1239 fi
1240
1241 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
1242
1243 REBUILD_PNGS=
1244 if test -z "$LIBPNG" && test x"$os_win32" = xno -o x$enable_gdiplus = xno; then
1245   REBUILD_PNGS=#
1246 fi
1247
1248 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
1249
1250 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
1251
1252 if test $cross_compiling = yes; then
1253   AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
1254   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
1255   if test x$GTK_UPDATE_ICON_CACHE = xno; then
1256     REBUILD_PNGS=#
1257   fi
1258 fi
1259
1260 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
1261    test "x$REBUILD_PNGS" = "x#" ; then
1262      AC_MSG_ERROR([
1263 *** gtkbuiltincache.h is not in the tree, and cannot be built
1264 *** because you don't have libpng, or (when cross-compiling) you
1265 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
1266 fi
1267
1268 AC_SUBST(REBUILD_PNGS)
1269
1270 GDK_PIXBUF_PACKAGES="gmodule-no-export-2.0 gobject-2.0 gio-2.0"
1271 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB $MEDIA_LIB"
1272 GDK_PIXBUF_EXTRA_CFLAGS=
1273 GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1274 GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $PNG_DEP_CFLAGS_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
1275
1276 ########################################
1277 # Windowing system checks
1278 ########################################
1279
1280 GDK_PIXBUF_XLIB_PACKAGES=
1281 GDK_PIXBUF_XLIB_EXTRA_CFLAGS=
1282 GDK_PIXBUF_XLIB_EXTRA_LIBS=
1283
1284 X_PACKAGES=fontconfig
1285 GDK_EXTRA_LIBS="$GDK_WLIBS"
1286 GDK_EXTRA_CFLAGS=
1287
1288 # GTK+ uses some X calls, so needs to link against X directly
1289 GTK_DEP_PACKAGES_FOR_X=
1290 GTK_DEP_LIBS_FOR_X=
1291
1292 if test "x$gdktarget" = "xx11"; then
1293   #
1294   # We use fontconfig very peripherally when decoding the default
1295   # settings.
1296   #
1297   if $PKG_CONFIG --exists fontconfig; then : ; else
1298     AC_MSG_ERROR([
1299 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
1300   fi
1301
1302   #
1303   # Check for basic X packages; we use pkg-config if available
1304   #
1305   if $PKG_CONFIG --exists x11 xext xrender; then
1306     have_base_x_pc=true
1307     X_PACKAGES="$X_PACKAGES x11 xext xrender"
1308     x_libs="`$PKG_CONFIG --libs x11 xext xrender`"
1309     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext xrender`"
1310
1311     # Strip out any .la files that pkg-config might give us (this happens
1312     # with -uninstalled.pc files)
1313     x_libs_for_checks=
1314     for I in $x_libs ; do
1315       case $I in
1316         *.la) ;;
1317         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
1318       esac
1319     done
1320
1321     GDK_PIXBUF_XLIB_PACKAGES="x11"
1322     GTK_PACKAGES_FOR_X="x11"
1323   else
1324     have_base_x_pc=false
1325     AC_PATH_XTRA
1326     if test x$no_x = xyes ; then
1327       AC_MSG_ERROR([X development libraries not found])
1328     fi
1329
1330     x_cflags="$X_CFLAGS"
1331     x_libs_for_checks="$X_LIBS -lXext -lXrender -lX11 $X_EXTRA_LIBS"
1332
1333     GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
1334     GDK_PIXBUF_XLIB_EXTRA_LIBS="$X_LIBS -lX11 $X_EXTRA_LIBS"
1335     GTK_DEP_LIBS_FOR_X="$X_LIBS -lXrender -lX11 $X_EXTRA_LIBS"
1336   fi
1337
1338   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
1339   x_extra_libs=
1340
1341   gtk_save_cppflags="$CPPFLAGS"
1342   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1343
1344   gtk_save_LIBS=$LIBS
1345   LIBS="$x_libs_for_checks $LIBS"
1346
1347   # Sanity check for the X11 and Xext libraries. While everything we need from
1348   # Xext is optional, the chances a system has *none* of these things is so
1349   # small that we just unconditionally require it.
1350   AC_CHECK_FUNC(XOpenDisplay, :,
1351                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
1352   AC_CHECK_FUNC(XextFindDisplay, :,
1353                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
1354   AC_CHECK_FUNC(XRenderQueryExtension, :,
1355                 AC_MSG_ERROR([*** libXrender not found. Check 'config.log' for more details.]))
1356
1357   # Check for xReply
1358
1359   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
1360   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
1361       [xReply *rep;],
1362       [AC_MSG_RESULT([no])],
1363       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
1364 #include <X11/Xlibint.h>],
1365            [xReply *rep;],
1366            [AC_MSG_RESULT([yes])
1367             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1368                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
1369            [AC_MSG_RESULT([unknown])
1370             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1371
1372   # Check for XConvertCase, XInternAtoms (X11R6 specific)
1373
1374   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1375
1376   # Generic X11R6 check needed for XIM support; we could
1377   # probably use this to replace the above, but we'll
1378   # leave the separate checks for XConvertCase and XInternAtoms
1379   # for clarity
1380
1381   have_x11r6=false
1382   AC_CHECK_FUNC(XAddConnectionWatch,
1383       have_x11r6=true)
1384
1385   if $have_x11r6; then
1386     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1387   fi
1388   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1389
1390   # Check for XKB support.
1391
1392   if test "x$enable_xkb" = "xyes"; then
1393         AC_MSG_WARN(XKB support explicitly enabled)
1394         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
1395   elif test "x$enable_xkb" = "xmaybe"; then
1396         AC_CHECK_FUNC(XkbQueryExtension,
1397                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1398   else
1399         AC_MSG_WARN(XKB support explicitly disabled)
1400   fi
1401
1402   # Check for shaped window extension
1403
1404   AC_CHECK_FUNC(XShapeCombineMask,
1405       AC_DEFINE(HAVE_SHAPE_EXT, 1,
1406                 [Define to 1 if the XShape extension is available]))
1407
1408   # X SYNC check
1409   gtk_save_CFLAGS="$CFLAGS"
1410   CFLAGS="$CFLAGS $x_cflags"
1411
1412   AC_CHECK_FUNC(XSyncQueryExtension,
1413       [AC_CHECK_HEADER(X11/extensions/sync.h,
1414           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1415           :, [#include <X11/Xlib.h>])])
1416
1417   CFLAGS="$gtk_save_CFLAGS"
1418
1419   # Xshm checks
1420
1421   if test "x$enable_shm" = "xyes"; then
1422      # Check for the XShm extension, normally in Xext
1423      AC_CHECK_FUNC(XShmAttach,
1424         :,
1425         # On AIX, it is in XextSam instead
1426         [AC_CHECK_LIB(XextSam, XShmAttach,
1427             [GTK_ADD_LIB(x_extra_libs,XextSam)])])
1428   fi
1429
1430   if test "x$enable_shm" = "xyes"; then
1431     # Check for shared memory
1432     AC_CHECK_HEADER(sys/ipc.h,
1433                     AC_DEFINE(HAVE_IPC_H, 1,
1434                               [Define to 1 if ipc.h is available]),
1435                     no_sys_ipc=yes)
1436     AC_CHECK_HEADER(sys/shm.h,
1437                     AC_DEFINE(HAVE_SHM_H, 1,
1438                               [Define to 1 if shm.h is available]),
1439                     no_sys_shm=yes)
1440
1441     # Check for the X shared memory extension header file
1442     have_xshm=no
1443     AC_MSG_CHECKING(X11/extensions/XShm.h)
1444     if test "x$no_xext_lib" = "xyes"; then
1445       :
1446     else
1447       gtk_save_CFLAGS="$CFLAGS"
1448       CFLAGS="$CFLAGS $x_cflags"
1449       AC_TRY_COMPILE([
1450 #include <stdlib.h>
1451 #include <sys/types.h>
1452 #include <sys/ipc.h>
1453 #include <sys/shm.h>
1454 #include <X11/Xlib.h>
1455 #include <X11/Xutil.h>
1456 #include <X11/extensions/XShm.h>
1457 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
1458       CFLAGS="$gtk_save_CFLAGS"
1459     fi
1460     AC_MSG_RESULT($have_xshm)
1461     if test $have_xshm = yes ; then
1462       AC_DEFINE(HAVE_XSHM_H, 1,
1463                 [Define to 1 if xshm.h is available])
1464     fi
1465   fi
1466
1467   if test "x$enable_xinerama" = "xyes"; then
1468     # Check for Xinerama extension (Solaris impl or Xfree impl)
1469     gtk_save_cppflags="$CPPFLAGS"
1470     CPPFLAGS="$CPPFLAGS $x_cflags"
1471
1472     case "$host" in
1473       *-*-solaris*)
1474           # Check for solaris
1475           AC_MSG_CHECKING(for Xinerama support on Solaris)
1476
1477           have_solaris_xinerama=false
1478           AC_CHECK_FUNC(XineramaGetInfo,
1479               [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1480                   [have_solaris_xinerama=true], :,
1481                   [#include <X11/Xlib.h>])])
1482
1483           if $have_solaris_xinerama ; then
1484             AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1485                       [Define to 1 if solaris xinerama is available])
1486             AC_DEFINE(HAVE_XINERAMA, 1,
1487                       [Define to 1 if xinerama is available])
1488             AC_MSG_RESULT(yes)
1489           else
1490             AC_MSG_RESULT(no)
1491           fi
1492           ;;
1493       *)
1494           # Check for XFree
1495           AC_MSG_CHECKING(for Xinerama support on XFree86)
1496
1497           have_xfree_xinerama=false
1498           if $PKG_CONFIG --exists xinerama ; then
1499              have_xfree_xinerama=true
1500              X_PACKAGES="$X_PACKAGES xinerama"
1501           else
1502               AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1503                   [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1504                       [GTK_ADD_LIB(x_extra_libs,Xinerama)
1505                       have_xfree_xinerama=true], :,
1506                       [#include <X11/Xlib.h>])])
1507           fi
1508
1509           if $have_xfree_xinerama ; then
1510             AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1511                       [Define to 1 if XFree Xinerama is available])
1512             AC_DEFINE(HAVE_XINERAMA, 1,
1513                       [Define to 1 is Xinerama is available])
1514             AC_MSG_RESULT(yes)
1515          else
1516             AC_MSG_RESULT(no)
1517          fi
1518          ;;
1519     esac
1520   fi
1521
1522   # set up things for XInput
1523
1524   if test "x$with_xinput" = "xxfree" || test "x$with_xinput" = "xyes"; then
1525     AC_DEFINE(XINPUT_XFREE, 1,
1526               [Define to 1 if XFree XInput should be used])
1527
1528     if $PKG_CONFIG --exists xi ; then
1529       X_PACKAGES="$X_PACKAGES xi"
1530     else
1531       GTK_ADD_LIB(x_extra_libs, Xi)
1532     fi
1533   else
1534     AC_DEFINE(XINPUT_NONE, 1,
1535               [Define to 1 if no XInput should be used])
1536   fi
1537
1538   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree || test x$with_xinput = xyes)
1539
1540   # Check for the RANDR extension
1541   if $PKG_CONFIG --exists "xrandr >= 1.2" ; then
1542      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1543
1544      X_PACKAGES="$X_PACKAGES xrandr"
1545   fi
1546
1547   # Checks for Xcursor library
1548
1549   if $PKG_CONFIG --exists xcursor ; then
1550     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1551
1552     X_PACKAGES="$X_PACKAGES xcursor"
1553   fi
1554
1555   # Checks for XFixes extension
1556
1557   if $PKG_CONFIG --exists xfixes ; then
1558     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1559
1560     X_PACKAGES="$X_PACKAGES xfixes"
1561     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1562   fi
1563
1564   # Checks for Xcomposite extension
1565
1566   if $PKG_CONFIG --exists xcomposite ; then
1567     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1568
1569     X_PACKAGES="$X_PACKAGES xcomposite"
1570     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1571   fi
1572
1573   # Checks for Xdamage extension
1574
1575   if $PKG_CONFIG --exists xdamage ; then
1576     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1577
1578     X_PACKAGES="$X_PACKAGES xdamage"
1579     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1580   fi
1581
1582   if $have_base_x_pc ; then
1583     GDK_EXTRA_LIBS="$x_extra_libs"
1584   else
1585     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1586   fi
1587
1588   CPPFLAGS="$gtk_save_cppflags"
1589   LIBS="$gtk_save_libs"
1590
1591   AM_CONDITIONAL(USE_X11, true)
1592 else
1593   AM_CONDITIONAL(XINPUT_XFREE, false)
1594   AM_CONDITIONAL(USE_X11, false)
1595   AM_CONDITIONAL(HAVE_X11R6, false)
1596 fi
1597
1598 if test "x$gdktarget" = "xwin32"; then
1599   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1600   AM_CONDITIONAL(USE_WIN32, true)
1601 else
1602   AM_CONDITIONAL(USE_WIN32, false)
1603 fi
1604
1605 if test "x$gdktarget" = "xquartz"; then
1606   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1607   AM_CONDITIONAL(USE_QUARTZ, true)
1608 else
1609   AM_CONDITIONAL(USE_QUARTZ, false)
1610 fi
1611
1612 GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1613 GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
1614
1615 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
1616 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
1617 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
1618 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
1619 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
1620
1621 if test "x$gdktarget" = "xdirectfb"; then
1622   DIRECTFB_REQUIRED_VERSION=0.9.24
1623   AC_MSG_CHECKING(for DirectFB)
1624
1625   if $PKG_CONFIG --atleast-version $DIRECTFB_REQUIRED_VERSION directfb && $PKG_CONFIG --exists cairo-directfb ; then
1626       AC_MSG_RESULT(found)
1627       GDK_EXTRA_CFLAGS="`$PKG_CONFIG --cflags cairo-directfb` $GDK_EXTRA_CFLAGS"
1628       GDK_EXTRA_LIBS="`$PKG_CONFIG --libs cairo-directfb` $GDK_EXTRA_LIBS"
1629   else
1630       AC_MSG_ERROR([
1631 *** DirectFB $DIRECTFB_REQUIRED_VERSION or newer and the cairo backend
1632 *** are required. The latest version of DirectFB is always available
1633 *** from http://www.directfb.org/.
1634   ])
1635   fi
1636
1637   AM_CONDITIONAL(USE_DIRECTFB, true)
1638 else
1639   AM_CONDITIONAL(USE_DIRECTFB, false)
1640 fi
1641
1642
1643 # Check for Pango flags
1644
1645 if test "x$gdktarget" = "xwin32"; then
1646         PANGO_PACKAGES="pangowin32 pangocairo"
1647 else
1648         PANGO_PACKAGES="pango pangocairo"
1649 fi
1650
1651 AC_MSG_CHECKING(Pango flags)
1652 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1653         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1654         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1655
1656         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1657 else
1658         AC_MSG_ERROR([
1659 *** Pango not found. Pango built with Cairo support is required
1660 *** to build GTK+. See http://www.pango.org for Pango information.
1661 ])
1662 fi
1663
1664 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1665
1666 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1667         :
1668 else
1669         gtk_save_LIBS="$LIBS"
1670         LIBS="$PANGO_LIBS $LIBS"
1671         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1672 *** Can't link to Pango. Pango is required to build
1673 *** GTK+. For more information see http://www.pango.org]))
1674         LIBS="$gtk_save_LIBS"
1675 fi
1676
1677 CFLAGS="$saved_cflags"
1678 LDFLAGS="$saved_ldflags"
1679
1680 GDK_PACKAGES="$PANGO_PACKAGES gio-2.0"
1681 if test "x$gdktarget" = "xx11"; then
1682   GDK_PACKAGES="$GDK_PACKAGES $X_PACKAGES"
1683 fi
1684 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1685 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
1686
1687 #
1688 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1689 # into the pkg-config files
1690 #
1691 if test $enable_explicit_deps != yes ; then
1692   GDK_PACKAGES="$PANGO_PACKAGES"
1693   GDK_EXTRA_LIBS=
1694 fi
1695
1696 AC_SUBST(GDK_PACKAGES)
1697 AC_SUBST(GDK_EXTRA_LIBS)
1698 AC_SUBST(GDK_EXTRA_CFLAGS)
1699 AC_SUBST(GDK_DEP_LIBS)
1700 AC_SUBST(GDK_DEP_CFLAGS)
1701
1702
1703 ########################################
1704 # Check for Accessibility Toolkit flags
1705 ########################################
1706
1707 ATK_PACKAGES=atk
1708 AC_MSG_CHECKING(ATK flags)
1709 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1710         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1711         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1712
1713         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1714 else
1715         AC_MSG_ERROR([
1716 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1717 *** to build GTK+.
1718 ])
1719 fi
1720
1721 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1722         :
1723 else
1724         gtk_save_LIBS="$LIBS"
1725         LIBS="$ATK_LIBS $LIBS"
1726         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1727                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1728                 *** to build GTK+]))
1729         LIBS="$gtk_save_LIBS"
1730 fi
1731
1732 GTK_PACKAGES="atk cairo gio-2.0"
1733 if test "x$gdktarget" = "xx11"; then
1734   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1735 fi
1736 GTK_EXTRA_LIBS=
1737 GTK_EXTRA_CFLAGS=
1738 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1739 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1740
1741 if test x"$os_win32" = xyes; then
1742   GTK_EXTRA_CFLAGS="$msnative_struct"
1743 fi
1744
1745 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1746 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1747 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1748 CAIRO_PREFIX="`pkg-config --variable=prefix cairo`"
1749
1750 if test $enable_explicit_deps != yes ; then
1751   GDK_PIXBUF_EXTRA_LIBS=
1752 fi
1753
1754 AC_SUBST(GDK_PIXBUF_PACKAGES)
1755 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
1756 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
1757 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
1758 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
1759
1760 AC_SUBST(GTK_PACKAGES)
1761 AC_SUBST(GTK_EXTRA_LIBS)
1762 AC_SUBST(GTK_EXTRA_CFLAGS)
1763 AC_SUBST(GTK_DEP_LIBS)
1764 AC_SUBST(GTK_DEP_CFLAGS)
1765
1766 AC_SUBST(GLIB_PREFIX)
1767 AC_SUBST(ATK_PREFIX)
1768 AC_SUBST(PANGO_PREFIX)
1769 AC_SUBST(CAIRO_PREFIX)
1770
1771 AC_SUBST(GTK_DEBUG_FLAGS)
1772 AC_SUBST(GTK_XIM_FLAGS)
1773
1774 ########################
1775 # Checks needed for gail
1776 ########################
1777
1778 old_LIBS="$LIBS"
1779 dnl Checks for inet libraries:
1780 AC_SEARCH_LIBS(gethostent, nsl)
1781 AC_SEARCH_LIBS(setsockopt, socket)
1782 AC_SEARCH_LIBS(connect, inet)
1783
1784 dnl check for the sockaddr_un.sun_len member
1785 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1786                 [struct_sockaddr_un_sun_len=true],
1787                 [struct_sockaddr_un_suin_len=false],
1788                 [#include <sys/types.h>
1789                  #include <sys/un.h>]
1790                 )
1791 case $struct_sockaddr_un_sun_len in
1792         true)
1793                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1794                                    [Have the sockaddr_un.sun_len member])
1795                 ;;
1796         *)
1797                 ;;
1798 esac
1799
1800 GAIL_INET_LIBS="$LIBS"
1801 AC_SUBST([GAIL_INET_LIBS])
1802
1803 LIBS="$old_LIBS"
1804
1805 ################################################################
1806 # Printing system checks
1807 ################################################################
1808
1809 AC_ARG_ENABLE(cups,
1810               [AC_HELP_STRING([--disable-cups]
1811                               [disable cups print backend])],,
1812               [enable_cups=auto])
1813
1814 if test "x$enable_cups" = "xauto"
1815 then
1816   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1817   if test "x$CUPS_CONFIG" != "xno"; then
1818     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1819     CUPS_LIBS=`$CUPS_CONFIG --libs`
1820
1821     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1822     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1823     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1824
1825     if test $CUPS_API_MAJOR -gt 1 -o \
1826             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1827       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1828                 [Define to 1 if CUPS 1.2 API is available])
1829     fi
1830
1831     AC_SUBST(CUPS_API_MAJOR)
1832     AC_SUBST(CUPS_API_MINOR)
1833     AC_SUBST(CUPS_CFLAGS)
1834     AC_SUBST(CUPS_LIBS)
1835
1836     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1837   fi
1838   AM_CONDITIONAL(HAVE_CUPS, test "x$CUPS_CONFIG" != "xno")
1839
1840   gtk_save_cflags="$CFLAGS"
1841   CFLAGS="$CUPS_CFLAGS"
1842   AC_TRY_COMPILE([#include <cups/http.h>],
1843                  [http_t http; char *s = http.authstring;],
1844                  [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1845                             [Define if cups http_t authstring field is accessible])],)
1846   CFLAGS="$gtk_save_cflags"
1847
1848   AC_SUBST(HAVE_HTTP_AUTHSTRING)
1849
1850   gtk_save_libs="$LIBS"
1851   LIBS="$CUPS_LIBS"
1852   AC_CHECK_FUNCS(httpGetAuthString)
1853   LIBS="$gtk_save_libs"
1854
1855 else
1856   AM_CONDITIONAL(HAVE_CUPS, false)
1857 fi
1858
1859 gtk_save_cppflags="$CPPFLAGS"
1860 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS"
1861
1862 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1863 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1864 *** backend enabled.]))
1865
1866 if test "$os_win32" != "yes"; then
1867   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1868 *** Can't find cairo-ps.h. You must build Cairo with the
1869 *** postscript backend enabled.]))
1870 fi
1871
1872 CPPFLAGS="$gtk_save_cppflags"
1873
1874
1875 AC_ARG_ENABLE(test-print-backend,
1876               [AC_HELP_STRING([--enable-test-print-backend],
1877                               [build test print backend])],,
1878               [enable_test_print_backend=no])
1879 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1880
1881
1882 ################################################################
1883 # Strip -export-dynamic from the link lines of various libraries
1884 ################################################################
1885
1886 #
1887 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1888 #  but this flag is only meaningful for executables. For libraries
1889 #  the effect is undefined; what it causes on Linux is that the
1890 #  export list from -export-symbols-regex is ignored and everything
1891 #  is exported
1892 #
1893 # We are using gmodule-no-export now, but I'm leaving the stripping
1894 # code in place for now, since pango and atk still require gmodule.
1895 export SED
1896 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1897 if test -n "$export_dynamic"; then
1898   GDK_PIXBUF_DEP_LIBS=`echo $GDK_PIXBUF_DEP_LIBS | sed -e "s/$export_dynamic//"`
1899   GDK_PIXBUF_XLIB_DEP_LIBS=`echo $GDK_PIXBUF_XLIB_DEP_LIBS | sed -e "s/$export_dynamic//"`
1900   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1901   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1902 fi
1903
1904
1905 ##################################################
1906 # Checks for gtk-doc and docbook-tools
1907 ##################################################
1908
1909 GTK_DOC_CHECK([1.8])
1910
1911 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1912 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1913
1914 AC_ARG_ENABLE(man,
1915               [AC_HELP_STRING([--enable-man],
1916                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1917               enable_man=no)
1918
1919 if test "${enable_man}" != no; then
1920   dnl
1921   dnl Check for xsltproc
1922   dnl
1923   AC_PATH_PROG([XSLTPROC], [xsltproc])
1924   if test -z "$XSLTPROC"; then
1925     enable_man=no
1926   fi
1927
1928   dnl check for DocBook DTD and stylesheets in the local catalog.
1929   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1930      [DocBook XML DTD V4.1.2],,enable_man=no)
1931   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1932      [DocBook XSL Stylesheets],,enable_man=no)
1933 fi
1934
1935 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1936
1937
1938 ##################################################
1939 # Output commands
1940 ##################################################
1941
1942 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1943         outfile=gdkconfig.h-tmp
1944         cat > $outfile <<\_______EOF
1945 /* gdkconfig.h
1946  *
1947  * This is a generated file.  Please modify `configure.in'
1948  */
1949
1950 #ifndef GDKCONFIG_H
1951 #define GDKCONFIG_H
1952
1953 #ifdef __cplusplus
1954 extern "C" {
1955 #endif /* __cplusplus */
1956
1957 #ifndef GSEAL
1958 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
1959 #  ifdef GSEAL_ENABLE
1960 #    define GSEAL(ident)      _g_sealed__ ## ident
1961 #  else
1962 #    define GSEAL(ident)      ident
1963 #  endif
1964 #endif /* !GSEAL */
1965
1966 _______EOF
1967
1968         cat >>$outfile <<_______EOF
1969 $gdk_windowing
1970 $gdk_wc
1971 _______EOF
1972
1973         cat >>$outfile <<_______EOF
1974
1975 #ifdef __cplusplus
1976 }
1977 #endif /* __cplusplus */
1978
1979 #endif /* GDKCONFIG_H */
1980 _______EOF
1981
1982
1983         if cmp -s $outfile gdk/gdkconfig.h; then
1984           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1985           rm -f $outfile
1986         else
1987           mv $outfile gdk/gdkconfig.h
1988         fi
1989 ],[
1990 if test "x$gdktarget" = "xx11" ; then
1991   gdk_windowing='
1992 #define GDK_WINDOWING_X11'
1993 elif test "x$gdktarget" = "xwin32" ; then
1994   gdk_windowing='
1995 #define GDK_NATIVE_WINDOW_POINTER
1996
1997 #define GDK_WINDOWING_WIN32'
1998 elif test "x$gdktarget" = "xquartz" ; then
1999   gdk_windowing='
2000 #define GDK_WINDOWING_QUARTZ'
2001 elif test "x$gdktarget" = "xdirectfb" ; then
2002   gdk_windowing='
2003 #define GDK_WINDOWING_DIRECTFB'
2004 fi
2005
2006 if test x$gdk_wchar_h = xyes; then
2007   gdk_wc='
2008 #define GDK_HAVE_WCHAR_H 1'
2009 fi
2010 if test x$gdk_wctype_h = xyes; then
2011   gdk_wc="\$gdk_wc
2012 #define GDK_HAVE_WCTYPE_H 1"
2013 fi
2014 if test x$gdk_working_wctype = xno; then
2015   gdk_wc="\$gdk_wc
2016 #define GDK_HAVE_BROKEN_WCTYPE 1"
2017 fi
2018
2019
2020 ])
2021
2022 AC_CONFIG_FILES([
2023 config.h.win32
2024 gtk-zip.sh
2025 Makefile
2026 gdk-pixbuf-2.0.pc
2027 gdk-2.0.pc
2028 gtk+-2.0.pc
2029 gtk+-unix-print-2.0.pc
2030 gail.pc
2031 gdk-pixbuf-2.0-uninstalled.pc
2032 gdk-2.0-uninstalled.pc
2033 gtk+-2.0-uninstalled.pc
2034 gail-uninstalled.pc
2035 m4macros/Makefile
2036 po/Makefile.in
2037 po-properties/Makefile.in
2038 demos/Makefile
2039 demos/gtk-demo/Makefile
2040 demos/gtk-demo/geninclude.pl
2041 tests/Makefile
2042 docs/Makefile
2043 docs/reference/Makefile
2044 docs/reference/gdk-pixbuf/Makefile
2045 docs/reference/gdk-pixbuf/version.xml
2046 docs/reference/gdk/Makefile
2047 docs/reference/gdk/version.xml
2048 docs/reference/gtk/Makefile
2049 docs/reference/gtk/version.xml
2050 docs/reference/libgail-util/Makefile
2051 docs/faq/Makefile
2052 docs/tools/Makefile
2053 docs/tutorial/Makefile
2054 gdk-pixbuf/Makefile
2055 gdk-pixbuf/gdk_pixbuf.rc
2056 gdk-pixbuf/gdk-pixbuf-features.h
2057 gdk-pixbuf/pixops/Makefile
2058 gdk/Makefile
2059 gdk/x11/Makefile
2060 gdk/win32/Makefile
2061 gdk/win32/rc/Makefile
2062 gdk/win32/rc/gdk.rc
2063 gdk/quartz/Makefile
2064 gdk/directfb/Makefile
2065 gdk/tests/Makefile
2066 gtk/Makefile
2067 gtk/makefile.msc
2068 gtk/gtkversion.h
2069 gtk/gtk-win32.rc
2070 gtk/theme-bits/Makefile
2071 gtk/tests/Makefile
2072 modules/Makefile
2073 modules/other/Makefile
2074 modules/other/gail/Makefile
2075 modules/other/gail/libgail-util/Makefile
2076 modules/other/gail/tests/Makefile
2077 modules/engines/Makefile
2078 modules/engines/pixbuf/Makefile
2079 modules/engines/ms-windows/Makefile
2080 modules/engines/ms-windows/Theme/Makefile
2081 modules/engines/ms-windows/Theme/gtk-2.0/Makefile
2082 modules/input/Makefile
2083 modules/printbackends/Makefile
2084 modules/printbackends/cups/Makefile
2085 modules/printbackends/lpr/Makefile
2086 modules/printbackends/file/Makefile
2087 modules/printbackends/test/Makefile
2088 perf/Makefile
2089 contrib/Makefile
2090 contrib/gdk-pixbuf-xlib/Makefile
2091 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
2092 ])
2093
2094 AC_OUTPUT
2095
2096 echo "configuration:
2097         target: $gdktarget"