Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [7])
  13 m4_define([gtk_micro_version], [5])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.35.3])
  43 m4_define([pango_required_version], [1.32.4])
  44 m4_define([atk_required_version], [2.5.3])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.26.0])
  47 m4_define([introspection_required_version], [1.32.0])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_MKDIR_P
 128 AC_PROG_INSTALL
 129 AC_PROG_MAKE_SET
 130
 131
 132 GETTEXT_PACKAGE=gtk30
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 135                    [The prefix for our gettext translation domains.])
 136
 137 AC_CANONICAL_HOST
 138
 139 MATH_LIB=-lm
 140 AC_MSG_CHECKING([for native Win32])
 141 LIB_EXE_MACHINE_FLAG=X86
 142 EXE_MANIFEST_ARCHITECTURE=X86
 143 DISABLE_ON_W32=''
 144 case "$host" in
 145   *-*-mingw*)
 146     dnl Comment-out certain gtk3.types.in lines
 147     DISABLE_ON_W32='%'
 148     os_win32=yes
 149     gio_can_sniff=no
 150     MATH_LIB=
 151     case "$host" in
 152     x86_64-*-*)
 153       LIB_EXE_MACHINE_FLAG=X64
 154       EXE_MANIFEST_ARCHITECTURE=AMD64
 155       ;;
 156     esac
 157     ;;
 158   *)
 159     os_win32=no
 160     ;;
 161 esac
 162 AC_MSG_RESULT([$os_win32])
 163
 164 AC_SUBST(DISABLE_ON_W32)
 165 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 166 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 167
 168 case $host in
 169   *-*-linux*)
 170     os_linux=yes
 171     ;;
 172 esac
 173
 174 dnl
 175 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 176 dnl We use this for an automated test for C++ header correctness.
 177 dnl
 178 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 179 AC_LANG_PUSH([C++])
 180
 181 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 182                                    [[class a { int b; } c;]])],
 183                   [],[CXX=])
 184 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 185
 186 gtk_save_cxxflags="$CXXFLAGS"
 187 CXXFLAGS="$CXXFLAGS -x objective-c++"
 188 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 189                                    [[]])],
 190                   [OBJC=yes],[OBJC=no])
 191 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 192 CXXFLAGS="$gtk_save_cxxflags"
 193 AC_LANG_POP([C++])
 194
 195 if test "$os_win32" = "yes"; then
 196   if test x$enable_static = xyes -o x$enable_static = x; then
 197     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 198     enable_static=no
 199   fi
 200   if test x$enable_shared = xno; then
 201     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 202   fi
 203   enable_shared=yes
 204 fi
 205
 206 dnl Initialize libtool
 207 LT_PREREQ([2.2.6])
 208 LT_INIT([disable-static win32-dll])
 209 # Create libtool early, because it's used in configure
 210 LT_OUTPUT
 211
 212 # Make sure we use 64-bit versions of various file stuff.
 213 AC_SYS_LARGEFILE
 214
 215 AM_PROG_AS
 216 AC_PATH_PROG(NM, nm, nm)
 217
 218 AC_MSG_CHECKING([for some Win32 platform])
 219 case "$host" in
 220   *-*-mingw*|*-*-cygwin*)
 221     platform_win32=yes
 222     ;;
 223   *)
 224     platform_win32=no
 225     ;;
 226 esac
 227 AC_MSG_RESULT([$platform_win32])
 228 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 229
 230 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 231 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 232 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 233
 234 if test "$os_win32" = "yes"; then
 235   AC_CHECK_TOOL(WINDRES, windres, no)
 236   if test "$WINDRES" = no; then
 237     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 238   fi
 239   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 240 fi
 241 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 242
 243 m4_define([debug_default],
 244           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 245
 246 dnl declare --enable-* args and collect ac_help strings
 247 AC_ARG_ENABLE(debug,
 248               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 249                               [turn on debugging @<:@default=debug_default@:>@])],,
 250               [enable_debug=debug_default])
 251
 252 AC_ARG_ENABLE(rebuilds,
 253               [AS_HELP_STRING([--disable-rebuilds],
 254                               [disable all source autogeneration rules])],,
 255               [enable_rebuilds=yes])
 256
 257 AC_ARG_ENABLE(gtk2-dependency,
 258               [AS_HELP_STRING([--enable-gtk2-dependency],
 259                               [Do not build gtk-update-icon-cache and other shared tools])],,
 260               [enable_gtk2_dependency=no])
 261
 262 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 263
 264 AC_ARG_ENABLE(xkb,
 265               [AS_HELP_STRING([--enable-xkb],
 266                               [support XKB extension [default=maybe]])],,
 267               [enable_xkb="maybe"])
 268 AC_ARG_ENABLE(xinerama,
 269               [AS_HELP_STRING([--enable-xinerama],
 270                               [support Xinerama extension [default=maybe]])],,
 271               [enable_xinerama="maybe"])
 272 AC_ARG_ENABLE(xrandr,
 273               [AS_HELP_STRING([--enable-xrandr],
 274                               [support XRandR extension [default=maybe]])],,
 275               [enable_xrandr="maybe"])
 276 AC_ARG_ENABLE(xfixes,
 277               [AS_HELP_STRING([--enable-xfixes],
 278                               [support XFixes extension [default=maybe]])],,
 279               [enable_xfixes="maybe"])
 280 AC_ARG_ENABLE(xcomposite,
 281               [AS_HELP_STRING([--enable-xcomposite],
 282                               [support X Composite extension [default=maybe]])],,
 283               [enable_xcomposite="maybe"])
 284 AC_ARG_ENABLE(xdamage,
 285               [AS_HELP_STRING([--enable-xdamage],
 286                               [support X Damage extension [default=maybe]])],,
 287               [enable_xdamage="maybe"])
 288
 289 AC_ARG_ENABLE(x11-backend,
 290               [AS_HELP_STRING([--enable-x11-backend],
 291                               [enable the X11 gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(win32-backend,
 294               [AS_HELP_STRING([--enable-win32-backend],
 295                               [enable the Win32 gdk backend])],
 296                               [backend_set=yes])
 297 AC_ARG_ENABLE(quartz-backend,
 298               [AS_HELP_STRING([--enable-quartz-backend],
 299                               [enable the quartz gdk backend])],
 300                               [backend_set=yes])
 301 AC_ARG_ENABLE(broadway-backend,
 302               [AS_HELP_STRING([--enable-broadway-backend],
 303                               [enable the broadway (HTML5) gdk backend])],
 304                               [backend_set=yes])
 305 AC_ARG_ENABLE(wayland-backend,
 306               [AS_HELP_STRING([--enable-wayland-backend],
 307                               [enable the wayland gdk backend])],
 308                               [backend_set=yes])
 309
 310 if test -z "$backend_set"; then
 311   if test "$platform_win32" = yes; then
 312     enable_win32_backend=yes
 313   else
 314     enable_x11_backend=yes
 315   fi
 316 fi
 317
 318 AC_ARG_ENABLE(quartz-relocation,
 319               [AS_HELP_STRING([--enable-quartz-relocation],
 320                               [enable bundle-based relocation functions])],
 321                               [quartz_relocation=yes])
 322
 323 AC_ARG_ENABLE(wayland-cairo-gl,
 324               AS_HELP_STRING([--enable-wayland-cairo-gl],
 325                              [enable the use of Cairo GL in the Wayland backend]),
 326               [enable_wayland_cairo_gl=yes])
 327
 328
 329 cairo_backends=
 330 backend_immodules=
 331 have_gio_unix=no
 332 GDK_BACKENDS=
 333 GDK_EXTRA_LIBS=
 334 GDK_EXTRA_CFLAGS=
 335 GDK_WINDOWING=
 336 PANGO_PACKAGES="pango pangocairo"
 337
 338 if test "$enable_x11_backend" = "yes"; then
 339   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 340   # backend names are identical.
 341   cairo_backends="$cairo_backends cairo-xlib"
 342   GDK_BACKENDS="$GDK_BACKENDS x11"
 343   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 344   # gdkapplaunchcontext-x11.c
 345   have_gio_unix=yes
 346   backend_immodules="$backend_immodules,xim"
 347   GDK_WINDOWING="$GDK_WINDOWING
 348 #define GDK_WINDOWING_X11"
 349 fi
 350
 351 if test "$enable_win32_backend" = "yes"; then
 352   cairo_backends="$cairo_backends cairo-win32"
 353   GDK_BACKENDS="$GDK_BACKENDS win32"
 354   backend_immodules="$backend_immodules,ime"
 355   GDK_WINDOWING="$GDK_WINDOWING
 356 #define GDK_WINDOWING_WIN32"
 357   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 358   AM_CONDITIONAL(USE_WIN32, true)
 359   PANGO_PACKAGES="pangowin32 pangocairo"
 360 else
 361   AM_CONDITIONAL(USE_WIN32, false)
 362 fi
 363
 364 DISABLE_ON_QUARTZ=''
 365 if test "x$enable_quartz_backend" = xyes; then
 366   cairo_backends="$cairo_backends cairo-quartz"
 367   GDK_BACKENDS="$GDK_BACKENDS quartz"
 368   GDK_WINDOWING="$GDK_WINDOWING
 369 #define GDK_WINDOWING_QUARTZ"
 370   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 371   DISABLE_ON_QUARTZ='%'
 372   AM_CONDITIONAL(USE_QUARTZ, true)
 373   if test "x$quartz_relocation" = xyes; then
 374     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 375   fi
 376   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 377   # gdkapplaunchcontext-x11.c
 378   have_gio_unix=yes
 379
 380 else
 381   AM_CONDITIONAL(USE_QUARTZ, false)
 382 fi
 383 AC_SUBST(DISABLE_ON_QUARTZ)
 384
 385 if test "x$enable_broadway_backend" = xyes; then
 386   GDK_BACKENDS="$GDK_BACKENDS broadway"
 387   cairo_backends="$cairo_backends cairo"
 388   GDK_WINDOWING="$GDK_WINDOWING
 389 #define GDK_WINDOWING_BROADWAY"
 390   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 391   AM_CONDITIONAL(USE_BROADWAY, true)
 392 else
 393   AM_CONDITIONAL(USE_BROADWAY, false)
 394 fi
 395
 396 if test "x$enable_wayland_backend" = "xyes"; then
 397   if test "x$enable_wayland_cairo_gl" = "xyes"; then
 398     # Wayland can use cairo-gl
 399     cairo_backends="$cairo_backends cairo-gl"
 400     AC_DEFINE(GDK_WAYLAND_USE_EGL, [1], [Whether to use EGL in Wayland backend])
 401   else
 402     # For the cairo image backend
 403     cairo_backends="$cairo_backends cairo"
 404   fi
 405   GDK_BACKENDS="$GDK_BACKENDS wayland"
 406   have_gio_unix=yes
 407   GDK_WINDOWING="$GDK_WINDOWING
 408 #define GDK_WINDOWING_WAYLAND"
 409   WAYLAND_PACKAGES="wayland-client >= 1.0.0 xkbcommon >= 0.2.0 wayland-cursor"
 410   if test "x$enable_wayland_cairo_gl" = "xyes"; then
 411     WAYLAND_PACKAGES="$WAYLAND_PACKAGES wayland-egl egl"
 412   fi
 413   AM_CONDITIONAL(USE_WAYLAND, true)
 414 else
 415   AM_CONDITIONAL(USE_WAYLAND, false)
 416 fi
 417
 418 # strip leading space
 419 GDK_BACKENDS=${GDK_BACKENDS#* }
 420
 421 AC_SUBST(GDK_BACKENDS)
 422
 423 if test -z "$GDK_BACKENDS"; then
 424   AC_MSG_ERROR([No GDK backends selected.])
 425 fi
 426
 427 if test "x$enable_debug" = "xyes"; then
 428   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 429   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 430 else
 431   if test "x$enable_debug" = "xno"; then
 432     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 433   else
 434     GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"
 435   fi
 436 fi
 437
 438
 439 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 440                    [Define if debugging is enabled])
 441
 442
 443 # Build time sanity check...
 444 AM_SANITY_CHECK
 445
 446 changequote(,)dnl
 447 if test "x$GCC" = "xyes"; then
 448   case " $CFLAGS " in
 449   *[\ \ ]-Wall[\ \      ]*) ;;
 450   *) CFLAGS="$CFLAGS -Wall" ;;
 451   esac
 452
 453   if test "x$enable_ansi" = "xyes"; then
 454     case " $CFLAGS " in
 455     *[\ \       ]-ansi[\ \      ]*) ;;
 456     *) CFLAGS="$CFLAGS -ansi" ;;
 457     esac
 458
 459     case " $CFLAGS " in
 460     *[\ \       ]-pedantic[\ \  ]*) ;;
 461     *) CFLAGS="$CFLAGS -pedantic" ;;
 462     esac
 463   fi
 464 fi
 465 changequote([,])dnl
 466
 467 # Ensure MSVC-compatible struct packing convention is used when
 468 # compiling for Win32 with gcc.
 469 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 470 # gcc2 uses "-fnative-struct".
 471 if test x"$os_win32" = xyes; then
 472   if test x"$GCC" = xyes; then
 473     msnative_struct=''
 474     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 475     if test -z "$ac_cv_prog_CC"; then
 476       our_gcc="$CC"
 477     else
 478       our_gcc="$ac_cv_prog_CC"
 479     fi
 480     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 481       2.)
 482         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 483           msnative_struct='-fnative-struct'
 484         fi
 485         ;;
 486       *)
 487         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 488           msnative_struct='-mms-bitfields'
 489         fi
 490         ;;
 491     esac
 492     if test x"$msnative_struct" = x ; then
 493       AC_MSG_RESULT([no way])
 494       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 495     else
 496       CFLAGS="$CFLAGS $msnative_struct"
 497       AC_MSG_RESULT([${msnative_struct}])
 498     fi
 499   fi
 500 fi
 501
 502 ## Initial sanity check, done here so that users get told they
 503 ## have the wrong dependencies as early in the process as possible.
 504 ## Later on we actually use the cflags/libs from separate pkg-config
 505 ## calls. Oh, also the later pkg-config calls don't include
 506 ## the version requirements since those make the module lists
 507 ## annoying to construct
 508 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 509   [glib-2.0 >= glib_required_version dnl
 510    atk >= atk_required_version dnl
 511    pango >= pango_required_version dnl
 512    cairo >= cairo_required_version dnl
 513    cairo-gobject >= cairo_required_version dnl
 514    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 515
 516 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 517
 518 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0])
 519
 520 if test "$os_win32" != yes; then
 521     # libtool option to control which symbols are exported
 522     # right now, symbols starting with _ are not exported
 523     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 524 else
 525     # We currently use .def files on Windows (for gdk and gtk)
 526     LIBTOOL_EXPORT_OPTIONS=
 527 fi
 528 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 529
 530 dnl ******************************************************
 531 dnl * See whether to include shared library dependencies *
 532 dnl ******************************************************
 533
 534 AC_ARG_ENABLE(explicit-deps,
 535               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 536                               [use explicit dependencies in .pc files [default=auto]])],,
 537               [enable_explicit_deps=auto])
 538
 539 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 540 case $enable_explicit_deps in
 541   auto)
 542     export SED
 543     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 544     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 545       enable_explicit_deps=yes
 546     else
 547       enable_explicit_deps=no
 548     fi
 549   ;;
 550   yes|no)
 551   ;;
 552   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 553   ;;
 554 esac
 555 AC_MSG_RESULT($enable_explicit_deps)
 556
 557 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 558
 559 # define a MAINT-like variable REBUILD which is set if Perl
 560 # and awk are found, so autogenerated sources can be rebuilt
 561
 562 AC_PATH_PROGS(PERL, perl5 perl)
 563
 564 # We would like indent, but don't require it.
 565 AC_CHECK_PROG(INDENT, indent, indent)
 566
 567 REBUILD=\#
 568 if test "x$enable_rebuilds" = "xyes" && \
 569      test -n "$PERL" && \
 570      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 571   REBUILD=
 572 fi
 573 AC_SUBST(REBUILD)
 574
 575 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 576 AC_CHECK_FUNCS(localtime_r)
 577
 578 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 579 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 580 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 581                                 [[char c;
 582                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 583                [gtk_ok=yes], [gtk_ok=no])
 584 AC_MSG_RESULT($gtk_ok)
 585 if test "$gtk_ok" = "yes"; then
 586   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 587             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 588 fi
 589
 590 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 591 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 592 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 593                                 [[char c;
 594                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 595                [gtk_ok=yes], [gtk_ok=no])
 596 AC_MSG_RESULT($gtk_ok)
 597 if test "$gtk_ok" = "yes"; then
 598   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 599             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 600 fi
 601
 602 # _NL_PAPER_HEIGHT is an enum and not a define
 603 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 604 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 605                                 [[char c;
 606                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 607                [gtk_ok=yes], [gtk_ok=no])
 608 AC_MSG_RESULT($gtk_ok)
 609 if test "$gtk_ok" = "yes"; then
 610   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 611             [Define if _NL_PAPER_HEIGHT is available])
 612 fi
 613
 614 # _NL_PAPER_WIDTH is an enum and not a define
 615 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 616 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 617                                 [[char c;
 618                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 619                [gtk_ok=yes], [gtk_ok=no])
 620 AC_MSG_RESULT($gtk_ok)
 621 if test "$gtk_ok" = "yes"; then
 622   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 623             [Define if _NL_PAPER_WIDTH is available])
 624 fi
 625
 626 # i18n stuff
 627 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 628 AM_GLIB_GNU_GETTEXT
 629 LIBS="$LIBS $INTLLIBS"
 630 AC_CONFIG_COMMANDS([po-properties],
 631                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 632                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 633                      esac]],
 634                    [[]])
 635
 636 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 637 dnl po-properties/POTFILES during configure; see GNOME #573515.
 638 dnl
 639 dnl Generate list of files to be processed by xgettext which will
 640 dnl be included in po-properties/Makefile.
 641 test -d po-properties || mkdir po-properties
 642 if test "x$srcdir" != "x."; then
 643   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 644     popropsrcprefix="$srcdir/"
 645   else
 646     popropsrcprefix="../$srcdir/"
 647   fi
 648 else
 649   popropsrcprefix="../"
 650 fi
 651 rm -f po-properties/POTFILES
 652 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 653 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 654 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 655
 656 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 657
 658 dnl The DU4 header files don't provide library prototypes unless
 659 dnl -std1 is given to the native cc.
 660 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 661
 662 gtk_save_LIBS=$LIBS
 663 LIBS="$LIBS -lm"
 664 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 665                                 int main (void) { return (log(1) != log(1.)); }]])],
 666               [AC_MSG_RESULT(none needed)],
 667               [gtk_save_CFLAGS="$CFLAGS"
 668                CFLAGS="$CFLAGS -std1"
 669                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 670                                                int main (void) { return (log(1) != log(1.)); }]])],
 671                              [AC_MSG_RESULT(-std1)],
 672                              [AC_MSG_RESULT()
 673                               CFLAGS="$gtk_save_CFLAGS"
 674                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 675                              [true])],
 676               [AC_MSG_RESULT(none needed)])
 677
 678 LIBS=$gtk_save_LIBS
 679
 680 AC_MSG_CHECKING(for the BeOS)
 681 case $host in
 682   *-*-beos*)
 683     AC_MSG_RESULT(yes)
 684     MATH_LIB=
 685   ;;
 686   *)
 687     AC_MSG_RESULT(no)
 688   ;;
 689 esac
 690
 691 AC_SUBST(MATH_LIB)
 692 #
 693 # see bug 162979
 694 #
 695 AC_MSG_CHECKING(for HP-UX)
 696 case $host_os in
 697   hpux9* | hpux10* | hpux11*)
 698     AC_MSG_RESULT(yes)
 699     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 700   ;;
 701   *)
 702     AC_MSG_RESULT(no)
 703   ;;
 704 esac
 705
 706 #
 707 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 708 #
 709
 710 AM_PATH_GLIB_2_0(glib_required_version, :,
 711   AC_MSG_ERROR([
 712 *** GLIB glib_required_version or better is required. The latest version of
 713 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 714   gobject gmodule-no-export)
 715
 716 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 717 dnl
 718 gtk_save_LIBS=$LIBS
 719 LIBS="$LIBS $GLIB_LIBS"
 720 AC_CHECK_FUNCS(bind_textdomain_codeset)
 721 LIBS=$gtk_save_LIBS
 722
 723 AC_CHECK_HEADERS(pwd.h,
 724                  AC_DEFINE(HAVE_PWD_H, 1,
 725                            [Define to 1 if pwd.h is available]))
 726 AC_CHECK_HEADERS(sys/time.h,
 727                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 728                            [Define to 1 if time.h is available]))
 729 AC_CHECK_HEADERS(unistd.h,
 730                  AC_DEFINE(HAVE_UNISTD_H, 1,
 731                            [Define to 1 if unistd.h is available]))
 732 AC_CHECK_HEADERS(ftw.h,
 733                  AC_DEFINE(HAVE_FTW_H, 1,
 734                            [Define to 1 if ftw.h is available]))
 735
 736 AC_MSG_CHECKING([for GNU ftw extensions])
 737 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 738                                      #define _GNU_SOURCE
 739                                      #include <ftw.h>]],
 740                                    [[int flags = FTW_ACTIONRETVAL;]])],
 741                   [gtk_ok=yes],[gtk_ok=no])
 742 if test $gtk_ok = yes; then
 743     AC_MSG_RESULT([yes])
 744     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 745 else
 746     AC_MSG_RESULT([no])
 747 fi
 748
 749 #
 750 # Disable deprecation checks for all libraries we depend on on stable branches.
 751 # This is so newer versions of those libraries don't cause more warnings with
 752 # a stable GTK version.
 753 # We don't ever want to turn off deprecation warnings for master however, because
 754 # that's where we get rid of deprecated API we use.
 755 #
 756 if test m4_eval(gtk_minor_version % 2) = 0 ; then
 757   AC_DEFINE_UNQUOTED(GLIB_DISABLE_DEPRECATION_WARNINGS, 1,
 758                      [Disable deprecation warnings from glib])
 759 fi
 760
 761 dnl
 762 saved_cflags="$CFLAGS"
 763 saved_ldflags="$LDFLAGS"
 764
 765
 766 # Checks for library functions.
 767 AC_FUNC_MMAP
 768
 769 AC_CHECK_FUNCS(mallinfo)
 770 AC_CHECK_FUNCS(getresuid)
 771 AC_TYPE_UID_T
 772
 773 # Check for round(), rint(), isnan(), isinf() and nearbyint()
 774 AC_CHECK_LIB(m,round,,)
 775 AC_CHECK_FUNCS(round rint nearbyint)
 776 AC_CHECK_DECLS([isnan, isinf], [], [], [[#include <math.h>]])
 777
 778 # Checks for gdkspawn
 779 AC_CHECK_HEADERS(crt_externs.h)
 780 AC_CHECK_FUNCS(_NSGetEnviron)
 781
 782 AC_MSG_CHECKING(whether to build dynamic modules)
 783
 784 AC_ARG_ENABLE(modules,
 785               [AS_HELP_STRING([--disable-modules],
 786                               [disable dynamic module loading])])
 787
 788 dynworks=false
 789 build_dynamic_modules=no
 790 deps=
 791 if test x$enable_modules = xno; then
 792     AC_MSG_RESULT(no)
 793 else
 794     AC_MSG_RESULT(yes)
 795     AC_MSG_CHECKING(whether dynamic modules work)
 796     ## for loop is to strip newline
 797     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 798     for I in $tmp; do
 799         dynworks=$I
 800     done
 801
 802     dnl Now we check to see if our libtool supports shared lib deps
 803     dnl (in a rather ugly way even)
 804     if $dynworks; then
 805         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 806         module_deplibs_check=`$module_libtool_config | \
 807             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 808             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 809         if test "x$module_deplibs_check" = "xnone" || \
 810            test "x$module_deplibs_check" = "xunknown" || \
 811            test "x$module_deplibs_check" = "x"; then
 812             dynworks=false
 813         fi
 814     fi
 815
 816     if $dynworks; then
 817         build_dynamic_modules=yes
 818         AC_DEFINE(USE_GMODULE, 1,
 819                   [Define to 1 if gmodule works and should be used])
 820         AC_MSG_RESULT(yes)
 821     else
 822         build_dynamic_modules=no
 823         AC_MSG_RESULT(no)
 824     fi
 825 fi
 826
 827 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 828
 829 #
 830 # Allow building some or all immodules included
 831 #
 832 AC_MSG_CHECKING(immodules to build)
 833
 834 AC_ARG_WITH(included_immodules,
 835             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 836                             [build the specified input methods into gtk])])
 837
 838 if $dynworks; then
 839    :
 840 else
 841    ## if the option was specified, leave it; otherwise disable included immodules
 842    if test x$with_included_immodules = xno; then
 843            with_included_immodules=yes
 844    fi
 845 fi
 846
 847 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 848
 849 included_immodules=""
 850 # If the switch specified without listing any specific ones, include all
 851 if test "x$with_included_immodules" = xyes ; then
 852   included_immodules="$all_immodules"
 853 else
 854   included_immodules="$with_included_immodules"
 855 fi
 856
 857 AC_MSG_RESULT($included_immodules)
 858 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 859
 860 INCLUDED_IMMODULE_OBJ=
 861 INCLUDED_IMMODULE_DEFINE=
 862
 863 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 864 for immodule in $included_immodules; do
 865  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 866  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 867    :
 868  else
 869    AC_MSG_ERROR([the specified input method $immodule does not exist])
 870  fi
 871
 872  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 873  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 874  eval INCLUDE_$immodule_underscores=yes
 875 done
 876 IFS="$gtk_save_ifs"
 877 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 878 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 879
 880 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 881 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 882 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 883 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 884 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 885 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 886 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 887 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 888 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 889 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 890 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 891 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 892
 893 # Checks to see whether we should include mediaLib
 894 # support.
 895 #
 896 AC_CHECK_HEADER(sys/systeminfo.h,
 897                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 898                           [Define to 1 if sys/systeminfo.h is available]))
 899 AC_CHECK_HEADER(sys/sysinfo.h,
 900                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 901                           [Define to 1 if sys/sysinfo.h is available]))
 902
 903 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 904
 905 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 906
 907 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 908   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 909   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 910     REBUILD_PNGS=#
 911   fi
 912 fi
 913
 914 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 915
 916 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 917
 918 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 919    test "x$REBUILD_PNGS" = "x#" ; then
 920      AC_MSG_ERROR([
 921 *** gtkbuiltincache.h is not in the tree, and cannot be built
 922 *** because you don't have libpng, or (when cross-compiling) you
 923 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 924 fi
 925
 926 ########################################
 927 # Windowing system checks
 928 ########################################
 929
 930 # GTK+ uses some X calls, so needs to link against X directly
 931 GTK_DEP_PACKAGES_FOR_X=
 932 GTK_DEP_LIBS_FOR_X=
 933 X_EXTENSIONS=
 934
 935 if test "x$enable_x11_backend" = xyes; then
 936   X_PACKAGES=fontconfig
 937
 938   #
 939   # We use fontconfig very peripherally when decoding the default
 940   # settings.
 941   #
 942   if $PKG_CONFIG --exists fontconfig; then : ; else
 943     AC_MSG_ERROR([
 944 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 945   fi
 946
 947   #
 948   # Check for basic X packages; we use pkg-config if available
 949   #
 950   if $PKG_CONFIG --exists x11 xext; then
 951     have_base_x_pc=true
 952     X_PACKAGES="$X_PACKAGES x11 xext"
 953     x_libs="`$PKG_CONFIG --libs x11 xext`"
 954     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 955
 956     # Strip out any .la files that pkg-config might give us (this happens
 957     # with -uninstalled.pc files)
 958     x_libs_for_checks=
 959     for I in $x_libs ; do
 960       case $I in
 961         *.la) ;;
 962         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 963       esac
 964     done
 965
 966     GTK_PACKAGES_FOR_X="x11"
 967   else
 968     have_base_x_pc=false
 969     AC_PATH_XTRA
 970     if test x$no_x = xyes ; then
 971       AC_MSG_ERROR([X development libraries not found])
 972     fi
 973
 974     x_cflags="$X_CFLAGS"
 975     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 976
 977     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 978   fi
 979
 980   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 981   x_extra_libs=
 982
 983   gtk_save_cppflags="$CPPFLAGS"
 984   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 985
 986   gtk_save_LIBS=$LIBS
 987   LIBS="$x_libs_for_checks $LIBS"
 988
 989   # Sanity check for the X11 and Xext libraries. While everything we need from
 990   # Xext is optional, the chances a system has *none* of these things is so
 991   # small that we just unconditionally require it.
 992   AC_CHECK_FUNC(XOpenDisplay, :,
 993                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 994   AC_CHECK_FUNC(XextFindDisplay, :,
 995                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 996
 997   # Check for xReply
 998
 999   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
1000   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
1001                                      [[xReply *rep = NULL;
1002                                        rep = rep;]])],
1003                     [AC_MSG_RESULT([no])],
1004                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
1005                                                           #include <X11/Xlibint.h>]],
1006                                                         [[xReply *rep = NULL;
1007                                                           rep = rep;]])],
1008                                        [AC_MSG_RESULT([yes])
1009                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
1010                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
1011                                        [AC_MSG_RESULT([unknown])
1012                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1013
1014   # Check for XKB support.
1015
1016   if test "x$enable_xkb" = "xyes"; then
1017         AC_CHECK_FUNC(XkbQueryExtension,
1018                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1019                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1020                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1021   elif test "x$enable_xkb" = "xmaybe"; then
1022         AC_CHECK_FUNC(XkbQueryExtension,
1023                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1024                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1025   else
1026         AC_MSG_WARN(XKB support explicitly disabled)
1027   fi
1028
1029   # Check for shaped window extension
1030
1031   AC_CHECK_FUNC(XShapeCombineMask, :,
1032      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1033
1034   # X SYNC check
1035   gtk_save_CFLAGS="$CFLAGS"
1036   CFLAGS="$CFLAGS $x_cflags"
1037
1038   AC_CHECK_FUNC(XSyncQueryExtension,
1039       [AC_CHECK_HEADER(X11/extensions/sync.h,
1040           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1041           :, [#include <X11/Xlib.h>])])
1042
1043   CFLAGS="$gtk_save_CFLAGS"
1044
1045   if test "x$enable_xinerama" != "xno"; then
1046     # Check for Xinerama extension (Solaris impl or Xfree impl)
1047     have_xfree_xinerama=false
1048     have_solaris_xinerama=false
1049
1050     gtk_save_cppflags="$CPPFLAGS"
1051     CPPFLAGS="$CPPFLAGS $x_cflags"
1052
1053     # Check for XFree
1054     AC_MSG_CHECKING(for Xinerama packages)
1055
1056     if $PKG_CONFIG --exists xinerama ; then
1057        AC_MSG_RESULT(yes)
1058        have_xfree_xinerama=true
1059        X_PACKAGES="$X_PACKAGES xinerama"
1060     else
1061        AC_MSG_RESULT(no)
1062        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1063            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1064            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1065            have_xfree_xinerama=true], :,
1066            [#include <X11/Xlib.h>])])
1067     fi
1068
1069     if $have_xfree_xinerama ; then
1070       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1071       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1072                 [Define to 1 if XFree Xinerama is available])
1073       AC_DEFINE(HAVE_XINERAMA, 1,
1074                 [Define to 1 is Xinerama is available])
1075     else
1076       case "$host" in
1077         *-*-solaris*)
1078             # Check for solaris
1079             AC_MSG_CHECKING(for Xinerama support on Solaris)
1080
1081             have_solaris_xinerama=false
1082             AC_CHECK_FUNC(XineramaGetInfo,
1083                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1084                     [have_solaris_xinerama=true], :,
1085                     [#include <X11/Xlib.h>])])
1086
1087             if $have_solaris_xinerama ; then
1088               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1089               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1090                         [Define to 1 if solaris xinerama is available])
1091               AC_DEFINE(HAVE_XINERAMA, 1,
1092                         [Define to 1 if xinerama is available])
1093               AC_MSG_RESULT(yes)
1094             else
1095               AC_MSG_RESULT(no)
1096             fi
1097             ;;
1098         *)
1099             ;;
1100       esac
1101     fi
1102   fi
1103   if test "x$enable_xinerama" = "xyes" ; then
1104     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1105       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1106     fi
1107   fi
1108
1109   # Check for XGetEventData for GenericEvents
1110   AC_CHECK_FUNC(XGetEventData,
1111                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1112
1113   # set up things for XInput
1114   if $PKG_CONFIG --exists "xi" ; then
1115
1116     X_PACKAGES="$X_PACKAGES xi"
1117     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xi"
1118
1119     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1120                     have_xinput2=yes
1121                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1122
1123     gtk_save_LIBS="$LIBS"
1124     LIBS="$LIBS -lXi"
1125
1126     # Note that we also check that the XIScrollClassInfo struct is defined,
1127     # because at least Ubuntu Oneiric seems to have XIAllowTouchEvents(), but not the XIScrollClassInfo struct.
1128     AC_CHECK_FUNC([XIAllowTouchEvents],
1129       [AC_CHECK_MEMBER([XIScrollClassInfo.number],
1130                        have_xinput2_2=yes
1131                        AC_DEFINE(XINPUT_2_2, 1, [Define to 1 if XInput 2.2 is available]),
1132                        have_xinput2_2=no,
1133                        [[#include <X11/extensions/XInput2.h>]])])
1134     LIBS="$gtk_save_LIBS"
1135
1136     if test "x$have_xinput2_2" = "xyes"; then
1137       X_EXTENSIONS="$X_EXTENSIONS XI2.2"
1138     else
1139       X_EXTENSIONS="$X_EXTENSIONS XI2"
1140     fi
1141   fi
1142
1143   AS_IF([test "x$have_xinput2" != "xyes"],
1144         [AC_MSG_ERROR([*** XInput2 extension not found. Check 'config.log' for more details.])])
1145
1146   # Check for the RANDR extension
1147   if test x"$enable_xrandr" != xno; then
1148     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1149       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1150
1151       X_PACKAGES="$X_PACKAGES xrandr"
1152       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1153     elif test x"$enable_xrandr" = xyes; then
1154       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1155     fi
1156   fi
1157
1158   # Checks for Xcursor library
1159
1160   if $PKG_CONFIG --exists xcursor ; then
1161     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1162
1163     X_PACKAGES="$X_PACKAGES xcursor"
1164   fi
1165
1166   # Checks for XFixes extension
1167
1168   if test x"$enable_xfixes" != xno; then
1169     if $PKG_CONFIG --exists xfixes ; then
1170       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1171
1172       X_PACKAGES="$X_PACKAGES xfixes"
1173       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1174       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1175     elif test x"$enable_xfixes" = xyes; then
1176       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1177     fi
1178   fi
1179
1180   # Checks for Xcomposite extension
1181
1182   if test x"$enable_xcomposite" != xno; then
1183     if $PKG_CONFIG --exists xcomposite ; then
1184       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1185
1186       X_PACKAGES="$X_PACKAGES xcomposite"
1187       X_EXTENSIONS="$X_EXTENSIONS Composite"
1188       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1189     elif test x"$enable_xcomposite" = xyes; then
1190       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1191     fi
1192   fi
1193
1194   # Checks for Xdamage extension
1195
1196   if test x"$enable_xdamage" != xno; then
1197     if $PKG_CONFIG --exists xdamage ; then
1198       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1199
1200       X_PACKAGES="$X_PACKAGES xdamage"
1201       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1202       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1203     elif test x"$enable_xdamage" = xyes; then
1204       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1205     fi
1206   fi
1207
1208   if $have_base_x_pc ; then
1209     GDK_EXTRA_LIBS="$x_extra_libs"
1210   else
1211     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1212   fi
1213
1214   CPPFLAGS="$gtk_save_cppflags"
1215   LIBS="$gtk_save_libs"
1216
1217   AM_CONDITIONAL(USE_X11, true)
1218
1219   # strip leading space
1220   X_EXTENSIONS=${X_EXTENSIONS#* }
1221
1222 else
1223   XPACKAGES=
1224
1225   AM_CONDITIONAL(USE_X11, false)
1226 fi
1227
1228 # Check for gio-unix
1229 if test "$have_gio_unix" = "yes"; then
1230   GDK_GIO_PACKAGE=gio-unix-2.0
1231   AC_DEFINE([HAVE_GIO_UNIX], [1],
1232             [Define if gio-unix is available])
1233 else
1234   GDK_GIO_PACKAGE=gio-2.0
1235 fi
1236
1237 # Check for Pango flags
1238
1239 AC_MSG_CHECKING(Pango flags)
1240 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1241         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1242         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1243
1244         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1245 else
1246         AC_MSG_ERROR([
1247 *** Pango not found. Pango built with Cairo support is required
1248 *** to build GTK+. See http://www.pango.org for Pango information.
1249 ])
1250 fi
1251
1252 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1253
1254 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1255         :
1256 else
1257         gtk_save_LIBS="$LIBS"
1258         LIBS="$PANGO_LIBS $LIBS"
1259         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1260 *** Can't link to Pango. Pango is required to build
1261 *** GTK+. For more information see http://www.pango.org]))
1262         LIBS="$gtk_save_LIBS"
1263 fi
1264
1265 CFLAGS="$saved_cflags"
1266 LDFLAGS="$saved_ldflags"
1267
1268 GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo cairo-gobject"
1269 GDK_PRIVATE_PACKAGES="$GDK_GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES $cairo_backends"
1270 if test "x$enable_x11_backend" = xyes; then
1271   GDK_PRIVATE_PACKAGES="$GDK_PRIVATE_PACKAGES pangoft2"
1272 fi
1273
1274 PKG_CHECK_MODULES(GDK_DEP, $GDK_PACKAGES $GDK_PRIVATE_PACKAGES)
1275 GDK_DEP_LIBS="$GDK_EXTRA_LIBS $GDK_DEP_LIBS $MATH_LIB"
1276 GDK_DEP_CFLAGS="$GDK_DEP_CFLAGS $GDK_EXTRA_CFLAGS"
1277 #
1278 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1279 # into the pkg-config files
1280 #
1281 if test $enable_explicit_deps != yes ; then
1282   GDK_EXTRA_LIBS=
1283 fi
1284
1285 AC_SUBST(GDK_PACKAGES)
1286 AC_SUBST(GDK_PRIVATE_PACKAGES)
1287 AC_SUBST(GDK_EXTRA_LIBS)
1288 AC_SUBST(GDK_EXTRA_CFLAGS)
1289 AC_SUBST(GDK_DEP_LIBS)
1290 AC_SUBST(GDK_DEP_CFLAGS)
1291
1292
1293 ########################################
1294 # Check for Accessibility Toolkit flags
1295 ########################################
1296
1297 if test x$enable_x11_backend = xyes; then
1298    ATK_PACKAGES="atk atk-bridge-2.0"
1299 else
1300    ATK_PACKAGES="atk"
1301 fi
1302
1303 PKG_CHECK_MODULES(ATK, $ATK_PACKAGES)
1304
1305 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1306 GTK_PRIVATE_PACKAGES="$ATK_PACKAGES"
1307 if test "x$enable_x11_backend" = xyes; then
1308   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES pangoft2"
1309 fi
1310 if test "$have_gio_unix" = "yes"; then
1311   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES gio-unix-2.0"
1312 fi
1313 GTK_EXTRA_LIBS=
1314
1315 GTK_EXTRA_CFLAGS=
1316 PKG_CHECK_MODULES(GTK_DEP, $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES $GTK_PRIVATE_PACKAGES)
1317 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X $GTK_DEP_LIBS $GTK_EXTRA_LIBS $MATH_LIB"
1318 GTK_DEP_CFLAGS="$GTK_DEP_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1319
1320 if test x"$os_win32" = xyes; then
1321   GTK_EXTRA_CFLAGS="$msnative_struct"
1322 fi
1323
1324 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1325 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1326 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1327 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1328
1329 AC_SUBST(GTK_PACKAGES)
1330 AC_SUBST(GTK_PRIVATE_PACKAGES)
1331 AC_SUBST(GTK_EXTRA_LIBS)
1332 AC_SUBST(GTK_EXTRA_CFLAGS)
1333 AC_SUBST(GTK_DEP_LIBS)
1334 AC_SUBST(GTK_DEP_CFLAGS)
1335
1336 AC_SUBST(GLIB_PREFIX)
1337 AC_SUBST(ATK_PREFIX)
1338 AC_SUBST(PANGO_PREFIX)
1339 AC_SUBST(CAIRO_PREFIX)
1340
1341 AC_SUBST(GTK_DEBUG_FLAGS)
1342 AC_SUBST(GTK_XIM_FLAGS)
1343
1344 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1345 AC_SUBST(GDK_PIXBUF_LIBS)
1346
1347 ########################
1348 # Checks needed for gail
1349 ########################
1350
1351 old_LIBS="$LIBS"
1352 dnl Checks for inet libraries:
1353 AC_SEARCH_LIBS(gethostent, nsl)
1354 AC_SEARCH_LIBS(setsockopt, socket)
1355 AC_SEARCH_LIBS(connect, inet)
1356
1357 dnl check for the sockaddr_un.sun_len member
1358 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1359                 [struct_sockaddr_un_sun_len=true],
1360                 [struct_sockaddr_un_suin_len=false],
1361                 [#include <sys/types.h>
1362                  #include <sys/un.h>]
1363                 )
1364 case $struct_sockaddr_un_sun_len in
1365         true)
1366                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1367                                    [Have the sockaddr_un.sun_len member])
1368                 ;;
1369         *)
1370                 ;;
1371 esac
1372
1373 GAIL_INET_LIBS="$LIBS"
1374 AC_SUBST([GAIL_INET_LIBS])
1375
1376 LIBS="$old_LIBS"
1377
1378 ################################################################
1379 # Printing system checks
1380 ################################################################
1381
1382 PRINT_BACKENDS="file lpr"
1383
1384 AC_ARG_ENABLE(cups,
1385               [AS_HELP_STRING([--disable-cups],
1386                               [disable cups print backend])],,
1387               [enable_cups=auto])
1388
1389 if test "x$enable_cups" = "xno"; then
1390   AM_CONDITIONAL(HAVE_CUPS, false)
1391 else
1392   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1393   if test "x$CUPS_CONFIG" = "xno"; then
1394     if test "x$enable_cups" = "xauto"; then
1395       AM_CONDITIONAL(HAVE_CUPS, false)
1396     else
1397       AC_MSG_ERROR([
1398 *** cups not found.
1399 ])
1400     fi
1401   else
1402     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1403     CUPS_LIBS=`$CUPS_CONFIG --libs`
1404
1405     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1406     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1407     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1408
1409     if test $CUPS_API_MAJOR -gt 1 -o \
1410             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -lt 2; then
1411       AC_MSG_ERROR([CUPS >= 1.2 not found])
1412     fi
1413     if test $CUPS_API_MAJOR -gt 1 -o \
1414             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 6; then
1415       AC_DEFINE(HAVE_CUPS_API_1_6, 1,
1416                 [Define to 1 if CUPS 1.6 API is available])
1417
1418     fi
1419
1420     AC_SUBST(CUPS_API_MAJOR)
1421     AC_SUBST(CUPS_API_MINOR)
1422     AC_SUBST(CUPS_CFLAGS)
1423     AC_SUBST(CUPS_LIBS)
1424
1425     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1426
1427     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1428     AM_CONDITIONAL(HAVE_CUPS, true)
1429
1430     gtk_save_cflags="$CFLAGS"
1431     CFLAGS="$CUPS_CFLAGS"
1432     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1433                                        [[http_t http; char *s = http.authstring;]])],
1434                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1435                                  [Define if cups http_t authstring field is accessible])],
1436                       [])
1437     CFLAGS="$gtk_save_cflags"
1438
1439     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1440
1441     gtk_save_libs="$LIBS"
1442     LIBS="$CUPS_LIBS"
1443     AC_CHECK_FUNCS(httpGetAuthString)
1444     LIBS="$gtk_save_libs"
1445   fi
1446 fi
1447
1448 # Checks to see if we should compile with PAPI backend for GTK+
1449 #
1450
1451 AC_ARG_ENABLE(papi,
1452               [AS_HELP_STRING([--disable-papi],
1453                               [disable papi print backend])],,
1454               [enable_papi=auto])
1455
1456 if test "x$enable_papi" = "xno"; then
1457   AM_CONDITIONAL(HAVE_PAPI, false)
1458 else
1459   AC_MSG_CHECKING(libpapi)
1460   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1461   if test $have_papi = yes; then
1462     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1463     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1464   fi
1465   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1466   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1467     AC_MSG_ERROR([
1468 *** papi not found.
1469 ])
1470   fi
1471 fi
1472
1473 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1474
1475 gtk_save_cppflags="$CPPFLAGS"
1476 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1477
1478 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1479 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1480 *** backend enabled.]))
1481
1482 if test "$os_win32" != "yes"; then
1483   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1484 *** Can't find cairo-ps.h. You must build Cairo with the
1485 *** postscript backend enabled.]))
1486
1487   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1488 *** Cannot find cairo-svg.h. You must build Cairo with the
1489 *** svg backend enabled.]))
1490 fi
1491
1492 CPPFLAGS="$gtk_save_cppflags"
1493
1494
1495 AC_ARG_ENABLE(test-print-backend,
1496               [AS_HELP_STRING([--enable-test-print-backend],
1497                               [build test print backend])],,
1498               [enable_test_print_backend=no])
1499 if test "x$enable_test_print_backend" != "xno" ; then
1500   PRINT_BACKENDS="$PRINT_BACKENDS test"
1501 fi
1502 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1503
1504 if test "$os_win32" = "yes"; then
1505   AC_CHECK_TYPES([IPrintDialogCallback],[],[],[[#include <windows.h>]])
1506 fi
1507
1508 ################################################################
1509 # Strip -export-dynamic from the link lines of various libraries
1510 ################################################################
1511
1512 #
1513 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1514 #  but this flag is only meaningful for executables. For libraries
1515 #  the effect is undefined; what it causes on Linux is that the
1516 #  export list from -export-symbols-regex is ignored and everything
1517 #  is exported
1518 #
1519 # We are using gmodule-no-export now, but I'm leaving the stripping
1520 # code in place for now, since pango and atk still require gmodule.
1521 export SED
1522 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1523 if test -n "$export_dynamic"; then
1524   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1525   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1526 fi
1527
1528 #############
1529 # GSettings #
1530 #############
1531
1532 GLIB_GSETTINGS
1533
1534 ##################################################
1535 # GObject introspection
1536 ##################################################
1537
1538 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1539
1540 ##################################################
1541 # Packagekit module
1542 #################################################
1543
1544 AC_ARG_ENABLE(packagekit,
1545               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1546                               [build PackageKit open-with module [default=auto]])],
1547               [enable_packagekit="$enableval"],
1548               [enable_packagekit=auto])
1549 if test "$enable_packagekit" = "auto"; then
1550   if test "$os_win32" = "yes"; then
1551     enable_packagekit=no
1552   else
1553     enable_packagekit=yes
1554   fi
1555 fi
1556
1557 AC_MSG_CHECKING([whether to use PackageKit])
1558 build_packagekit=no
1559 if test "x$enable_packagekit" != "xno"; then
1560   if test "$os_win32" != "yes"; then
1561     build_packagekit=yes
1562     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1563   else
1564     AC_MSG_ERROR([packagekit support is not available on win32])
1565   fi
1566 fi
1567 AC_MSG_RESULT([$build_packagekit])
1568
1569 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1570
1571 ##################################################
1572 # colord module
1573 #################################################
1574
1575 AC_ARG_ENABLE(colord,
1576               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1577                               [build colord support code [default=auto]])],
1578               [enable_colord="$enableval"],
1579               [enable_colord=auto])
1580
1581 AC_MSG_CHECKING([whether to use colord])
1582 if test "$enable_colord" = "auto"; then
1583   if test "$os_win32" = "yes"; then
1584     enable_colord=no
1585   fi
1586 fi
1587 if test "$enable_colord" != "no"; then
1588   AC_MSG_RESULT([yes])
1589 else
1590   AC_MSG_RESULT([no])
1591 fi
1592
1593 have_colord=no
1594 if test "$enable_colord" != "no"; then
1595         if test "$os_win32" != "yes"; then
1596                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1597                                   have_colord=yes, have_colord=no)
1598                 if test "$enable_colord" = "yes"; then
1599                         if test "$have_colord" = "no"; then
1600                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1601                         fi
1602                 fi
1603         else
1604                 AC_MSG_ERROR([colord support is not available on win32])
1605         fi
1606 fi
1607
1608 if test "$have_colord" = "yes"; then
1609         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1610 fi
1611 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1612
1613 ##################################################
1614 # Checks for gtk-doc and docbook-tools
1615 ##################################################
1616
1617 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1618
1619 AC_ARG_ENABLE(man,
1620               [AS_HELP_STRING([--enable-man],
1621                               [generate man pages [default=auto]])],,
1622               enable_man=maybe)
1623
1624 if test "$enable_man" != no; then
1625   AC_PATH_PROG([XSLTPROC], [xsltproc])
1626   if test -z "$XSLTPROC"; then
1627     if test "$enable_man" = yes ; then
1628       AC_MSG_ERROR([xsltproc is required for --enable-man])
1629     fi
1630     enable_man=no
1631   fi
1632 fi
1633
1634 if test "$enable_man" != no; then
1635   dnl check for DocBook DTD in the local catalog
1636   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1637      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
1638   if test "$have_docbook_dtd" != yes; then
1639     if test "$enable_man" = yes ; then
1640       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
1641     fi
1642     enable_man=no
1643   fi
1644 fi
1645
1646 if test "$enable_man" != no; then
1647   dnl check for DocBook XSL stylesheets in the local catalog
1648   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1649      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
1650   if test "$have_docbook_dtd" != yes; then
1651     if test "$enable_man" = yes ; then
1652       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
1653     fi
1654     enable_man=no
1655   fi
1656 fi
1657
1658 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
1659
1660 AC_MSG_CHECKING([whether to generate man pages])
1661 if test "$enable_man" != no; then
1662   AC_MSG_RESULT([yes])
1663 else
1664   AC_MSG_RESULT([no])
1665 fi
1666
1667 ##################################################
1668 # Output commands
1669 ##################################################
1670
1671 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1672         outfile=gdkconfig.h-tmp
1673         cat > $outfile <<\_______EOF
1674 /* gdkconfig.h
1675  *
1676  * This is a generated file.  Please modify `configure.ac'
1677  */
1678
1679 #ifndef __GDKCONFIG_H__
1680 #define __GDKCONFIG_H__
1681
1682 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1683 #error "Only <gdk/gdk.h> can be included directly."
1684 #endif
1685
1686 #include <glib.h>
1687
1688 G_BEGIN_DECLS
1689
1690 _______EOF
1691
1692         cat >>$outfile <<_______EOF
1693 $gdk_windowing
1694 _______EOF
1695
1696         cat >>$outfile <<_______EOF
1697
1698 G_END_DECLS
1699
1700 #endif  /* __GDKCONFIG_H__ */
1701 _______EOF
1702
1703
1704         if cmp -s $outfile gdk/gdkconfig.h; then
1705           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1706           rm -f $outfile
1707         else
1708           mv $outfile gdk/gdkconfig.h
1709         fi
1710 ],[
1711 gdk_windowing='$GDK_WINDOWING'
1712 ])
1713
1714 dnl
1715 dnl Check for -Bsymbolic-functions linker flag used to avoid
1716 dnl intra-library PLT jumps, if available.
1717 dnl
1718 AC_ARG_ENABLE(Bsymbolic,
1719               [AS_HELP_STRING([--disable-Bsymbolic],
1720                               [avoid linking with -Bsymbolic])],,
1721               [SAVED_LDFLAGS="${LDFLAGS}"
1722                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1723                LDFLAGS=-Wl,-Bsymbolic-functions
1724                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1725                                                [[int main (void) { return 0; }]])],
1726                               [AC_MSG_RESULT(yes)
1727                                enable_Bsymbolic=yes],
1728                               [AC_MSG_RESULT(no)
1729                                enable_Bsymbolic=no])
1730                LDFLAGS="${SAVED_LDFLAGS}"])
1731
1732 if test "x${enable_Bsymbolic}" = "xyes" ; then
1733   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1734 fi
1735 AC_SUBST(GTK_LINK_FLAGS)
1736
1737 AC_CONFIG_FILES([
1738 config.h.win32
1739 gtk-zip.sh
1740 Makefile
1741 gdk-3.0.pc
1742 gtk+-3.0.pc
1743 gtk+-unix-print-3.0.pc
1744 gail-3.0.pc
1745 m4macros/Makefile
1746 po/Makefile.in
1747 po-properties/Makefile.in
1748 demos/Makefile
1749 demos/gtk-demo/Makefile
1750 demos/gtk-demo/geninclude.pl
1751 demos/pixbuf-demo/Makefile
1752 demos/widget-factory/Makefile
1753 examples/Makefile
1754 tests/Makefile
1755 tests/a11y/Makefile
1756 tests/css/Makefile
1757 tests/css/parser/Makefile
1758 tests/reftests/Makefile
1759 tests/visuals/Makefile
1760 docs/Makefile
1761 docs/reference/Makefile
1762 docs/reference/gdk/Makefile
1763 docs/reference/gdk/version.xml
1764 docs/reference/gtk/Makefile
1765 docs/reference/gtk/gtk3.types
1766 docs/reference/gtk/version.xml
1767 docs/reference/libgail-util/Makefile
1768 docs/reference/libgail-util/version.xml
1769 docs/tools/Makefile
1770 build/Makefile
1771 build/win32/Makefile
1772 build/win32/vs9/Makefile
1773 build/win32/vs10/Makefile
1774 gdk/Makefile
1775 gdk/broadway/Makefile
1776 gdk/x11/Makefile
1777 gdk/win32/Makefile
1778 gdk/win32/rc/Makefile
1779 gdk/win32/rc/gdk.rc
1780 gdk/quartz/Makefile
1781 gdk/wayland/Makefile
1782 gdk/tests/Makefile
1783 gdk/gdkversionmacros.h
1784 gtk/Makefile
1785 gtk/makefile.msc
1786 gtk/gtkversion.h
1787 gtk/gtk-win32.rc
1788 gtk/a11y/Makefile
1789 gtk/tests/Makefile
1790 libgail-util/Makefile
1791 modules/Makefile
1792 modules/engines/Makefile
1793 modules/engines/pixbuf/Makefile
1794 modules/input/Makefile
1795 modules/printbackends/Makefile
1796 modules/printbackends/cups/Makefile
1797 modules/printbackends/lpr/Makefile
1798 modules/printbackends/file/Makefile
1799 modules/printbackends/papi/Makefile
1800 modules/printbackends/test/Makefile
1801 perf/Makefile
1802 ])
1803
1804 AC_OUTPUT
1805
1806 # beautify the immodule list a bit
1807 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1808 if test -z "${included_immodules}"; then included_immodules="none"; fi
1809
1810 echo ""
1811 echo "        GTK+ $GTK_VERSION"
1812 echo "        ==========="
1813 echo ""
1814 echo "        GDK backends:         $GDK_BACKENDS"
1815 if test "$enable_x11_backend" = "yes"; then
1816 echo "        X11 extensions:       $X_EXTENSIONS"
1817 fi
1818 echo "        Print backends:       $PRINT_BACKENDS"
1819 echo "        Dynamic modules:      $build_dynamic_modules"
1820 echo "        Included immodules:   $included_immodules"
1821 echo "        PackageKit support:   $build_packagekit"
1822 echo "        colord support:       $have_colord"
1823 echo "        Introspection:        $found_introspection"
1824 echo "        Debugging:            $enable_debug"
1825 echo "        Documentation:        $enable_gtk_doc"