Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [7])
  13 m4_define([gtk_micro_version], [3])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.35.3])
  43 m4_define([pango_required_version], [1.32.4])
  44 m4_define([atk_required_version], [2.5.3])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.26.0])
  47 m4_define([introspection_required_version], [1.32.0])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_MKDIR_P
 129 AC_PROG_INSTALL
 130 AC_PROG_MAKE_SET
 131
 132
 133 GETTEXT_PACKAGE=gtk30
 134 AC_SUBST(GETTEXT_PACKAGE)
 135 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 136                    [The prefix for our gettext translation domains.])
 137
 138 AC_CANONICAL_HOST
 139
 140 MATH_LIB=-lm
 141 AC_MSG_CHECKING([for native Win32])
 142 LIB_EXE_MACHINE_FLAG=X86
 143 EXE_MANIFEST_ARCHITECTURE=X86
 144 DISABLE_ON_W32=''
 145 case "$host" in
 146   *-*-mingw*)
 147     dnl Comment-out certain gtk3.types.in lines
 148     DISABLE_ON_W32='%'
 149     os_win32=yes
 150     gio_can_sniff=no
 151     MATH_LIB=
 152     case "$host" in
 153     x86_64-*-*)
 154       LIB_EXE_MACHINE_FLAG=X64
 155       EXE_MANIFEST_ARCHITECTURE=AMD64
 156       ;;
 157     esac
 158     ;;
 159   *)
 160     os_win32=no
 161     ;;
 162 esac
 163 AC_MSG_RESULT([$os_win32])
 164
 165 AC_SUBST(DISABLE_ON_W32)
 166 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 167 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 168
 169 case $host in
 170   *-*-linux*)
 171     os_linux=yes
 172     ;;
 173 esac
 174
 175 dnl
 176 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 177 dnl We use this for an automated test for C++ header correctness.
 178 dnl
 179 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 180 AC_LANG_PUSH([C++])
 181
 182 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 183                                    [[class a { int b; } c;]])],
 184                   [],[CXX=])
 185 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 186
 187 gtk_save_cxxflags="$CXXFLAGS"
 188 CXXFLAGS="$CXXFLAGS -x objective-c++"
 189 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 190                                    [[]])],
 191                   [OBJC=yes],[OBJC=no])
 192 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 193 CXXFLAGS="$gtk_save_cxxflags"
 194 AC_LANG_POP([C++])
 195
 196 if test "$os_win32" = "yes"; then
 197   if test x$enable_static = xyes -o x$enable_static = x; then
 198     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 199     enable_static=no
 200   fi
 201   if test x$enable_shared = xno; then
 202     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 203   fi
 204   enable_shared=yes
 205 fi
 206
 207 dnl Initialize libtool
 208 LT_PREREQ([2.2.6])
 209 LT_INIT([disable-static win32-dll])
 210 # Create libtool early, because it's used in configure
 211 LT_OUTPUT
 212
 213 # Make sure we use 64-bit versions of various file stuff.
 214 AC_SYS_LARGEFILE
 215
 216 AM_PROG_AS
 217 AC_PATH_PROG(NM, nm, nm)
 218
 219 AC_MSG_CHECKING([for some Win32 platform])
 220 case "$host" in
 221   *-*-mingw*|*-*-cygwin*)
 222     platform_win32=yes
 223     ;;
 224   *)
 225     platform_win32=no
 226     ;;
 227 esac
 228 AC_MSG_RESULT([$platform_win32])
 229 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 230
 231 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 232 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 233 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 234
 235 if test "$os_win32" = "yes"; then
 236   AC_CHECK_TOOL(WINDRES, windres, no)
 237   if test "$WINDRES" = no; then
 238     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 239   fi
 240   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 241 fi
 242 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 243
 244 m4_define([debug_default],
 245           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 246
 247 dnl declare --enable-* args and collect ac_help strings
 248 AC_ARG_ENABLE(debug,
 249               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 250                               [turn on debugging @<:@default=debug_default@:>@])],,
 251               [enable_debug=debug_default])
 252
 253 AC_ARG_ENABLE(rebuilds,
 254               [AS_HELP_STRING([--disable-rebuilds],
 255                               [disable all source autogeneration rules])],,
 256               [enable_rebuilds=yes])
 257
 258 AC_ARG_ENABLE(gtk2-dependency,
 259               [AS_HELP_STRING([--enable-gtk2-dependency],
 260                               [Do not build gtk-update-icon-cache and other shared tools])],,
 261               [enable_gtk2_dependency=no])
 262
 263 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 264
 265 AC_ARG_ENABLE(xkb,
 266               [AS_HELP_STRING([--enable-xkb],
 267                               [support XKB extension [default=maybe]])],,
 268               [enable_xkb="maybe"])
 269 AC_ARG_ENABLE(xinerama,
 270               [AS_HELP_STRING([--enable-xinerama],
 271                               [support Xinerama extension [default=maybe]])],,
 272               [enable_xinerama="maybe"])
 273 AC_ARG_ENABLE(xrandr,
 274               [AS_HELP_STRING([--enable-xrandr],
 275                               [support XRandR extension [default=maybe]])],,
 276               [enable_xrandr="maybe"])
 277 AC_ARG_ENABLE(xfixes,
 278               [AS_HELP_STRING([--enable-xfixes],
 279                               [support XFixes extension [default=maybe]])],,
 280               [enable_xfixes="maybe"])
 281 AC_ARG_ENABLE(xcomposite,
 282               [AS_HELP_STRING([--enable-xcomposite],
 283                               [support X Composite extension [default=maybe]])],,
 284               [enable_xcomposite="maybe"])
 285 AC_ARG_ENABLE(xdamage,
 286               [AS_HELP_STRING([--enable-xdamage],
 287                               [support X Damage extension [default=maybe]])],,
 288               [enable_xdamage="maybe"])
 289
 290 AC_ARG_ENABLE(x11-backend,
 291               [AS_HELP_STRING([--enable-x11-backend],
 292                               [enable the X11 gdk backend])],
 293                               [backend_set=yes])
 294 AC_ARG_ENABLE(win32-backend,
 295               [AS_HELP_STRING([--enable-win32-backend],
 296                               [enable the Win32 gdk backend])],
 297                               [backend_set=yes])
 298 AC_ARG_ENABLE(quartz-backend,
 299               [AS_HELP_STRING([--enable-quartz-backend],
 300                               [enable the quartz gdk backend])],
 301                               [backend_set=yes])
 302 AC_ARG_ENABLE(broadway-backend,
 303               [AS_HELP_STRING([--enable-broadway-backend],
 304                               [enable the broadway (HTML5) gdk backend])],
 305                               [backend_set=yes])
 306 AC_ARG_ENABLE(wayland-backend,
 307               [AS_HELP_STRING([--enable-wayland-backend],
 308                               [enable the wayland gdk backend])],
 309                               [backend_set=yes])
 310
 311 if test -z "$backend_set"; then
 312   if test "$platform_win32" = yes; then
 313     enable_win32_backend=yes
 314   else
 315     enable_x11_backend=yes
 316   fi
 317 fi
 318
 319 AC_ARG_ENABLE(quartz-relocation,
 320               [AS_HELP_STRING([--enable-quartz-relocation],
 321                               [enable bundle-based relocation functions])],
 322                               [quartz_relocation=yes])
 323
 324 AC_ARG_ENABLE(wayland-cairo-gl,
 325               AS_HELP_STRING([--enable-wayland-cairo-gl],
 326                              [enable the use of Cairo GL in the Wayland backend]),
 327               [enable_wayland_cairo_gl=yes])
 328
 329
 330 cairo_backends=
 331 backend_immodules=
 332 have_gio_unix=no
 333 GDK_BACKENDS=
 334 GDK_EXTRA_LIBS=
 335 GDK_EXTRA_CFLAGS=
 336 GDK_WINDOWING=
 337 PANGO_PACKAGES="pango pangocairo"
 338
 339 if test "$enable_x11_backend" = "yes"; then
 340   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 341   # backend names are identical.
 342   cairo_backends="$cairo_backends cairo-xlib"
 343   GDK_BACKENDS="$GDK_BACKENDS x11"
 344   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 345   # gdkapplaunchcontext-x11.c
 346   have_gio_unix=yes
 347   backend_immodules="$backend_immodules,xim"
 348   GDK_WINDOWING="$GDK_WINDOWING
 349 #define GDK_WINDOWING_X11"
 350 fi
 351
 352 if test "$enable_win32_backend" = "yes"; then
 353   cairo_backends="$cairo_backends cairo-win32"
 354   GDK_BACKENDS="$GDK_BACKENDS win32"
 355   backend_immodules="$backend_immodules,ime"
 356   GDK_WINDOWING="$GDK_WINDOWING
 357 #define GDK_WINDOWING_WIN32"
 358   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 359   AM_CONDITIONAL(USE_WIN32, true)
 360   PANGO_PACKAGES="pangowin32 pangocairo"
 361 else
 362   AM_CONDITIONAL(USE_WIN32, false)
 363 fi
 364
 365 DISABLE_ON_QUARTZ=''
 366 if test "x$enable_quartz_backend" = xyes; then
 367   cairo_backends="$cairo_backends cairo-quartz"
 368   GDK_BACKENDS="$GDK_BACKENDS quartz"
 369   GDK_WINDOWING="$GDK_WINDOWING
 370 #define GDK_WINDOWING_QUARTZ"
 371   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 372   DISABLE_ON_QUARTZ='%'
 373   AM_CONDITIONAL(USE_QUARTZ, true)
 374   if test "x$quartz_relocation" = xyes; then
 375     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 376   fi
 377   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 378   # gdkapplaunchcontext-x11.c
 379   have_gio_unix=yes
 380
 381 else
 382   AM_CONDITIONAL(USE_QUARTZ, false)
 383 fi
 384 AC_SUBST(DISABLE_ON_QUARTZ)
 385
 386 if test "x$enable_broadway_backend" = xyes; then
 387   GDK_BACKENDS="$GDK_BACKENDS broadway"
 388   cairo_backends="$cairo_backends cairo"
 389   GDK_WINDOWING="$GDK_WINDOWING
 390 #define GDK_WINDOWING_BROADWAY"
 391   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 392   AM_CONDITIONAL(USE_BROADWAY, true)
 393 else
 394   AM_CONDITIONAL(USE_BROADWAY, false)
 395 fi
 396
 397 if test "x$enable_wayland_backend" = "xyes"; then
 398   if test "x$enable_wayland_cairo_gl" = "xyes"; then
 399     # Wayland can use cairo-gl
 400     cairo_backends="$cairo_backends cairo-gl"
 401     AC_DEFINE(GDK_WAYLAND_USE_EGL, [1], [Whether to use EGL in Wayland backend])
 402   else
 403     # For the cairo image backend
 404     cairo_backends="$cairo_backends cairo"
 405   fi
 406   GDK_BACKENDS="$GDK_BACKENDS wayland"
 407   have_gio_unix=yes
 408   GDK_WINDOWING="$GDK_WINDOWING
 409 #define GDK_WINDOWING_WAYLAND"
 410   WAYLAND_PACKAGES="wayland-client >= 1.0.0 xkbcommon >= 0.2.0 wayland-cursor"
 411   if test "x$enable_wayland_cairo_gl" = "xyes"; then
 412     WAYLAND_PACKAGES="$WAYLAND_PACKAGES wayland-egl egl"
 413   fi
 414   AM_CONDITIONAL(USE_WAYLAND, true)
 415 else
 416   AM_CONDITIONAL(USE_WAYLAND, false)
 417 fi
 418
 419 # strip leading space
 420 GDK_BACKENDS=${GDK_BACKENDS#* }
 421
 422 AC_SUBST(GDK_BACKENDS)
 423
 424 if test -z "$GDK_BACKENDS"; then
 425   AC_MSG_ERROR([No GDK backends selected.])
 426 fi
 427
 428 if test "x$enable_debug" = "xyes"; then
 429   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 430   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 431 else
 432   if test "x$enable_debug" = "xno"; then
 433     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 434   else
 435     GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"
 436   fi
 437 fi
 438
 439
 440 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 441                    [Define if debugging is enabled])
 442
 443
 444 # Build time sanity check...
 445 AM_SANITY_CHECK
 446
 447 changequote(,)dnl
 448 if test "x$GCC" = "xyes"; then
 449   case " $CFLAGS " in
 450   *[\ \ ]-Wall[\ \      ]*) ;;
 451   *) CFLAGS="$CFLAGS -Wall" ;;
 452   esac
 453
 454   if test "x$enable_ansi" = "xyes"; then
 455     case " $CFLAGS " in
 456     *[\ \       ]-ansi[\ \      ]*) ;;
 457     *) CFLAGS="$CFLAGS -ansi" ;;
 458     esac
 459
 460     case " $CFLAGS " in
 461     *[\ \       ]-pedantic[\ \  ]*) ;;
 462     *) CFLAGS="$CFLAGS -pedantic" ;;
 463     esac
 464   fi
 465 fi
 466 changequote([,])dnl
 467
 468 # Ensure MSVC-compatible struct packing convention is used when
 469 # compiling for Win32 with gcc.
 470 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 471 # gcc2 uses "-fnative-struct".
 472 if test x"$os_win32" = xyes; then
 473   if test x"$GCC" = xyes; then
 474     msnative_struct=''
 475     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 476     if test -z "$ac_cv_prog_CC"; then
 477       our_gcc="$CC"
 478     else
 479       our_gcc="$ac_cv_prog_CC"
 480     fi
 481     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 482       2.)
 483         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 484           msnative_struct='-fnative-struct'
 485         fi
 486         ;;
 487       *)
 488         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 489           msnative_struct='-mms-bitfields'
 490         fi
 491         ;;
 492     esac
 493     if test x"$msnative_struct" = x ; then
 494       AC_MSG_RESULT([no way])
 495       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 496     else
 497       CFLAGS="$CFLAGS $msnative_struct"
 498       AC_MSG_RESULT([${msnative_struct}])
 499     fi
 500   fi
 501 fi
 502
 503 ## Initial sanity check, done here so that users get told they
 504 ## have the wrong dependencies as early in the process as possible.
 505 ## Later on we actually use the cflags/libs from separate pkg-config
 506 ## calls. Oh, also the later pkg-config calls don't include
 507 ## the version requirements since those make the module lists
 508 ## annoying to construct
 509 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 510   [glib-2.0 >= glib_required_version dnl
 511    atk >= atk_required_version dnl
 512    pango >= pango_required_version dnl
 513    cairo >= cairo_required_version dnl
 514    cairo-gobject >= cairo_required_version dnl
 515    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 516
 517 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 518
 519 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0])
 520
 521 if test "$os_win32" != yes; then
 522     # libtool option to control which symbols are exported
 523     # right now, symbols starting with _ are not exported
 524     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 525 else
 526     # We currently use .def files on Windows (for gdk and gtk)
 527     LIBTOOL_EXPORT_OPTIONS=
 528 fi
 529 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 530
 531 dnl ******************************************************
 532 dnl * See whether to include shared library dependencies *
 533 dnl ******************************************************
 534
 535 AC_ARG_ENABLE(explicit-deps,
 536               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 537                               [use explicit dependencies in .pc files [default=auto]])],,
 538               [enable_explicit_deps=auto])
 539
 540 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 541 case $enable_explicit_deps in
 542   auto)
 543     export SED
 544     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 545     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 546       enable_explicit_deps=yes
 547     else
 548       enable_explicit_deps=no
 549     fi
 550   ;;
 551   yes|no)
 552   ;;
 553   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 554   ;;
 555 esac
 556 AC_MSG_RESULT($enable_explicit_deps)
 557
 558 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 559
 560 # define a MAINT-like variable REBUILD which is set if Perl
 561 # and awk are found, so autogenerated sources can be rebuilt
 562
 563 AC_PATH_PROGS(PERL, perl5 perl)
 564
 565 # We would like indent, but don't require it.
 566 AC_CHECK_PROG(INDENT, indent, indent)
 567
 568 REBUILD=\#
 569 if test "x$enable_rebuilds" = "xyes" && \
 570      test -n "$PERL" && \
 571      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 572   REBUILD=
 573 fi
 574 AC_SUBST(REBUILD)
 575
 576 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 577 AC_CHECK_FUNCS(localtime_r)
 578
 579 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 580 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 581 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 582                                 [[char c;
 583                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 584                [gtk_ok=yes], [gtk_ok=no])
 585 AC_MSG_RESULT($gtk_ok)
 586 if test "$gtk_ok" = "yes"; then
 587   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 588             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 589 fi
 590
 591 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 592 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 593 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 594                                 [[char c;
 595                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 596                [gtk_ok=yes], [gtk_ok=no])
 597 AC_MSG_RESULT($gtk_ok)
 598 if test "$gtk_ok" = "yes"; then
 599   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 600             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 601 fi
 602
 603 # _NL_PAPER_HEIGHT is an enum and not a define
 604 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 605 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 606                                 [[char c;
 607                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 608                [gtk_ok=yes], [gtk_ok=no])
 609 AC_MSG_RESULT($gtk_ok)
 610 if test "$gtk_ok" = "yes"; then
 611   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 612             [Define if _NL_PAPER_HEIGHT is available])
 613 fi
 614
 615 # _NL_PAPER_WIDTH is an enum and not a define
 616 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 617 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 618                                 [[char c;
 619                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 620                [gtk_ok=yes], [gtk_ok=no])
 621 AC_MSG_RESULT($gtk_ok)
 622 if test "$gtk_ok" = "yes"; then
 623   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 624             [Define if _NL_PAPER_WIDTH is available])
 625 fi
 626
 627 # i18n stuff
 628 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 629 AM_GLIB_GNU_GETTEXT
 630 LIBS="$LIBS $INTLLIBS"
 631 AC_CONFIG_COMMANDS([po-properties],
 632                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 633                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 634                      esac]],
 635                    [[]])
 636
 637 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 638 dnl po-properties/POTFILES during configure; see GNOME #573515.
 639 dnl
 640 dnl Generate list of files to be processed by xgettext which will
 641 dnl be included in po-properties/Makefile.
 642 test -d po-properties || mkdir po-properties
 643 if test "x$srcdir" != "x."; then
 644   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 645     popropsrcprefix="$srcdir/"
 646   else
 647     popropsrcprefix="../$srcdir/"
 648   fi
 649 else
 650   popropsrcprefix="../"
 651 fi
 652 rm -f po-properties/POTFILES
 653 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 654 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 655 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 656
 657 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 658
 659 dnl The DU4 header files don't provide library prototypes unless
 660 dnl -std1 is given to the native cc.
 661 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 662
 663 gtk_save_LIBS=$LIBS
 664 LIBS="$LIBS -lm"
 665 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 666                                 int main (void) { return (log(1) != log(1.)); }]])],
 667               [AC_MSG_RESULT(none needed)],
 668               [gtk_save_CFLAGS="$CFLAGS"
 669                CFLAGS="$CFLAGS -std1"
 670                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 671                                                int main (void) { return (log(1) != log(1.)); }]])],
 672                              [AC_MSG_RESULT(-std1)],
 673                              [AC_MSG_RESULT()
 674                               CFLAGS="$gtk_save_CFLAGS"
 675                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 676                              [true])],
 677               [AC_MSG_RESULT(none needed)])
 678
 679 LIBS=$gtk_save_LIBS
 680
 681 AC_MSG_CHECKING(for the BeOS)
 682 case $host in
 683   *-*-beos*)
 684     AC_MSG_RESULT(yes)
 685     MATH_LIB=
 686   ;;
 687   *)
 688     AC_MSG_RESULT(no)
 689   ;;
 690 esac
 691
 692 AC_SUBST(MATH_LIB)
 693 #
 694 # see bug 162979
 695 #
 696 AC_MSG_CHECKING(for HP-UX)
 697 case $host_os in
 698   hpux9* | hpux10* | hpux11*)
 699     AC_MSG_RESULT(yes)
 700     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 701   ;;
 702   *)
 703     AC_MSG_RESULT(no)
 704   ;;
 705 esac
 706
 707 #
 708 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 709 #
 710
 711 AM_PATH_GLIB_2_0(glib_required_version, :,
 712   AC_MSG_ERROR([
 713 *** GLIB glib_required_version or better is required. The latest version of
 714 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 715   gobject gmodule-no-export)
 716
 717 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 718 dnl
 719 gtk_save_LIBS=$LIBS
 720 LIBS="$LIBS $GLIB_LIBS"
 721 AC_CHECK_FUNCS(bind_textdomain_codeset)
 722 LIBS=$gtk_save_LIBS
 723
 724 AC_CHECK_HEADERS(pwd.h,
 725                  AC_DEFINE(HAVE_PWD_H, 1,
 726                            [Define to 1 if pwd.h is available]))
 727 AC_CHECK_HEADERS(sys/time.h,
 728                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 729                            [Define to 1 if time.h is available]))
 730 AC_CHECK_HEADERS(unistd.h,
 731                  AC_DEFINE(HAVE_UNISTD_H, 1,
 732                            [Define to 1 if unistd.h is available]))
 733 AC_CHECK_HEADERS(ftw.h,
 734                  AC_DEFINE(HAVE_FTW_H, 1,
 735                            [Define to 1 if ftw.h is available]))
 736
 737 AC_MSG_CHECKING([for GNU ftw extensions])
 738 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 739                                      #define _GNU_SOURCE
 740                                      #include <ftw.h>]],
 741                                    [[int flags = FTW_ACTIONRETVAL;]])],
 742                   [gtk_ok=yes],[gtk_ok=no])
 743 if test $gtk_ok = yes; then
 744     AC_MSG_RESULT([yes])
 745     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 746 else
 747     AC_MSG_RESULT([no])
 748 fi
 749
 750 #
 751 # Disable deprecation checks for all libraries we depend on on stable branches.
 752 # This is so newer versions of those libraries don't cause more warnings with
 753 # a stable GTK version.
 754 # We don't ever want to turn off deprecation warnings for master however, because
 755 # that's where we get rid of deprecated API we use.
 756 #
 757 if test m4_eval(gtk_minor_version % 2) = 0 ; then
 758   AC_DEFINE_UNQUOTED(GLIB_DISABLE_DEPRECATION_WARNINGS, 1,
 759                      [Disable deprecation warnings from glib])
 760 fi
 761
 762 dnl
 763 saved_cflags="$CFLAGS"
 764 saved_ldflags="$LDFLAGS"
 765
 766
 767 # Checks for library functions.
 768 AC_FUNC_MMAP
 769
 770 AC_CHECK_FUNCS(mallinfo)
 771 AC_CHECK_FUNCS(getresuid)
 772 AC_TYPE_UID_T
 773
 774 # Check for round(), rint(), isnan(), isinf() and nearbyint()
 775 AC_CHECK_LIB(m,round,,)
 776 AC_CHECK_FUNCS(round rint nearbyint)
 777 AC_CHECK_DECLS([isnan, isinf], [], [], [[#include <math.h>]])
 778
 779 # Checks for gdkspawn
 780 AC_CHECK_HEADERS(crt_externs.h)
 781 AC_CHECK_FUNCS(_NSGetEnviron)
 782
 783 AC_MSG_CHECKING(whether to build dynamic modules)
 784
 785 AC_ARG_ENABLE(modules,
 786               [AS_HELP_STRING([--disable-modules],
 787                               [disable dynamic module loading])])
 788
 789 dynworks=false
 790 build_dynamic_modules=no
 791 deps=
 792 if test x$enable_modules = xno; then
 793     AC_MSG_RESULT(no)
 794 else
 795     AC_MSG_RESULT(yes)
 796     AC_MSG_CHECKING(whether dynamic modules work)
 797     ## for loop is to strip newline
 798     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 799     for I in $tmp; do
 800         dynworks=$I
 801     done
 802
 803     dnl Now we check to see if our libtool supports shared lib deps
 804     dnl (in a rather ugly way even)
 805     if $dynworks; then
 806         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 807         module_deplibs_check=`$module_libtool_config | \
 808             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 809             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 810         if test "x$module_deplibs_check" = "xnone" || \
 811            test "x$module_deplibs_check" = "xunknown" || \
 812            test "x$module_deplibs_check" = "x"; then
 813             dynworks=false
 814         fi
 815     fi
 816
 817     if $dynworks; then
 818         build_dynamic_modules=yes
 819         AC_DEFINE(USE_GMODULE, 1,
 820                   [Define to 1 if gmodule works and should be used])
 821         AC_MSG_RESULT(yes)
 822     else
 823         build_dynamic_modules=no
 824         AC_MSG_RESULT(no)
 825     fi
 826 fi
 827
 828 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 829
 830 #
 831 # Allow building some or all immodules included
 832 #
 833 AC_MSG_CHECKING(immodules to build)
 834
 835 AC_ARG_WITH(included_immodules,
 836             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 837                             [build the specified input methods into gtk])])
 838
 839 if $dynworks; then
 840    :
 841 else
 842    ## if the option was specified, leave it; otherwise disable included immodules
 843    if test x$with_included_immodules = xno; then
 844            with_included_immodules=yes
 845    fi
 846 fi
 847
 848 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 849
 850 included_immodules=""
 851 # If the switch specified without listing any specific ones, include all
 852 if test "x$with_included_immodules" = xyes ; then
 853   included_immodules="$all_immodules"
 854 else
 855   included_immodules="$with_included_immodules"
 856 fi
 857
 858 AC_MSG_RESULT($included_immodules)
 859 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 860
 861 INCLUDED_IMMODULE_OBJ=
 862 INCLUDED_IMMODULE_DEFINE=
 863
 864 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 865 for immodule in $included_immodules; do
 866  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 867  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 868    :
 869  else
 870    AC_MSG_ERROR([the specified input method $immodule does not exist])
 871  fi
 872
 873  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 874  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 875  eval INCLUDE_$immodule_underscores=yes
 876 done
 877 IFS="$gtk_save_ifs"
 878 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 879 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 880
 881 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 882 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 883 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 884 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 885 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 886 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 887 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 888 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 889 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 890 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 891 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 892 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 893
 894 # Checks to see whether we should include mediaLib
 895 # support.
 896 #
 897 AC_CHECK_HEADER(sys/systeminfo.h,
 898                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 899                           [Define to 1 if sys/systeminfo.h is available]))
 900 AC_CHECK_HEADER(sys/sysinfo.h,
 901                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 902                           [Define to 1 if sys/sysinfo.h is available]))
 903
 904 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 905
 906 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 907
 908 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 909   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 910   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 911     REBUILD_PNGS=#
 912   fi
 913 fi
 914
 915 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 916
 917 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 918
 919 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 920    test "x$REBUILD_PNGS" = "x#" ; then
 921      AC_MSG_ERROR([
 922 *** gtkbuiltincache.h is not in the tree, and cannot be built
 923 *** because you don't have libpng, or (when cross-compiling) you
 924 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 925 fi
 926
 927 ########################################
 928 # Windowing system checks
 929 ########################################
 930
 931 # GTK+ uses some X calls, so needs to link against X directly
 932 GTK_DEP_PACKAGES_FOR_X=
 933 GTK_DEP_LIBS_FOR_X=
 934 X_EXTENSIONS=
 935
 936 if test "x$enable_x11_backend" = xyes; then
 937   X_PACKAGES=fontconfig
 938
 939   #
 940   # We use fontconfig very peripherally when decoding the default
 941   # settings.
 942   #
 943   if $PKG_CONFIG --exists fontconfig; then : ; else
 944     AC_MSG_ERROR([
 945 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 946   fi
 947
 948   #
 949   # Check for basic X packages; we use pkg-config if available
 950   #
 951   if $PKG_CONFIG --exists x11 xext; then
 952     have_base_x_pc=true
 953     X_PACKAGES="$X_PACKAGES x11 xext"
 954     x_libs="`$PKG_CONFIG --libs x11 xext`"
 955     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 956
 957     # Strip out any .la files that pkg-config might give us (this happens
 958     # with -uninstalled.pc files)
 959     x_libs_for_checks=
 960     for I in $x_libs ; do
 961       case $I in
 962         *.la) ;;
 963         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 964       esac
 965     done
 966
 967     GTK_PACKAGES_FOR_X="x11"
 968   else
 969     have_base_x_pc=false
 970     AC_PATH_XTRA
 971     if test x$no_x = xyes ; then
 972       AC_MSG_ERROR([X development libraries not found])
 973     fi
 974
 975     x_cflags="$X_CFLAGS"
 976     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 977
 978     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 979   fi
 980
 981   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 982   x_extra_libs=
 983
 984   gtk_save_cppflags="$CPPFLAGS"
 985   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 986
 987   gtk_save_LIBS=$LIBS
 988   LIBS="$x_libs_for_checks $LIBS"
 989
 990   # Sanity check for the X11 and Xext libraries. While everything we need from
 991   # Xext is optional, the chances a system has *none* of these things is so
 992   # small that we just unconditionally require it.
 993   AC_CHECK_FUNC(XOpenDisplay, :,
 994                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 995   AC_CHECK_FUNC(XextFindDisplay, :,
 996                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 997
 998   # Check for xReply
 999
1000   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
1001   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
1002                                      [[xReply *rep = NULL;
1003                                        rep = rep;]])],
1004                     [AC_MSG_RESULT([no])],
1005                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
1006                                                           #include <X11/Xlibint.h>]],
1007                                                         [[xReply *rep = NULL;
1008                                                           rep = rep;]])],
1009                                        [AC_MSG_RESULT([yes])
1010                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
1011                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
1012                                        [AC_MSG_RESULT([unknown])
1013                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1014
1015   # Check for XKB support.
1016
1017   if test "x$enable_xkb" = "xyes"; then
1018         AC_CHECK_FUNC(XkbQueryExtension,
1019                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1020                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1021                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1022   elif test "x$enable_xkb" = "xmaybe"; then
1023         AC_CHECK_FUNC(XkbQueryExtension,
1024                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1025                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1026   else
1027         AC_MSG_WARN(XKB support explicitly disabled)
1028   fi
1029
1030   # Check for shaped window extension
1031
1032   AC_CHECK_FUNC(XShapeCombineMask, :,
1033      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1034
1035   # X SYNC check
1036   gtk_save_CFLAGS="$CFLAGS"
1037   CFLAGS="$CFLAGS $x_cflags"
1038
1039   AC_CHECK_FUNC(XSyncQueryExtension,
1040       [AC_CHECK_HEADER(X11/extensions/sync.h,
1041           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1042           :, [#include <X11/Xlib.h>])])
1043
1044   CFLAGS="$gtk_save_CFLAGS"
1045
1046   if test "x$enable_xinerama" != "xno"; then
1047     # Check for Xinerama extension (Solaris impl or Xfree impl)
1048     have_xfree_xinerama=false
1049     have_solaris_xinerama=false
1050
1051     gtk_save_cppflags="$CPPFLAGS"
1052     CPPFLAGS="$CPPFLAGS $x_cflags"
1053
1054     # Check for XFree
1055     AC_MSG_CHECKING(for Xinerama packages)
1056
1057     if $PKG_CONFIG --exists xinerama ; then
1058        AC_MSG_RESULT(yes)
1059        have_xfree_xinerama=true
1060        X_PACKAGES="$X_PACKAGES xinerama"
1061     else
1062        AC_MSG_RESULT(no)
1063        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1064            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1065            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1066            have_xfree_xinerama=true], :,
1067            [#include <X11/Xlib.h>])])
1068     fi
1069
1070     if $have_xfree_xinerama ; then
1071       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1072       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1073                 [Define to 1 if XFree Xinerama is available])
1074       AC_DEFINE(HAVE_XINERAMA, 1,
1075                 [Define to 1 is Xinerama is available])
1076     else
1077       case "$host" in
1078         *-*-solaris*)
1079             # Check for solaris
1080             AC_MSG_CHECKING(for Xinerama support on Solaris)
1081
1082             have_solaris_xinerama=false
1083             AC_CHECK_FUNC(XineramaGetInfo,
1084                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1085                     [have_solaris_xinerama=true], :,
1086                     [#include <X11/Xlib.h>])])
1087
1088             if $have_solaris_xinerama ; then
1089               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1090               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1091                         [Define to 1 if solaris xinerama is available])
1092               AC_DEFINE(HAVE_XINERAMA, 1,
1093                         [Define to 1 if xinerama is available])
1094               AC_MSG_RESULT(yes)
1095             else
1096               AC_MSG_RESULT(no)
1097             fi
1098             ;;
1099         *)
1100             ;;
1101       esac
1102     fi
1103   fi
1104   if test "x$enable_xinerama" = "xyes" ; then
1105     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1106       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1107     fi
1108   fi
1109
1110   # Check for XGetEventData for GenericEvents
1111   AC_CHECK_FUNC(XGetEventData,
1112                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1113
1114   # set up things for XInput
1115   if $PKG_CONFIG --exists "xi" ; then
1116
1117     X_PACKAGES="$X_PACKAGES xi"
1118     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xi"
1119
1120     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1121                     have_xinput2=yes
1122                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1123
1124     gtk_save_LIBS="$LIBS"
1125     LIBS="$LIBS -lXi"
1126
1127     # Note that we also check that the XIScrollClassInfo struct is defined,
1128     # because at least Ubuntu Oneiric seems to have XIAllowTouchEvents(), but not the XIScrollClassInfo struct.
1129     AC_CHECK_FUNC([XIAllowTouchEvents],
1130       [AC_CHECK_MEMBER([XIScrollClassInfo.number],
1131                        have_xinput2_2=yes
1132                        AC_DEFINE(XINPUT_2_2, 1, [Define to 1 if XInput 2.2 is available]),
1133                        have_xinput2_2=no,
1134                        [[#include <X11/extensions/XInput2.h>]])])
1135     LIBS="$gtk_save_LIBS"
1136
1137     if test "x$have_xinput2_2" = "xyes"; then
1138       X_EXTENSIONS="$X_EXTENSIONS XI2.2"
1139     else
1140       X_EXTENSIONS="$X_EXTENSIONS XI2"
1141     fi
1142   fi
1143
1144   AS_IF([test "x$have_xinput2" != "xyes"],
1145         [AC_MSG_ERROR([*** XInput2 extension not found. Check 'config.log' for more details.])])
1146
1147   # Check for the RANDR extension
1148   if test x"$enable_xrandr" != xno; then
1149     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1150       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1151
1152       X_PACKAGES="$X_PACKAGES xrandr"
1153       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1154     elif test x"$enable_xrandr" = xyes; then
1155       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1156     fi
1157   fi
1158
1159   # Checks for Xcursor library
1160
1161   if $PKG_CONFIG --exists xcursor ; then
1162     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1163
1164     X_PACKAGES="$X_PACKAGES xcursor"
1165   fi
1166
1167   # Checks for XFixes extension
1168
1169   if test x"$enable_xfixes" != xno; then
1170     if $PKG_CONFIG --exists xfixes ; then
1171       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1172
1173       X_PACKAGES="$X_PACKAGES xfixes"
1174       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1175       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1176     elif test x"$enable_xfixes" = xyes; then
1177       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1178     fi
1179   fi
1180
1181   # Checks for Xcomposite extension
1182
1183   if test x"$enable_xcomposite" != xno; then
1184     if $PKG_CONFIG --exists xcomposite ; then
1185       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1186
1187       X_PACKAGES="$X_PACKAGES xcomposite"
1188       X_EXTENSIONS="$X_EXTENSIONS Composite"
1189       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1190     elif test x"$enable_xcomposite" = xyes; then
1191       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1192     fi
1193   fi
1194
1195   # Checks for Xdamage extension
1196
1197   if test x"$enable_xdamage" != xno; then
1198     if $PKG_CONFIG --exists xdamage ; then
1199       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1200
1201       X_PACKAGES="$X_PACKAGES xdamage"
1202       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1203       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1204     elif test x"$enable_xdamage" = xyes; then
1205       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1206     fi
1207   fi
1208
1209   if $have_base_x_pc ; then
1210     GDK_EXTRA_LIBS="$x_extra_libs"
1211   else
1212     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1213   fi
1214
1215   CPPFLAGS="$gtk_save_cppflags"
1216   LIBS="$gtk_save_libs"
1217
1218   AM_CONDITIONAL(USE_X11, true)
1219
1220   # strip leading space
1221   X_EXTENSIONS=${X_EXTENSIONS#* }
1222
1223 else
1224   XPACKAGES=
1225
1226   AM_CONDITIONAL(USE_X11, false)
1227 fi
1228
1229 # Check for gio-unix
1230 if test "$have_gio_unix" = "yes"; then
1231   GDK_GIO_PACKAGE=gio-unix-2.0
1232   AC_DEFINE([HAVE_GIO_UNIX], [1],
1233             [Define if gio-unix is available])
1234 else
1235   GDK_GIO_PACKAGE=gio-2.0
1236 fi
1237
1238 # Check for Pango flags
1239
1240 AC_MSG_CHECKING(Pango flags)
1241 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1242         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1243         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1244
1245         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1246 else
1247         AC_MSG_ERROR([
1248 *** Pango not found. Pango built with Cairo support is required
1249 *** to build GTK+. See http://www.pango.org for Pango information.
1250 ])
1251 fi
1252
1253 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1254
1255 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1256         :
1257 else
1258         gtk_save_LIBS="$LIBS"
1259         LIBS="$PANGO_LIBS $LIBS"
1260         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1261 *** Can't link to Pango. Pango is required to build
1262 *** GTK+. For more information see http://www.pango.org]))
1263         LIBS="$gtk_save_LIBS"
1264 fi
1265
1266 CFLAGS="$saved_cflags"
1267 LDFLAGS="$saved_ldflags"
1268
1269 GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo cairo-gobject"
1270 GDK_PRIVATE_PACKAGES="$GDK_GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES $cairo_backends"
1271 if test "x$enable_x11_backend" = xyes; then
1272   GDK_PRIVATE_PACKAGES="$GDK_PRIVATE_PACKAGES pangoft2"
1273 fi
1274
1275 PKG_CHECK_MODULES(GDK_DEP, $GDK_PACKAGES $GDK_PRIVATE_PACKAGES)
1276 GDK_DEP_LIBS="$GDK_EXTRA_LIBS $GDK_DEP_LIBS $MATH_LIB"
1277 GDK_DEP_CFLAGS="$GDK_DEP_CFLAGS $GDK_EXTRA_CFLAGS"
1278 #
1279 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1280 # into the pkg-config files
1281 #
1282 if test $enable_explicit_deps != yes ; then
1283   GDK_EXTRA_LIBS=
1284 fi
1285
1286 AC_SUBST(GDK_PACKAGES)
1287 AC_SUBST(GDK_PRIVATE_PACKAGES)
1288 AC_SUBST(GDK_EXTRA_LIBS)
1289 AC_SUBST(GDK_EXTRA_CFLAGS)
1290 AC_SUBST(GDK_DEP_LIBS)
1291 AC_SUBST(GDK_DEP_CFLAGS)
1292
1293
1294 ########################################
1295 # Check for Accessibility Toolkit flags
1296 ########################################
1297
1298 if test x$enable_x11_backend = xyes; then
1299    ATK_PACKAGES="atk atk-bridge-2.0"
1300 else
1301    ATK_PACKAGES="atk"
1302 fi
1303
1304 PKG_CHECK_MODULES(ATK, $ATK_PACKAGES)
1305
1306 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1307 GTK_PRIVATE_PACKAGES="$ATK_PACKAGES"
1308 if test "x$enable_x11_backend" = xyes; then
1309   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES pangoft2"
1310 fi
1311 if test "$have_gio_unix" = "yes"; then
1312   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES gio-unix-2.0"
1313 fi
1314 GTK_EXTRA_LIBS=
1315
1316 GTK_EXTRA_CFLAGS=
1317 PKG_CHECK_MODULES(GTK_DEP, $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES $GTK_PRIVATE_PACKAGES)
1318 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X $GTK_DEP_LIBS $GTK_EXTRA_LIBS $MATH_LIB"
1319 GTK_DEP_CFLAGS="$GTK_DEP_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1320
1321 if test x"$os_win32" = xyes; then
1322   GTK_EXTRA_CFLAGS="$msnative_struct"
1323 fi
1324
1325 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1326 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1327 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1328 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1329
1330 AC_SUBST(GTK_PACKAGES)
1331 AC_SUBST(GTK_PRIVATE_PACKAGES)
1332 AC_SUBST(GTK_EXTRA_LIBS)
1333 AC_SUBST(GTK_EXTRA_CFLAGS)
1334 AC_SUBST(GTK_DEP_LIBS)
1335 AC_SUBST(GTK_DEP_CFLAGS)
1336
1337 AC_SUBST(GLIB_PREFIX)
1338 AC_SUBST(ATK_PREFIX)
1339 AC_SUBST(PANGO_PREFIX)
1340 AC_SUBST(CAIRO_PREFIX)
1341
1342 AC_SUBST(GTK_DEBUG_FLAGS)
1343 AC_SUBST(GTK_XIM_FLAGS)
1344
1345 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1346 AC_SUBST(GDK_PIXBUF_LIBS)
1347
1348 ########################
1349 # Checks needed for gail
1350 ########################
1351
1352 old_LIBS="$LIBS"
1353 dnl Checks for inet libraries:
1354 AC_SEARCH_LIBS(gethostent, nsl)
1355 AC_SEARCH_LIBS(setsockopt, socket)
1356 AC_SEARCH_LIBS(connect, inet)
1357
1358 dnl check for the sockaddr_un.sun_len member
1359 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1360                 [struct_sockaddr_un_sun_len=true],
1361                 [struct_sockaddr_un_suin_len=false],
1362                 [#include <sys/types.h>
1363                  #include <sys/un.h>]
1364                 )
1365 case $struct_sockaddr_un_sun_len in
1366         true)
1367                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1368                                    [Have the sockaddr_un.sun_len member])
1369                 ;;
1370         *)
1371                 ;;
1372 esac
1373
1374 GAIL_INET_LIBS="$LIBS"
1375 AC_SUBST([GAIL_INET_LIBS])
1376
1377 LIBS="$old_LIBS"
1378
1379 ################################################################
1380 # Printing system checks
1381 ################################################################
1382
1383 PRINT_BACKENDS="file lpr"
1384
1385 AC_ARG_ENABLE(cups,
1386               [AS_HELP_STRING([--disable-cups],
1387                               [disable cups print backend])],,
1388               [enable_cups=auto])
1389
1390 if test "x$enable_cups" = "xno"; then
1391   AM_CONDITIONAL(HAVE_CUPS, false)
1392 else
1393   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1394   if test "x$CUPS_CONFIG" = "xno"; then
1395     if test "x$enable_cups" = "xauto"; then
1396       AM_CONDITIONAL(HAVE_CUPS, false)
1397     else
1398       AC_MSG_ERROR([
1399 *** cups not found.
1400 ])
1401     fi
1402   else
1403     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1404     CUPS_LIBS=`$CUPS_CONFIG --libs`
1405
1406     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1407     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1408     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1409
1410     if test $CUPS_API_MAJOR -gt 1 -o \
1411             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -lt 2; then
1412       AC_MSG_ERROR([CUPS >= 1.2 not found])
1413     fi
1414     if test $CUPS_API_MAJOR -gt 1 -o \
1415             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 6; then
1416       AC_DEFINE(HAVE_CUPS_API_1_6, 1,
1417                 [Define to 1 if CUPS 1.6 API is available])
1418
1419     fi
1420
1421     AC_SUBST(CUPS_API_MAJOR)
1422     AC_SUBST(CUPS_API_MINOR)
1423     AC_SUBST(CUPS_CFLAGS)
1424     AC_SUBST(CUPS_LIBS)
1425
1426     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1427
1428     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1429     AM_CONDITIONAL(HAVE_CUPS, true)
1430
1431     gtk_save_cflags="$CFLAGS"
1432     CFLAGS="$CUPS_CFLAGS"
1433     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1434                                        [[http_t http; char *s = http.authstring;]])],
1435                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1436                                  [Define if cups http_t authstring field is accessible])],
1437                       [])
1438     CFLAGS="$gtk_save_cflags"
1439
1440     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1441
1442     gtk_save_libs="$LIBS"
1443     LIBS="$CUPS_LIBS"
1444     AC_CHECK_FUNCS(httpGetAuthString)
1445     LIBS="$gtk_save_libs"
1446   fi
1447 fi
1448
1449 # Checks to see if we should compile with PAPI backend for GTK+
1450 #
1451
1452 AC_ARG_ENABLE(papi,
1453               [AS_HELP_STRING([--disable-papi],
1454                               [disable papi print backend])],,
1455               [enable_papi=auto])
1456
1457 if test "x$enable_papi" = "xno"; then
1458   AM_CONDITIONAL(HAVE_PAPI, false)
1459 else
1460   AC_MSG_CHECKING(libpapi)
1461   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1462   if test $have_papi = yes; then
1463     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1464     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1465   fi
1466   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1467   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1468     AC_MSG_ERROR([
1469 *** papi not found.
1470 ])
1471   fi
1472 fi
1473
1474 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1475
1476 gtk_save_cppflags="$CPPFLAGS"
1477 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1478
1479 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1480 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1481 *** backend enabled.]))
1482
1483 if test "$os_win32" != "yes"; then
1484   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1485 *** Can't find cairo-ps.h. You must build Cairo with the
1486 *** postscript backend enabled.]))
1487
1488   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1489 *** Cannot find cairo-svg.h. You must build Cairo with the
1490 *** svg backend enabled.]))
1491 fi
1492
1493 CPPFLAGS="$gtk_save_cppflags"
1494
1495
1496 AC_ARG_ENABLE(test-print-backend,
1497               [AS_HELP_STRING([--enable-test-print-backend],
1498                               [build test print backend])],,
1499               [enable_test_print_backend=no])
1500 if test "x$enable_test_print_backend" != "xno" ; then
1501   PRINT_BACKENDS="$PRINT_BACKENDS test"
1502 fi
1503 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1504
1505 if test "$os_win32" = "yes"; then
1506   AC_CHECK_TYPES([IPrintDialogCallback],[],[],[[#include <windows.h>]])
1507 fi
1508
1509 ################################################################
1510 # Strip -export-dynamic from the link lines of various libraries
1511 ################################################################
1512
1513 #
1514 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1515 #  but this flag is only meaningful for executables. For libraries
1516 #  the effect is undefined; what it causes on Linux is that the
1517 #  export list from -export-symbols-regex is ignored and everything
1518 #  is exported
1519 #
1520 # We are using gmodule-no-export now, but I'm leaving the stripping
1521 # code in place for now, since pango and atk still require gmodule.
1522 export SED
1523 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1524 if test -n "$export_dynamic"; then
1525   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1526   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1527 fi
1528
1529 #############
1530 # GSettings #
1531 #############
1532
1533 GLIB_GSETTINGS
1534
1535 ##################################################
1536 # GObject introspection
1537 ##################################################
1538
1539 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1540
1541 ##################################################
1542 # Packagekit module
1543 #################################################
1544
1545 AC_ARG_ENABLE(packagekit,
1546               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1547                               [build PackageKit open-with module [default=auto]])],
1548               [enable_packagekit="$enableval"],
1549               [enable_packagekit=auto])
1550 if test "$enable_packagekit" = "auto"; then
1551   if test "$os_win32" = "yes"; then
1552     enable_packagekit=no
1553   else
1554     enable_packagekit=yes
1555   fi
1556 fi
1557
1558 AC_MSG_CHECKING([whether to use PackageKit])
1559 build_packagekit=no
1560 if test "x$enable_packagekit" != "xno"; then
1561   if test "$os_win32" != "yes"; then
1562     build_packagekit=yes
1563     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1564   else
1565     AC_MSG_ERROR([packagekit support is not available on win32])
1566   fi
1567 fi
1568 AC_MSG_RESULT([$build_packagekit])
1569
1570 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1571
1572 ##################################################
1573 # colord module
1574 #################################################
1575
1576 AC_ARG_ENABLE(colord,
1577               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1578                               [build colord support code [default=auto]])],
1579               [enable_colord="$enableval"],
1580               [enable_colord=auto])
1581
1582 AC_MSG_CHECKING([whether to use colord])
1583 if test "$enable_colord" = "auto"; then
1584   if test "$os_win32" = "yes"; then
1585     enable_colord=no
1586   fi
1587 fi
1588 if test "$enable_colord" != "no"; then
1589   AC_MSG_RESULT([yes])
1590 else
1591   AC_MSG_RESULT([no])
1592 fi
1593
1594 have_colord=no
1595 if test "$enable_colord" != "no"; then
1596         if test "$os_win32" != "yes"; then
1597                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1598                                   have_colord=yes, have_colord=no)
1599                 if test "$enable_colord" = "yes"; then
1600                         if test "$have_colord" = "no"; then
1601                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1602                         fi
1603                 fi
1604         else
1605                 AC_MSG_ERROR([colord support is not available on win32])
1606         fi
1607 fi
1608
1609 if test "$have_colord" = "yes"; then
1610         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1611 fi
1612 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1613
1614 ##################################################
1615 # Checks for gtk-doc and docbook-tools
1616 ##################################################
1617
1618 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1619
1620 AC_ARG_ENABLE(man,
1621               [AS_HELP_STRING([--enable-man],
1622                               [generate man pages [default=auto]])],,
1623               enable_man=maybe)
1624
1625 if test "$enable_man" != no; then
1626   AC_PATH_PROG([XSLTPROC], [xsltproc])
1627   if test -z "$XSLTPROC"; then
1628     if test "$enable_man" = yes ; then
1629       AC_MSG_ERROR([xsltproc is required for --enable-man])
1630     fi
1631     enable_man=no
1632   fi
1633 fi
1634
1635 if test "$enable_man" != no; then
1636   dnl check for DocBook DTD in the local catalog
1637   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1638      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
1639   if test "$have_docbook_dtd" != yes; then
1640     if test "$enable_man" = yes ; then
1641       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
1642     fi
1643     enable_man=no
1644   fi
1645 fi
1646
1647 if test "$enable_man" != no; then
1648   dnl check for DocBook XSL stylesheets in the local catalog
1649   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1650      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
1651   if test "$have_docbook_dtd" != yes; then
1652     if test "$enable_man" = yes ; then
1653       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
1654     fi
1655     enable_man=no
1656   fi
1657 fi
1658
1659 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
1660
1661 AC_MSG_CHECKING([whether to generate man pages])
1662 if test "$enable_man" != no; then
1663   AC_MSG_RESULT([yes])
1664 else
1665   AC_MSG_RESULT([no])
1666 fi
1667
1668 ##################################################
1669 # Output commands
1670 ##################################################
1671
1672 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1673         outfile=gdkconfig.h-tmp
1674         cat > $outfile <<\_______EOF
1675 /* gdkconfig.h
1676  *
1677  * This is a generated file.  Please modify `configure.ac'
1678  */
1679
1680 #ifndef __GDKCONFIG_H__
1681 #define __GDKCONFIG_H__
1682
1683 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1684 #error "Only <gdk/gdk.h> can be included directly."
1685 #endif
1686
1687 #include <glib.h>
1688
1689 G_BEGIN_DECLS
1690
1691 _______EOF
1692
1693         cat >>$outfile <<_______EOF
1694 $gdk_windowing
1695 _______EOF
1696
1697         cat >>$outfile <<_______EOF
1698
1699 G_END_DECLS
1700
1701 #endif  /* __GDKCONFIG_H__ */
1702 _______EOF
1703
1704
1705         if cmp -s $outfile gdk/gdkconfig.h; then
1706           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1707           rm -f $outfile
1708         else
1709           mv $outfile gdk/gdkconfig.h
1710         fi
1711 ],[
1712 gdk_windowing='$GDK_WINDOWING'
1713 ])
1714
1715 dnl
1716 dnl Check for -Bsymbolic-functions linker flag used to avoid
1717 dnl intra-library PLT jumps, if available.
1718 dnl
1719 AC_ARG_ENABLE(Bsymbolic,
1720               [AS_HELP_STRING([--disable-Bsymbolic],
1721                               [avoid linking with -Bsymbolic])],,
1722               [SAVED_LDFLAGS="${LDFLAGS}"
1723                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1724                LDFLAGS=-Wl,-Bsymbolic-functions
1725                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1726                                                [[int main (void) { return 0; }]])],
1727                               [AC_MSG_RESULT(yes)
1728                                enable_Bsymbolic=yes],
1729                               [AC_MSG_RESULT(no)
1730                                enable_Bsymbolic=no])
1731                LDFLAGS="${SAVED_LDFLAGS}"])
1732
1733 if test "x${enable_Bsymbolic}" = "xyes" ; then
1734   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1735 fi
1736 AC_SUBST(GTK_LINK_FLAGS)
1737
1738 AC_CONFIG_FILES([
1739 config.h.win32
1740 gtk-zip.sh
1741 Makefile
1742 gdk-3.0.pc
1743 gtk+-3.0.pc
1744 gtk+-unix-print-3.0.pc
1745 gail-3.0.pc
1746 m4macros/Makefile
1747 po/Makefile.in
1748 po-properties/Makefile.in
1749 demos/Makefile
1750 demos/gtk-demo/Makefile
1751 demos/gtk-demo/geninclude.pl
1752 demos/pixbuf-demo/Makefile
1753 demos/widget-factory/Makefile
1754 examples/Makefile
1755 tests/Makefile
1756 tests/a11y/Makefile
1757 tests/css/Makefile
1758 tests/css/parser/Makefile
1759 tests/reftests/Makefile
1760 tests/visuals/Makefile
1761 docs/Makefile
1762 docs/reference/Makefile
1763 docs/reference/gdk/Makefile
1764 docs/reference/gdk/version.xml
1765 docs/reference/gtk/Makefile
1766 docs/reference/gtk/gtk3.types
1767 docs/reference/gtk/version.xml
1768 docs/reference/libgail-util/Makefile
1769 docs/reference/libgail-util/version.xml
1770 docs/tools/Makefile
1771 build/Makefile
1772 build/win32/Makefile
1773 build/win32/vs9/Makefile
1774 build/win32/vs10/Makefile
1775 gdk/Makefile
1776 gdk/broadway/Makefile
1777 gdk/x11/Makefile
1778 gdk/win32/Makefile
1779 gdk/win32/rc/Makefile
1780 gdk/win32/rc/gdk.rc
1781 gdk/quartz/Makefile
1782 gdk/wayland/Makefile
1783 gdk/tests/Makefile
1784 gdk/gdkversionmacros.h
1785 gtk/Makefile
1786 gtk/makefile.msc
1787 gtk/gtkversion.h
1788 gtk/gtk-win32.rc
1789 gtk/a11y/Makefile
1790 gtk/tests/Makefile
1791 libgail-util/Makefile
1792 modules/Makefile
1793 modules/engines/Makefile
1794 modules/engines/pixbuf/Makefile
1795 modules/input/Makefile
1796 modules/printbackends/Makefile
1797 modules/printbackends/cups/Makefile
1798 modules/printbackends/lpr/Makefile
1799 modules/printbackends/file/Makefile
1800 modules/printbackends/papi/Makefile
1801 modules/printbackends/test/Makefile
1802 perf/Makefile
1803 ])
1804
1805 AC_OUTPUT
1806
1807 # beautify the immodule list a bit
1808 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1809 if test -z "${included_immodules}"; then included_immodules="none"; fi
1810
1811 echo ""
1812 echo "        GTK+ $GTK_VERSION"
1813 echo "        ==========="
1814 echo ""
1815 echo "        GDK backends:         $GDK_BACKENDS"
1816 if test "$enable_x11_backend" = "yes"; then
1817 echo "        X11 extensions:       $X_EXTENSIONS"
1818 fi
1819 echo "        Print backends:       $PRINT_BACKENDS"
1820 echo "        Dynamic modules:      $build_dynamic_modules"
1821 echo "        Included immodules:   $included_immodules"
1822 echo "        PackageKit support:   $build_packagekit"
1823 echo "        colord support:       $have_colord"
1824 echo "        Introspection:        $found_introspection"
1825 echo "        Debugging:            $enable_debug"
1826 echo "        Documentation:        $enable_gtk_doc"