Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [5])
  13 m4_define([gtk_micro_version], [3])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.33.1])
  43 m4_define([pango_required_version], [1.30.0])
  44 m4_define([atk_required_version], [2.2.0])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.26.0])
  47 m4_define([introspection_required_version], [1.32.0])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_INSTALL
 129 AC_PROG_MAKE_SET
 130
 131
 132 GETTEXT_PACKAGE=gtk30
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 135                    [The prefix for our gettext translation domains.])
 136
 137 AC_CANONICAL_HOST
 138
 139 MATH_LIB=-lm
 140 AC_MSG_CHECKING([for native Win32])
 141 LIB_EXE_MACHINE_FLAG=X86
 142 EXE_MANIFEST_ARCHITECTURE=X86
 143 DISABLE_ON_W32=''
 144 case "$host" in
 145   *-*-mingw*)
 146     dnl Comment-out certain gtk3.types.in lines
 147     DISABLE_ON_W32='%'
 148     os_win32=yes
 149     gio_can_sniff=no
 150     MATH_LIB=
 151     case "$host" in
 152     x86_64-*-*)
 153       LIB_EXE_MACHINE_FLAG=X64
 154       EXE_MANIFEST_ARCHITECTURE=AMD64
 155       ;;
 156     esac
 157     ;;
 158   *)
 159     os_win32=no
 160     ;;
 161 esac
 162 AC_MSG_RESULT([$os_win32])
 163
 164 AC_SUBST(DISABLE_ON_W32)
 165 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 166 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 167
 168 case $host in
 169   *-*-linux*)
 170     os_linux=yes
 171     ;;
 172 esac
 173
 174 dnl
 175 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 176 dnl We use this for an automated test for C++ header correctness.
 177 dnl
 178 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 179 AC_LANG_PUSH([C++])
 180
 181 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 182                                    [[class a { int b; } c;]])],
 183                   [],[CXX=])
 184 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 185
 186 gtk_save_cxxflags="$CXXFLAGS"
 187 CXXFLAGS="$CXXFLAGS -x objective-c++"
 188 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 189                                    [[]])],
 190                   [OBJC=yes],[OBJC=no])
 191 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 192 CXXFLAGS="$gtk_save_cxxflags"
 193 AC_LANG_POP([C++])
 194
 195 if test "$os_win32" = "yes"; then
 196   if test x$enable_static = xyes -o x$enable_static = x; then
 197     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 198     enable_static=no
 199   fi
 200   if test x$enable_shared = xno; then
 201     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 202   fi
 203   enable_shared=yes
 204 fi
 205
 206 dnl Initialize libtool
 207 LT_PREREQ([2.2.6])
 208 LT_INIT([disable-static win32-dll])
 209 # Create libtool early, because it's used in configure
 210 LT_OUTPUT
 211
 212 # Make sure we use 64-bit versions of various file stuff.
 213 AC_SYS_LARGEFILE
 214
 215 AM_PROG_AS
 216 AC_PATH_PROG(NM, nm, nm)
 217
 218 AC_MSG_CHECKING([for some Win32 platform])
 219 case "$host" in
 220   *-*-mingw*|*-*-cygwin*)
 221     platform_win32=yes
 222     ;;
 223   *)
 224     platform_win32=no
 225     ;;
 226 esac
 227 AC_MSG_RESULT([$platform_win32])
 228 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 229
 230 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 231 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 232 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 233
 234 if test "$os_win32" = "yes"; then
 235   AC_CHECK_TOOL(WINDRES, windres, no)
 236   if test "$WINDRES" = no; then
 237     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 238   fi
 239   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 240 fi
 241 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 242
 243 m4_define([debug_default],
 244           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 245
 246 dnl declare --enable-* args and collect ac_help strings
 247 AC_ARG_ENABLE(debug,
 248               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 249                               [turn on debugging @<:@default=debug_default@:>@])],,
 250               [enable_debug=debug_default])
 251
 252 AC_ARG_ENABLE(rebuilds,
 253               [AS_HELP_STRING([--disable-rebuilds],
 254                               [disable all source autogeneration rules])],,
 255               [enable_rebuilds=yes])
 256
 257 AC_ARG_ENABLE(gtk2-dependency,
 258               [AS_HELP_STRING([--enable-gtk2-dependency],
 259                               [Do not build gtk-update-icon-cache and other shared tools])],,
 260               [enable_gtk2_dependency=no])
 261
 262 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 263
 264 AC_ARG_ENABLE(xkb,
 265               [AS_HELP_STRING([--enable-xkb],
 266                               [support XKB extension [default=maybe]])],,
 267               [enable_xkb="maybe"])
 268 AC_ARG_ENABLE(xinerama,
 269               [AS_HELP_STRING([--enable-xinerama],
 270                               [support Xinerama extension [default=maybe]])],,
 271               [enable_xinerama="maybe"])
 272 AC_ARG_ENABLE(xrandr,
 273               [AS_HELP_STRING([--enable-xrandr],
 274                               [support XRandR extension [default=maybe]])],,
 275               [enable_xrandr="maybe"])
 276 AC_ARG_ENABLE(xfixes,
 277               [AS_HELP_STRING([--enable-xfixes],
 278                               [support XFixes extension [default=maybe]])],,
 279               [enable_xfixes="maybe"])
 280 AC_ARG_ENABLE(xcomposite,
 281               [AS_HELP_STRING([--enable-xcomposite],
 282                               [support X Composite extension [default=maybe]])],,
 283               [enable_xcomposite="maybe"])
 284 AC_ARG_ENABLE(xdamage,
 285               [AS_HELP_STRING([--enable-xdamage],
 286                               [support X Damage extension [default=maybe]])],,
 287               [enable_xdamage="maybe"])
 288
 289 AC_ARG_ENABLE(x11-backend,
 290               [AS_HELP_STRING([--enable-x11-backend],
 291                               [enable the X11 gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(win32-backend,
 294               [AS_HELP_STRING([--enable-win32-backend],
 295                               [enable the Win32 gdk backend])],
 296                               [backend_set=yes])
 297 AC_ARG_ENABLE(quartz-backend,
 298               [AS_HELP_STRING([--enable-quartz-backend],
 299                               [enable the quartz gdk backend])],
 300                               [backend_set=yes])
 301 AC_ARG_ENABLE(broadway-backend,
 302               [AS_HELP_STRING([--enable-broadway-backend],
 303                               [enable the broadway (HTML5) gdk backend])],
 304                               [backend_set=yes])
 305 AC_ARG_ENABLE(wayland-backend,
 306               [AS_HELP_STRING([--enable-wayland-backend],
 307                               [enable the wayland gdk backend])],
 308                               [backend_set=yes])
 309
 310 if test -z "$backend_set"; then
 311   if test "$platform_win32" = yes; then
 312     enable_win32_backend=yes
 313   else
 314     enable_x11_backend=yes
 315   fi
 316 fi
 317
 318 AC_ARG_ENABLE(quartz-relocation,
 319               [AS_HELP_STRING([--enable-quartz-relocation],
 320                               [enable bundle-based relocation functions])],
 321                               [quartz_relocation=yes])
 322
 323 AC_ARG_ENABLE(wayland-cairo-gl,
 324               AS_HELP_STRING([--enable-wayland-cairo-gl],
 325                              [enable the use of Cairo GL in the Wayland backend]),
 326               [enable_wayland_cairo_gl=yes])
 327
 328
 329 cairo_backends=
 330 backend_immodules=
 331 have_gio_unix=no
 332 GDK_BACKENDS=
 333 GDK_EXTRA_LIBS=
 334 GDK_EXTRA_CFLAGS=
 335 GDK_WINDOWING=
 336 PANGO_PACKAGES="pango pangocairo"
 337
 338 if test "$enable_x11_backend" = "yes"; then
 339   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 340   # backend names are identical.
 341   cairo_backends="$cairo_backends cairo-xlib"
 342   GDK_BACKENDS="$GDK_BACKENDS x11"
 343   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 344   # gdkapplaunchcontext-x11.c
 345   have_gio_unix=yes
 346   backend_immodules="$backend_immodules,xim"
 347   GDK_WINDOWING="$GDK_WINDOWING
 348 #define GDK_WINDOWING_X11"
 349 fi
 350
 351 if test "$enable_win32_backend" = "yes"; then
 352   cairo_backends="$cairo_backends cairo-win32"
 353   GDK_BACKENDS="$GDK_BACKENDS win32"
 354   backend_immodules="$backend_immodules,ime"
 355   GDK_WINDOWING="$GDK_WINDOWING
 356 #define GDK_WINDOWING_WIN32"
 357   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 358   AM_CONDITIONAL(USE_WIN32, true)
 359   PANGO_PACKAGES="pangowin32 pangocairo"
 360 else
 361   AM_CONDITIONAL(USE_WIN32, false)
 362 fi
 363
 364 DISABLE_ON_QUARTZ=''
 365 if test "x$enable_quartz_backend" = xyes; then
 366   cairo_backends="$cairo_backends cairo-quartz"
 367   GDK_BACKENDS="$GDK_BACKENDS quartz"
 368   GDK_WINDOWING="$GDK_WINDOWING
 369 #define GDK_WINDOWING_QUARTZ"
 370   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 371   DISABLE_ON_QUARTZ='%'
 372   AM_CONDITIONAL(USE_QUARTZ, true)
 373   if test "x$quartz_relocation" = xyes; then
 374     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 375   fi
 376
 377 else
 378   AM_CONDITIONAL(USE_QUARTZ, false)
 379 fi
 380 AC_SUBST(DISABLE_ON_QUARTZ)
 381
 382 if test "x$enable_broadway_backend" == xyes; then
 383   GDK_BACKENDS="$GDK_BACKENDS broadway"
 384   cairo_backends="$cairo_backends cairo"
 385   GDK_WINDOWING="$GDK_WINDOWING
 386 #define GDK_WINDOWING_BROADWAY"
 387   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 388   AM_CONDITIONAL(USE_BROADWAY, true)
 389 else
 390   AM_CONDITIONAL(USE_BROADWAY, false)
 391 fi
 392
 393 if test "x$enable_wayland_backend" == "xyes"; then
 394   if test "x$enable_wayland_cairo_gl" == "xyes"; then
 395     # Wayland can use cairo-gl
 396     cairo_backends="$cairo_backends cairo-gl"
 397     AC_DEFINE(GDK_WAYLAND_USE_EGL, [1], [Whether to use EGL in Wayland backend])
 398   else
 399     # For the cairo image backend
 400     cairo_backends="$cairo_backends cairo"
 401   fi
 402   GDK_BACKENDS="$GDK_BACKENDS wayland"
 403   have_gio_unix=yes
 404   GDK_WINDOWING="$GDK_WINDOWING
 405 #define GDK_WINDOWING_WAYLAND"
 406   WAYLAND_PACKAGES="wayland-client xkbcommon "
 407   if test "x$enable_wayland_cairo_gl" == "xyes"; then
 408     WAYLAND_PACKAGES="$WAYLAND_PACKAGES wayland-egl egl"
 409   fi
 410   AM_CONDITIONAL(USE_WAYLAND, true)
 411 else
 412   AM_CONDITIONAL(USE_WAYLAND, false)
 413 fi
 414
 415 # strip leading space
 416 GDK_BACKENDS=${GDK_BACKENDS#* }
 417
 418 AC_SUBST(GDK_BACKENDS)
 419
 420 if test -z "$GDK_BACKENDS"; then
 421   AC_MSG_ERROR([No GDK backends selected.])
 422 fi
 423
 424 if test "x$enable_debug" = "xyes"; then
 425   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 426   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 427 else
 428   if test "x$enable_debug" = "xno"; then
 429     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 430   else
 431     GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"
 432   fi
 433 fi
 434
 435
 436 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 437                    [Define if debugging is enabled])
 438
 439
 440 # Build time sanity check...
 441 AM_SANITY_CHECK
 442
 443 changequote(,)dnl
 444 if test "x$GCC" = "xyes"; then
 445   case " $CFLAGS " in
 446   *[\ \ ]-Wall[\ \      ]*) ;;
 447   *) CFLAGS="$CFLAGS -Wall" ;;
 448   esac
 449
 450   if test "x$enable_ansi" = "xyes"; then
 451     case " $CFLAGS " in
 452     *[\ \       ]-ansi[\ \      ]*) ;;
 453     *) CFLAGS="$CFLAGS -ansi" ;;
 454     esac
 455
 456     case " $CFLAGS " in
 457     *[\ \       ]-pedantic[\ \  ]*) ;;
 458     *) CFLAGS="$CFLAGS -pedantic" ;;
 459     esac
 460   fi
 461 fi
 462 changequote([,])dnl
 463
 464 # Ensure MSVC-compatible struct packing convention is used when
 465 # compiling for Win32 with gcc.
 466 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 467 # gcc2 uses "-fnative-struct".
 468 if test x"$os_win32" = xyes; then
 469   if test x"$GCC" = xyes; then
 470     msnative_struct=''
 471     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 472     if test -z "$ac_cv_prog_CC"; then
 473       our_gcc="$CC"
 474     else
 475       our_gcc="$ac_cv_prog_CC"
 476     fi
 477     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 478       2.)
 479         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 480           msnative_struct='-fnative-struct'
 481         fi
 482         ;;
 483       *)
 484         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 485           msnative_struct='-mms-bitfields'
 486         fi
 487         ;;
 488     esac
 489     if test x"$msnative_struct" = x ; then
 490       AC_MSG_RESULT([no way])
 491       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 492     else
 493       CFLAGS="$CFLAGS $msnative_struct"
 494       AC_MSG_RESULT([${msnative_struct}])
 495     fi
 496   fi
 497 fi
 498
 499 ## Initial sanity check, done here so that users get told they
 500 ## have the wrong dependencies as early in the process as possible.
 501 ## Later on we actually use the cflags/libs from separate pkg-config
 502 ## calls. Oh, also the later pkg-config calls don't include
 503 ## the version requirements since those make the module lists
 504 ## annoying to construct
 505 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 506   [glib-2.0 >= glib_required_version dnl
 507    atk >= atk_required_version dnl
 508    pango >= pango_required_version dnl
 509    cairo >= cairo_required_version dnl
 510    cairo-gobject >= cairo_required_version dnl
 511    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 512
 513 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 514
 515 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0])
 516
 517 if test "$os_win32" != yes; then
 518     # libtool option to control which symbols are exported
 519     # right now, symbols starting with _ are not exported
 520     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 521 else
 522     # We currently use .def files on Windows (for gdk and gtk)
 523     LIBTOOL_EXPORT_OPTIONS=
 524 fi
 525 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 526
 527 dnl ******************************************************
 528 dnl * See whether to include shared library dependencies *
 529 dnl ******************************************************
 530
 531 AC_ARG_ENABLE(explicit-deps,
 532               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 533                               [use explicit dependencies in .pc files [default=auto]])],,
 534               [enable_explicit_deps=auto])
 535
 536 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 537 case $enable_explicit_deps in
 538   auto)
 539     export SED
 540     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 541     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 542       enable_explicit_deps=yes
 543     else
 544       enable_explicit_deps=no
 545     fi
 546   ;;
 547   yes|no)
 548   ;;
 549   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 550   ;;
 551 esac
 552 AC_MSG_RESULT($enable_explicit_deps)
 553
 554 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 555
 556 # define a MAINT-like variable REBUILD which is set if Perl
 557 # and awk are found, so autogenerated sources can be rebuilt
 558
 559 AC_PATH_PROGS(PERL, perl5 perl)
 560
 561 # We would like indent, but don't require it.
 562 AC_CHECK_PROG(INDENT, indent, indent)
 563
 564 REBUILD=\#
 565 if test "x$enable_rebuilds" = "xyes" && \
 566      test -n "$PERL" && \
 567      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 568   REBUILD=
 569 fi
 570 AC_SUBST(REBUILD)
 571
 572 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 573 AC_CHECK_FUNCS(localtime_r)
 574
 575 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 576 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 577 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 578                                 [[char c;
 579                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 580                [gtk_ok=yes], [gtk_ok=no])
 581 AC_MSG_RESULT($gtk_ok)
 582 if test "$gtk_ok" = "yes"; then
 583   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 584             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 585 fi
 586
 587 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 588 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 589 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 590                                 [[char c;
 591                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 592                [gtk_ok=yes], [gtk_ok=no])
 593 AC_MSG_RESULT($gtk_ok)
 594 if test "$gtk_ok" = "yes"; then
 595   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 596             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 597 fi
 598
 599 # _NL_PAPER_HEIGHT is an enum and not a define
 600 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 601 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 602                                 [[char c;
 603                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 604                [gtk_ok=yes], [gtk_ok=no])
 605 AC_MSG_RESULT($gtk_ok)
 606 if test "$gtk_ok" = "yes"; then
 607   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 608             [Define if _NL_PAPER_HEIGHT is available])
 609 fi
 610
 611 # _NL_PAPER_WIDTH is an enum and not a define
 612 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 613 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 614                                 [[char c;
 615                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 616                [gtk_ok=yes], [gtk_ok=no])
 617 AC_MSG_RESULT($gtk_ok)
 618 if test "$gtk_ok" = "yes"; then
 619   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 620             [Define if _NL_PAPER_WIDTH is available])
 621 fi
 622
 623 # i18n stuff
 624 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 625 AM_GLIB_GNU_GETTEXT
 626 LIBS="$LIBS $INTLLIBS"
 627 AC_CONFIG_COMMANDS([po-properties],
 628                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 629                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 630                      esac]],
 631                    [[]])
 632
 633 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 634 dnl po-properties/POTFILES during configure; see GNOME #573515.
 635 dnl
 636 dnl Generate list of files to be processed by xgettext which will
 637 dnl be included in po-properties/Makefile.
 638 test -d po-properties || mkdir po-properties
 639 if test "x$srcdir" != "x."; then
 640   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 641     popropsrcprefix="$srcdir/"
 642   else
 643     popropsrcprefix="../$srcdir/"
 644   fi
 645 else
 646   popropsrcprefix="../"
 647 fi
 648 rm -f po-properties/POTFILES
 649 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 650 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 651 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 652
 653 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 654
 655 dnl The DU4 header files don't provide library prototypes unless
 656 dnl -std1 is given to the native cc.
 657 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 658
 659 gtk_save_LIBS=$LIBS
 660 LIBS="$LIBS -lm"
 661 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 662                                 int main (void) { return (log(1) != log(1.)); }]])],
 663               [AC_MSG_RESULT(none needed)],
 664               [gtk_save_CFLAGS="$CFLAGS"
 665                CFLAGS="$CFLAGS -std1"
 666                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 667                                                int main (void) { return (log(1) != log(1.)); }]])],
 668                              [AC_MSG_RESULT(-std1)],
 669                              [AC_MSG_RESULT()
 670                               CFLAGS="$gtk_save_CFLAGS"
 671                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 672                              [true])],
 673               [AC_MSG_RESULT(none needed)])
 674
 675 LIBS=$gtk_save_LIBS
 676
 677 AC_MSG_CHECKING(for the BeOS)
 678 case $host in
 679   *-*-beos*)
 680     AC_MSG_RESULT(yes)
 681     MATH_LIB=
 682   ;;
 683   *)
 684     AC_MSG_RESULT(no)
 685   ;;
 686 esac
 687
 688 AC_SUBST(MATH_LIB)
 689 #
 690 # see bug 162979
 691 #
 692 AC_MSG_CHECKING(for HP-UX)
 693 case $host_os in
 694   hpux9* | hpux10* | hpux11*)
 695     AC_MSG_RESULT(yes)
 696     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 697   ;;
 698   *)
 699     AC_MSG_RESULT(no)
 700   ;;
 701 esac
 702
 703 #
 704 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 705 #
 706
 707 AM_PATH_GLIB_2_0(glib_required_version, :,
 708   AC_MSG_ERROR([
 709 *** GLIB glib_required_version or better is required. The latest version of
 710 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 711   gobject gmodule-no-export)
 712
 713 dnl
 714 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 715 dnl
 716 gtk_save_LIBS=$LIBS
 717 LIBS="$LIBS $GLIB_LIBS"
 718 AC_CHECK_FUNCS(bind_textdomain_codeset)
 719 LIBS=$gtk_save_LIBS
 720
 721 AC_CHECK_HEADERS(pwd.h,
 722                  AC_DEFINE(HAVE_PWD_H, 1,
 723                            [Define to 1 if pwd.h is available]))
 724 AC_CHECK_HEADERS(sys/time.h,
 725                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 726                            [Define to 1 if time.h is available]))
 727 AC_CHECK_HEADERS(unistd.h,
 728                  AC_DEFINE(HAVE_UNISTD_H, 1,
 729                            [Define to 1 if unistd.h is available]))
 730 AC_CHECK_HEADERS(ftw.h,
 731                  AC_DEFINE(HAVE_FTW_H, 1,
 732                            [Define to 1 if ftw.h is available]))
 733
 734 AC_MSG_CHECKING([for GNU ftw extensions])
 735 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 736                                      #define _GNU_SOURCE
 737                                      #include <ftw.h>]],
 738                                    [[int flags = FTW_ACTIONRETVAL;]])],
 739                   [gtk_ok=yes],[gtk_ok=no])
 740 if test $gtk_ok = yes; then
 741     AC_MSG_RESULT([yes])
 742     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 743 else
 744     AC_MSG_RESULT([no])
 745 fi
 746
 747 saved_cflags="$CFLAGS"
 748 saved_ldflags="$LDFLAGS"
 749
 750
 751 # Checks for library functions.
 752 AC_FUNC_MMAP
 753
 754 AC_CHECK_FUNCS(mallinfo)
 755 AC_CHECK_FUNCS(getresuid)
 756 AC_TYPE_UID_T
 757
 758 # Check for round(), rint(), isnan(), isinf() and nearbyint()
 759 AC_CHECK_LIB(m,round,,)
 760 AC_CHECK_FUNCS(round rint nearbyint)
 761 AC_CHECK_DECLS([isnan, isinf], [], [], [[#include <math.h>]])
 762
 763 # Checks for gdkspawn
 764 AC_CHECK_HEADERS(crt_externs.h)
 765 AC_CHECK_FUNCS(_NSGetEnviron)
 766
 767 AC_MSG_CHECKING(whether to build dynamic modules)
 768
 769 AC_ARG_ENABLE(modules,
 770               [AS_HELP_STRING([--disable-modules],
 771                               [disable dynamic module loading])])
 772
 773 dynworks=false
 774 build_dynamic_modules=no
 775 deps=
 776 if test x$enable_modules = xno; then
 777     AC_MSG_RESULT(no)
 778 else
 779     AC_MSG_RESULT(yes)
 780     AC_MSG_CHECKING(whether dynamic modules work)
 781     ## for loop is to strip newline
 782     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 783     for I in $tmp; do
 784         dynworks=$I
 785     done
 786
 787     dnl Now we check to see if our libtool supports shared lib deps
 788     dnl (in a rather ugly way even)
 789     if $dynworks; then
 790         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 791         module_deplibs_check=`$module_libtool_config | \
 792             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 793             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 794         if test "x$module_deplibs_check" = "xnone" || \
 795            test "x$module_deplibs_check" = "xunknown" || \
 796            test "x$module_deplibs_check" = "x"; then
 797             dynworks=false
 798         fi
 799     fi
 800
 801     if $dynworks; then
 802         build_dynamic_modules=yes
 803         AC_DEFINE(USE_GMODULE, 1,
 804                   [Define to 1 if gmodule works and should be used])
 805         AC_MSG_RESULT(yes)
 806     else
 807         build_dynamic_modules=no
 808         AC_MSG_RESULT(no)
 809     fi
 810 fi
 811
 812 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 813
 814 #
 815 # Allow building some or all immodules included
 816 #
 817 AC_MSG_CHECKING(immodules to build)
 818
 819 AC_ARG_WITH(included_immodules,
 820             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 821                             [build the specified input methods into gtk])])
 822
 823 if $dynworks; then
 824    :
 825 else
 826    ## if the option was specified, leave it; otherwise disable included immodules
 827    if test x$with_included_immodules = xno; then
 828            with_included_immodules=yes
 829    fi
 830 fi
 831
 832 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 833
 834 included_immodules=""
 835 # If the switch specified without listing any specific ones, include all
 836 if test "x$with_included_immodules" = xyes ; then
 837   included_immodules="$all_immodules"
 838 else
 839   included_immodules="$with_included_immodules"
 840 fi
 841
 842 AC_MSG_RESULT($included_immodules)
 843 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 844
 845 INCLUDED_IMMODULE_OBJ=
 846 INCLUDED_IMMODULE_DEFINE=
 847
 848 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 849 for immodule in $included_immodules; do
 850  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 851  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 852    :
 853  else
 854    AC_MSG_ERROR([the specified input method $immodule does not exist])
 855  fi
 856
 857  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 858  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 859  eval INCLUDE_$immodule_underscores=yes
 860 done
 861 IFS="$gtk_save_ifs"
 862 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 863 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 864
 865 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 866 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 867 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 868 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 869 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 870 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 871 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 872 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 873 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 874 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 875 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 876 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 877
 878 # Checks to see whether we should include mediaLib
 879 # support.
 880 #
 881 AC_CHECK_HEADER(sys/systeminfo.h,
 882                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 883                           [Define to 1 if sys/systeminfo.h is available]))
 884 AC_CHECK_HEADER(sys/sysinfo.h,
 885                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 886                           [Define to 1 if sys/sysinfo.h is available]))
 887
 888 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 889
 890 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 891
 892 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 893   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 894   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 895     REBUILD_PNGS=#
 896   fi
 897 fi
 898
 899 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 900
 901 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 902
 903 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 904    test "x$REBUILD_PNGS" = "x#" ; then
 905      AC_MSG_ERROR([
 906 *** gtkbuiltincache.h is not in the tree, and cannot be built
 907 *** because you don't have libpng, or (when cross-compiling) you
 908 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 909 fi
 910
 911 ########################################
 912 # Windowing system checks
 913 ########################################
 914
 915 # GTK+ uses some X calls, so needs to link against X directly
 916 GTK_DEP_PACKAGES_FOR_X=
 917 GTK_DEP_LIBS_FOR_X=
 918 X_EXTENSIONS=
 919
 920 if test "x$enable_x11_backend" = xyes; then
 921   X_PACKAGES=fontconfig
 922
 923   #
 924   # We use fontconfig very peripherally when decoding the default
 925   # settings.
 926   #
 927   if $PKG_CONFIG --exists fontconfig; then : ; else
 928     AC_MSG_ERROR([
 929 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 930   fi
 931
 932   #
 933   # Check for basic X packages; we use pkg-config if available
 934   #
 935   if $PKG_CONFIG --exists x11 xext; then
 936     have_base_x_pc=true
 937     X_PACKAGES="$X_PACKAGES x11 xext"
 938     x_libs="`$PKG_CONFIG --libs x11 xext`"
 939     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 940
 941     # Strip out any .la files that pkg-config might give us (this happens
 942     # with -uninstalled.pc files)
 943     x_libs_for_checks=
 944     for I in $x_libs ; do
 945       case $I in
 946         *.la) ;;
 947         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 948       esac
 949     done
 950
 951     GTK_PACKAGES_FOR_X="x11"
 952   else
 953     have_base_x_pc=false
 954     AC_PATH_XTRA
 955     if test x$no_x = xyes ; then
 956       AC_MSG_ERROR([X development libraries not found])
 957     fi
 958
 959     x_cflags="$X_CFLAGS"
 960     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 961
 962     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 963   fi
 964
 965   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 966   x_extra_libs=
 967
 968   gtk_save_cppflags="$CPPFLAGS"
 969   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 970
 971   gtk_save_LIBS=$LIBS
 972   LIBS="$x_libs_for_checks $LIBS"
 973
 974   # Sanity check for the X11 and Xext libraries. While everything we need from
 975   # Xext is optional, the chances a system has *none* of these things is so
 976   # small that we just unconditionally require it.
 977   AC_CHECK_FUNC(XOpenDisplay, :,
 978                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 979   AC_CHECK_FUNC(XextFindDisplay, :,
 980                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 981
 982   # Check for xReply
 983
 984   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 985   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 986                                      [[xReply *rep;]])],
 987                     [AC_MSG_RESULT([no])],
 988                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 989                                                           #include <X11/Xlibint.h>]],
 990                                                         [[xReply *rep;]])],
 991                                        [AC_MSG_RESULT([yes])
 992                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 993                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 994                                        [AC_MSG_RESULT([unknown])
 995                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 996
 997   # Check for XKB support.
 998
 999   if test "x$enable_xkb" = "xyes"; then
1000         AC_CHECK_FUNC(XkbQueryExtension,
1001                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1002                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1003                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1004   elif test "x$enable_xkb" = "xmaybe"; then
1005         AC_CHECK_FUNC(XkbQueryExtension,
1006                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1007                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1008   else
1009         AC_MSG_WARN(XKB support explicitly disabled)
1010   fi
1011
1012   # Check for shaped window extension
1013
1014   AC_CHECK_FUNC(XShapeCombineMask, :,
1015      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1016
1017   # X SYNC check
1018   gtk_save_CFLAGS="$CFLAGS"
1019   CFLAGS="$CFLAGS $x_cflags"
1020
1021   AC_CHECK_FUNC(XSyncQueryExtension,
1022       [AC_CHECK_HEADER(X11/extensions/sync.h,
1023           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1024           :, [#include <X11/Xlib.h>])])
1025
1026   CFLAGS="$gtk_save_CFLAGS"
1027
1028   if test "x$enable_xinerama" != "xno"; then
1029     # Check for Xinerama extension (Solaris impl or Xfree impl)
1030     have_xfree_xinerama=false
1031     have_solaris_xinerama=false
1032
1033     gtk_save_cppflags="$CPPFLAGS"
1034     CPPFLAGS="$CPPFLAGS $x_cflags"
1035
1036     # Check for XFree
1037     AC_MSG_CHECKING(for Xinerama packages)
1038
1039     if $PKG_CONFIG --exists xinerama ; then
1040        AC_MSG_RESULT(yes)
1041        have_xfree_xinerama=true
1042        X_PACKAGES="$X_PACKAGES xinerama"
1043     else
1044        AC_MSG_RESULT(no)
1045        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1046            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1047            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1048            have_xfree_xinerama=true], :,
1049            [#include <X11/Xlib.h>])])
1050     fi
1051
1052     if $have_xfree_xinerama ; then
1053       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1054       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1055                 [Define to 1 if XFree Xinerama is available])
1056       AC_DEFINE(HAVE_XINERAMA, 1,
1057                 [Define to 1 is Xinerama is available])
1058     else
1059       case "$host" in
1060         *-*-solaris*)
1061             # Check for solaris
1062             AC_MSG_CHECKING(for Xinerama support on Solaris)
1063
1064             have_solaris_xinerama=false
1065             AC_CHECK_FUNC(XineramaGetInfo,
1066                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1067                     [have_solaris_xinerama=true], :,
1068                     [#include <X11/Xlib.h>])])
1069
1070             if $have_solaris_xinerama ; then
1071               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1072               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1073                         [Define to 1 if solaris xinerama is available])
1074               AC_DEFINE(HAVE_XINERAMA, 1,
1075                         [Define to 1 if xinerama is available])
1076               AC_MSG_RESULT(yes)
1077             else
1078               AC_MSG_RESULT(no)
1079             fi
1080             ;;
1081         *)
1082             ;;
1083       esac
1084     fi
1085   fi
1086   if test "x$enable_xinerama" = "xyes" ; then
1087     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1088       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1089     fi
1090   fi
1091
1092   # Check for XGetEventData for GenericEvents
1093   AC_CHECK_FUNC(XGetEventData,
1094                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1095
1096   # set up things for XInput
1097   if $PKG_CONFIG --exists "xi" ; then
1098
1099     X_PACKAGES="$X_PACKAGES xi"
1100     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xi"
1101
1102     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1103                     have_xinput2=yes
1104                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1105
1106     gtk_save_LIBS="$LIBS"
1107     LIBS="$LIBS -lXi"
1108
1109     # Note that we also check that the XIScrollClassInfo struct is defined,
1110     # because at least Ubuntu Oneiric seems to have XIAllowTouchEvents(), but not the XIScrollClassInfo struct.
1111     AC_CHECK_FUNC([XIAllowTouchEvents],
1112       [AC_CHECK_MEMBER([XIScrollClassInfo.number],
1113                        have_xinput2_2=yes
1114                        AC_DEFINE(XINPUT_2_2, 1, [Define to 1 if XInput 2.2 is available]),
1115                        have_xinput2_2=no,
1116                        [[#include <X11/extensions/XInput2.h>]])])
1117     LIBS="$gtk_save_LIBS"
1118
1119     if test "x$have_xinput2_2" = "xyes"; then
1120       X_EXTENSIONS="$X_EXTENSIONS XI2.2"
1121     else
1122       X_EXTENSIONS="$X_EXTENSIONS XI2"
1123     fi
1124   fi
1125
1126   AS_IF([test "x$have_xinput2" != "xyes"],
1127         [AC_MSG_ERROR([*** XInput2 extension not found. Check 'config.log' for more details.])])
1128
1129   # Check for the RANDR extension
1130   if test x"$enable_xrandr" != xno; then
1131     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1132       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1133
1134       X_PACKAGES="$X_PACKAGES xrandr"
1135       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1136     elif test x"$enable_xrandr" = xyes; then
1137       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1138     fi
1139   fi
1140
1141   # Checks for Xcursor library
1142
1143   if $PKG_CONFIG --exists xcursor ; then
1144     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1145
1146     X_PACKAGES="$X_PACKAGES xcursor"
1147   fi
1148
1149   # Checks for XFixes extension
1150
1151   if test x"$enable_xfixes" != xno; then
1152     if $PKG_CONFIG --exists xfixes ; then
1153       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1154
1155       X_PACKAGES="$X_PACKAGES xfixes"
1156       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1157       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1158     elif test x"$enable_xfixes" = xyes; then
1159       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1160     fi
1161   fi
1162
1163   # Checks for Xcomposite extension
1164
1165   if test x"$enable_xcomposite" != xno; then
1166     if $PKG_CONFIG --exists xcomposite ; then
1167       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1168
1169       X_PACKAGES="$X_PACKAGES xcomposite"
1170       X_EXTENSIONS="$X_EXTENSIONS Composite"
1171       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1172     elif test x"$enable_xcomposite" = xyes; then
1173       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1174     fi
1175   fi
1176
1177   # Checks for Xdamage extension
1178
1179   if test x"$enable_xdamage" != xno; then
1180     if $PKG_CONFIG --exists xdamage ; then
1181       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1182
1183       X_PACKAGES="$X_PACKAGES xdamage"
1184       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1185       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1186     elif test x"$enable_xdamage" = xyes; then
1187       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1188     fi
1189   fi
1190
1191   if $have_base_x_pc ; then
1192     GDK_EXTRA_LIBS="$x_extra_libs"
1193   else
1194     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1195   fi
1196
1197   CPPFLAGS="$gtk_save_cppflags"
1198   LIBS="$gtk_save_libs"
1199
1200   AM_CONDITIONAL(USE_X11, true)
1201
1202   # strip leading space
1203   X_EXTENSIONS=${X_EXTENSIONS#* }
1204
1205 else
1206   XPACKAGES=
1207
1208   AM_CONDITIONAL(USE_X11, false)
1209 fi
1210
1211 # Check for gio-unix
1212 if test "$have_gio_unix" = "yes"; then
1213   GDK_GIO_PACKAGE=gio-unix-2.0
1214   AC_DEFINE([HAVE_GIO_UNIX], [1],
1215             [Define if gio-unix is available])
1216 else
1217   GDK_GIO_PACKAGE=gio-2.0
1218 fi
1219
1220 # Check for Pango flags
1221
1222 AC_MSG_CHECKING(Pango flags)
1223 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1224         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1225         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1226
1227         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1228 else
1229         AC_MSG_ERROR([
1230 *** Pango not found. Pango built with Cairo support is required
1231 *** to build GTK+. See http://www.pango.org for Pango information.
1232 ])
1233 fi
1234
1235 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1236
1237 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1238         :
1239 else
1240         gtk_save_LIBS="$LIBS"
1241         LIBS="$PANGO_LIBS $LIBS"
1242         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1243 *** Can't link to Pango. Pango is required to build
1244 *** GTK+. For more information see http://www.pango.org]))
1245         LIBS="$gtk_save_LIBS"
1246 fi
1247
1248 CFLAGS="$saved_cflags"
1249 LDFLAGS="$saved_ldflags"
1250
1251 GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo cairo-gobject"
1252 GDK_PRIVATE_PACKAGES="$GDK_GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES $cairo_backends"
1253 if test "x$enable_x11_backend" = xyes; then
1254   GDK_PRIVATE_PACKAGES="$GDK_PRIVATE_PACKAGES pangoft2"
1255 fi
1256
1257 PKG_CHECK_MODULES(GDK_DEP, $GDK_PACKAGES $GDK_PRIVATE_PACKAGES)
1258 GDK_DEP_LIBS="$GDK_EXTRA_LIBS $GDK_DEP_LIBS $MATH_LIB"
1259 GDK_DEP_CFLAGS="$GDK_DEP_CFLAGS $GDK_EXTRA_CFLAGS"
1260 #
1261 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1262 # into the pkg-config files
1263 #
1264 if test $enable_explicit_deps != yes ; then
1265   GDK_EXTRA_LIBS=
1266 fi
1267
1268 AC_SUBST(GDK_PACKAGES)
1269 AC_SUBST(GDK_PRIVATE_PACKAGES)
1270 AC_SUBST(GDK_EXTRA_LIBS)
1271 AC_SUBST(GDK_EXTRA_CFLAGS)
1272 AC_SUBST(GDK_DEP_LIBS)
1273 AC_SUBST(GDK_DEP_CFLAGS)
1274
1275
1276 ########################################
1277 # Check for Accessibility Toolkit flags
1278 ########################################
1279
1280 ATK_PACKAGES=atk
1281 PKG_CHECK_MODULES(ATK, $ATK_PACKAGES)
1282
1283 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1284 GTK_PRIVATE_PACKAGES=""
1285 if test "x$enable_x11_backend" = xyes; then
1286   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES pangoft2"
1287 fi
1288 if test "$have_gio_unix" = "yes"; then
1289   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES gio-unix-2.0"
1290 fi
1291 GTK_EXTRA_LIBS=
1292
1293 GTK_EXTRA_CFLAGS=
1294 PKG_CHECK_MODULES(GTK_DEP, $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES $GTK_PRIVATE_PACKAGES)
1295 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X $GTK_DEP_LIBS $GTK_EXTRA_LIBS $MATH_LIB"
1296 GTK_DEP_CFLAGS="$GTK_DEP_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1297
1298 if test x"$os_win32" = xyes; then
1299   GTK_EXTRA_CFLAGS="$msnative_struct"
1300 fi
1301
1302 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1303 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1304 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1305 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1306
1307 AC_SUBST(GTK_PACKAGES)
1308 AC_SUBST(GTK_PRIVATE_PACKAGES)
1309 AC_SUBST(GTK_EXTRA_LIBS)
1310 AC_SUBST(GTK_EXTRA_CFLAGS)
1311 AC_SUBST(GTK_DEP_LIBS)
1312 AC_SUBST(GTK_DEP_CFLAGS)
1313
1314 AC_SUBST(GLIB_PREFIX)
1315 AC_SUBST(ATK_PREFIX)
1316 AC_SUBST(PANGO_PREFIX)
1317 AC_SUBST(CAIRO_PREFIX)
1318
1319 AC_SUBST(GTK_DEBUG_FLAGS)
1320 AC_SUBST(GTK_XIM_FLAGS)
1321
1322 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1323 AC_SUBST(GDK_PIXBUF_LIBS)
1324
1325 ########################
1326 # Checks needed for gail
1327 ########################
1328
1329 old_LIBS="$LIBS"
1330 dnl Checks for inet libraries:
1331 AC_SEARCH_LIBS(gethostent, nsl)
1332 AC_SEARCH_LIBS(setsockopt, socket)
1333 AC_SEARCH_LIBS(connect, inet)
1334
1335 dnl check for the sockaddr_un.sun_len member
1336 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1337                 [struct_sockaddr_un_sun_len=true],
1338                 [struct_sockaddr_un_suin_len=false],
1339                 [#include <sys/types.h>
1340                  #include <sys/un.h>]
1341                 )
1342 case $struct_sockaddr_un_sun_len in
1343         true)
1344                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1345                                    [Have the sockaddr_un.sun_len member])
1346                 ;;
1347         *)
1348                 ;;
1349 esac
1350
1351 GAIL_INET_LIBS="$LIBS"
1352 AC_SUBST([GAIL_INET_LIBS])
1353
1354 LIBS="$old_LIBS"
1355
1356 ################################################################
1357 # Printing system checks
1358 ################################################################
1359
1360 PRINT_BACKENDS="file lpr"
1361
1362 AC_ARG_ENABLE(cups,
1363               [AS_HELP_STRING([--disable-cups],
1364                               [disable cups print backend])],,
1365               [enable_cups=auto])
1366
1367 if test "x$enable_cups" = "xno"; then
1368   AM_CONDITIONAL(HAVE_CUPS, false)
1369 else
1370   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1371   if test "x$CUPS_CONFIG" = "xno"; then
1372     if test "x$enable_cups" = "xauto"; then
1373       AM_CONDITIONAL(HAVE_CUPS, false)
1374     else
1375       AC_MSG_ERROR([
1376 *** cups not found.
1377 ])
1378     fi
1379   else
1380     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1381     CUPS_LIBS=`$CUPS_CONFIG --libs`
1382
1383     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1384     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1385     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1386
1387     if test $CUPS_API_MAJOR -gt 1 -o \
1388             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -lt 2; then
1389       AC_MSG_ERROR([CUPS >= 1.2 not found])
1390     fi
1391     if test $CUPS_API_MAJOR -gt 1 -o \
1392             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 6; then
1393       AC_DEFINE(HAVE_CUPS_API_1_6, 1,
1394                 [Define to 1 if CUPS 1.6 API is available])
1395
1396     fi
1397
1398     AC_SUBST(CUPS_API_MAJOR)
1399     AC_SUBST(CUPS_API_MINOR)
1400     AC_SUBST(CUPS_CFLAGS)
1401     AC_SUBST(CUPS_LIBS)
1402
1403     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1404
1405     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1406     AM_CONDITIONAL(HAVE_CUPS, true)
1407
1408     gtk_save_cflags="$CFLAGS"
1409     CFLAGS="$CUPS_CFLAGS"
1410     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1411                                        [[http_t http; char *s = http.authstring;]])],
1412                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1413                                  [Define if cups http_t authstring field is accessible])],
1414                       [])
1415     CFLAGS="$gtk_save_cflags"
1416
1417     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1418
1419     gtk_save_libs="$LIBS"
1420     LIBS="$CUPS_LIBS"
1421     AC_CHECK_FUNCS(httpGetAuthString)
1422     LIBS="$gtk_save_libs"
1423   fi
1424 fi
1425
1426 # Checks to see if we should compile with PAPI backend for GTK+
1427 #
1428
1429 AC_ARG_ENABLE(papi,
1430               [AS_HELP_STRING([--disable-papi],
1431                               [disable papi print backend])],,
1432               [enable_papi=auto])
1433
1434 if test "x$enable_papi" = "xno"; then
1435   AM_CONDITIONAL(HAVE_PAPI, false)
1436 else
1437   AC_MSG_CHECKING(libpapi)
1438   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1439   if test $have_papi = yes; then
1440     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1441     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1442   fi
1443   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1444   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1445     AC_MSG_ERROR([
1446 *** papi not found.
1447 ])
1448   fi
1449 fi
1450
1451 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1452
1453 gtk_save_cppflags="$CPPFLAGS"
1454 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1455
1456 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1457 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1458 *** backend enabled.]))
1459
1460 if test "$os_win32" != "yes"; then
1461   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1462 *** Can't find cairo-ps.h. You must build Cairo with the
1463 *** postscript backend enabled.]))
1464
1465   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1466 *** Cannot find cairo-svg.h. You must build Cairo with the
1467 *** svg backend enabled.]))
1468 fi
1469
1470 CPPFLAGS="$gtk_save_cppflags"
1471
1472
1473 AC_ARG_ENABLE(test-print-backend,
1474               [AS_HELP_STRING([--enable-test-print-backend],
1475                               [build test print backend])],,
1476               [enable_test_print_backend=no])
1477 if test "x$enable_test_print_backend" != "xno" ; then
1478   PRINT_BACKENDS="$PRINT_BACKENDS test"
1479 fi
1480 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1481
1482 if test "$os_win32" = "yes"; then
1483   AC_CHECK_TYPES([IPrintDialogCallback],[],[],[[#include <windows.h>]])
1484 fi
1485
1486 ################################################################
1487 # Strip -export-dynamic from the link lines of various libraries
1488 ################################################################
1489
1490 #
1491 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1492 #  but this flag is only meaningful for executables. For libraries
1493 #  the effect is undefined; what it causes on Linux is that the
1494 #  export list from -export-symbols-regex is ignored and everything
1495 #  is exported
1496 #
1497 # We are using gmodule-no-export now, but I'm leaving the stripping
1498 # code in place for now, since pango and atk still require gmodule.
1499 export SED
1500 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1501 if test -n "$export_dynamic"; then
1502   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1503   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1504 fi
1505
1506 #############
1507 # GSettings #
1508 #############
1509
1510 GLIB_GSETTINGS
1511
1512 ##################################################
1513 # GObject introspection
1514 ##################################################
1515
1516 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1517
1518 ##################################################
1519 # Packagekit module
1520 #################################################
1521
1522 AC_ARG_ENABLE(packagekit,
1523               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1524                               [build PackageKit open-with module [default=auto]])],
1525               [enable_packagekit="$enableval"],
1526               [enable_packagekit=auto])
1527 if test "$enable_packagekit" = "auto"; then
1528   if test "$os_win32" = "yes"; then
1529     enable_packagekit=no
1530   else
1531     enable_packagekit=yes
1532   fi
1533 fi
1534
1535 AC_MSG_CHECKING([whether to use PackageKit])
1536 build_packagekit=no
1537 if test "x$enable_packagekit" != "xno"; then
1538   if test "$os_win32" != "yes"; then
1539     build_packagekit=yes
1540     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1541   else
1542     AC_MSG_ERROR([packagekit support is not available on win32])
1543   fi
1544 fi
1545 AC_MSG_RESULT([$build_packagekit])
1546
1547 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1548
1549 ##################################################
1550 # colord module
1551 #################################################
1552
1553 AC_ARG_ENABLE(colord,
1554               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1555                               [build colord support code [default=auto]])],
1556               [enable_colord="$enableval"],
1557               [enable_colord=auto])
1558
1559 AC_MSG_CHECKING([whether to use colord])
1560 if test "$enable_colord" = "auto"; then
1561   if test "$os_win32" = "yes"; then
1562     enable_colord=no
1563   fi
1564 fi
1565 if test "$enable_colord" != "no"; then
1566   AC_MSG_RESULT([yes])
1567 else
1568   AC_MSG_RESULT([no])
1569 fi
1570
1571 have_colord=no
1572 if test "$enable_colord" != "no"; then
1573         if test "$os_win32" != "yes"; then
1574                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1575                                   have_colord=yes, have_colord=no)
1576                 if test "$enable_colord" = "yes"; then
1577                         if test "$have_colord" = "no"; then
1578                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1579                         fi
1580                 fi
1581         else
1582                 AC_MSG_ERROR([colord support is not available on win32])
1583         fi
1584 fi
1585
1586 if test "$have_colord" = "yes"; then
1587         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1588 fi
1589 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1590
1591 ##################################################
1592 # Checks for gtk-doc and docbook-tools
1593 ##################################################
1594
1595 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1596
1597 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1598 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1599
1600 AC_ARG_ENABLE(man,
1601               [AS_HELP_STRING([--enable-man],
1602                               [regenerate man pages from Docbook [default=no]])],
1603               [enable_man=yes],
1604               [enable_man=no])
1605
1606 if test "${enable_man}" != no; then
1607   dnl
1608   dnl Check for xsltproc
1609   dnl
1610   AC_PATH_PROG([XSLTPROC], [xsltproc])
1611   if test -z "$XSLTPROC"; then
1612     enable_man=no
1613   fi
1614
1615   dnl check for DocBook DTD and stylesheets in the local catalog.
1616   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1617      [DocBook XML DTD V4.1.2],,enable_man=no)
1618   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1619      [DocBook XSL Stylesheets],,enable_man=no)
1620 fi
1621
1622 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1623
1624
1625 ##################################################
1626 # Output commands
1627 ##################################################
1628
1629 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1630         outfile=gdkconfig.h-tmp
1631         cat > $outfile <<\_______EOF
1632 /* gdkconfig.h
1633  *
1634  * This is a generated file.  Please modify `configure.ac'
1635  */
1636
1637 #ifndef __GDKCONFIG_H__
1638 #define __GDKCONFIG_H__
1639
1640 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1641 #error "Only <gdk/gdk.h> can be included directly."
1642 #endif
1643
1644 #include <glib.h>
1645
1646 G_BEGIN_DECLS
1647
1648 _______EOF
1649
1650         cat >>$outfile <<_______EOF
1651 $gdk_windowing
1652 _______EOF
1653
1654         cat >>$outfile <<_______EOF
1655
1656 G_END_DECLS
1657
1658 #endif  /* __GDKCONFIG_H__ */
1659 _______EOF
1660
1661
1662         if cmp -s $outfile gdk/gdkconfig.h; then
1663           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1664           rm -f $outfile
1665         else
1666           mv $outfile gdk/gdkconfig.h
1667         fi
1668 ],[
1669 gdk_windowing='$GDK_WINDOWING'
1670 ])
1671
1672 dnl
1673 dnl Check for -Bsymbolic-functions linker flag used to avoid
1674 dnl intra-library PLT jumps, if available.
1675 dnl
1676 AC_ARG_ENABLE(Bsymbolic,
1677               [AS_HELP_STRING([--disable-Bsymbolic],
1678                               [avoid linking with -Bsymbolic])],,
1679               [SAVED_LDFLAGS="${LDFLAGS}"
1680                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1681                LDFLAGS=-Wl,-Bsymbolic-functions
1682                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1683                                                [[int main (void) { return 0; }]])],
1684                               [AC_MSG_RESULT(yes)
1685                                enable_Bsymbolic=yes],
1686                               [AC_MSG_RESULT(no)
1687                                enable_Bsymbolic=no])
1688                LDFLAGS="${SAVED_LDFLAGS}"])
1689
1690 if test "x${enable_Bsymbolic}" = "xyes" ; then
1691   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1692 fi
1693 AC_SUBST(GTK_LINK_FLAGS)
1694
1695 AC_CONFIG_FILES([
1696 config.h.win32
1697 gtk-zip.sh
1698 Makefile
1699 gdk-3.0.pc
1700 gtk+-3.0.pc
1701 gtk+-unix-print-3.0.pc
1702 gail-3.0.pc
1703 m4macros/Makefile
1704 po/Makefile.in
1705 po-properties/Makefile.in
1706 demos/Makefile
1707 demos/gtk-demo/Makefile
1708 demos/gtk-demo/geninclude.pl
1709 demos/pixbuf-demo/Makefile
1710 demos/widget-factory/Makefile
1711 examples/Makefile
1712 tests/Makefile
1713 tests/a11y/Makefile
1714 tests/css/Makefile
1715 tests/css/parser/Makefile
1716 tests/reftests/Makefile
1717 tests/visuals/Makefile
1718 docs/Makefile
1719 docs/reference/Makefile
1720 docs/reference/gdk/Makefile
1721 docs/reference/gdk/version.xml
1722 docs/reference/gtk/Makefile
1723 docs/reference/gtk/gtk3.types
1724 docs/reference/gtk/version.xml
1725 docs/reference/libgail-util/Makefile
1726 docs/reference/libgail-util/version.xml
1727 docs/tools/Makefile
1728 build/Makefile
1729 build/win32/Makefile
1730 build/win32/vs9/Makefile
1731 build/win32/vs10/Makefile
1732 gdk/Makefile
1733 gdk/broadway/Makefile
1734 gdk/x11/Makefile
1735 gdk/win32/Makefile
1736 gdk/win32/rc/Makefile
1737 gdk/win32/rc/gdk.rc
1738 gdk/quartz/Makefile
1739 gdk/wayland/Makefile
1740 gdk/tests/Makefile
1741 gdk/gdkversionmacros.h
1742 gtk/Makefile
1743 gtk/makefile.msc
1744 gtk/gtkversion.h
1745 gtk/gtk-win32.rc
1746 gtk/a11y/Makefile
1747 gtk/tests/Makefile
1748 libgail-util/Makefile
1749 modules/Makefile
1750 modules/engines/Makefile
1751 modules/engines/pixbuf/Makefile
1752 modules/input/Makefile
1753 modules/printbackends/Makefile
1754 modules/printbackends/cups/Makefile
1755 modules/printbackends/lpr/Makefile
1756 modules/printbackends/file/Makefile
1757 modules/printbackends/papi/Makefile
1758 modules/printbackends/test/Makefile
1759 perf/Makefile
1760 ])
1761
1762 AC_OUTPUT
1763
1764 # beautify the immodule list a bit
1765 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1766 if test -z "${included_immodules}"; then included_immodules="none"; fi
1767
1768 echo ""
1769 echo "        GTK+ $GTK_VERSION"
1770 echo "        ==========="
1771 echo ""
1772 echo "        GDK backends:         $GDK_BACKENDS"
1773 if test "$enable_x11_backend" = "yes"; then
1774 echo "        X11 extensions:       $X_EXTENSIONS"
1775 fi
1776 echo "        Print backends:       $PRINT_BACKENDS"
1777 echo "        Dynamic modules:      $build_dynamic_modules"
1778 echo "        Included immodules:   $included_immodules"
1779 echo "        PackageKit support:   $build_packagekit"
1780 echo "        colord support:       $have_colord"
1781 echo "        Introspection:        $found_introspection"
1782 echo "        Debugging:            $enable_debug"
1783 echo "        Documentation:        $enable_gtk_doc"