Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [3])
  13 m4_define([gtk_micro_version], [18])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.31.20])
  43 m4_define([pango_required_version], [1.29.0])
  44 m4_define([atk_required_version], [2.1.5])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.25.2])
  47 m4_define([introspection_required_version], [0.10.1])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_INSTALL
 129 AC_PROG_MAKE_SET
 130
 131
 132 GETTEXT_PACKAGE=gtk30
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 135                    [The prefix for our gettext translation domains.])
 136
 137 AC_CANONICAL_HOST
 138
 139 MATH_LIB=-lm
 140 AC_MSG_CHECKING([for native Win32])
 141 LIB_EXE_MACHINE_FLAG=X86
 142 EXE_MANIFEST_ARCHITECTURE=X86
 143 case "$host" in
 144   *-*-mingw*)
 145     os_win32=yes
 146     gio_can_sniff=no
 147     MATH_LIB=
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       EXE_MANIFEST_ARCHITECTURE=AMD64
 152       ;;
 153     esac
 154     ;;
 155   *)
 156     os_win32=no
 157     ;;
 158 esac
 159 AC_MSG_RESULT([$os_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 163
 164 case $host in
 165   *-*-linux*)
 166     os_linux=yes
 167     ;;
 168 esac
 169
 170 dnl
 171 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 172 dnl We use this for an automated test for C++ header correctness.
 173 dnl
 174 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 175 AC_LANG_PUSH([C++])
 176
 177 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 178                                    [[class a { int b; } c;]])],
 179                   [],[CXX=])
 180 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 181
 182 gtk_save_cxxflags="$CXXFLAGS"
 183 CXXFLAGS="$CXXFLAGS -x objective-c++"
 184 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 185                                    [[]])],
 186                   [OBJC=yes],[OBJC=no])
 187 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 188 CXXFLAGS="$gtk_save_cxxflags"
 189 AC_LANG_POP([C++])
 190
 191 if test "$os_win32" = "yes"; then
 192   if test x$enable_static = xyes -o x$enable_static = x; then
 193     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 194     enable_static=no
 195   fi
 196   if test x$enable_shared = xno; then
 197     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 198   fi
 199   enable_shared=yes
 200 fi
 201
 202 dnl Initialize libtool
 203 LT_PREREQ([2.2.6])
 204 LT_INIT([disable-static win32-dll])
 205 # Create libtool early, because it's used in configure
 206 LT_OUTPUT
 207
 208 # Make sure we use 64-bit versions of various file stuff.
 209 AC_SYS_LARGEFILE
 210
 211 AM_PROG_AS
 212 AC_PATH_PROG(NM, nm, nm)
 213
 214 AC_MSG_CHECKING([for some Win32 platform])
 215 case "$host" in
 216   *-*-mingw*|*-*-cygwin*)
 217     platform_win32=yes
 218     ;;
 219   *)
 220     platform_win32=no
 221     ;;
 222 esac
 223 AC_MSG_RESULT([$platform_win32])
 224 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 225
 226 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 227 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 228 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 229
 230 if test "$os_win32" = "yes"; then
 231   AC_CHECK_TOOL(WINDRES, windres, no)
 232   if test "$WINDRES" = no; then
 233     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 234   fi
 235   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 236 fi
 237 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 238
 239 m4_define([debug_default],
 240           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 241
 242 dnl declare --enable-* args and collect ac_help strings
 243 AC_ARG_ENABLE(debug,
 244               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 245                               [turn on debugging @<:@default=debug_default@:>@])],,
 246               [enable_debug=debug_default])
 247
 248 AC_ARG_ENABLE(rebuilds,
 249               [AS_HELP_STRING([--disable-rebuilds],
 250                               [disable all source autogeneration rules])],,
 251               [enable_rebuilds=yes])
 252
 253 AC_ARG_ENABLE(gtk2-dependency,
 254               [AS_HELP_STRING([--enable-gtk2-dependency],
 255                               [Do not build gtk-update-icon-cache and other shared tools])],,
 256               [enable_gtk2_dependency=no])
 257
 258 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 259
 260 AC_ARG_ENABLE(xkb,
 261               [AS_HELP_STRING([--enable-xkb],
 262                               [support XKB extension [default=maybe]])],,
 263               [enable_xkb="maybe"])
 264 AC_ARG_ENABLE(xinerama,
 265               [AS_HELP_STRING([--enable-xinerama],
 266                               [support Xinerama extension [default=maybe]])],,
 267               [enable_xinerama="maybe"])
 268 AC_ARG_ENABLE(xrandr,
 269               [AS_HELP_STRING([--enable-xrandr],
 270                               [support XRandR extension [default=maybe]])],,
 271               [enable_xrandr="maybe"])
 272 AC_ARG_ENABLE(xfixes,
 273               [AS_HELP_STRING([--enable-xfixes],
 274                               [support XFixes extension [default=maybe]])],,
 275               [enable_xfixes="maybe"])
 276 AC_ARG_ENABLE(xcomposite,
 277               [AS_HELP_STRING([--enable-xcomposite],
 278                               [support X Composite extension [default=maybe]])],,
 279               [enable_xcomposite="maybe"])
 280 AC_ARG_ENABLE(xdamage,
 281               [AS_HELP_STRING([--enable-xdamage],
 282                               [support X Damage extension [default=maybe]])],,
 283               [enable_xdamage="maybe"])
 284
 285 AC_ARG_ENABLE(x11-backend,
 286               [AS_HELP_STRING([--enable-x11-backend],
 287                               [enable the X11 gdk backend])],
 288                               [backend_set=yes])
 289 AC_ARG_ENABLE(win32-backend,
 290               [AS_HELP_STRING([--enable-win32-backend],
 291                               [enable the Win32 gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(quartz-backend,
 294               [AS_HELP_STRING([--enable-quartz-backend],
 295                               [enable the quartz gdk backend])],
 296                               [backend_set=yes])
 297 AC_ARG_ENABLE(broadway-backend,
 298               [AS_HELP_STRING([--enable-broadway-backend],
 299                               [enable the broadway (HTML5) gdk backend])],
 300                               [backend_set=yes])
 301 AC_ARG_ENABLE(wayland-backend,
 302               [AS_HELP_STRING([--enable-wayland-backend],
 303                               [enable the wayland gdk backend])],
 304                               [backend_set=yes])
 305
 306 if test -z "$backend_set"; then
 307   if test "$platform_win32" = yes; then
 308     enable_win32_backend=yes
 309   else
 310     enable_x11_backend=yes
 311   fi
 312 fi
 313
 314 AC_ARG_ENABLE(quartz-relocation,
 315               [AS_HELP_STRING([--enable-quartz-relocation],
 316                               [enable bundle-based relocation functions])],
 317                               [quartz_relocation=yes])
 318
 319 cairo_backends=
 320 backend_immodules=
 321 GDK_BACKENDS=
 322 GDK_EXTRA_LIBS=
 323 GDK_EXTRA_CFLAGS=
 324 GDK_WINDOWING=
 325 GIO_PACKAGE=gio-2.0
 326 PANGO_PACKAGES="pango pangocairo"
 327
 328 if test "$enable_x11_backend" = "yes"; then
 329   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 330   # backend names are identical.
 331   cairo_backends="$cairo_backends cairo-xlib"
 332   GDK_BACKENDS="$GDK_BACKENDS x11"
 333   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 334   # gdkapplaunchcontext-x11.c
 335   GIO_PACKAGE=gio-unix-2.0
 336   backend_immodules="$backend_immodules,xim"
 337   GDK_WINDOWING="$GDK_WINDOWING
 338 #define GDK_WINDOWING_X11"
 339 fi
 340
 341 if test "$enable_win32_backend" = "yes"; then
 342   cairo_backends="$cairo_backends cairo-win32"
 343   GDK_BACKENDS="$GDK_BACKENDS win32"
 344   backend_immodules="$backend_immodules,ime"
 345   GDK_WINDOWING="$GDK_WINDOWING
 346 #define GDK_WINDOWING_WIN32"
 347   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 348   AM_CONDITIONAL(USE_WIN32, true)
 349   PANGO_PACKAGES="pangowin32 pangocairo"
 350 else
 351   AM_CONDITIONAL(USE_WIN32, false)
 352 fi
 353
 354 if test "x$enable_quartz_backend" = xyes; then
 355   cairo_backends="$cairo_backends cairo-quartz"
 356   GDK_BACKENDS="$GDK_BACKENDS quartz"
 357   GDK_WINDOWING="$GDK_WINDOWING
 358 #define GDK_WINDOWING_QUARTZ"
 359   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 360   AM_CONDITIONAL(USE_QUARTZ, true)
 361   if test "x$quartz_relocation" = xyes; then
 362     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 363   fi
 364
 365 else
 366   AM_CONDITIONAL(USE_QUARTZ, false)
 367 fi
 368
 369
 370 if test "x$enable_broadway_backend" == xyes; then
 371   GDK_BACKENDS="$GDK_BACKENDS broadway"
 372   cairo_backends="$cairo_backends cairo"
 373   GDK_WINDOWING="$GDK_WINDOWING
 374 #define GDK_WINDOWING_BROADWAY"
 375   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 376   AM_CONDITIONAL(USE_BROADWAY, true)
 377 else
 378   AM_CONDITIONAL(USE_BROADWAY, false)
 379 fi
 380
 381 if test "x$enable_wayland_backend" == "xyes"; then
 382   # Wayland uses cairo-gl
 383   cairo_backends="$cairo_backends cairo-gl"
 384   GDK_BACKENDS="$GDK_BACKENDS wayland"
 385   GIO_PACKAGE=gio-unix-2.0
 386   GDK_WINDOWING="$GDK_WINDOWING
 387 #define GDK_WINDOWING_WAYLAND"
 388   WAYLAND_PACKAGES="wayland-client xkbcommon wayland-egl egl"
 389   AM_CONDITIONAL(USE_WAYLAND, true)
 390 else
 391   AM_CONDITIONAL(USE_WAYLAND, false)
 392 fi
 393
 394 # strip leading space
 395 GDK_BACKENDS=${GDK_BACKENDS#* }
 396
 397 AC_SUBST(GDK_BACKENDS)
 398
 399 if test -z "$GDK_BACKENDS"; then
 400   AC_MSG_ERROR([No GDK backends selected.])
 401 fi
 402
 403 if test "x$enable_debug" = "xyes"; then
 404   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 405   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 406 else
 407   if test "x$enable_debug" = "xno"; then
 408     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 409   else
 410     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 411   fi
 412 fi
 413
 414
 415 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 416                    [Define if debugging is enabled])
 417
 418
 419 # Build time sanity check...
 420 AM_SANITY_CHECK
 421
 422 changequote(,)dnl
 423 if test "x$GCC" = "xyes"; then
 424   case " $CFLAGS " in
 425   *[\ \ ]-Wall[\ \      ]*) ;;
 426   *) CFLAGS="$CFLAGS -Wall" ;;
 427   esac
 428
 429   if test "x$enable_ansi" = "xyes"; then
 430     case " $CFLAGS " in
 431     *[\ \       ]-ansi[\ \      ]*) ;;
 432     *) CFLAGS="$CFLAGS -ansi" ;;
 433     esac
 434
 435     case " $CFLAGS " in
 436     *[\ \       ]-pedantic[\ \  ]*) ;;
 437     *) CFLAGS="$CFLAGS -pedantic" ;;
 438     esac
 439   fi
 440 fi
 441 changequote([,])dnl
 442
 443 # Ensure MSVC-compatible struct packing convention is used when
 444 # compiling for Win32 with gcc.
 445 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 446 # gcc2 uses "-fnative-struct".
 447 if test x"$os_win32" = xyes; then
 448   if test x"$GCC" = xyes; then
 449     msnative_struct=''
 450     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 451     if test -z "$ac_cv_prog_CC"; then
 452       our_gcc="$CC"
 453     else
 454       our_gcc="$ac_cv_prog_CC"
 455     fi
 456     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 457       2.)
 458         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 459           msnative_struct='-fnative-struct'
 460         fi
 461         ;;
 462       *)
 463         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 464           msnative_struct='-mms-bitfields'
 465         fi
 466         ;;
 467     esac
 468     if test x"$msnative_struct" = x ; then
 469       AC_MSG_RESULT([no way])
 470       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 471     else
 472       CFLAGS="$CFLAGS $msnative_struct"
 473       AC_MSG_RESULT([${msnative_struct}])
 474     fi
 475   fi
 476 fi
 477
 478 ## Initial sanity check, done here so that users get told they
 479 ## have the wrong dependencies as early in the process as possible.
 480 ## Later on we actually use the cflags/libs from separate pkg-config
 481 ## calls. Oh, also the later pkg-config calls don't include
 482 ## the version requirements since those make the module lists
 483 ## annoying to construct
 484 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 485   [glib-2.0 >= glib_required_version dnl
 486    atk >= atk_required_version dnl
 487    pango >= pango_required_version dnl
 488    cairo >= cairo_required_version dnl
 489    cairo-gobject >= cairo_required_version dnl
 490    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 491
 492 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 493
 494 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0])
 495
 496 if test "$os_win32" != yes; then
 497     # libtool option to control which symbols are exported
 498     # right now, symbols starting with _ are not exported
 499     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 500 else
 501     # We currently use .def files on Windows (for gdk and gtk)
 502     LIBTOOL_EXPORT_OPTIONS=
 503 fi
 504 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 505
 506 dnl ******************************************************
 507 dnl * See whether to include shared library dependencies *
 508 dnl ******************************************************
 509
 510 AC_ARG_ENABLE(explicit-deps,
 511               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 512                               [use explicit dependencies in .pc files [default=auto]])],,
 513               [enable_explicit_deps=auto])
 514
 515 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 516 case $enable_explicit_deps in
 517   auto)
 518     export SED
 519     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 520     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 521       enable_explicit_deps=yes
 522     else
 523       enable_explicit_deps=no
 524     fi
 525   ;;
 526   yes|no)
 527   ;;
 528   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 529   ;;
 530 esac
 531 AC_MSG_RESULT($enable_explicit_deps)
 532
 533 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 534
 535 # define a MAINT-like variable REBUILD which is set if Perl
 536 # and awk are found, so autogenerated sources can be rebuilt
 537
 538 AC_PATH_PROGS(PERL, perl5 perl)
 539
 540 # We would like indent, but don't require it.
 541 AC_CHECK_PROG(INDENT, indent, indent)
 542
 543 REBUILD=\#
 544 if test "x$enable_rebuilds" = "xyes" && \
 545      test -n "$PERL" && \
 546      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 547   REBUILD=
 548 fi
 549 AC_SUBST(REBUILD)
 550
 551 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 552 AC_CHECK_FUNCS(localtime_r)
 553
 554 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 555 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 556 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 557                                 [[char c;
 558                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 559                [gtk_ok=yes], [gtk_ok=no])
 560 AC_MSG_RESULT($gtk_ok)
 561 if test "$gtk_ok" = "yes"; then
 562   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 563             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 564 fi
 565
 566 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 567 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 568 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 569                                 [[char c;
 570                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 571                [gtk_ok=yes], [gtk_ok=no])
 572 AC_MSG_RESULT($gtk_ok)
 573 if test "$gtk_ok" = "yes"; then
 574   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 575             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 576 fi
 577
 578 # _NL_PAPER_HEIGHT is an enum and not a define
 579 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 580 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 581                                 [[char c;
 582                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 583                [gtk_ok=yes], [gtk_ok=no])
 584 AC_MSG_RESULT($gtk_ok)
 585 if test "$gtk_ok" = "yes"; then
 586   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 587             [Define if _NL_PAPER_HEIGHT is available])
 588 fi
 589
 590 # _NL_PAPER_WIDTH is an enum and not a define
 591 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 592 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 593                                 [[char c;
 594                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 595                [gtk_ok=yes], [gtk_ok=no])
 596 AC_MSG_RESULT($gtk_ok)
 597 if test "$gtk_ok" = "yes"; then
 598   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 599             [Define if _NL_PAPER_WIDTH is available])
 600 fi
 601
 602 # i18n stuff
 603 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 604 AM_GLIB_GNU_GETTEXT
 605 LIBS="$LIBS $INTLLIBS"
 606 AC_CONFIG_COMMANDS([po-properties],
 607                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 608                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 609                      esac]],
 610                    [[]])
 611
 612 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 613 dnl po-properties/POTFILES during configure; see GNOME #573515.
 614 dnl
 615 dnl Generate list of files to be processed by xgettext which will
 616 dnl be included in po-properties/Makefile.
 617 test -d po-properties || mkdir po-properties
 618 if test "x$srcdir" != "x."; then
 619   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 620     popropsrcprefix="$srcdir/"
 621   else
 622     popropsrcprefix="../$srcdir/"
 623   fi
 624 else
 625   popropsrcprefix="../"
 626 fi
 627 rm -f po-properties/POTFILES
 628 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 629 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 630 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 631
 632 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 633
 634 dnl The DU4 header files don't provide library prototypes unless
 635 dnl -std1 is given to the native cc.
 636 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 637
 638 gtk_save_LIBS=$LIBS
 639 LIBS="$LIBS -lm"
 640 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 641                                 int main (void) { return (log(1) != log(1.)); }]])],
 642               [AC_MSG_RESULT(none needed)],
 643               [gtk_save_CFLAGS="$CFLAGS"
 644                CFLAGS="$CFLAGS -std1"
 645                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 646                                                int main (void) { return (log(1) != log(1.)); }]])],
 647                              [AC_MSG_RESULT(-std1)],
 648                              [AC_MSG_RESULT()
 649                               CFLAGS="$gtk_save_CFLAGS"
 650                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 651                              [true])],
 652               [AC_MSG_RESULT(none needed)])
 653
 654 LIBS=$gtk_save_LIBS
 655
 656 AC_MSG_CHECKING(for the BeOS)
 657 case $host in
 658   *-*-beos*)
 659     AC_MSG_RESULT(yes)
 660     MATH_LIB=
 661   ;;
 662   *)
 663     AC_MSG_RESULT(no)
 664   ;;
 665 esac
 666
 667 AC_SUBST(MATH_LIB)
 668 #
 669 # see bug 162979
 670 #
 671 AC_MSG_CHECKING(for HP-UX)
 672 case $host_os in
 673   hpux9* | hpux10* | hpux11*)
 674     AC_MSG_RESULT(yes)
 675     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 676   ;;
 677   *)
 678     AC_MSG_RESULT(no)
 679   ;;
 680 esac
 681
 682 #
 683 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 684 #
 685
 686 AM_PATH_GLIB_2_0(glib_required_version, :,
 687   AC_MSG_ERROR([
 688 *** GLIB glib_required_version or better is required. The latest version of
 689 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 690   gobject gmodule-no-export)
 691
 692 dnl
 693 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 694 dnl
 695 gtk_save_LIBS=$LIBS
 696 LIBS="$LIBS $GLIB_LIBS"
 697 AC_CHECK_FUNCS(bind_textdomain_codeset)
 698 LIBS=$gtk_save_LIBS
 699
 700 AC_CHECK_HEADERS(pwd.h,
 701                  AC_DEFINE(HAVE_PWD_H, 1,
 702                            [Define to 1 if pwd.h is available]))
 703 AC_CHECK_HEADERS(sys/time.h,
 704                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 705                            [Define to 1 if time.h is available]))
 706 AC_CHECK_HEADERS(unistd.h,
 707                  AC_DEFINE(HAVE_UNISTD_H, 1,
 708                            [Define to 1 if unistd.h is available]))
 709 AC_CHECK_HEADERS(ftw.h,
 710                  AC_DEFINE(HAVE_FTW_H, 1,
 711                            [Define to 1 if ftw.h is available]))
 712
 713 AC_MSG_CHECKING([for GNU ftw extensions])
 714 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 715                                      #define _GNU_SOURCE
 716                                      #include <ftw.h>]],
 717                                    [[int flags = FTW_ACTIONRETVAL;]])],
 718                   [gtk_ok=yes],[gtk_ok=no])
 719 if test $gtk_ok = yes; then
 720     AC_MSG_RESULT([yes])
 721     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 722 else
 723     AC_MSG_RESULT([no])
 724 fi
 725
 726 saved_cflags="$CFLAGS"
 727 saved_ldflags="$LDFLAGS"
 728
 729
 730 # Checks for library functions.
 731 AC_FUNC_MMAP
 732
 733 AC_CHECK_FUNCS(mallinfo)
 734 AC_CHECK_FUNCS(getresuid)
 735 AC_TYPE_UID_T
 736
 737 # Check for uxtheme.h (for MS-Windows Engine)
 738 AC_MSG_CHECKING(for uxtheme.h)
 739 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <uxtheme.h>]])],
 740                   [gtk_uxtheme_h=yes], [gtk_uxtheme_h=no])
 741 if test $gtk_uxtheme_h = yes; then
 742    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 743 fi
 744 AC_MSG_RESULT($gtk_uxtheme_h)
 745
 746 # Check for round()
 747 AC_CHECK_LIB(m,round,have_round=yes,have_round=no)
 748 if test $have_round = yes; then
 749     AC_DEFINE(HAVE_ROUND, 1, [Define to 1 if round() is available])
 750 fi
 751
 752 # Check for rint()
 753 AC_CHECK_LIB(m,rint,have_rint=yes,have_rint=no)
 754 if test $have_rint = yes; then
 755     AC_DEFINE(HAVE_RINT, 1, [Define to 1 if rint() is available])
 756 fi
 757
 758 # Checks for gdkspawn
 759 AC_CHECK_HEADERS(crt_externs.h)
 760 AC_CHECK_FUNCS(_NSGetEnviron)
 761
 762 AC_MSG_CHECKING(whether to build dynamic modules)
 763
 764 AC_ARG_ENABLE(modules,
 765               [AS_HELP_STRING([--disable-modules],
 766                               [disable dynamic module loading])])
 767
 768 dynworks=false
 769 build_dynamic_modules=no
 770 deps=
 771 if test x$enable_modules = xno; then
 772     AC_MSG_RESULT(no)
 773 else
 774     AC_MSG_RESULT(yes)
 775     AC_MSG_CHECKING(whether dynamic modules work)
 776     ## for loop is to strip newline
 777     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 778     for I in $tmp; do
 779         dynworks=$I
 780     done
 781
 782     dnl Now we check to see if our libtool supports shared lib deps
 783     dnl (in a rather ugly way even)
 784     if $dynworks; then
 785         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 786         module_deplibs_check=`$module_libtool_config | \
 787             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 788             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 789         if test "x$module_deplibs_check" = "xnone" || \
 790            test "x$module_deplibs_check" = "xunknown" || \
 791            test "x$module_deplibs_check" = "x"; then
 792             dynworks=false
 793         fi
 794     fi
 795
 796     if $dynworks; then
 797         build_dynamic_modules=yes
 798         AC_DEFINE(USE_GMODULE, 1,
 799                   [Define to 1 if gmodule works and should be used])
 800         AC_MSG_RESULT(yes)
 801     else
 802         build_dynamic_modules=no
 803         AC_MSG_RESULT(no)
 804     fi
 805 fi
 806
 807 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 808
 809 #
 810 # Allow building some or all immodules included
 811 #
 812 AC_MSG_CHECKING(immodules to build)
 813
 814 AC_ARG_WITH(included_immodules,
 815             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 816                             [build the specified input methods into gtk])])
 817
 818 if $dynworks; then
 819    :
 820 else
 821    ## if the option was specified, leave it; otherwise disable included immodules
 822    if test x$with_included_immodules = xno; then
 823            with_included_immodules=yes
 824    fi
 825 fi
 826
 827 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 828
 829 included_immodules=""
 830 # If the switch specified without listing any specific ones, include all
 831 if test "x$with_included_immodules" = xyes ; then
 832   included_immodules="$all_immodules"
 833 else
 834   included_immodules="$with_included_immodules"
 835 fi
 836
 837 AC_MSG_RESULT($included_immodules)
 838 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 839
 840 INCLUDED_IMMODULE_OBJ=
 841 INCLUDED_IMMODULE_DEFINE=
 842
 843 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 844 for immodule in $included_immodules; do
 845  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 846  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 847    :
 848  else
 849    AC_MSG_ERROR([the specified input method $immodule does not exist])
 850  fi
 851
 852  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 853  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 854  eval INCLUDE_$immodule_underscores=yes
 855 done
 856 IFS="$gtk_save_ifs"
 857 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 858 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 859
 860 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 861 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 862 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 863 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 864 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 865 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 866 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 867 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 868 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 869 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 870 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 871 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 872
 873 # Checks to see whether we should include mediaLib
 874 # support.
 875 #
 876 AC_CHECK_HEADER(sys/systeminfo.h,
 877                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 878                           [Define to 1 if sys/systeminfo.h is available]))
 879 AC_CHECK_HEADER(sys/sysinfo.h,
 880                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 881                           [Define to 1 if sys/sysinfo.h is available]))
 882
 883 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 884
 885 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 886
 887 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 888   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 889   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 890     REBUILD_PNGS=#
 891   fi
 892 fi
 893
 894 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 895
 896 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 897
 898 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 899    test "x$REBUILD_PNGS" = "x#" ; then
 900      AC_MSG_ERROR([
 901 *** gtkbuiltincache.h is not in the tree, and cannot be built
 902 *** because you don't have libpng, or (when cross-compiling) you
 903 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 904 fi
 905
 906 ########################################
 907 # Windowing system checks
 908 ########################################
 909
 910 # GTK+ uses some X calls, so needs to link against X directly
 911 GTK_DEP_PACKAGES_FOR_X=
 912 GTK_DEP_LIBS_FOR_X=
 913 X_EXTENSIONS=
 914
 915 if test "x$enable_x11_backend" = xyes; then
 916   X_PACKAGES=fontconfig
 917
 918   #
 919   # We use fontconfig very peripherally when decoding the default
 920   # settings.
 921   #
 922   if $PKG_CONFIG --exists fontconfig; then : ; else
 923     AC_MSG_ERROR([
 924 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 925   fi
 926
 927   #
 928   # Check for basic X packages; we use pkg-config if available
 929   #
 930   if $PKG_CONFIG --exists x11 xext; then
 931     have_base_x_pc=true
 932     X_PACKAGES="$X_PACKAGES x11 xext"
 933     x_libs="`$PKG_CONFIG --libs x11 xext`"
 934     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext` -DXINPUT2_1_USE_UNSTABLE_PROTOCOL -DXINPUT2_2_USE_UNSTABLE_PROTOCOL"
 935
 936     # Strip out any .la files that pkg-config might give us (this happens
 937     # with -uninstalled.pc files)
 938     x_libs_for_checks=
 939     for I in $x_libs ; do
 940       case $I in
 941         *.la) ;;
 942         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 943       esac
 944     done
 945
 946     GTK_PACKAGES_FOR_X="x11"
 947   else
 948     have_base_x_pc=false
 949     AC_PATH_XTRA
 950     if test x$no_x = xyes ; then
 951       AC_MSG_ERROR([X development libraries not found])
 952     fi
 953
 954     x_cflags="$X_CFLAGS"
 955     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 956
 957     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 958   fi
 959
 960   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 961   x_extra_libs=
 962
 963   gtk_save_cppflags="$CPPFLAGS"
 964   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 965
 966   gtk_save_LIBS=$LIBS
 967   LIBS="$x_libs_for_checks $LIBS"
 968
 969   # Sanity check for the X11 and Xext libraries. While everything we need from
 970   # Xext is optional, the chances a system has *none* of these things is so
 971   # small that we just unconditionally require it.
 972   AC_CHECK_FUNC(XOpenDisplay, :,
 973                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 974   AC_CHECK_FUNC(XextFindDisplay, :,
 975                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 976
 977   # Check for xReply
 978
 979   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 980   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 981                                      [[xReply *rep;]])],
 982                     [AC_MSG_RESULT([no])],
 983                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 984                                                           #include <X11/Xlibint.h>]],
 985                                                         [[xReply *rep;]])],
 986                                        [AC_MSG_RESULT([yes])
 987                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 988                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 989                                        [AC_MSG_RESULT([unknown])
 990                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 991
 992   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 993
 994   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 995
 996   # Generic X11R6 check needed for XIM support; we could
 997   # probably use this to replace the above, but we'll
 998   # leave the separate checks for XConvertCase and XInternAtoms
 999   # for clarity
1000
1001   have_x11r6=false
1002   AC_CHECK_FUNC(XAddConnectionWatch,
1003       have_x11r6=true)
1004
1005   if $have_x11r6; then
1006     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1007   fi
1008   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1009
1010   # Check for XKB support.
1011
1012   if test "x$enable_xkb" = "xyes"; then
1013         AC_CHECK_FUNC(XkbQueryExtension,
1014                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1015                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1016                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1017   elif test "x$enable_xkb" = "xmaybe"; then
1018         AC_CHECK_FUNC(XkbQueryExtension,
1019                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1020                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1021   else
1022         AC_MSG_WARN(XKB support explicitly disabled)
1023   fi
1024
1025   # Check for shaped window extension
1026
1027   AC_CHECK_FUNC(XShapeCombineMask, :,
1028      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1029
1030   # X SYNC check
1031   gtk_save_CFLAGS="$CFLAGS"
1032   CFLAGS="$CFLAGS $x_cflags"
1033
1034   AC_CHECK_FUNC(XSyncQueryExtension,
1035       [AC_CHECK_HEADER(X11/extensions/sync.h,
1036           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1037           :, [#include <X11/Xlib.h>])])
1038
1039   CFLAGS="$gtk_save_CFLAGS"
1040
1041   if test "x$enable_xinerama" != "xno"; then
1042     # Check for Xinerama extension (Solaris impl or Xfree impl)
1043     have_xfree_xinerama=false
1044     have_solaris_xinerama=false
1045
1046     gtk_save_cppflags="$CPPFLAGS"
1047     CPPFLAGS="$CPPFLAGS $x_cflags"
1048
1049     # Check for XFree
1050     AC_MSG_CHECKING(for Xinerama packages)
1051
1052     if $PKG_CONFIG --exists xinerama ; then
1053        AC_MSG_RESULT(yes)
1054        have_xfree_xinerama=true
1055        X_PACKAGES="$X_PACKAGES xinerama"
1056     else
1057        AC_MSG_RESULT(no)
1058        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1059            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1060            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1061            have_xfree_xinerama=true], :,
1062            [#include <X11/Xlib.h>])])
1063     fi
1064
1065     if $have_xfree_xinerama ; then
1066       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1067       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1068                 [Define to 1 if XFree Xinerama is available])
1069       AC_DEFINE(HAVE_XINERAMA, 1,
1070                 [Define to 1 is Xinerama is available])
1071     else
1072       case "$host" in
1073         *-*-solaris*)
1074             # Check for solaris
1075             AC_MSG_CHECKING(for Xinerama support on Solaris)
1076
1077             have_solaris_xinerama=false
1078             AC_CHECK_FUNC(XineramaGetInfo,
1079                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1080                     [have_solaris_xinerama=true], :,
1081                     [#include <X11/Xlib.h>])])
1082
1083             if $have_solaris_xinerama ; then
1084               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1085               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1086                         [Define to 1 if solaris xinerama is available])
1087               AC_DEFINE(HAVE_XINERAMA, 1,
1088                         [Define to 1 if xinerama is available])
1089               AC_MSG_RESULT(yes)
1090             else
1091               AC_MSG_RESULT(no)
1092             fi
1093             ;;
1094         *)
1095             ;;
1096       esac
1097     fi
1098   fi
1099   if test "x$enable_xinerama" = "xyes" ; then
1100     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1101       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1102     fi
1103   fi
1104
1105   # Check for XGetEventData for GenericEvents
1106   AC_CHECK_FUNC(XGetEventData,
1107                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1108
1109   # set up things for XInput
1110   if $PKG_CONFIG --exists "xi" ; then
1111
1112     X_PACKAGES="$X_PACKAGES xi"
1113     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xi"
1114
1115     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1116                     have_xinput2=yes
1117                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1118                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1119
1120     gtk_save_LIBS="$LIBS"
1121     LIBS="$LIBS -lXi"
1122     AC_CHECK_FUNC(XIAllowTouchEvents, AC_DEFINE(XINPUT_2_2, 1, [Define to 1 if XInput 2.2 is available]))
1123     LIBS="$gtk_save_LIBS"
1124   fi
1125
1126   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1127
1128   AS_IF([test "x$have_xinput2" != "xyes"],
1129         [AC_MSG_ERROR([*** XInput2 extension not found. Check 'config.log' for more details.])])
1130
1131   # Check for the RANDR extension
1132   if test x"$enable_xrandr" != xno; then
1133     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1134       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1135
1136       X_PACKAGES="$X_PACKAGES xrandr"
1137       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1138     elif test x"$enable_xrandr" = xyes; then
1139       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1140     fi
1141   fi
1142
1143   # Checks for Xcursor library
1144
1145   if $PKG_CONFIG --exists xcursor ; then
1146     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1147
1148     X_PACKAGES="$X_PACKAGES xcursor"
1149   fi
1150
1151   # Checks for XFixes extension
1152
1153   if test x"$enable_xfixes" != xno; then
1154     if $PKG_CONFIG --exists xfixes ; then
1155       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1156
1157       X_PACKAGES="$X_PACKAGES xfixes"
1158       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1159       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1160     elif test x"$enable_xfixes" = xyes; then
1161       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1162     fi
1163   fi
1164
1165   # Checks for Xcomposite extension
1166
1167   if test x"$enable_xcomposite" != xno; then
1168     if $PKG_CONFIG --exists xcomposite ; then
1169       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1170
1171       X_PACKAGES="$X_PACKAGES xcomposite"
1172       X_EXTENSIONS="$X_EXTENSIONS Composite"
1173       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1174     elif test x"$enable_xcomposite" = xyes; then
1175       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1176     fi
1177   fi
1178
1179   # Checks for Xdamage extension
1180
1181   if test x"$enable_xdamage" != xno; then
1182     if $PKG_CONFIG --exists xdamage ; then
1183       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1184
1185       X_PACKAGES="$X_PACKAGES xdamage"
1186       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1187       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1188     elif test x"$enable_xdamage" = xyes; then
1189       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1190     fi
1191   fi
1192
1193   if $have_base_x_pc ; then
1194     GDK_EXTRA_LIBS="$x_extra_libs"
1195   else
1196     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1197   fi
1198
1199   CPPFLAGS="$gtk_save_cppflags"
1200   LIBS="$gtk_save_libs"
1201
1202   AM_CONDITIONAL(USE_X11, true)
1203
1204   # strip leading space
1205   X_EXTENSIONS=${X_EXTENSIONS#* }
1206
1207 else
1208   XPACKAGES=
1209
1210   AM_CONDITIONAL(XINPUT_2, false)
1211   AM_CONDITIONAL(USE_X11, false)
1212   AM_CONDITIONAL(HAVE_X11R6, false)
1213 fi
1214
1215 # Check for Pango flags
1216
1217 AC_MSG_CHECKING(Pango flags)
1218 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1219         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1220         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1221
1222         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1223 else
1224         AC_MSG_ERROR([
1225 *** Pango not found. Pango built with Cairo support is required
1226 *** to build GTK+. See http://www.pango.org for Pango information.
1227 ])
1228 fi
1229
1230 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1231
1232 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1233         :
1234 else
1235         gtk_save_LIBS="$LIBS"
1236         LIBS="$PANGO_LIBS $LIBS"
1237         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1238 *** Can't link to Pango. Pango is required to build
1239 *** GTK+. For more information see http://www.pango.org]))
1240         LIBS="$gtk_save_LIBS"
1241 fi
1242
1243 CFLAGS="$saved_cflags"
1244 LDFLAGS="$saved_ldflags"
1245
1246 GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo cairo-gobject"
1247 GDK_PRIVATE_PACKAGES="$GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES $cairo_backends"
1248 if test "x$enable_x11_backend" = xyes; then
1249   GDK_PRIVATE_PACKAGES="$GDK_PRIVATE_PACKAGES pangoft2"
1250 fi
1251
1252 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES $GDK_PRIVATE_PACKAGES` $MATH_LIB"
1253 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PACKAGES $GDK_PRIVATE_PACKAGES` $GDK_EXTRA_CFLAGS"
1254 #
1255 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1256 # into the pkg-config files
1257 #
1258 if test $enable_explicit_deps != yes ; then
1259   GDK_EXTRA_LIBS=
1260 fi
1261
1262 AC_SUBST(GDK_PACKAGES)
1263 AC_SUBST(GDK_PRIVATE_PACKAGES)
1264 AC_SUBST(GDK_EXTRA_LIBS)
1265 AC_SUBST(GDK_EXTRA_CFLAGS)
1266 AC_SUBST(GDK_DEP_LIBS)
1267 AC_SUBST(GDK_DEP_CFLAGS)
1268
1269
1270 ########################################
1271 # Check for Accessibility Toolkit flags
1272 ########################################
1273
1274 ATK_PACKAGES=atk
1275 AC_MSG_CHECKING(ATK flags)
1276 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1277         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1278         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1279
1280         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1281 else
1282         AC_MSG_ERROR([
1283 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1284 *** to build GTK+.
1285 ])
1286 fi
1287
1288 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1289         :
1290 else
1291         gtk_save_LIBS="$LIBS"
1292         LIBS="$ATK_LIBS $LIBS"
1293         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1294                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1295                 *** to build GTK+]))
1296         LIBS="$gtk_save_LIBS"
1297 fi
1298
1299 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1300 GTK_PRIVATE_PACKAGES=""
1301 if test "x$enable_x11_backend" = xyes; then
1302   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES pangoft2"
1303 fi
1304 GTK_EXTRA_LIBS=
1305
1306 GTK_EXTRA_CFLAGS=
1307 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES $GTK_PRIVATE_PACKAGES` $GTK_EXTRA_LIBS $MATH_LIB"
1308 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PACKAGES $GTK_PACKAGES $GTK_PRIVATE_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1309
1310 if test x"$os_win32" = xyes; then
1311   GTK_EXTRA_CFLAGS="$msnative_struct"
1312 fi
1313
1314 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1315 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1316 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1317 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1318
1319 AC_SUBST(GTK_PACKAGES)
1320 AC_SUBST(GTK_PRIVATE_PACKAGES)
1321 AC_SUBST(GTK_EXTRA_LIBS)
1322 AC_SUBST(GTK_EXTRA_CFLAGS)
1323 AC_SUBST(GTK_DEP_LIBS)
1324 AC_SUBST(GTK_DEP_CFLAGS)
1325
1326 AC_SUBST(GLIB_PREFIX)
1327 AC_SUBST(ATK_PREFIX)
1328 AC_SUBST(PANGO_PREFIX)
1329 AC_SUBST(CAIRO_PREFIX)
1330
1331 AC_SUBST(GTK_DEBUG_FLAGS)
1332 AC_SUBST(GTK_XIM_FLAGS)
1333
1334 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1335 AC_SUBST(GDK_PIXBUF_LIBS)
1336
1337 ########################
1338 # Checks needed for gail
1339 ########################
1340
1341 old_LIBS="$LIBS"
1342 dnl Checks for inet libraries:
1343 AC_SEARCH_LIBS(gethostent, nsl)
1344 AC_SEARCH_LIBS(setsockopt, socket)
1345 AC_SEARCH_LIBS(connect, inet)
1346
1347 dnl check for the sockaddr_un.sun_len member
1348 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1349                 [struct_sockaddr_un_sun_len=true],
1350                 [struct_sockaddr_un_suin_len=false],
1351                 [#include <sys/types.h>
1352                  #include <sys/un.h>]
1353                 )
1354 case $struct_sockaddr_un_sun_len in
1355         true)
1356                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1357                                    [Have the sockaddr_un.sun_len member])
1358                 ;;
1359         *)
1360                 ;;
1361 esac
1362
1363 GAIL_INET_LIBS="$LIBS"
1364 AC_SUBST([GAIL_INET_LIBS])
1365
1366 LIBS="$old_LIBS"
1367
1368 ################################################################
1369 # Printing system checks
1370 ################################################################
1371
1372 PRINT_BACKENDS="file lpr"
1373
1374 AC_ARG_ENABLE(cups,
1375               [AS_HELP_STRING([--disable-cups],
1376                               [disable cups print backend])],,
1377               [enable_cups=auto])
1378
1379 if test "x$enable_cups" = "xno"; then
1380   AM_CONDITIONAL(HAVE_CUPS, false)
1381 else
1382   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1383   if test "x$CUPS_CONFIG" = "xno"; then
1384     if test "x$enable_cups" = "xauto"; then
1385       AM_CONDITIONAL(HAVE_CUPS, false)
1386     else
1387       AC_MSG_ERROR([
1388 *** cups not found.
1389 ])
1390     fi
1391   else
1392     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1393     CUPS_LIBS=`$CUPS_CONFIG --libs`
1394
1395     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1396     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1397     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1398
1399     if test $CUPS_API_MAJOR -gt 1 -o \
1400             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1401       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1402                 [Define to 1 if CUPS 1.2 API is available])
1403     fi
1404
1405     AC_SUBST(CUPS_API_MAJOR)
1406     AC_SUBST(CUPS_API_MINOR)
1407     AC_SUBST(CUPS_CFLAGS)
1408     AC_SUBST(CUPS_LIBS)
1409
1410     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1411
1412     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1413     AM_CONDITIONAL(HAVE_CUPS, true)
1414
1415     gtk_save_cflags="$CFLAGS"
1416     CFLAGS="$CUPS_CFLAGS"
1417     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1418                                        [[http_t http; char *s = http.authstring;]])],
1419                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1420                                  [Define if cups http_t authstring field is accessible])],
1421                       [])
1422     CFLAGS="$gtk_save_cflags"
1423
1424     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1425
1426     gtk_save_libs="$LIBS"
1427     LIBS="$CUPS_LIBS"
1428     AC_CHECK_FUNCS(httpGetAuthString)
1429     LIBS="$gtk_save_libs"
1430   fi
1431 fi
1432
1433 # Checks to see if we should compile with PAPI backend for GTK+
1434 #
1435
1436 AC_ARG_ENABLE(papi,
1437               [AS_HELP_STRING([--disable-papi],
1438                               [disable papi print backend])],,
1439               [enable_papi=auto])
1440
1441 if test "x$enable_papi" = "xno"; then
1442   AM_CONDITIONAL(HAVE_PAPI, false)
1443 else
1444   AC_MSG_CHECKING(libpapi)
1445   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1446   if test $have_papi = yes; then
1447     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1448     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1449   fi
1450   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1451   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1452     AC_MSG_ERROR([
1453 *** papi not found.
1454 ])
1455   fi
1456 fi
1457
1458 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1459
1460 gtk_save_cppflags="$CPPFLAGS"
1461 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1462
1463 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1464 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1465 *** backend enabled.]))
1466
1467 if test "$os_win32" != "yes"; then
1468   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1469 *** Can't find cairo-ps.h. You must build Cairo with the
1470 *** postscript backend enabled.]))
1471
1472   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1473 *** Cannot find cairo-svg.h. You must build Cairo with the
1474 *** svg backend enabled.]))
1475 fi
1476
1477 CPPFLAGS="$gtk_save_cppflags"
1478
1479
1480 AC_ARG_ENABLE(test-print-backend,
1481               [AS_HELP_STRING([--enable-test-print-backend],
1482                               [build test print backend])],,
1483               [enable_test_print_backend=no])
1484 if test "x$enable_test_print_backend" != "xno" ; then
1485   PRINT_BACKENDS="$PRINT_BACKENDS test"
1486 fi
1487 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1488
1489 if test "$os_win32" = "yes"; then
1490   AC_CHECK_TYPES([IPrintDialogCallback],[],[],[[#include <windows.h>]])
1491 fi
1492
1493 ################################################################
1494 # Strip -export-dynamic from the link lines of various libraries
1495 ################################################################
1496
1497 #
1498 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1499 #  but this flag is only meaningful for executables. For libraries
1500 #  the effect is undefined; what it causes on Linux is that the
1501 #  export list from -export-symbols-regex is ignored and everything
1502 #  is exported
1503 #
1504 # We are using gmodule-no-export now, but I'm leaving the stripping
1505 # code in place for now, since pango and atk still require gmodule.
1506 export SED
1507 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1508 if test -n "$export_dynamic"; then
1509   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1510   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1511 fi
1512
1513 #############
1514 # GSettings #
1515 #############
1516
1517 GLIB_GSETTINGS
1518
1519 #############
1520 # Resources #
1521 #############
1522
1523 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG --variable glib_compile_resources gio-2.0`
1524 AC_SUBST(GLIB_COMPILE_RESOURCES)
1525
1526 ##################################################
1527 # GObject introspection
1528 ##################################################
1529
1530 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1531
1532 ##################################################
1533 # Packagekit module
1534 #################################################
1535
1536 AC_ARG_ENABLE(packagekit,
1537               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1538                               [build PackageKit open-with module [default=auto]])],
1539               [enable_packagekit="$enableval"],
1540               [enable_packagekit=auto])
1541 if test "$enable_packagekit" = "auto"; then
1542   if test "$os_win32" = "yes"; then
1543     enable_packagekit=no
1544   else
1545     enable_packagekit=yes
1546   fi
1547 fi
1548
1549 AC_MSG_CHECKING([whether to use PackageKit])
1550 build_packagekit=no
1551 if test "x$enable_packagekit" != "xno"; then
1552   if test "$os_win32" != "yes"; then
1553     build_packagekit=yes
1554     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1555   else
1556     AC_MSG_ERROR([packagekit support is not available on win32])
1557   fi
1558 fi
1559 AC_MSG_RESULT([$build_packagekit])
1560
1561 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1562
1563 ##################################################
1564 # colord module
1565 #################################################
1566
1567 AC_ARG_ENABLE(colord,
1568               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1569                               [build colord support code [default=auto]])],
1570               [enable_colord="$enableval"],
1571               [enable_colord=auto])
1572
1573 AC_MSG_CHECKING([whether to use colord])
1574 if test "$enable_colord" = "auto"; then
1575   if test "$os_win32" = "yes"; then
1576     enable_colord=no
1577   fi
1578 fi
1579 if test "$enable_colord" != "no"; then
1580   AC_MSG_RESULT([yes])
1581 else
1582   AC_MSG_RESULT([no])
1583 fi
1584
1585 have_colord=no
1586 if test "$enable_colord" != "no"; then
1587         if test "$os_win32" != "yes"; then
1588                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1589                                   have_colord=yes, have_colord=no)
1590                 if test "$enable_colord" = "yes"; then
1591                         if test "$have_colord" = "no"; then
1592                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1593                         fi
1594                 fi
1595         else
1596                 AC_MSG_ERROR([colord support is not available on win32])
1597         fi
1598 fi
1599
1600 if test "$have_colord" = "yes"; then
1601         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1602 fi
1603 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1604
1605 ##################################################
1606 # Checks for gtk-doc and docbook-tools
1607 ##################################################
1608
1609 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1610
1611 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1612 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1613
1614 AC_ARG_ENABLE(man,
1615               [AS_HELP_STRING([--enable-man],
1616                               [regenerate man pages from Docbook [default=no]])],
1617               [enable_man=yes],
1618               [enable_man=no])
1619
1620 if test "${enable_man}" != no; then
1621   dnl
1622   dnl Check for xsltproc
1623   dnl
1624   AC_PATH_PROG([XSLTPROC], [xsltproc])
1625   if test -z "$XSLTPROC"; then
1626     enable_man=no
1627   fi
1628
1629   dnl check for DocBook DTD and stylesheets in the local catalog.
1630   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1631      [DocBook XML DTD V4.1.2],,enable_man=no)
1632   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1633      [DocBook XSL Stylesheets],,enable_man=no)
1634 fi
1635
1636 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1637
1638
1639 ##################################################
1640 # Output commands
1641 ##################################################
1642
1643 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1644         outfile=gdkconfig.h-tmp
1645         cat > $outfile <<\_______EOF
1646 /* gdkconfig.h
1647  *
1648  * This is a generated file.  Please modify `configure.ac'
1649  */
1650
1651 #ifndef __GDKCONFIG_H__
1652 #define __GDKCONFIG_H__
1653
1654 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1655 #error "Only <gdk/gdk.h> can be included directly."
1656 #endif
1657
1658 #include <glib.h>
1659
1660 G_BEGIN_DECLS
1661
1662 _______EOF
1663
1664         cat >>$outfile <<_______EOF
1665 $gdk_windowing
1666 _______EOF
1667
1668         cat >>$outfile <<_______EOF
1669
1670 G_END_DECLS
1671
1672 #endif  /* __GDKCONFIG_H__ */
1673 _______EOF
1674
1675
1676         if cmp -s $outfile gdk/gdkconfig.h; then
1677           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1678           rm -f $outfile
1679         else
1680           mv $outfile gdk/gdkconfig.h
1681         fi
1682 ],[
1683 gdk_windowing='$GDK_WINDOWING'
1684 ])
1685
1686 dnl
1687 dnl Check for -Bsymbolic-functions linker flag used to avoid
1688 dnl intra-library PLT jumps, if available.
1689 dnl
1690 AC_ARG_ENABLE(Bsymbolic,
1691               [AS_HELP_STRING([--disable-Bsymbolic],
1692                               [avoid linking with -Bsymbolic])],,
1693               [SAVED_LDFLAGS="${LDFLAGS}"
1694                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1695                LDFLAGS=-Wl,-Bsymbolic-functions
1696                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1697                                                [[int main (void) { return 0; }]])],
1698                               [AC_MSG_RESULT(yes)
1699                                enable_Bsymbolic=yes],
1700                               [AC_MSG_RESULT(no)
1701                                enable_Bsymbolic=no])
1702                LDFLAGS="${SAVED_LDFLAGS}"])
1703
1704 if test "x${enable_Bsymbolic}" = "xyes" ; then
1705   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1706 fi
1707 AC_SUBST(GTK_LINK_FLAGS)
1708
1709 AC_CONFIG_FILES([
1710 config.h.win32
1711 gtk-zip.sh
1712 Makefile
1713 gdk-3.0.pc
1714 gtk+-3.0.pc
1715 gtk+-unix-print-3.0.pc
1716 gail-3.0.pc
1717 m4macros/Makefile
1718 po/Makefile.in
1719 po-properties/Makefile.in
1720 demos/Makefile
1721 demos/gtk-demo/Makefile
1722 demos/gtk-demo/geninclude.pl
1723 demos/pixbuf-demo/Makefile
1724 demos/widget-factory/Makefile
1725 examples/Makefile
1726 tests/Makefile
1727 tests/a11y/Makefile
1728 tests/css/Makefile
1729 tests/css/parser/Makefile
1730 tests/reftests/Makefile
1731 tests/visuals/Makefile
1732 docs/Makefile
1733 docs/reference/Makefile
1734 docs/reference/gdk/Makefile
1735 docs/reference/gdk/version.xml
1736 docs/reference/gtk/Makefile
1737 docs/reference/gtk/version.xml
1738 docs/reference/libgail-util/Makefile
1739 docs/reference/libgail-util/version.xml
1740 docs/tools/Makefile
1741 build/Makefile
1742 build/win32/Makefile
1743 build/win32/vs9/Makefile
1744 build/win32/vs10/Makefile
1745 gdk/Makefile
1746 gdk/broadway/Makefile
1747 gdk/x11/Makefile
1748 gdk/win32/Makefile
1749 gdk/win32/rc/Makefile
1750 gdk/win32/rc/gdk.rc
1751 gdk/quartz/Makefile
1752 gdk/wayland/Makefile
1753 gdk/tests/Makefile
1754 gdk/gdkversionmacros.h
1755 gtk/Makefile
1756 gtk/makefile.msc
1757 gtk/gtkversion.h
1758 gtk/gtk-win32.rc
1759 gtk/a11y/Makefile
1760 gtk/tests/Makefile
1761 libgail-util/Makefile
1762 modules/Makefile
1763 modules/engines/Makefile
1764 modules/engines/pixbuf/Makefile
1765 modules/engines/ms-windows/Makefile
1766 modules/engines/ms-windows/Theme/Makefile
1767 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1768 modules/input/Makefile
1769 modules/printbackends/Makefile
1770 modules/printbackends/cups/Makefile
1771 modules/printbackends/lpr/Makefile
1772 modules/printbackends/file/Makefile
1773 modules/printbackends/papi/Makefile
1774 modules/printbackends/test/Makefile
1775 perf/Makefile
1776 ])
1777
1778 AC_OUTPUT
1779
1780 # beautify the immodule list a bit
1781 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1782 if test -z "${included_immodules}"; then included_immodules="none"; fi
1783
1784 echo ""
1785 echo "        GTK+ $GTK_VERSION"
1786 echo "        ==========="
1787 echo ""
1788 echo "        GDK backends:         $GDK_BACKENDS"
1789 if test "$enable_x11_backend" = "yes"; then
1790 echo "        X11 extensions:       $X_EXTENSIONS"
1791 fi
1792 echo "        Print backends:       $PRINT_BACKENDS"
1793 echo "        Dynamic modules:      $build_dynamic_modules"
1794 echo "        Included immodules:   $included_immodules"
1795 echo "        PackageKit support:   $build_packagekit"
1796 echo "        colord support:       $have_colord"
1797 echo "        Introspection:        $found_introspection"
1798 echo "        Debugging:            $enable_debug"
1799 echo "        Documentation:        $enable_gtk_doc"