Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [5])
  13 m4_define([gtk_micro_version], [3])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.33.1])
  43 m4_define([pango_required_version], [1.30.0])
  44 m4_define([atk_required_version], [2.2.0])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.26.0])
  47 m4_define([introspection_required_version], [1.32.0])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_INSTALL
 129 AC_PROG_MAKE_SET
 130
 131
 132 GETTEXT_PACKAGE=gtk30
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 135                    [The prefix for our gettext translation domains.])
 136
 137 AC_CANONICAL_HOST
 138
 139 MATH_LIB=-lm
 140 AC_MSG_CHECKING([for native Win32])
 141 LIB_EXE_MACHINE_FLAG=X86
 142 EXE_MANIFEST_ARCHITECTURE=X86
 143 DISABLE_ON_W32=''
 144 case "$host" in
 145   *-*-mingw*)
 146     dnl Comment-out certain gtk3.types.in lines
 147     DISABLE_ON_W32='%'
 148     os_win32=yes
 149     gio_can_sniff=no
 150     MATH_LIB=
 151     case "$host" in
 152     x86_64-*-*)
 153       LIB_EXE_MACHINE_FLAG=X64
 154       EXE_MANIFEST_ARCHITECTURE=AMD64
 155       ;;
 156     esac
 157     ;;
 158   *)
 159     os_win32=no
 160     ;;
 161 esac
 162 AC_MSG_RESULT([$os_win32])
 163
 164 AC_SUBST(DISABLE_ON_W32)
 165 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 166 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 167
 168 case $host in
 169   *-*-linux*)
 170     os_linux=yes
 171     ;;
 172 esac
 173
 174 dnl
 175 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 176 dnl We use this for an automated test for C++ header correctness.
 177 dnl
 178 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 179 AC_LANG_PUSH([C++])
 180
 181 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 182                                    [[class a { int b; } c;]])],
 183                   [],[CXX=])
 184 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 185
 186 gtk_save_cxxflags="$CXXFLAGS"
 187 CXXFLAGS="$CXXFLAGS -x objective-c++"
 188 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 189                                    [[]])],
 190                   [OBJC=yes],[OBJC=no])
 191 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 192 CXXFLAGS="$gtk_save_cxxflags"
 193 AC_LANG_POP([C++])
 194
 195 if test "$os_win32" = "yes"; then
 196   if test x$enable_static = xyes -o x$enable_static = x; then
 197     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 198     enable_static=no
 199   fi
 200   if test x$enable_shared = xno; then
 201     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 202   fi
 203   enable_shared=yes
 204 fi
 205
 206 dnl Initialize libtool
 207 LT_PREREQ([2.2.6])
 208 LT_INIT([disable-static win32-dll])
 209 # Create libtool early, because it's used in configure
 210 LT_OUTPUT
 211
 212 # Make sure we use 64-bit versions of various file stuff.
 213 AC_SYS_LARGEFILE
 214
 215 AM_PROG_AS
 216 AC_PATH_PROG(NM, nm, nm)
 217
 218 AC_MSG_CHECKING([for some Win32 platform])
 219 case "$host" in
 220   *-*-mingw*|*-*-cygwin*)
 221     platform_win32=yes
 222     ;;
 223   *)
 224     platform_win32=no
 225     ;;
 226 esac
 227 AC_MSG_RESULT([$platform_win32])
 228 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 229
 230 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 231 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 232 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 233
 234 if test "$os_win32" = "yes"; then
 235   AC_CHECK_TOOL(WINDRES, windres, no)
 236   if test "$WINDRES" = no; then
 237     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 238   fi
 239   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 240 fi
 241 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 242
 243 m4_define([debug_default],
 244           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 245
 246 dnl declare --enable-* args and collect ac_help strings
 247 AC_ARG_ENABLE(debug,
 248               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 249                               [turn on debugging @<:@default=debug_default@:>@])],,
 250               [enable_debug=debug_default])
 251
 252 AC_ARG_ENABLE(rebuilds,
 253               [AS_HELP_STRING([--disable-rebuilds],
 254                               [disable all source autogeneration rules])],,
 255               [enable_rebuilds=yes])
 256
 257 AC_ARG_ENABLE(gtk2-dependency,
 258               [AS_HELP_STRING([--enable-gtk2-dependency],
 259                               [Do not build gtk-update-icon-cache and other shared tools])],,
 260               [enable_gtk2_dependency=no])
 261
 262 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 263
 264 AC_ARG_ENABLE(xkb,
 265               [AS_HELP_STRING([--enable-xkb],
 266                               [support XKB extension [default=maybe]])],,
 267               [enable_xkb="maybe"])
 268 AC_ARG_ENABLE(xinerama,
 269               [AS_HELP_STRING([--enable-xinerama],
 270                               [support Xinerama extension [default=maybe]])],,
 271               [enable_xinerama="maybe"])
 272 AC_ARG_ENABLE(xrandr,
 273               [AS_HELP_STRING([--enable-xrandr],
 274                               [support XRandR extension [default=maybe]])],,
 275               [enable_xrandr="maybe"])
 276 AC_ARG_ENABLE(xfixes,
 277               [AS_HELP_STRING([--enable-xfixes],
 278                               [support XFixes extension [default=maybe]])],,
 279               [enable_xfixes="maybe"])
 280 AC_ARG_ENABLE(xcomposite,
 281               [AS_HELP_STRING([--enable-xcomposite],
 282                               [support X Composite extension [default=maybe]])],,
 283               [enable_xcomposite="maybe"])
 284 AC_ARG_ENABLE(xdamage,
 285               [AS_HELP_STRING([--enable-xdamage],
 286                               [support X Damage extension [default=maybe]])],,
 287               [enable_xdamage="maybe"])
 288
 289 AC_ARG_ENABLE(x11-backend,
 290               [AS_HELP_STRING([--enable-x11-backend],
 291                               [enable the X11 gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(win32-backend,
 294               [AS_HELP_STRING([--enable-win32-backend],
 295                               [enable the Win32 gdk backend])],
 296                               [backend_set=yes])
 297 AC_ARG_ENABLE(quartz-backend,
 298               [AS_HELP_STRING([--enable-quartz-backend],
 299                               [enable the quartz gdk backend])],
 300                               [backend_set=yes])
 301 AC_ARG_ENABLE(broadway-backend,
 302               [AS_HELP_STRING([--enable-broadway-backend],
 303                               [enable the broadway (HTML5) gdk backend])],
 304                               [backend_set=yes])
 305 AC_ARG_ENABLE(wayland-backend,
 306               [AS_HELP_STRING([--enable-wayland-backend],
 307                               [enable the wayland gdk backend])],
 308                               [backend_set=yes])
 309
 310 if test -z "$backend_set"; then
 311   if test "$platform_win32" = yes; then
 312     enable_win32_backend=yes
 313   else
 314     enable_x11_backend=yes
 315   fi
 316 fi
 317
 318 AC_ARG_ENABLE(quartz-relocation,
 319               [AS_HELP_STRING([--enable-quartz-relocation],
 320                               [enable bundle-based relocation functions])],
 321                               [quartz_relocation=yes])
 322
 323 AC_ARG_ENABLE(wayland-cairo-gl,
 324               AS_HELP_STRING([--enable-wayland-cairo-gl],
 325                              [enable the use of Cairo GL in the Wayland backend]),
 326               [enable_wayland_cairo_gl=yes])
 327
 328
 329 cairo_backends=
 330 backend_immodules=
 331 have_gio_unix=no
 332 GDK_BACKENDS=
 333 GDK_EXTRA_LIBS=
 334 GDK_EXTRA_CFLAGS=
 335 GDK_WINDOWING=
 336 PANGO_PACKAGES="pango pangocairo"
 337
 338 if test "$enable_x11_backend" = "yes"; then
 339   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 340   # backend names are identical.
 341   cairo_backends="$cairo_backends cairo-xlib"
 342   GDK_BACKENDS="$GDK_BACKENDS x11"
 343   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 344   # gdkapplaunchcontext-x11.c
 345   have_gio_unix=yes
 346   backend_immodules="$backend_immodules,xim"
 347   GDK_WINDOWING="$GDK_WINDOWING
 348 #define GDK_WINDOWING_X11"
 349 fi
 350
 351 if test "$enable_win32_backend" = "yes"; then
 352   cairo_backends="$cairo_backends cairo-win32"
 353   GDK_BACKENDS="$GDK_BACKENDS win32"
 354   backend_immodules="$backend_immodules,ime"
 355   GDK_WINDOWING="$GDK_WINDOWING
 356 #define GDK_WINDOWING_WIN32"
 357   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 358   AM_CONDITIONAL(USE_WIN32, true)
 359   PANGO_PACKAGES="pangowin32 pangocairo"
 360 else
 361   AM_CONDITIONAL(USE_WIN32, false)
 362 fi
 363
 364 if test "x$enable_quartz_backend" = xyes; then
 365   cairo_backends="$cairo_backends cairo-quartz"
 366   GDK_BACKENDS="$GDK_BACKENDS quartz"
 367   GDK_WINDOWING="$GDK_WINDOWING
 368 #define GDK_WINDOWING_QUARTZ"
 369   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 370   AM_CONDITIONAL(USE_QUARTZ, true)
 371   if test "x$quartz_relocation" = xyes; then
 372     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 373   fi
 374
 375 else
 376   AM_CONDITIONAL(USE_QUARTZ, false)
 377 fi
 378
 379
 380 if test "x$enable_broadway_backend" == xyes; then
 381   GDK_BACKENDS="$GDK_BACKENDS broadway"
 382   cairo_backends="$cairo_backends cairo"
 383   GDK_WINDOWING="$GDK_WINDOWING
 384 #define GDK_WINDOWING_BROADWAY"
 385   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 386   AM_CONDITIONAL(USE_BROADWAY, true)
 387 else
 388   AM_CONDITIONAL(USE_BROADWAY, false)
 389 fi
 390
 391 if test "x$enable_wayland_backend" == "xyes"; then
 392   if test "x$enable_wayland_cairo_gl" == "xyes"; then
 393     # Wayland can use cairo-gl
 394     cairo_backends="$cairo_backends cairo-gl"
 395     AC_DEFINE(GDK_WAYLAND_USE_EGL, [1], [Whether to use EGL in Wayland backend])
 396   else
 397     # For the cairo image backend
 398     cairo_backends="$cairo_backends cairo"
 399   fi
 400   GDK_BACKENDS="$GDK_BACKENDS wayland"
 401   have_gio_unix=yes
 402   GDK_WINDOWING="$GDK_WINDOWING
 403 #define GDK_WINDOWING_WAYLAND"
 404   WAYLAND_PACKAGES="wayland-client xkbcommon "
 405   if test "x$enable_wayland_cairo_gl" == "xyes"; then
 406     WAYLAND_PACKAGES="$WAYLAND_PACKAGES wayland-egl egl"
 407   fi
 408   AM_CONDITIONAL(USE_WAYLAND, true)
 409 else
 410   AM_CONDITIONAL(USE_WAYLAND, false)
 411 fi
 412
 413 # strip leading space
 414 GDK_BACKENDS=${GDK_BACKENDS#* }
 415
 416 AC_SUBST(GDK_BACKENDS)
 417
 418 if test -z "$GDK_BACKENDS"; then
 419   AC_MSG_ERROR([No GDK backends selected.])
 420 fi
 421
 422 if test "x$enable_debug" = "xyes"; then
 423   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 424   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 425 else
 426   if test "x$enable_debug" = "xno"; then
 427     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 428   else
 429     GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"
 430   fi
 431 fi
 432
 433
 434 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 435                    [Define if debugging is enabled])
 436
 437
 438 # Build time sanity check...
 439 AM_SANITY_CHECK
 440
 441 changequote(,)dnl
 442 if test "x$GCC" = "xyes"; then
 443   case " $CFLAGS " in
 444   *[\ \ ]-Wall[\ \      ]*) ;;
 445   *) CFLAGS="$CFLAGS -Wall" ;;
 446   esac
 447
 448   if test "x$enable_ansi" = "xyes"; then
 449     case " $CFLAGS " in
 450     *[\ \       ]-ansi[\ \      ]*) ;;
 451     *) CFLAGS="$CFLAGS -ansi" ;;
 452     esac
 453
 454     case " $CFLAGS " in
 455     *[\ \       ]-pedantic[\ \  ]*) ;;
 456     *) CFLAGS="$CFLAGS -pedantic" ;;
 457     esac
 458   fi
 459 fi
 460 changequote([,])dnl
 461
 462 # Ensure MSVC-compatible struct packing convention is used when
 463 # compiling for Win32 with gcc.
 464 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 465 # gcc2 uses "-fnative-struct".
 466 if test x"$os_win32" = xyes; then
 467   if test x"$GCC" = xyes; then
 468     msnative_struct=''
 469     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 470     if test -z "$ac_cv_prog_CC"; then
 471       our_gcc="$CC"
 472     else
 473       our_gcc="$ac_cv_prog_CC"
 474     fi
 475     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 476       2.)
 477         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 478           msnative_struct='-fnative-struct'
 479         fi
 480         ;;
 481       *)
 482         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 483           msnative_struct='-mms-bitfields'
 484         fi
 485         ;;
 486     esac
 487     if test x"$msnative_struct" = x ; then
 488       AC_MSG_RESULT([no way])
 489       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 490     else
 491       CFLAGS="$CFLAGS $msnative_struct"
 492       AC_MSG_RESULT([${msnative_struct}])
 493     fi
 494   fi
 495 fi
 496
 497 ## Initial sanity check, done here so that users get told they
 498 ## have the wrong dependencies as early in the process as possible.
 499 ## Later on we actually use the cflags/libs from separate pkg-config
 500 ## calls. Oh, also the later pkg-config calls don't include
 501 ## the version requirements since those make the module lists
 502 ## annoying to construct
 503 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 504   [glib-2.0 >= glib_required_version dnl
 505    atk >= atk_required_version dnl
 506    pango >= pango_required_version dnl
 507    cairo >= cairo_required_version dnl
 508    cairo-gobject >= cairo_required_version dnl
 509    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 510
 511 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 512
 513 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0])
 514
 515 if test "$os_win32" != yes; then
 516     # libtool option to control which symbols are exported
 517     # right now, symbols starting with _ are not exported
 518     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 519 else
 520     # We currently use .def files on Windows (for gdk and gtk)
 521     LIBTOOL_EXPORT_OPTIONS=
 522 fi
 523 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 524
 525 dnl ******************************************************
 526 dnl * See whether to include shared library dependencies *
 527 dnl ******************************************************
 528
 529 AC_ARG_ENABLE(explicit-deps,
 530               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 531                               [use explicit dependencies in .pc files [default=auto]])],,
 532               [enable_explicit_deps=auto])
 533
 534 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 535 case $enable_explicit_deps in
 536   auto)
 537     export SED
 538     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 539     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 540       enable_explicit_deps=yes
 541     else
 542       enable_explicit_deps=no
 543     fi
 544   ;;
 545   yes|no)
 546   ;;
 547   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 548   ;;
 549 esac
 550 AC_MSG_RESULT($enable_explicit_deps)
 551
 552 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 553
 554 # define a MAINT-like variable REBUILD which is set if Perl
 555 # and awk are found, so autogenerated sources can be rebuilt
 556
 557 AC_PATH_PROGS(PERL, perl5 perl)
 558
 559 # We would like indent, but don't require it.
 560 AC_CHECK_PROG(INDENT, indent, indent)
 561
 562 REBUILD=\#
 563 if test "x$enable_rebuilds" = "xyes" && \
 564      test -n "$PERL" && \
 565      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 566   REBUILD=
 567 fi
 568 AC_SUBST(REBUILD)
 569
 570 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 571 AC_CHECK_FUNCS(localtime_r)
 572
 573 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 574 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 575 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 576                                 [[char c;
 577                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 578                [gtk_ok=yes], [gtk_ok=no])
 579 AC_MSG_RESULT($gtk_ok)
 580 if test "$gtk_ok" = "yes"; then
 581   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 582             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 583 fi
 584
 585 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 586 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 587 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 588                                 [[char c;
 589                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 590                [gtk_ok=yes], [gtk_ok=no])
 591 AC_MSG_RESULT($gtk_ok)
 592 if test "$gtk_ok" = "yes"; then
 593   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 594             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 595 fi
 596
 597 # _NL_PAPER_HEIGHT is an enum and not a define
 598 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 599 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 600                                 [[char c;
 601                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 602                [gtk_ok=yes], [gtk_ok=no])
 603 AC_MSG_RESULT($gtk_ok)
 604 if test "$gtk_ok" = "yes"; then
 605   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 606             [Define if _NL_PAPER_HEIGHT is available])
 607 fi
 608
 609 # _NL_PAPER_WIDTH is an enum and not a define
 610 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 611 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 612                                 [[char c;
 613                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 614                [gtk_ok=yes], [gtk_ok=no])
 615 AC_MSG_RESULT($gtk_ok)
 616 if test "$gtk_ok" = "yes"; then
 617   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 618             [Define if _NL_PAPER_WIDTH is available])
 619 fi
 620
 621 # i18n stuff
 622 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 623 AM_GLIB_GNU_GETTEXT
 624 LIBS="$LIBS $INTLLIBS"
 625 AC_CONFIG_COMMANDS([po-properties],
 626                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 627                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 628                      esac]],
 629                    [[]])
 630
 631 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 632 dnl po-properties/POTFILES during configure; see GNOME #573515.
 633 dnl
 634 dnl Generate list of files to be processed by xgettext which will
 635 dnl be included in po-properties/Makefile.
 636 test -d po-properties || mkdir po-properties
 637 if test "x$srcdir" != "x."; then
 638   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 639     popropsrcprefix="$srcdir/"
 640   else
 641     popropsrcprefix="../$srcdir/"
 642   fi
 643 else
 644   popropsrcprefix="../"
 645 fi
 646 rm -f po-properties/POTFILES
 647 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 648 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 649 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 650
 651 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 652
 653 dnl The DU4 header files don't provide library prototypes unless
 654 dnl -std1 is given to the native cc.
 655 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 656
 657 gtk_save_LIBS=$LIBS
 658 LIBS="$LIBS -lm"
 659 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 660                                 int main (void) { return (log(1) != log(1.)); }]])],
 661               [AC_MSG_RESULT(none needed)],
 662               [gtk_save_CFLAGS="$CFLAGS"
 663                CFLAGS="$CFLAGS -std1"
 664                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 665                                                int main (void) { return (log(1) != log(1.)); }]])],
 666                              [AC_MSG_RESULT(-std1)],
 667                              [AC_MSG_RESULT()
 668                               CFLAGS="$gtk_save_CFLAGS"
 669                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 670                              [true])],
 671               [AC_MSG_RESULT(none needed)])
 672
 673 LIBS=$gtk_save_LIBS
 674
 675 AC_MSG_CHECKING(for the BeOS)
 676 case $host in
 677   *-*-beos*)
 678     AC_MSG_RESULT(yes)
 679     MATH_LIB=
 680   ;;
 681   *)
 682     AC_MSG_RESULT(no)
 683   ;;
 684 esac
 685
 686 AC_SUBST(MATH_LIB)
 687 #
 688 # see bug 162979
 689 #
 690 AC_MSG_CHECKING(for HP-UX)
 691 case $host_os in
 692   hpux9* | hpux10* | hpux11*)
 693     AC_MSG_RESULT(yes)
 694     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 695   ;;
 696   *)
 697     AC_MSG_RESULT(no)
 698   ;;
 699 esac
 700
 701 #
 702 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 703 #
 704
 705 AM_PATH_GLIB_2_0(glib_required_version, :,
 706   AC_MSG_ERROR([
 707 *** GLIB glib_required_version or better is required. The latest version of
 708 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 709   gobject gmodule-no-export)
 710
 711 dnl
 712 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 713 dnl
 714 gtk_save_LIBS=$LIBS
 715 LIBS="$LIBS $GLIB_LIBS"
 716 AC_CHECK_FUNCS(bind_textdomain_codeset)
 717 LIBS=$gtk_save_LIBS
 718
 719 AC_CHECK_HEADERS(pwd.h,
 720                  AC_DEFINE(HAVE_PWD_H, 1,
 721                            [Define to 1 if pwd.h is available]))
 722 AC_CHECK_HEADERS(sys/time.h,
 723                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 724                            [Define to 1 if time.h is available]))
 725 AC_CHECK_HEADERS(unistd.h,
 726                  AC_DEFINE(HAVE_UNISTD_H, 1,
 727                            [Define to 1 if unistd.h is available]))
 728 AC_CHECK_HEADERS(ftw.h,
 729                  AC_DEFINE(HAVE_FTW_H, 1,
 730                            [Define to 1 if ftw.h is available]))
 731
 732 AC_MSG_CHECKING([for GNU ftw extensions])
 733 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 734                                      #define _GNU_SOURCE
 735                                      #include <ftw.h>]],
 736                                    [[int flags = FTW_ACTIONRETVAL;]])],
 737                   [gtk_ok=yes],[gtk_ok=no])
 738 if test $gtk_ok = yes; then
 739     AC_MSG_RESULT([yes])
 740     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 741 else
 742     AC_MSG_RESULT([no])
 743 fi
 744
 745 saved_cflags="$CFLAGS"
 746 saved_ldflags="$LDFLAGS"
 747
 748
 749 # Checks for library functions.
 750 AC_FUNC_MMAP
 751
 752 AC_CHECK_FUNCS(mallinfo)
 753 AC_CHECK_FUNCS(getresuid)
 754 AC_TYPE_UID_T
 755
 756 # Check for round(), rint(), isnan(), isinf() and nearbyint()
 757 AC_CHECK_LIB(m,round,,)
 758 AC_CHECK_FUNCS(round rint nearbyint)
 759 AC_CHECK_DECLS([isnan, isinf], [], [], [[#include <math.h>]])
 760
 761 # Checks for gdkspawn
 762 AC_CHECK_HEADERS(crt_externs.h)
 763 AC_CHECK_FUNCS(_NSGetEnviron)
 764
 765 AC_MSG_CHECKING(whether to build dynamic modules)
 766
 767 AC_ARG_ENABLE(modules,
 768               [AS_HELP_STRING([--disable-modules],
 769                               [disable dynamic module loading])])
 770
 771 dynworks=false
 772 build_dynamic_modules=no
 773 deps=
 774 if test x$enable_modules = xno; then
 775     AC_MSG_RESULT(no)
 776 else
 777     AC_MSG_RESULT(yes)
 778     AC_MSG_CHECKING(whether dynamic modules work)
 779     ## for loop is to strip newline
 780     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 781     for I in $tmp; do
 782         dynworks=$I
 783     done
 784
 785     dnl Now we check to see if our libtool supports shared lib deps
 786     dnl (in a rather ugly way even)
 787     if $dynworks; then
 788         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 789         module_deplibs_check=`$module_libtool_config | \
 790             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 791             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 792         if test "x$module_deplibs_check" = "xnone" || \
 793            test "x$module_deplibs_check" = "xunknown" || \
 794            test "x$module_deplibs_check" = "x"; then
 795             dynworks=false
 796         fi
 797     fi
 798
 799     if $dynworks; then
 800         build_dynamic_modules=yes
 801         AC_DEFINE(USE_GMODULE, 1,
 802                   [Define to 1 if gmodule works and should be used])
 803         AC_MSG_RESULT(yes)
 804     else
 805         build_dynamic_modules=no
 806         AC_MSG_RESULT(no)
 807     fi
 808 fi
 809
 810 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 811
 812 #
 813 # Allow building some or all immodules included
 814 #
 815 AC_MSG_CHECKING(immodules to build)
 816
 817 AC_ARG_WITH(included_immodules,
 818             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 819                             [build the specified input methods into gtk])])
 820
 821 if $dynworks; then
 822    :
 823 else
 824    ## if the option was specified, leave it; otherwise disable included immodules
 825    if test x$with_included_immodules = xno; then
 826            with_included_immodules=yes
 827    fi
 828 fi
 829
 830 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 831
 832 included_immodules=""
 833 # If the switch specified without listing any specific ones, include all
 834 if test "x$with_included_immodules" = xyes ; then
 835   included_immodules="$all_immodules"
 836 else
 837   included_immodules="$with_included_immodules"
 838 fi
 839
 840 AC_MSG_RESULT($included_immodules)
 841 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 842
 843 INCLUDED_IMMODULE_OBJ=
 844 INCLUDED_IMMODULE_DEFINE=
 845
 846 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 847 for immodule in $included_immodules; do
 848  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 849  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 850    :
 851  else
 852    AC_MSG_ERROR([the specified input method $immodule does not exist])
 853  fi
 854
 855  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 856  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 857  eval INCLUDE_$immodule_underscores=yes
 858 done
 859 IFS="$gtk_save_ifs"
 860 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 861 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 862
 863 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 864 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 865 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 866 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 867 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 868 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 869 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 870 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 871 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 872 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 873 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 874 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 875
 876 # Checks to see whether we should include mediaLib
 877 # support.
 878 #
 879 AC_CHECK_HEADER(sys/systeminfo.h,
 880                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 881                           [Define to 1 if sys/systeminfo.h is available]))
 882 AC_CHECK_HEADER(sys/sysinfo.h,
 883                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 884                           [Define to 1 if sys/sysinfo.h is available]))
 885
 886 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 887
 888 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 889
 890 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 891   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 892   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 893     REBUILD_PNGS=#
 894   fi
 895 fi
 896
 897 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 898
 899 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 900
 901 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 902    test "x$REBUILD_PNGS" = "x#" ; then
 903      AC_MSG_ERROR([
 904 *** gtkbuiltincache.h is not in the tree, and cannot be built
 905 *** because you don't have libpng, or (when cross-compiling) you
 906 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 907 fi
 908
 909 ########################################
 910 # Windowing system checks
 911 ########################################
 912
 913 # GTK+ uses some X calls, so needs to link against X directly
 914 GTK_DEP_PACKAGES_FOR_X=
 915 GTK_DEP_LIBS_FOR_X=
 916 X_EXTENSIONS=
 917
 918 if test "x$enable_x11_backend" = xyes; then
 919   X_PACKAGES=fontconfig
 920
 921   #
 922   # We use fontconfig very peripherally when decoding the default
 923   # settings.
 924   #
 925   if $PKG_CONFIG --exists fontconfig; then : ; else
 926     AC_MSG_ERROR([
 927 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 928   fi
 929
 930   #
 931   # Check for basic X packages; we use pkg-config if available
 932   #
 933   if $PKG_CONFIG --exists x11 xext; then
 934     have_base_x_pc=true
 935     X_PACKAGES="$X_PACKAGES x11 xext"
 936     x_libs="`$PKG_CONFIG --libs x11 xext`"
 937     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 938
 939     # Strip out any .la files that pkg-config might give us (this happens
 940     # with -uninstalled.pc files)
 941     x_libs_for_checks=
 942     for I in $x_libs ; do
 943       case $I in
 944         *.la) ;;
 945         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 946       esac
 947     done
 948
 949     GTK_PACKAGES_FOR_X="x11"
 950   else
 951     have_base_x_pc=false
 952     AC_PATH_XTRA
 953     if test x$no_x = xyes ; then
 954       AC_MSG_ERROR([X development libraries not found])
 955     fi
 956
 957     x_cflags="$X_CFLAGS"
 958     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 959
 960     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 961   fi
 962
 963   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 964   x_extra_libs=
 965
 966   gtk_save_cppflags="$CPPFLAGS"
 967   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 968
 969   gtk_save_LIBS=$LIBS
 970   LIBS="$x_libs_for_checks $LIBS"
 971
 972   # Sanity check for the X11 and Xext libraries. While everything we need from
 973   # Xext is optional, the chances a system has *none* of these things is so
 974   # small that we just unconditionally require it.
 975   AC_CHECK_FUNC(XOpenDisplay, :,
 976                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 977   AC_CHECK_FUNC(XextFindDisplay, :,
 978                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 979
 980   # Check for xReply
 981
 982   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 983   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 984                                      [[xReply *rep;]])],
 985                     [AC_MSG_RESULT([no])],
 986                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 987                                                           #include <X11/Xlibint.h>]],
 988                                                         [[xReply *rep;]])],
 989                                        [AC_MSG_RESULT([yes])
 990                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 991                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 992                                        [AC_MSG_RESULT([unknown])
 993                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 994
 995   # Check for XKB support.
 996
 997   if test "x$enable_xkb" = "xyes"; then
 998         AC_CHECK_FUNC(XkbQueryExtension,
 999                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1000                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1001                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1002   elif test "x$enable_xkb" = "xmaybe"; then
1003         AC_CHECK_FUNC(XkbQueryExtension,
1004                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1005                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1006   else
1007         AC_MSG_WARN(XKB support explicitly disabled)
1008   fi
1009
1010   # Check for shaped window extension
1011
1012   AC_CHECK_FUNC(XShapeCombineMask, :,
1013      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1014
1015   # X SYNC check
1016   gtk_save_CFLAGS="$CFLAGS"
1017   CFLAGS="$CFLAGS $x_cflags"
1018
1019   AC_CHECK_FUNC(XSyncQueryExtension,
1020       [AC_CHECK_HEADER(X11/extensions/sync.h,
1021           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1022           :, [#include <X11/Xlib.h>])])
1023
1024   CFLAGS="$gtk_save_CFLAGS"
1025
1026   if test "x$enable_xinerama" != "xno"; then
1027     # Check for Xinerama extension (Solaris impl or Xfree impl)
1028     have_xfree_xinerama=false
1029     have_solaris_xinerama=false
1030
1031     gtk_save_cppflags="$CPPFLAGS"
1032     CPPFLAGS="$CPPFLAGS $x_cflags"
1033
1034     # Check for XFree
1035     AC_MSG_CHECKING(for Xinerama packages)
1036
1037     if $PKG_CONFIG --exists xinerama ; then
1038        AC_MSG_RESULT(yes)
1039        have_xfree_xinerama=true
1040        X_PACKAGES="$X_PACKAGES xinerama"
1041     else
1042        AC_MSG_RESULT(no)
1043        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1044            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1045            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1046            have_xfree_xinerama=true], :,
1047            [#include <X11/Xlib.h>])])
1048     fi
1049
1050     if $have_xfree_xinerama ; then
1051       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1052       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1053                 [Define to 1 if XFree Xinerama is available])
1054       AC_DEFINE(HAVE_XINERAMA, 1,
1055                 [Define to 1 is Xinerama is available])
1056     else
1057       case "$host" in
1058         *-*-solaris*)
1059             # Check for solaris
1060             AC_MSG_CHECKING(for Xinerama support on Solaris)
1061
1062             have_solaris_xinerama=false
1063             AC_CHECK_FUNC(XineramaGetInfo,
1064                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1065                     [have_solaris_xinerama=true], :,
1066                     [#include <X11/Xlib.h>])])
1067
1068             if $have_solaris_xinerama ; then
1069               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1070               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1071                         [Define to 1 if solaris xinerama is available])
1072               AC_DEFINE(HAVE_XINERAMA, 1,
1073                         [Define to 1 if xinerama is available])
1074               AC_MSG_RESULT(yes)
1075             else
1076               AC_MSG_RESULT(no)
1077             fi
1078             ;;
1079         *)
1080             ;;
1081       esac
1082     fi
1083   fi
1084   if test "x$enable_xinerama" = "xyes" ; then
1085     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1086       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1087     fi
1088   fi
1089
1090   # Check for XGetEventData for GenericEvents
1091   AC_CHECK_FUNC(XGetEventData,
1092                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1093
1094   # set up things for XInput
1095   if $PKG_CONFIG --exists "xi" ; then
1096
1097     X_PACKAGES="$X_PACKAGES xi"
1098     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xi"
1099
1100     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1101                     have_xinput2=yes
1102                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1103
1104     gtk_save_LIBS="$LIBS"
1105     LIBS="$LIBS -lXi"
1106
1107     # Note that we also check that the XIScrollClassInfo struct is defined,
1108     # because at least Ubuntu Oneiric seems to have XIAllowTouchEvents(), but not the XIScrollClassInfo struct.
1109     AC_CHECK_FUNC([XIAllowTouchEvents],
1110       [AC_CHECK_MEMBER([XIScrollClassInfo.number],
1111                        have_xinput2_2=yes
1112                        AC_DEFINE(XINPUT_2_2, 1, [Define to 1 if XInput 2.2 is available]),
1113                        have_xinput2_2=no,
1114                        [[#include <X11/extensions/XInput2.h>]])])
1115     LIBS="$gtk_save_LIBS"
1116
1117     if test "x$have_xinput2_2" = "xyes"; then
1118       X_EXTENSIONS="$X_EXTENSIONS XI2.2"
1119     else
1120       X_EXTENSIONS="$X_EXTENSIONS XI2"
1121     fi
1122   fi
1123
1124   AS_IF([test "x$have_xinput2" != "xyes"],
1125         [AC_MSG_ERROR([*** XInput2 extension not found. Check 'config.log' for more details.])])
1126
1127   # Check for the RANDR extension
1128   if test x"$enable_xrandr" != xno; then
1129     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1130       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1131
1132       X_PACKAGES="$X_PACKAGES xrandr"
1133       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1134     elif test x"$enable_xrandr" = xyes; then
1135       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1136     fi
1137   fi
1138
1139   # Checks for Xcursor library
1140
1141   if $PKG_CONFIG --exists xcursor ; then
1142     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1143
1144     X_PACKAGES="$X_PACKAGES xcursor"
1145   fi
1146
1147   # Checks for XFixes extension
1148
1149   if test x"$enable_xfixes" != xno; then
1150     if $PKG_CONFIG --exists xfixes ; then
1151       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1152
1153       X_PACKAGES="$X_PACKAGES xfixes"
1154       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1155       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1156     elif test x"$enable_xfixes" = xyes; then
1157       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1158     fi
1159   fi
1160
1161   # Checks for Xcomposite extension
1162
1163   if test x"$enable_xcomposite" != xno; then
1164     if $PKG_CONFIG --exists xcomposite ; then
1165       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1166
1167       X_PACKAGES="$X_PACKAGES xcomposite"
1168       X_EXTENSIONS="$X_EXTENSIONS Composite"
1169       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1170     elif test x"$enable_xcomposite" = xyes; then
1171       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1172     fi
1173   fi
1174
1175   # Checks for Xdamage extension
1176
1177   if test x"$enable_xdamage" != xno; then
1178     if $PKG_CONFIG --exists xdamage ; then
1179       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1180
1181       X_PACKAGES="$X_PACKAGES xdamage"
1182       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1183       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1184     elif test x"$enable_xdamage" = xyes; then
1185       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1186     fi
1187   fi
1188
1189   if $have_base_x_pc ; then
1190     GDK_EXTRA_LIBS="$x_extra_libs"
1191   else
1192     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1193   fi
1194
1195   CPPFLAGS="$gtk_save_cppflags"
1196   LIBS="$gtk_save_libs"
1197
1198   AM_CONDITIONAL(USE_X11, true)
1199
1200   # strip leading space
1201   X_EXTENSIONS=${X_EXTENSIONS#* }
1202
1203 else
1204   XPACKAGES=
1205
1206   AM_CONDITIONAL(USE_X11, false)
1207 fi
1208
1209 # Check for gio-unix
1210 if test "$have_gio_unix" = "yes"; then
1211   GDK_GIO_PACKAGE=gio-unix-2.0
1212   AC_DEFINE([HAVE_GIO_UNIX], [1],
1213             [Define if gio-unix is available])
1214 else
1215   GDK_GIO_PACKAGE=gio-2.0
1216 fi
1217
1218 # Check for Pango flags
1219
1220 AC_MSG_CHECKING(Pango flags)
1221 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1222         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1223         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1224
1225         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1226 else
1227         AC_MSG_ERROR([
1228 *** Pango not found. Pango built with Cairo support is required
1229 *** to build GTK+. See http://www.pango.org for Pango information.
1230 ])
1231 fi
1232
1233 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1234
1235 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1236         :
1237 else
1238         gtk_save_LIBS="$LIBS"
1239         LIBS="$PANGO_LIBS $LIBS"
1240         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1241 *** Can't link to Pango. Pango is required to build
1242 *** GTK+. For more information see http://www.pango.org]))
1243         LIBS="$gtk_save_LIBS"
1244 fi
1245
1246 CFLAGS="$saved_cflags"
1247 LDFLAGS="$saved_ldflags"
1248
1249 GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo cairo-gobject"
1250 GDK_PRIVATE_PACKAGES="$GDK_GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES $cairo_backends"
1251 if test "x$enable_x11_backend" = xyes; then
1252   GDK_PRIVATE_PACKAGES="$GDK_PRIVATE_PACKAGES pangoft2"
1253 fi
1254
1255 PKG_CHECK_MODULES(GDK_DEP, $GDK_PACKAGES $GDK_PRIVATE_PACKAGES)
1256 GDK_DEP_LIBS="$GDK_EXTRA_LIBS $GDK_DEP_LIBS $MATH_LIB"
1257 GDK_DEP_CFLAGS="$GDK_DEP_CFLAGS $GDK_EXTRA_CFLAGS"
1258 #
1259 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1260 # into the pkg-config files
1261 #
1262 if test $enable_explicit_deps != yes ; then
1263   GDK_EXTRA_LIBS=
1264 fi
1265
1266 AC_SUBST(GDK_PACKAGES)
1267 AC_SUBST(GDK_PRIVATE_PACKAGES)
1268 AC_SUBST(GDK_EXTRA_LIBS)
1269 AC_SUBST(GDK_EXTRA_CFLAGS)
1270 AC_SUBST(GDK_DEP_LIBS)
1271 AC_SUBST(GDK_DEP_CFLAGS)
1272
1273
1274 ########################################
1275 # Check for Accessibility Toolkit flags
1276 ########################################
1277
1278 ATK_PACKAGES=atk
1279 PKG_CHECK_MODULES(ATK, $ATK_PACKAGES)
1280
1281 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1282 GTK_PRIVATE_PACKAGES=""
1283 if test "x$enable_x11_backend" = xyes; then
1284   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES pangoft2"
1285 fi
1286 if test "$have_gio_unix" = "yes"; then
1287   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES gio-unix-2.0"
1288 fi
1289 GTK_EXTRA_LIBS=
1290
1291 GTK_EXTRA_CFLAGS=
1292 PKG_CHECK_MODULES(GTK_DEP, $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES $GTK_PRIVATE_PACKAGES)
1293 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X $GTK_DEP_LIBS $GTK_EXTRA_LIBS $MATH_LIB"
1294 GTK_DEP_CFLAGS="$GTK_DEP_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1295
1296 if test x"$os_win32" = xyes; then
1297   GTK_EXTRA_CFLAGS="$msnative_struct"
1298 fi
1299
1300 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1301 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1302 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1303 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1304
1305 AC_SUBST(GTK_PACKAGES)
1306 AC_SUBST(GTK_PRIVATE_PACKAGES)
1307 AC_SUBST(GTK_EXTRA_LIBS)
1308 AC_SUBST(GTK_EXTRA_CFLAGS)
1309 AC_SUBST(GTK_DEP_LIBS)
1310 AC_SUBST(GTK_DEP_CFLAGS)
1311
1312 AC_SUBST(GLIB_PREFIX)
1313 AC_SUBST(ATK_PREFIX)
1314 AC_SUBST(PANGO_PREFIX)
1315 AC_SUBST(CAIRO_PREFIX)
1316
1317 AC_SUBST(GTK_DEBUG_FLAGS)
1318 AC_SUBST(GTK_XIM_FLAGS)
1319
1320 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1321 AC_SUBST(GDK_PIXBUF_LIBS)
1322
1323 ########################
1324 # Checks needed for gail
1325 ########################
1326
1327 old_LIBS="$LIBS"
1328 dnl Checks for inet libraries:
1329 AC_SEARCH_LIBS(gethostent, nsl)
1330 AC_SEARCH_LIBS(setsockopt, socket)
1331 AC_SEARCH_LIBS(connect, inet)
1332
1333 dnl check for the sockaddr_un.sun_len member
1334 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1335                 [struct_sockaddr_un_sun_len=true],
1336                 [struct_sockaddr_un_suin_len=false],
1337                 [#include <sys/types.h>
1338                  #include <sys/un.h>]
1339                 )
1340 case $struct_sockaddr_un_sun_len in
1341         true)
1342                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1343                                    [Have the sockaddr_un.sun_len member])
1344                 ;;
1345         *)
1346                 ;;
1347 esac
1348
1349 GAIL_INET_LIBS="$LIBS"
1350 AC_SUBST([GAIL_INET_LIBS])
1351
1352 LIBS="$old_LIBS"
1353
1354 ################################################################
1355 # Printing system checks
1356 ################################################################
1357
1358 PRINT_BACKENDS="file lpr"
1359
1360 AC_ARG_ENABLE(cups,
1361               [AS_HELP_STRING([--disable-cups],
1362                               [disable cups print backend])],,
1363               [enable_cups=auto])
1364
1365 if test "x$enable_cups" = "xno"; then
1366   AM_CONDITIONAL(HAVE_CUPS, false)
1367 else
1368   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1369   if test "x$CUPS_CONFIG" = "xno"; then
1370     if test "x$enable_cups" = "xauto"; then
1371       AM_CONDITIONAL(HAVE_CUPS, false)
1372     else
1373       AC_MSG_ERROR([
1374 *** cups not found.
1375 ])
1376     fi
1377   else
1378     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1379     CUPS_LIBS=`$CUPS_CONFIG --libs`
1380
1381     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1382     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1383     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1384
1385     if test $CUPS_API_MAJOR -gt 1 -o \
1386             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -lt 2; then
1387       AC_MSG_ERROR([CUPS >= 1.2 not found])
1388     fi
1389     if test $CUPS_API_MAJOR -gt 1 -o \
1390             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 6; then
1391       AC_DEFINE(HAVE_CUPS_API_1_6, 1,
1392                 [Define to 1 if CUPS 1.6 API is available])
1393
1394     fi
1395
1396     AC_SUBST(CUPS_API_MAJOR)
1397     AC_SUBST(CUPS_API_MINOR)
1398     AC_SUBST(CUPS_CFLAGS)
1399     AC_SUBST(CUPS_LIBS)
1400
1401     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1402
1403     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1404     AM_CONDITIONAL(HAVE_CUPS, true)
1405
1406     gtk_save_cflags="$CFLAGS"
1407     CFLAGS="$CUPS_CFLAGS"
1408     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1409                                        [[http_t http; char *s = http.authstring;]])],
1410                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1411                                  [Define if cups http_t authstring field is accessible])],
1412                       [])
1413     CFLAGS="$gtk_save_cflags"
1414
1415     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1416
1417     gtk_save_libs="$LIBS"
1418     LIBS="$CUPS_LIBS"
1419     AC_CHECK_FUNCS(httpGetAuthString)
1420     LIBS="$gtk_save_libs"
1421   fi
1422 fi
1423
1424 # Checks to see if we should compile with PAPI backend for GTK+
1425 #
1426
1427 AC_ARG_ENABLE(papi,
1428               [AS_HELP_STRING([--disable-papi],
1429                               [disable papi print backend])],,
1430               [enable_papi=auto])
1431
1432 if test "x$enable_papi" = "xno"; then
1433   AM_CONDITIONAL(HAVE_PAPI, false)
1434 else
1435   AC_MSG_CHECKING(libpapi)
1436   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1437   if test $have_papi = yes; then
1438     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1439     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1440   fi
1441   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1442   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1443     AC_MSG_ERROR([
1444 *** papi not found.
1445 ])
1446   fi
1447 fi
1448
1449 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1450
1451 gtk_save_cppflags="$CPPFLAGS"
1452 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1453
1454 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1455 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1456 *** backend enabled.]))
1457
1458 if test "$os_win32" != "yes"; then
1459   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1460 *** Can't find cairo-ps.h. You must build Cairo with the
1461 *** postscript backend enabled.]))
1462
1463   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1464 *** Cannot find cairo-svg.h. You must build Cairo with the
1465 *** svg backend enabled.]))
1466 fi
1467
1468 CPPFLAGS="$gtk_save_cppflags"
1469
1470
1471 AC_ARG_ENABLE(test-print-backend,
1472               [AS_HELP_STRING([--enable-test-print-backend],
1473                               [build test print backend])],,
1474               [enable_test_print_backend=no])
1475 if test "x$enable_test_print_backend" != "xno" ; then
1476   PRINT_BACKENDS="$PRINT_BACKENDS test"
1477 fi
1478 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1479
1480 if test "$os_win32" = "yes"; then
1481   AC_CHECK_TYPES([IPrintDialogCallback],[],[],[[#include <windows.h>]])
1482 fi
1483
1484 ################################################################
1485 # Strip -export-dynamic from the link lines of various libraries
1486 ################################################################
1487
1488 #
1489 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1490 #  but this flag is only meaningful for executables. For libraries
1491 #  the effect is undefined; what it causes on Linux is that the
1492 #  export list from -export-symbols-regex is ignored and everything
1493 #  is exported
1494 #
1495 # We are using gmodule-no-export now, but I'm leaving the stripping
1496 # code in place for now, since pango and atk still require gmodule.
1497 export SED
1498 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1499 if test -n "$export_dynamic"; then
1500   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1501   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1502 fi
1503
1504 #############
1505 # GSettings #
1506 #############
1507
1508 GLIB_GSETTINGS
1509
1510 ##################################################
1511 # GObject introspection
1512 ##################################################
1513
1514 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1515
1516 ##################################################
1517 # Packagekit module
1518 #################################################
1519
1520 AC_ARG_ENABLE(packagekit,
1521               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1522                               [build PackageKit open-with module [default=auto]])],
1523               [enable_packagekit="$enableval"],
1524               [enable_packagekit=auto])
1525 if test "$enable_packagekit" = "auto"; then
1526   if test "$os_win32" = "yes"; then
1527     enable_packagekit=no
1528   else
1529     enable_packagekit=yes
1530   fi
1531 fi
1532
1533 AC_MSG_CHECKING([whether to use PackageKit])
1534 build_packagekit=no
1535 if test "x$enable_packagekit" != "xno"; then
1536   if test "$os_win32" != "yes"; then
1537     build_packagekit=yes
1538     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1539   else
1540     AC_MSG_ERROR([packagekit support is not available on win32])
1541   fi
1542 fi
1543 AC_MSG_RESULT([$build_packagekit])
1544
1545 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1546
1547 ##################################################
1548 # colord module
1549 #################################################
1550
1551 AC_ARG_ENABLE(colord,
1552               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1553                               [build colord support code [default=auto]])],
1554               [enable_colord="$enableval"],
1555               [enable_colord=auto])
1556
1557 AC_MSG_CHECKING([whether to use colord])
1558 if test "$enable_colord" = "auto"; then
1559   if test "$os_win32" = "yes"; then
1560     enable_colord=no
1561   fi
1562 fi
1563 if test "$enable_colord" != "no"; then
1564   AC_MSG_RESULT([yes])
1565 else
1566   AC_MSG_RESULT([no])
1567 fi
1568
1569 have_colord=no
1570 if test "$enable_colord" != "no"; then
1571         if test "$os_win32" != "yes"; then
1572                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1573                                   have_colord=yes, have_colord=no)
1574                 if test "$enable_colord" = "yes"; then
1575                         if test "$have_colord" = "no"; then
1576                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1577                         fi
1578                 fi
1579         else
1580                 AC_MSG_ERROR([colord support is not available on win32])
1581         fi
1582 fi
1583
1584 if test "$have_colord" = "yes"; then
1585         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1586 fi
1587 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1588
1589 ##################################################
1590 # Checks for gtk-doc and docbook-tools
1591 ##################################################
1592
1593 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1594
1595 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1596 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1597
1598 AC_ARG_ENABLE(man,
1599               [AS_HELP_STRING([--enable-man],
1600                               [regenerate man pages from Docbook [default=no]])],
1601               [enable_man=yes],
1602               [enable_man=no])
1603
1604 if test "${enable_man}" != no; then
1605   dnl
1606   dnl Check for xsltproc
1607   dnl
1608   AC_PATH_PROG([XSLTPROC], [xsltproc])
1609   if test -z "$XSLTPROC"; then
1610     enable_man=no
1611   fi
1612
1613   dnl check for DocBook DTD and stylesheets in the local catalog.
1614   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1615      [DocBook XML DTD V4.1.2],,enable_man=no)
1616   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1617      [DocBook XSL Stylesheets],,enable_man=no)
1618 fi
1619
1620 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1621
1622
1623 ##################################################
1624 # Output commands
1625 ##################################################
1626
1627 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1628         outfile=gdkconfig.h-tmp
1629         cat > $outfile <<\_______EOF
1630 /* gdkconfig.h
1631  *
1632  * This is a generated file.  Please modify `configure.ac'
1633  */
1634
1635 #ifndef __GDKCONFIG_H__
1636 #define __GDKCONFIG_H__
1637
1638 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1639 #error "Only <gdk/gdk.h> can be included directly."
1640 #endif
1641
1642 #include <glib.h>
1643
1644 G_BEGIN_DECLS
1645
1646 _______EOF
1647
1648         cat >>$outfile <<_______EOF
1649 $gdk_windowing
1650 _______EOF
1651
1652         cat >>$outfile <<_______EOF
1653
1654 G_END_DECLS
1655
1656 #endif  /* __GDKCONFIG_H__ */
1657 _______EOF
1658
1659
1660         if cmp -s $outfile gdk/gdkconfig.h; then
1661           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1662           rm -f $outfile
1663         else
1664           mv $outfile gdk/gdkconfig.h
1665         fi
1666 ],[
1667 gdk_windowing='$GDK_WINDOWING'
1668 ])
1669
1670 dnl
1671 dnl Check for -Bsymbolic-functions linker flag used to avoid
1672 dnl intra-library PLT jumps, if available.
1673 dnl
1674 AC_ARG_ENABLE(Bsymbolic,
1675               [AS_HELP_STRING([--disable-Bsymbolic],
1676                               [avoid linking with -Bsymbolic])],,
1677               [SAVED_LDFLAGS="${LDFLAGS}"
1678                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1679                LDFLAGS=-Wl,-Bsymbolic-functions
1680                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1681                                                [[int main (void) { return 0; }]])],
1682                               [AC_MSG_RESULT(yes)
1683                                enable_Bsymbolic=yes],
1684                               [AC_MSG_RESULT(no)
1685                                enable_Bsymbolic=no])
1686                LDFLAGS="${SAVED_LDFLAGS}"])
1687
1688 if test "x${enable_Bsymbolic}" = "xyes" ; then
1689   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1690 fi
1691 AC_SUBST(GTK_LINK_FLAGS)
1692
1693 AC_CONFIG_FILES([
1694 config.h.win32
1695 gtk-zip.sh
1696 Makefile
1697 gdk-3.0.pc
1698 gtk+-3.0.pc
1699 gtk+-unix-print-3.0.pc
1700 gail-3.0.pc
1701 m4macros/Makefile
1702 po/Makefile.in
1703 po-properties/Makefile.in
1704 demos/Makefile
1705 demos/gtk-demo/Makefile
1706 demos/gtk-demo/geninclude.pl
1707 demos/pixbuf-demo/Makefile
1708 demos/widget-factory/Makefile
1709 examples/Makefile
1710 tests/Makefile
1711 tests/a11y/Makefile
1712 tests/css/Makefile
1713 tests/css/parser/Makefile
1714 tests/reftests/Makefile
1715 tests/visuals/Makefile
1716 docs/Makefile
1717 docs/reference/Makefile
1718 docs/reference/gdk/Makefile
1719 docs/reference/gdk/version.xml
1720 docs/reference/gtk/Makefile
1721 docs/reference/gtk/gtk3.types
1722 docs/reference/gtk/version.xml
1723 docs/reference/libgail-util/Makefile
1724 docs/reference/libgail-util/version.xml
1725 docs/tools/Makefile
1726 build/Makefile
1727 build/win32/Makefile
1728 build/win32/vs9/Makefile
1729 build/win32/vs10/Makefile
1730 gdk/Makefile
1731 gdk/broadway/Makefile
1732 gdk/x11/Makefile
1733 gdk/win32/Makefile
1734 gdk/win32/rc/Makefile
1735 gdk/win32/rc/gdk.rc
1736 gdk/quartz/Makefile
1737 gdk/wayland/Makefile
1738 gdk/tests/Makefile
1739 gdk/gdkversionmacros.h
1740 gtk/Makefile
1741 gtk/makefile.msc
1742 gtk/gtkversion.h
1743 gtk/gtk-win32.rc
1744 gtk/a11y/Makefile
1745 gtk/tests/Makefile
1746 libgail-util/Makefile
1747 modules/Makefile
1748 modules/engines/Makefile
1749 modules/engines/pixbuf/Makefile
1750 modules/input/Makefile
1751 modules/printbackends/Makefile
1752 modules/printbackends/cups/Makefile
1753 modules/printbackends/lpr/Makefile
1754 modules/printbackends/file/Makefile
1755 modules/printbackends/papi/Makefile
1756 modules/printbackends/test/Makefile
1757 perf/Makefile
1758 ])
1759
1760 AC_OUTPUT
1761
1762 # beautify the immodule list a bit
1763 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1764 if test -z "${included_immodules}"; then included_immodules="none"; fi
1765
1766 echo ""
1767 echo "        GTK+ $GTK_VERSION"
1768 echo "        ==========="
1769 echo ""
1770 echo "        GDK backends:         $GDK_BACKENDS"
1771 if test "$enable_x11_backend" = "yes"; then
1772 echo "        X11 extensions:       $X_EXTENSIONS"
1773 fi
1774 echo "        Print backends:       $PRINT_BACKENDS"
1775 echo "        Dynamic modules:      $build_dynamic_modules"
1776 echo "        Included immodules:   $included_immodules"
1777 echo "        PackageKit support:   $build_packagekit"
1778 echo "        colord support:       $have_colord"
1779 echo "        Introspection:        $found_introspection"
1780 echo "        Debugging:            $enable_debug"
1781 echo "        Documentation:        $enable_gtk_doc"