Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [3])
  13 m4_define([gtk_micro_version], [3])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.31.0])
  43 m4_define([pango_required_version], [1.29.0])
  44 m4_define([atk_required_version], [2.1.5])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.23.5])
  47 m4_define([introspection_required_version], [0.10.1])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_INSTALL
 129 AC_PROG_MAKE_SET
 130
 131
 132 GETTEXT_PACKAGE=gtk30
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 135                    [The prefix for our gettext translation domains.])
 136
 137 AC_CANONICAL_HOST
 138
 139 MATH_LIB=-lm
 140 AC_MSG_CHECKING([for native Win32])
 141 LIB_EXE_MACHINE_FLAG=X86
 142 EXE_MANIFEST_ARCHITECTURE=X86
 143 case "$host" in
 144   *-*-mingw*)
 145     os_win32=yes
 146     gio_can_sniff=no
 147     MATH_LIB=
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       EXE_MANIFEST_ARCHITECTURE=AMD64
 152       ;;
 153     esac
 154     ;;
 155   *)
 156     os_win32=no
 157     ;;
 158 esac
 159 AC_MSG_RESULT([$os_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 163
 164 case $host in
 165   *-*-linux*)
 166     os_linux=yes
 167     ;;
 168 esac
 169
 170 dnl
 171 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 172 dnl We use this for an automated test for C++ header correctness.
 173 dnl
 174 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 175 AC_LANG_PUSH([C++])
 176
 177 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 178                                    [[class a { int b; } c;]])],
 179                   [],[CXX=])
 180 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 181
 182 gtk_save_cxxflags="$CXXFLAGS"
 183 CXXFLAGS="$CXXFLAGS -x objective-c++"
 184 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 185                                    [[]])],
 186                   [OBJC=yes],[OBJC=no])
 187 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 188 CXXFLAGS="$gtk_save_cxxflags"
 189 AC_LANG_POP([C++])
 190
 191 if test "$os_win32" = "yes"; then
 192   if test x$enable_static = xyes -o x$enable_static = x; then
 193     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 194     enable_static=no
 195   fi
 196   if test x$enable_shared = xno; then
 197     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 198   fi
 199   enable_shared=yes
 200 fi
 201
 202 dnl Initialize libtool
 203 LT_PREREQ([2.2.6])
 204 LT_INIT([disable-static win32-dll])
 205 # Create libtool early, because it's used in configure
 206 LT_OUTPUT
 207
 208 # Make sure we use 64-bit versions of various file stuff.
 209 AC_SYS_LARGEFILE
 210
 211 AM_PROG_AS
 212 AC_PATH_PROG(NM, nm, nm)
 213
 214 AC_MSG_CHECKING([for some Win32 platform])
 215 case "$host" in
 216   *-*-mingw*|*-*-cygwin*)
 217     platform_win32=yes
 218     ;;
 219   *)
 220     platform_win32=no
 221     ;;
 222 esac
 223 AC_MSG_RESULT([$platform_win32])
 224 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 225
 226 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 227 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 228 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 229
 230 if test "$os_win32" = "yes"; then
 231   AC_CHECK_TOOL(WINDRES, windres, no)
 232   if test "$WINDRES" = no; then
 233     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 234   fi
 235   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 236 fi
 237 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 238
 239 m4_define([debug_default],
 240           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 241
 242 dnl declare --enable-* args and collect ac_help strings
 243 AC_ARG_ENABLE(debug,
 244               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 245                               [turn on debugging @<:@default=debug_default@:>@])],,
 246               [enable_debug=debug_default])
 247
 248 AC_ARG_ENABLE(rebuilds,
 249               [AS_HELP_STRING([--disable-rebuilds],
 250                               [disable all source autogeneration rules])],,
 251               [enable_rebuilds=yes])
 252
 253 AC_ARG_ENABLE(gtk2-dependency,
 254               [AS_HELP_STRING([--enable-gtk2-dependency],
 255                               [Do not build gtk-update-icon-cache and other shared tools])],,
 256               [enable_gtk2_dependency=no])
 257
 258 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 259
 260 AC_ARG_ENABLE(xkb,
 261               [AS_HELP_STRING([--enable-xkb],
 262                               [support XKB extension [default=maybe]])],,
 263               [enable_xkb="maybe"])
 264 AC_ARG_ENABLE(xinerama,
 265               [AS_HELP_STRING([--enable-xinerama],
 266                               [support Xinerama extension if available [default=maybe]])],,
 267               [enable_xinerama="maybe"])
 268 AC_ARG_ENABLE(xinput,
 269               [AS_HELP_STRING([--enable-xinput],
 270                               [support XInput extension if available [default=yes]])],,
 271               [enable_xinput="maybe"])
 272 AC_ARG_ENABLE(xrandr,
 273               [AS_HELP_STRING([--enable-xrandr],
 274                               [support XRandR extension if available [default=maybe]])],,
 275               [enable_xrandr="maybe"])
 276 AC_ARG_ENABLE(xfixes,
 277               [AS_HELP_STRING([--enable-xfixes],
 278                               [support XFixes extension if available [default=maybe]])],,
 279               [enable_xfixes="maybe"])
 280 AC_ARG_ENABLE(xcomposite,
 281               [AS_HELP_STRING([--enable-xcomposite],
 282                               [support X Composite extension if available [default=maybe]])],,
 283               [enable_xcomposite="maybe"])
 284 AC_ARG_ENABLE(xdamage,
 285               [AS_HELP_STRING([--enable-xdamage],
 286                               [support X Damage extension if available [default=maybe]])],,
 287               [enable_xdamage="maybe"])
 288
 289 AC_ARG_ENABLE(x11-backend,
 290               [AS_HELP_STRING([--enable-x11-backend],
 291                               [enable the X11 gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(win32-backend,
 294               [AS_HELP_STRING([--enable-win32-backend],
 295                               [enable the Win32 gdk backend])],
 296                               [backend_set=yes])
 297 AC_ARG_ENABLE(quartz-backend,
 298               [AS_HELP_STRING([--enable-quartz-backend],
 299                               [enable the quartz gdk backend])],
 300                               [backend_set=yes])
 301 AC_ARG_ENABLE(broadway-backend,
 302               [AS_HELP_STRING([--enable-broadway-backend],
 303                               [enable the broadway (HTML5) gdk backend])],
 304                               [backend_set=yes])
 305 AC_ARG_ENABLE(wayland-backend,
 306               [AS_HELP_STRING([--enable-wayland-backend],
 307                               [enable the wayland gdk backend])],
 308                               [backend_set=yes])
 309
 310 if test -z "$backend_set"; then
 311   if test "$platform_win32" = yes; then
 312     enable_win32_backend=yes
 313   else
 314     enable_x11_backend=yes
 315   fi
 316 fi
 317
 318 AC_ARG_ENABLE(quartz-relocation,
 319               [AS_HELP_STRING([--enable-quartz-relocation],
 320                               [enable bundle-based relocation functions])],
 321                               [quartz_relocation=yes])
 322
 323 cairo_backends=
 324 backend_immodules=
 325 GDK_BACKENDS=
 326 GDK_EXTRA_LIBS=
 327 GDK_EXTRA_CFLAGS=
 328 GDK_WINDOWING=
 329 GIO_PACKAGE=gio-2.0
 330 PANGO_PACKAGES="pango pangocairo"
 331
 332 if test "$enable_x11_backend" = "yes"; then
 333   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 334   # backend names are identical.
 335   cairo_backends="$cairo_backends cairo-xlib"
 336   GDK_BACKENDS="$GDK_BACKENDS x11"
 337   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 338   # gdkapplaunchcontext-x11.c
 339   GIO_PACKAGE=gio-unix-2.0
 340   backend_immodules="$backend_immodules,xim"
 341   GDK_WINDOWING="$GDK_WINDOWING
 342 #define GDK_WINDOWING_X11"
 343 fi
 344
 345 if test "$enable_win32_backend" = "yes"; then
 346   cairo_backends="$cairo_backends cairo-win32"
 347   GDK_BACKENDS="$GDK_BACKENDS win32"
 348   backend_immodules="$backend_immodules,ime"
 349   GDK_WINDOWING="$GDK_WINDOWING
 350 #define GDK_WINDOWING_WIN32"
 351   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 352   AM_CONDITIONAL(USE_WIN32, true)
 353   PANGO_PACKAGES="pangowin32 pangocairo"
 354 else
 355   AM_CONDITIONAL(USE_WIN32, false)
 356 fi
 357
 358 if test "x$enable_quartz_backend" = xyes; then
 359   cairo_backends="$cairo_backends cairo-quartz"
 360   GDK_BACKENDS="$GDK_BACKENDS quartz"
 361   GDK_WINDOWING="$GDK_WINDOWING
 362 #define GDK_WINDOWING_QUARTZ"
 363   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 364   AM_CONDITIONAL(USE_QUARTZ, true)
 365   if test "x$quartz_relocation" = xyes; then
 366     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 367   fi
 368
 369 else
 370   AM_CONDITIONAL(USE_QUARTZ, false)
 371 fi
 372
 373
 374 if test "x$enable_broadway_backend" == xyes; then
 375   GDK_BACKENDS="$GDK_BACKENDS broadway"
 376   cairo_backends="$cairo_backends cairo"
 377   GDK_WINDOWING="$GDK_WINDOWING
 378 #define GDK_WINDOWING_BROADWAY"
 379   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 380   AM_CONDITIONAL(USE_BROADWAY, true)
 381 else
 382   AM_CONDITIONAL(USE_BROADWAY, false)
 383 fi
 384
 385 if test "x$enable_wayland_backend" == "xyes"; then
 386   # Wayland uses cairo-gl
 387   cairo_backends="$cairo_backends cairo-gl"
 388   GDK_BACKENDS="$GDK_BACKENDS wayland"
 389   GIO_PACKAGE=gio-unix-2.0
 390   GDK_WINDOWING="$GDK_WINDOWING
 391 #define GDK_WINDOWING_WAYLAND"
 392   WAYLAND_PACKAGES="wayland-client xkbcommon wayland-egl egl"
 393   AM_CONDITIONAL(USE_WAYLAND, true)
 394 else
 395   AM_CONDITIONAL(USE_WAYLAND, false)
 396 fi
 397
 398 # strip leading space
 399 GDK_BACKENDS=${GDK_BACKENDS#* }
 400
 401 AC_SUBST(GDK_BACKENDS)
 402
 403 if test -z "$GDK_BACKENDS"; then
 404   AC_MSG_ERROR([No GDK backends selected.])
 405 fi
 406
 407 if test "x$enable_debug" = "xyes"; then
 408   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 409   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 410 else
 411   if test "x$enable_debug" = "xno"; then
 412     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 413   else
 414     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 415   fi
 416 fi
 417
 418
 419 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 420                    [Define if debugging is enabled])
 421
 422
 423 # Build time sanity check...
 424 AM_SANITY_CHECK
 425
 426 changequote(,)dnl
 427 if test "x$GCC" = "xyes"; then
 428   case " $CFLAGS " in
 429   *[\ \ ]-Wall[\ \      ]*) ;;
 430   *) CFLAGS="$CFLAGS -Wall" ;;
 431   esac
 432
 433   if test "x$enable_ansi" = "xyes"; then
 434     case " $CFLAGS " in
 435     *[\ \       ]-ansi[\ \      ]*) ;;
 436     *) CFLAGS="$CFLAGS -ansi" ;;
 437     esac
 438
 439     case " $CFLAGS " in
 440     *[\ \       ]-pedantic[\ \  ]*) ;;
 441     *) CFLAGS="$CFLAGS -pedantic" ;;
 442     esac
 443   fi
 444 fi
 445 changequote([,])dnl
 446
 447 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 448
 449 # Ensure MSVC-compatible struct packing convention is used when
 450 # compiling for Win32 with gcc.
 451 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 452 # gcc2 uses "-fnative-struct".
 453 if test x"$os_win32" = xyes; then
 454   if test x"$GCC" = xyes; then
 455     msnative_struct=''
 456     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 457     if test -z "$ac_cv_prog_CC"; then
 458       our_gcc="$CC"
 459     else
 460       our_gcc="$ac_cv_prog_CC"
 461     fi
 462     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 463       2.)
 464         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 465           msnative_struct='-fnative-struct'
 466         fi
 467         ;;
 468       *)
 469         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 470           msnative_struct='-mms-bitfields'
 471         fi
 472         ;;
 473     esac
 474     if test x"$msnative_struct" = x ; then
 475       AC_MSG_RESULT([no way])
 476       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 477     else
 478       CFLAGS="$CFLAGS $msnative_struct"
 479       AC_MSG_RESULT([${msnative_struct}])
 480     fi
 481   fi
 482 fi
 483
 484 ## Initial sanity check, done here so that users get told they
 485 ## have the wrong dependencies as early in the process as possible.
 486 ## Later on we actually use the cflags/libs from separate pkg-config
 487 ## calls. Oh, also the later pkg-config calls don't include
 488 ## the version requirements since those make the module lists
 489 ## annoying to construct
 490 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 491   [glib-2.0 >= glib_required_version dnl
 492    atk >= atk_required_version dnl
 493    pango >= pango_required_version dnl
 494    cairo >= cairo_required_version dnl
 495    cairo-gobject >= cairo_required_version dnl
 496    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 497
 498 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 499
 500 if test "$os_win32" != yes; then
 501     # libtool option to control which symbols are exported
 502     # right now, symbols starting with _ are not exported
 503     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 504 else
 505     # We currently use .def files on Windows (for gdk and gtk)
 506     LIBTOOL_EXPORT_OPTIONS=
 507 fi
 508 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 509
 510 dnl ******************************************************
 511 dnl * See whether to include shared library dependencies *
 512 dnl ******************************************************
 513
 514 AC_ARG_ENABLE(explicit-deps,
 515               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 516                               [use explicit dependencies in .pc files [default=auto]])],,
 517               [enable_explicit_deps=auto])
 518
 519 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 520 case $enable_explicit_deps in
 521   auto)
 522     export SED
 523     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 524     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 525       enable_explicit_deps=yes
 526     else
 527       enable_explicit_deps=no
 528     fi
 529   ;;
 530   yes|no)
 531   ;;
 532   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 533   ;;
 534 esac
 535 AC_MSG_RESULT($enable_explicit_deps)
 536
 537 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 538
 539 # define a MAINT-like variable REBUILD which is set if Perl
 540 # and awk are found, so autogenerated sources can be rebuilt
 541
 542 AC_PATH_PROGS(PERL, perl5 perl)
 543
 544 # We would like indent, but don't require it.
 545 AC_CHECK_PROG(INDENT, indent, indent)
 546
 547 REBUILD=\#
 548 if test "x$enable_rebuilds" = "xyes" && \
 549      test -n "$PERL" && \
 550      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 551   REBUILD=
 552 fi
 553 AC_SUBST(REBUILD)
 554
 555 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 556 AC_CHECK_FUNCS(localtime_r)
 557
 558 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 559 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 560 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 561                                 [[char c;
 562                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 563                [gtk_ok=yes], [gtk_ok=no])
 564 AC_MSG_RESULT($gtk_ok)
 565 if test "$gtk_ok" = "yes"; then
 566   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 567             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 568 fi
 569
 570 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 571 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 572 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 573                                 [[char c;
 574                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 575                [gtk_ok=yes], [gtk_ok=no])
 576 AC_MSG_RESULT($gtk_ok)
 577 if test "$gtk_ok" = "yes"; then
 578   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 579             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 580 fi
 581
 582 # _NL_PAPER_HEIGHT is an enum and not a define
 583 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 584 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 585                                 [[char c;
 586                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 587                [gtk_ok=yes], [gtk_ok=no])
 588 AC_MSG_RESULT($gtk_ok)
 589 if test "$gtk_ok" = "yes"; then
 590   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 591             [Define if _NL_PAPER_HEIGHT is available])
 592 fi
 593
 594 # _NL_PAPER_WIDTH is an enum and not a define
 595 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 596 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 597                                 [[char c;
 598                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 599                [gtk_ok=yes], [gtk_ok=no])
 600 AC_MSG_RESULT($gtk_ok)
 601 if test "$gtk_ok" = "yes"; then
 602   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 603             [Define if _NL_PAPER_WIDTH is available])
 604 fi
 605
 606 # i18n stuff
 607 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 608 AM_GLIB_GNU_GETTEXT
 609 LIBS="$LIBS $INTLLIBS"
 610 AC_CONFIG_COMMANDS([po-properties],
 611                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 612                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 613                      esac]],
 614                    [[]])
 615
 616 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 617 dnl po-properties/POTFILES during configure; see GNOME #573515.
 618 dnl
 619 dnl Generate list of files to be processed by xgettext which will
 620 dnl be included in po-properties/Makefile.
 621 test -d po-properties || mkdir po-properties
 622 if test "x$srcdir" != "x."; then
 623   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 624     popropsrcprefix="$srcdir/"
 625   else
 626     popropsrcprefix="../$srcdir/"
 627   fi
 628 else
 629   popropsrcprefix="../"
 630 fi
 631 rm -f po-properties/POTFILES
 632 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 633 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 634 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 635
 636 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 637
 638 dnl The DU4 header files don't provide library prototypes unless
 639 dnl -std1 is given to the native cc.
 640 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 641
 642 gtk_save_LIBS=$LIBS
 643 LIBS="$LIBS -lm"
 644 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 645                                 int main (void) { return (log(1) != log(1.)); }]])],
 646               [AC_MSG_RESULT(none needed)],
 647               [gtk_save_CFLAGS="$CFLAGS"
 648                CFLAGS="$CFLAGS -std1"
 649                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 650                                                int main (void) { return (log(1) != log(1.)); }]])],
 651                              [AC_MSG_RESULT(-std1)],
 652                              [AC_MSG_RESULT()
 653                               CFLAGS="$gtk_save_CFLAGS"
 654                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 655                              [true])],
 656               [AC_MSG_RESULT(none needed)])
 657
 658 LIBS=$gtk_save_LIBS
 659
 660 AC_MSG_CHECKING(for the BeOS)
 661 case $host in
 662   *-*-beos*)
 663     AC_MSG_RESULT(yes)
 664     MATH_LIB=
 665   ;;
 666   *)
 667     AC_MSG_RESULT(no)
 668   ;;
 669 esac
 670
 671 AC_SUBST(MATH_LIB)
 672 #
 673 # see bug 162979
 674 #
 675 AC_MSG_CHECKING(for HP-UX)
 676 case $host_os in
 677   hpux9* | hpux10* | hpux11*)
 678     AC_MSG_RESULT(yes)
 679     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 680   ;;
 681   *)
 682     AC_MSG_RESULT(no)
 683   ;;
 684 esac
 685
 686 #
 687 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 688 #
 689
 690 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 691
 692 AM_PATH_GLIB_2_0(glib_required_version, :,
 693   AC_MSG_ERROR([
 694 *** GLIB glib_required_version or better is required. The latest version of
 695 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 696   gobject gmodule-no-export gthread)
 697
 698 dnl
 699 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 700 dnl
 701 gtk_save_LIBS=$LIBS
 702 LIBS="$LIBS $GLIB_LIBS"
 703 AC_CHECK_FUNCS(bind_textdomain_codeset)
 704 LIBS=$gtk_save_LIBS
 705
 706 AC_CHECK_HEADERS(pwd.h,
 707                  AC_DEFINE(HAVE_PWD_H, 1,
 708                            [Define to 1 if pwd.h is available]))
 709 AC_CHECK_HEADERS(sys/time.h,
 710                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 711                            [Define to 1 if time.h is available]))
 712 AC_CHECK_HEADERS(unistd.h,
 713                  AC_DEFINE(HAVE_UNISTD_H, 1,
 714                            [Define to 1 if unistd.h is available]))
 715 AC_CHECK_HEADERS(ftw.h,
 716                  AC_DEFINE(HAVE_FTW_H, 1,
 717                            [Define to 1 if ftw.h is available]))
 718
 719 AC_MSG_CHECKING([for GNU ftw extensions])
 720 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 721                                      #define _GNU_SOURCE
 722                                      #include <ftw.h>]],
 723                                    [[int flags = FTW_ACTIONRETVAL;]])],
 724                   [gtk_ok=yes],[gtk_ok=no])
 725 if test $gtk_ok = yes; then
 726     AC_MSG_RESULT([yes])
 727     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 728 else
 729     AC_MSG_RESULT([no])
 730 fi
 731
 732 saved_cflags="$CFLAGS"
 733 saved_ldflags="$LDFLAGS"
 734
 735
 736 # Checks for library functions.
 737 AC_FUNC_MMAP
 738
 739 AC_CHECK_FUNCS(mallinfo)
 740 AC_CHECK_FUNCS(getresuid)
 741 AC_TYPE_UID_T
 742
 743 # Check for uxtheme.h (for MS-Windows Engine)
 744 AC_MSG_CHECKING(for uxtheme.h)
 745 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <uxtheme.h>]])],
 746                   [gtk_uxtheme_h=yes], [gtk_uxtheme_h=no])
 747 if test $gtk_uxtheme_h = yes; then
 748    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 749 fi
 750 AC_MSG_RESULT($gtk_uxtheme_h)
 751
 752 # Check for round()
 753 AC_CHECK_LIB(m,round,have_round=yes,have_round=no)
 754 if test $have_round = yes; then
 755     AC_DEFINE(HAVE_ROUND, 1, [Define to 1 if round() is available])
 756 fi
 757
 758 # Check for rint()
 759 AC_CHECK_LIB(m,rint,have_rint=yes,have_rint=no)
 760 if test $have_rint = yes; then
 761     AC_DEFINE(HAVE_RINT, 1, [Define to 1 if rint() is available])
 762 fi
 763
 764 # Checks for gdkspawn
 765 AC_CHECK_HEADERS(crt_externs.h)
 766 AC_CHECK_FUNCS(_NSGetEnviron)
 767
 768 AC_MSG_CHECKING(whether to build dynamic modules)
 769
 770 AC_ARG_ENABLE(modules,
 771               [AS_HELP_STRING([--disable-modules],
 772                               [disable dynamic module loading])])
 773
 774 dynworks=false
 775 build_dynamic_modules=no
 776 deps=
 777 if test x$enable_modules = xno; then
 778     AC_MSG_RESULT(no)
 779 else
 780     AC_MSG_RESULT(yes)
 781     AC_MSG_CHECKING(whether dynamic modules work)
 782     ## for loop is to strip newline
 783     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 784     for I in $tmp; do
 785         dynworks=$I
 786     done
 787
 788     dnl Now we check to see if our libtool supports shared lib deps
 789     dnl (in a rather ugly way even)
 790     if $dynworks; then
 791         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 792         module_deplibs_check=`$module_libtool_config | \
 793             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 794             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 795         if test "x$module_deplibs_check" = "xnone" || \
 796            test "x$module_deplibs_check" = "xunknown" || \
 797            test "x$module_deplibs_check" = "x"; then
 798             dynworks=false
 799         fi
 800     fi
 801
 802     if $dynworks; then
 803         build_dynamic_modules=yes
 804         AC_DEFINE(USE_GMODULE, 1,
 805                   [Define to 1 if gmodule works and should be used])
 806         AC_MSG_RESULT(yes)
 807     else
 808         build_dynamic_modules=no
 809         AC_MSG_RESULT(no)
 810     fi
 811 fi
 812
 813 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 814
 815 #
 816 # Allow building some or all immodules included
 817 #
 818 AC_MSG_CHECKING(immodules to build)
 819
 820 AC_ARG_WITH(included_immodules,
 821             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 822                             [build the specified input methods into gtk])])
 823
 824 if $dynworks; then
 825    :
 826 else
 827    ## if the option was specified, leave it; otherwise disable included immodules
 828    if test x$with_included_immodules = xno; then
 829            with_included_immodules=yes
 830    fi
 831 fi
 832
 833 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 834
 835 included_immodules=""
 836 # If the switch specified without listing any specific ones, include all
 837 if test "x$with_included_immodules" = xyes ; then
 838   included_immodules="$all_immodules"
 839 else
 840   included_immodules="$with_included_immodules"
 841 fi
 842
 843 AC_MSG_RESULT($included_immodules)
 844 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 845
 846 INCLUDED_IMMODULE_OBJ=
 847 INCLUDED_IMMODULE_DEFINE=
 848
 849 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 850 for immodule in $included_immodules; do
 851  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 852  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 853    :
 854  else
 855    AC_MSG_ERROR([the specified input method $immodule does not exist])
 856  fi
 857
 858  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 859  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 860  eval INCLUDE_$immodule_underscores=yes
 861 done
 862 IFS="$gtk_save_ifs"
 863 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 864 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 865
 866 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 867 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 868 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 869 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 870 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 871 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 872 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 873 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 874 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 875 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 876 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 877 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 878
 879 # Checks to see whether we should include mediaLib
 880 # support.
 881 #
 882 AC_CHECK_HEADER(sys/systeminfo.h,
 883                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 884                           [Define to 1 if sys/systeminfo.h is available]))
 885 AC_CHECK_HEADER(sys/sysinfo.h,
 886                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 887                           [Define to 1 if sys/sysinfo.h is available]))
 888
 889 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 890
 891 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 892
 893 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 894   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 895   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 896     REBUILD_PNGS=#
 897   fi
 898 fi
 899
 900 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 901
 902 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 903
 904 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 905    test "x$REBUILD_PNGS" = "x#" ; then
 906      AC_MSG_ERROR([
 907 *** gtkbuiltincache.h is not in the tree, and cannot be built
 908 *** because you don't have libpng, or (when cross-compiling) you
 909 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 910 fi
 911
 912 ########################################
 913 # Windowing system checks
 914 ########################################
 915
 916 # GTK+ uses some X calls, so needs to link against X directly
 917 GTK_DEP_PACKAGES_FOR_X=
 918 GTK_DEP_LIBS_FOR_X=
 919 X_EXTENSIONS=
 920
 921 if test "x$enable_x11_backend" = xyes; then
 922   X_PACKAGES=fontconfig
 923
 924   #
 925   # We use fontconfig very peripherally when decoding the default
 926   # settings.
 927   #
 928   if $PKG_CONFIG --exists fontconfig; then : ; else
 929     AC_MSG_ERROR([
 930 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 931   fi
 932
 933   #
 934   # Check for basic X packages; we use pkg-config if available
 935   #
 936   if $PKG_CONFIG --exists x11 xext; then
 937     have_base_x_pc=true
 938     X_PACKAGES="$X_PACKAGES x11 xext"
 939     x_libs="`$PKG_CONFIG --libs x11 xext`"
 940     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 941
 942     # Strip out any .la files that pkg-config might give us (this happens
 943     # with -uninstalled.pc files)
 944     x_libs_for_checks=
 945     for I in $x_libs ; do
 946       case $I in
 947         *.la) ;;
 948         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 949       esac
 950     done
 951
 952     GTK_PACKAGES_FOR_X="x11"
 953   else
 954     have_base_x_pc=false
 955     AC_PATH_XTRA
 956     if test x$no_x = xyes ; then
 957       AC_MSG_ERROR([X development libraries not found])
 958     fi
 959
 960     x_cflags="$X_CFLAGS"
 961     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 962
 963     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 964   fi
 965
 966   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 967   x_extra_libs=
 968
 969   gtk_save_cppflags="$CPPFLAGS"
 970   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 971
 972   gtk_save_LIBS=$LIBS
 973   LIBS="$x_libs_for_checks $LIBS"
 974
 975   # Sanity check for the X11 and Xext libraries. While everything we need from
 976   # Xext is optional, the chances a system has *none* of these things is so
 977   # small that we just unconditionally require it.
 978   AC_CHECK_FUNC(XOpenDisplay, :,
 979                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 980   AC_CHECK_FUNC(XextFindDisplay, :,
 981                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 982
 983   # Check for xReply
 984
 985   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 986   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 987                                      [[xReply *rep;]])],
 988                     [AC_MSG_RESULT([no])],
 989                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 990                                                           #include <X11/Xlibint.h>]],
 991                                                         [[xReply *rep;]])],
 992                                        [AC_MSG_RESULT([yes])
 993                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 994                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 995                                        [AC_MSG_RESULT([unknown])
 996                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 997
 998   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 999
1000   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1001
1002   # Generic X11R6 check needed for XIM support; we could
1003   # probably use this to replace the above, but we'll
1004   # leave the separate checks for XConvertCase and XInternAtoms
1005   # for clarity
1006
1007   have_x11r6=false
1008   AC_CHECK_FUNC(XAddConnectionWatch,
1009       have_x11r6=true)
1010
1011   if $have_x11r6; then
1012     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1013   fi
1014   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1015
1016   # Check for XKB support.
1017
1018   if test "x$enable_xkb" = "xyes"; then
1019         AC_CHECK_FUNC(XkbQueryExtension,
1020                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1021                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1022                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1023   elif test "x$enable_xkb" = "xmaybe"; then
1024         AC_CHECK_FUNC(XkbQueryExtension,
1025                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1026                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1027   else
1028         AC_MSG_WARN(XKB support explicitly disabled)
1029   fi
1030
1031   # Check for shaped window extension
1032
1033   AC_CHECK_FUNC(XShapeCombineMask, :,
1034      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1035
1036   # X SYNC check
1037   gtk_save_CFLAGS="$CFLAGS"
1038   CFLAGS="$CFLAGS $x_cflags"
1039
1040   AC_CHECK_FUNC(XSyncQueryExtension,
1041       [AC_CHECK_HEADER(X11/extensions/sync.h,
1042           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1043           :, [#include <X11/Xlib.h>])])
1044
1045   CFLAGS="$gtk_save_CFLAGS"
1046
1047   if test "x$enable_xinerama" != "xno"; then
1048     # Check for Xinerama extension (Solaris impl or Xfree impl)
1049     have_xfree_xinerama=false
1050     have_solaris_xinerama=false
1051
1052     gtk_save_cppflags="$CPPFLAGS"
1053     CPPFLAGS="$CPPFLAGS $x_cflags"
1054
1055     # Check for XFree
1056     AC_MSG_CHECKING(for Xinerama packages)
1057
1058     if $PKG_CONFIG --exists xinerama ; then
1059        AC_MSG_RESULT(yes)
1060        have_xfree_xinerama=true
1061        X_PACKAGES="$X_PACKAGES xinerama"
1062     else
1063        AC_MSG_RESULT(no)
1064        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1065            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1066            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1067            have_xfree_xinerama=true], :,
1068            [#include <X11/Xlib.h>])])
1069     fi
1070
1071     if $have_xfree_xinerama ; then
1072       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1073       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1074                 [Define to 1 if XFree Xinerama is available])
1075       AC_DEFINE(HAVE_XINERAMA, 1,
1076                 [Define to 1 is Xinerama is available])
1077     else
1078       case "$host" in
1079         *-*-solaris*)
1080             # Check for solaris
1081             AC_MSG_CHECKING(for Xinerama support on Solaris)
1082
1083             have_solaris_xinerama=false
1084             AC_CHECK_FUNC(XineramaGetInfo,
1085                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1086                     [have_solaris_xinerama=true], :,
1087                     [#include <X11/Xlib.h>])])
1088
1089             if $have_solaris_xinerama ; then
1090               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1091               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1092                         [Define to 1 if solaris xinerama is available])
1093               AC_DEFINE(HAVE_XINERAMA, 1,
1094                         [Define to 1 if xinerama is available])
1095               AC_MSG_RESULT(yes)
1096             else
1097               AC_MSG_RESULT(no)
1098             fi
1099             ;;
1100         *)
1101             ;;
1102       esac
1103     fi
1104   fi
1105   if test "x$enable_xinerama" = "xyes" ; then
1106     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1107       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1108     fi
1109   fi
1110
1111   # Check for XGetEventData for GenericEvents
1112   AC_CHECK_FUNC(XGetEventData,
1113                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1114
1115   # set up things for XInput
1116   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1117     have_xinput=yes
1118
1119     AC_DEFINE(XINPUT_XFREE, 1,
1120               [Define to 1 if XFree XInput should be used])
1121
1122     X_PACKAGES="$X_PACKAGES xi"
1123
1124     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1125                     have_xinput2=yes
1126                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1127                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1128                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1129
1130   else
1131     AC_DEFINE(XINPUT_NONE, 1,
1132               [Define to 1 if no XInput should be used])
1133   fi
1134
1135   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1136   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1137
1138   if test "x$enable_xinput" = "xyes" ; then
1139     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1140       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1141     fi
1142   fi
1143
1144   # Check for the RANDR extension
1145   if test x"$enable_xrandr" != xno; then
1146     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1147       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1148
1149       X_PACKAGES="$X_PACKAGES xrandr"
1150       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1151     elif test x"$enable_xrandr" = xyes; then
1152       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1153     fi
1154   fi
1155
1156   # Checks for Xcursor library
1157
1158   if $PKG_CONFIG --exists xcursor ; then
1159     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1160
1161     X_PACKAGES="$X_PACKAGES xcursor"
1162   fi
1163
1164   # Checks for XFixes extension
1165
1166   if test x"$enable_xfixes" != xno; then
1167     if $PKG_CONFIG --exists xfixes ; then
1168       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1169
1170       X_PACKAGES="$X_PACKAGES xfixes"
1171       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1172       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1173     elif test x"$enable_xfixes" = xyes; then
1174       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1175     fi
1176   fi
1177
1178   # Checks for Xcomposite extension
1179
1180   if test x"$enable_xcomposite" != xno; then
1181     if $PKG_CONFIG --exists xcomposite ; then
1182       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1183
1184       X_PACKAGES="$X_PACKAGES xcomposite"
1185       X_EXTENSIONS="$X_EXTENSIONS Composite"
1186       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1187     elif test x"$enable_xcomposite" = xyes; then
1188       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1189     fi
1190   fi
1191
1192   # Checks for Xdamage extension
1193
1194   if test x"$enable_xdamage" != xno; then
1195     if $PKG_CONFIG --exists xdamage ; then
1196       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1197
1198       X_PACKAGES="$X_PACKAGES xdamage"
1199       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1200       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1201     elif test x"$enable_xdamage" = xyes; then
1202       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1203     fi
1204   fi
1205
1206   if $have_base_x_pc ; then
1207     GDK_EXTRA_LIBS="$x_extra_libs"
1208   else
1209     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1210   fi
1211
1212   CPPFLAGS="$gtk_save_cppflags"
1213   LIBS="$gtk_save_libs"
1214
1215   AM_CONDITIONAL(USE_X11, true)
1216
1217   # strip leading space
1218   X_EXTENSIONS=${X_EXTENSIONS#* }
1219
1220 else
1221   XPACKAGES=
1222
1223   AM_CONDITIONAL(XINPUT_XFREE, false)
1224   AM_CONDITIONAL(XINPUT_2, false)
1225   AM_CONDITIONAL(USE_X11, false)
1226   AM_CONDITIONAL(HAVE_X11R6, false)
1227 fi
1228
1229 # Check for Pango flags
1230
1231 AC_MSG_CHECKING(Pango flags)
1232 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1233         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1234         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1235
1236         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1237 else
1238         AC_MSG_ERROR([
1239 *** Pango not found. Pango built with Cairo support is required
1240 *** to build GTK+. See http://www.pango.org for Pango information.
1241 ])
1242 fi
1243
1244 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1245
1246 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1247         :
1248 else
1249         gtk_save_LIBS="$LIBS"
1250         LIBS="$PANGO_LIBS $LIBS"
1251         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1252 *** Can't link to Pango. Pango is required to build
1253 *** GTK+. For more information see http://www.pango.org]))
1254         LIBS="$gtk_save_LIBS"
1255 fi
1256
1257 CFLAGS="$saved_cflags"
1258 LDFLAGS="$saved_ldflags"
1259
1260 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1261
1262 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES` $MATH_LIB"
1263 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1264 #
1265 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1266 # into the pkg-config files
1267 #
1268 if test $enable_explicit_deps != yes ; then
1269   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1270   GDK_EXTRA_LIBS=
1271 fi
1272
1273 AC_SUBST(GDK_PACKAGES)
1274 AC_SUBST(GDK_EXTRA_LIBS)
1275 AC_SUBST(GDK_EXTRA_CFLAGS)
1276 AC_SUBST(GDK_DEP_LIBS)
1277 AC_SUBST(GDK_DEP_CFLAGS)
1278
1279
1280 ########################################
1281 # Check for Accessibility Toolkit flags
1282 ########################################
1283
1284 ATK_PACKAGES=atk
1285 AC_MSG_CHECKING(ATK flags)
1286 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1287         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1288         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1289
1290         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1291 else
1292         AC_MSG_ERROR([
1293 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1294 *** to build GTK+.
1295 ])
1296 fi
1297
1298 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1299         :
1300 else
1301         gtk_save_LIBS="$LIBS"
1302         LIBS="$ATK_LIBS $LIBS"
1303         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1304                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1305                 *** to build GTK+]))
1306         LIBS="$gtk_save_LIBS"
1307 fi
1308
1309 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1310 if test "x$enable_x11_backend" = xyes; then
1311   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1312 fi
1313 GTK_EXTRA_LIBS=
1314
1315 GTK_EXTRA_CFLAGS=
1316 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS $MATH_LIB"
1317 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1318
1319 if test x"$os_win32" = xyes; then
1320   GTK_EXTRA_CFLAGS="$msnative_struct"
1321 fi
1322
1323 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1324 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1325 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1326 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1327
1328 AC_SUBST(GTK_PACKAGES)
1329 AC_SUBST(GTK_EXTRA_LIBS)
1330 AC_SUBST(GTK_EXTRA_CFLAGS)
1331 AC_SUBST(GTK_DEP_LIBS)
1332 AC_SUBST(GTK_DEP_CFLAGS)
1333
1334 AC_SUBST(GLIB_PREFIX)
1335 AC_SUBST(ATK_PREFIX)
1336 AC_SUBST(PANGO_PREFIX)
1337 AC_SUBST(CAIRO_PREFIX)
1338
1339 AC_SUBST(GTK_DEBUG_FLAGS)
1340 AC_SUBST(GTK_XIM_FLAGS)
1341
1342 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1343 AC_SUBST(GDK_PIXBUF_LIBS)
1344
1345 ########################
1346 # Checks needed for gail
1347 ########################
1348
1349 old_LIBS="$LIBS"
1350 dnl Checks for inet libraries:
1351 AC_SEARCH_LIBS(gethostent, nsl)
1352 AC_SEARCH_LIBS(setsockopt, socket)
1353 AC_SEARCH_LIBS(connect, inet)
1354
1355 dnl check for the sockaddr_un.sun_len member
1356 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1357                 [struct_sockaddr_un_sun_len=true],
1358                 [struct_sockaddr_un_suin_len=false],
1359                 [#include <sys/types.h>
1360                  #include <sys/un.h>]
1361                 )
1362 case $struct_sockaddr_un_sun_len in
1363         true)
1364                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1365                                    [Have the sockaddr_un.sun_len member])
1366                 ;;
1367         *)
1368                 ;;
1369 esac
1370
1371 GAIL_INET_LIBS="$LIBS"
1372 AC_SUBST([GAIL_INET_LIBS])
1373
1374 LIBS="$old_LIBS"
1375
1376 ################################################################
1377 # Printing system checks
1378 ################################################################
1379
1380 PRINT_BACKENDS="file lpr"
1381
1382 AC_ARG_ENABLE(cups,
1383               [AS_HELP_STRING([--disable-cups],
1384                               [disable cups print backend])],,
1385               [enable_cups=auto])
1386
1387 if test "x$enable_cups" = "xno"; then
1388   AM_CONDITIONAL(HAVE_CUPS, false)
1389 else
1390   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1391   if test "x$CUPS_CONFIG" = "xno"; then
1392     if test "x$enable_cups" = "xauto"; then
1393       AM_CONDITIONAL(HAVE_CUPS, false)
1394     else
1395       AC_MSG_ERROR([
1396 *** cups not found.
1397 ])
1398     fi
1399   else
1400     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1401     CUPS_LIBS=`$CUPS_CONFIG --libs`
1402
1403     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1404     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1405     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1406
1407     if test $CUPS_API_MAJOR -gt 1 -o \
1408             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1409       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1410                 [Define to 1 if CUPS 1.2 API is available])
1411     fi
1412
1413     AC_SUBST(CUPS_API_MAJOR)
1414     AC_SUBST(CUPS_API_MINOR)
1415     AC_SUBST(CUPS_CFLAGS)
1416     AC_SUBST(CUPS_LIBS)
1417
1418     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1419
1420     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1421     AM_CONDITIONAL(HAVE_CUPS, true)
1422
1423     gtk_save_cflags="$CFLAGS"
1424     CFLAGS="$CUPS_CFLAGS"
1425     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1426                                        [[http_t http; char *s = http.authstring;]])],
1427                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1428                                  [Define if cups http_t authstring field is accessible])],
1429                       [])
1430     CFLAGS="$gtk_save_cflags"
1431
1432     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1433
1434     gtk_save_libs="$LIBS"
1435     LIBS="$CUPS_LIBS"
1436     AC_CHECK_FUNCS(httpGetAuthString)
1437     LIBS="$gtk_save_libs"
1438   fi
1439 fi
1440
1441 # Checks to see if we should compile with PAPI backend for GTK+
1442 #
1443
1444 AC_ARG_ENABLE(papi,
1445               [AS_HELP_STRING([--disable-papi],
1446                               [disable papi print backend])],,
1447               [enable_papi=auto])
1448
1449 if test "x$enable_papi" = "xno"; then
1450   AM_CONDITIONAL(HAVE_PAPI, false)
1451 else
1452   AC_MSG_CHECKING(libpapi)
1453   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1454   if test $have_papi = yes; then
1455     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1456     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1457   fi
1458   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1459   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1460     AC_MSG_ERROR([
1461 *** papi not found.
1462 ])
1463   fi
1464 fi
1465
1466 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1467
1468 gtk_save_cppflags="$CPPFLAGS"
1469 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1470
1471 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1472 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1473 *** backend enabled.]))
1474
1475 if test "$os_win32" != "yes"; then
1476   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1477 *** Can't find cairo-ps.h. You must build Cairo with the
1478 *** postscript backend enabled.]))
1479
1480   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1481 *** Cannot find cairo-svg.h. You must build Cairo with the
1482 *** svg backend enabled.]))
1483 fi
1484
1485 CPPFLAGS="$gtk_save_cppflags"
1486
1487
1488 AC_ARG_ENABLE(test-print-backend,
1489               [AS_HELP_STRING([--enable-test-print-backend],
1490                               [build test print backend])],,
1491               [enable_test_print_backend=no])
1492 if test "x$enable_test_print_backend" != "xno" ; then
1493   PRINT_BACKENDS="$PRINT_BACKENDS test"
1494 fi
1495 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1496
1497
1498 ################################################################
1499 # Strip -export-dynamic from the link lines of various libraries
1500 ################################################################
1501
1502 #
1503 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1504 #  but this flag is only meaningful for executables. For libraries
1505 #  the effect is undefined; what it causes on Linux is that the
1506 #  export list from -export-symbols-regex is ignored and everything
1507 #  is exported
1508 #
1509 # We are using gmodule-no-export now, but I'm leaving the stripping
1510 # code in place for now, since pango and atk still require gmodule.
1511 export SED
1512 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1513 if test -n "$export_dynamic"; then
1514   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1515   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1516 fi
1517
1518 #############
1519 # GSettings #
1520 #############
1521
1522 GLIB_GSETTINGS
1523
1524 ##################################################
1525 # GObject introspection
1526 ##################################################
1527
1528 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1529
1530 ##################################################
1531 # Packagekit module
1532 #################################################
1533
1534 AC_ARG_ENABLE(packagekit,
1535               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1536                               [build PackageKit open-with module [default=auto]])],
1537               [enable_packagekit="$enableval"],
1538               [enable_packagekit=auto])
1539 if test "$enable_packagekit" = "auto"; then
1540   if test "$os_win32" = "yes"; then
1541     enable_packagekit=no
1542   else
1543     enable_packagekit=yes
1544   fi
1545 fi
1546
1547 AC_MSG_CHECKING([whether to use PackageKit])
1548 build_packagekit=no
1549 if test "x$enable_packagekit" != "xno"; then
1550   if test "$os_win32" != "yes"; then
1551     build_packagekit=yes
1552     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1553   else
1554     AC_MSG_ERROR([packagekit support is not available on win32])
1555   fi
1556 fi
1557 AC_MSG_RESULT([$build_packagekit])
1558
1559 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1560
1561 ##################################################
1562 # colord module
1563 #################################################
1564
1565 AC_ARG_ENABLE(colord,
1566               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1567                               [build colord support code [default=auto]])],
1568               [enable_colord="$enableval"],
1569               [enable_colord=auto])
1570
1571 AC_MSG_CHECKING([whether to use colord])
1572 if test "$enable_colord" = "auto"; then
1573   if test "$os_win32" = "yes"; then
1574     enable_colord=no
1575   fi
1576 fi
1577 if test "$enable_colord" != "no"; then
1578   AC_MSG_RESULT([yes])
1579 else
1580   AC_MSG_RESULT([no])
1581 fi
1582
1583 have_colord=no
1584 if test "$enable_colord" != "no"; then
1585         if test "$os_win32" != "yes"; then
1586                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1587                                   have_colord=yes, have_colord=no)
1588                 if test "$enable_colord" = "yes"; then
1589                         if test "$have_colord" = "no"; then
1590                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1591                         fi
1592                 fi
1593         else
1594                 AC_MSG_ERROR([colord support is not available on win32])
1595         fi
1596 fi
1597
1598 if test "$have_colord" = "yes"; then
1599         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1600 fi
1601 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1602
1603 ##################################################
1604 # Checks for gtk-doc and docbook-tools
1605 ##################################################
1606
1607 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1608
1609 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1610 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1611
1612 AC_ARG_ENABLE(man,
1613               [AS_HELP_STRING([--enable-man],
1614                               [regenerate man pages from Docbook [default=no]])],
1615               [enable_man=yes],
1616               [enable_man=no])
1617
1618 if test "${enable_man}" != no; then
1619   dnl
1620   dnl Check for xsltproc
1621   dnl
1622   AC_PATH_PROG([XSLTPROC], [xsltproc])
1623   if test -z "$XSLTPROC"; then
1624     enable_man=no
1625   fi
1626
1627   dnl check for DocBook DTD and stylesheets in the local catalog.
1628   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1629      [DocBook XML DTD V4.1.2],,enable_man=no)
1630   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1631      [DocBook XSL Stylesheets],,enable_man=no)
1632 fi
1633
1634 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1635
1636
1637 ##################################################
1638 # Output commands
1639 ##################################################
1640
1641 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1642         outfile=gdkconfig.h-tmp
1643         cat > $outfile <<\_______EOF
1644 /* gdkconfig.h
1645  *
1646  * This is a generated file.  Please modify `configure.ac'
1647  */
1648
1649 #ifndef __GDKCONFIG_H__
1650 #define __GDKCONFIG_H__
1651
1652 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1653 #error "Only <gdk/gdk.h> can be included directly."
1654 #endif
1655
1656 #include <glib.h>
1657
1658 G_BEGIN_DECLS
1659
1660 /* These macros are used to mark deprecated functions in GDK and
1661  * GTK+ headers, and thus have to be exposed in installed headers.
1662  * But please do *not* use them in other projects. Instead, use
1663  * G_DEPRECATED or define your own wrappers around it.
1664  */
1665
1666 #ifdef GDK_DISABLE_DEPRECATION_WARNINGS
1667 #define GDK_DEPRECATED
1668 #define GDK_DEPRECATED_FOR(f)
1669 #else
1670 #define GDK_DEPRECATED G_DEPRECATED
1671 #define GDK_DEPRECATED_FOR(f) G_DEPRECATED_FOR(f)
1672 #endif
1673
1674 _______EOF
1675
1676         cat >>$outfile <<_______EOF
1677 $gdk_windowing
1678 _______EOF
1679
1680         cat >>$outfile <<_______EOF
1681
1682 G_END_DECLS
1683
1684 #endif  /* __GDKCONFIG_H__ */
1685 _______EOF
1686
1687
1688         if cmp -s $outfile gdk/gdkconfig.h; then
1689           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1690           rm -f $outfile
1691         else
1692           mv $outfile gdk/gdkconfig.h
1693         fi
1694 ],[
1695 gdk_windowing='$GDK_WINDOWING'
1696 ])
1697
1698 dnl
1699 dnl Check for -Bsymbolic-functions linker flag used to avoid
1700 dnl intra-library PLT jumps, if available.
1701 dnl
1702 AC_ARG_ENABLE(Bsymbolic,
1703               [AS_HELP_STRING([--disable-Bsymbolic],
1704                               [avoid linking with -Bsymbolic])],,
1705               [SAVED_LDFLAGS="${LDFLAGS}"
1706                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1707                LDFLAGS=-Wl,-Bsymbolic-functions
1708                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1709                                                [[int main (void) { return 0; }]])],
1710                               [AC_MSG_RESULT(yes)
1711                                enable_Bsymbolic=yes],
1712                               [AC_MSG_RESULT(no)
1713                                enable_Bsymbolic=no])
1714                LDFLAGS="${SAVED_LDFLAGS}"])
1715
1716 if test "x${enable_Bsymbolic}" = "xyes" ; then
1717   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1718 fi
1719 AC_SUBST(GTK_LINK_FLAGS)
1720
1721 AC_CONFIG_FILES([
1722 config.h.win32
1723 gtk-zip.sh
1724 Makefile
1725 gdk-3.0.pc
1726 gtk+-3.0.pc
1727 gtk+-unix-print-3.0.pc
1728 gail-3.0.pc
1729 gtk+-3.0-uninstalled.pc
1730 gail-3.0-uninstalled.pc
1731 m4macros/Makefile
1732 po/Makefile.in
1733 po-properties/Makefile.in
1734 demos/Makefile
1735 demos/gtk-demo/Makefile
1736 demos/gtk-demo/geninclude.pl
1737 demos/pixbuf-demo/Makefile
1738 examples/Makefile
1739 tests/Makefile
1740 tests/a11y/Makefile
1741 tests/css/Makefile
1742 tests/css/parser/Makefile
1743 tests/reftests/Makefile
1744 docs/Makefile
1745 docs/reference/Makefile
1746 docs/reference/gdk/Makefile
1747 docs/reference/gdk/version.xml
1748 docs/reference/gtk/Makefile
1749 docs/reference/gtk/version.xml
1750 docs/reference/libgail-util/Makefile
1751 docs/reference/libgail-util/version.xml
1752 docs/tools/Makefile
1753 build/Makefile
1754 build/win32/Makefile
1755 build/win32/vs9/Makefile
1756 build/win32/vs10/Makefile
1757 gdk/Makefile
1758 gdk/broadway/Makefile
1759 gdk/x11/Makefile
1760 gdk/win32/Makefile
1761 gdk/win32/rc/Makefile
1762 gdk/win32/rc/gdk.rc
1763 gdk/quartz/Makefile
1764 gdk/wayland/Makefile
1765 gdk/tests/Makefile
1766 gtk/Makefile
1767 gtk/makefile.msc
1768 gtk/gtkversion.h
1769 gtk/gtk-win32.rc
1770 gtk/a11y/Makefile
1771 gtk/tests/Makefile
1772 libgail-util/Makefile
1773 modules/Makefile
1774 modules/engines/Makefile
1775 modules/engines/pixbuf/Makefile
1776 modules/engines/ms-windows/Makefile
1777 modules/engines/ms-windows/Theme/Makefile
1778 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1779 modules/input/Makefile
1780 modules/printbackends/Makefile
1781 modules/printbackends/cups/Makefile
1782 modules/printbackends/lpr/Makefile
1783 modules/printbackends/file/Makefile
1784 modules/printbackends/papi/Makefile
1785 modules/printbackends/test/Makefile
1786 perf/Makefile
1787 ])
1788
1789 AC_OUTPUT
1790
1791 # beautify the immodule list a bit
1792 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1793 if test -z "${included_immodules}"; then included_immodules="none"; fi
1794
1795 echo ""
1796 echo "        GTK+ $GTK_VERSION"
1797 echo "        ==========="
1798 echo ""
1799 echo "        GDK backends:         $GDK_BACKENDS"
1800 if test "$enable_x11_backend" = "yes"; then
1801 echo "        X11 extensions:       $X_EXTENSIONS"
1802 fi
1803 echo "        Print backends:       $PRINT_BACKENDS"
1804 echo "        Dynamic modules:      $build_dynamic_modules"
1805 echo "        Included immodules:   $included_immodules"
1806 echo "        PackageKit support:   $build_packagekit"
1807 echo "        colord support:       $have_colord"
1808 echo "        Introspection:        $found_introspection"
1809 echo "        Debugging:            $enable_debug"
1810 echo "        Documentation:        $enable_gtk_doc"