Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [1])
  13 m4_define([gtk_micro_version], [3])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.29.2])
  42 m4_define([pango_required_version], [1.24.0])
  43 m4_define([atk_required_version], [1.30])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.22.0])
  46 m4_define([introspection_required_version], [0.10.1])
  47 GLIB_REQUIRED_VERSION=glib_required_version
  48 PANGO_REQUIRED_VERSION=pango_required_version
  49 ATK_REQUIRED_VERSION=atk_required_version
  50 CAIRO_REQUIRED_VERSION=cairo_required_version
  51 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  52 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  53
  54 AC_SUBST(GLIB_REQUIRED_VERSION)
  55 AC_SUBST(PANGO_REQUIRED_VERSION)
  56 AC_SUBST(ATK_REQUIRED_VERSION)
  57 AC_SUBST(CAIRO_REQUIRED_VERSION)
  58 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  59 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  60
  61 # Save this value here, since automake will set cflags later
  62 cflags_set=${CFLAGS+set}
  63
  64 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  65 AM_MAINTAINER_MODE([enable])
  66
  67 # Support silent build rules, requires at least automake-1.11. Disable
  68 # by either passing --disable-silent-rules to configure or passing V=1
  69 # to make
  70 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  71
  72 #
  73 # For each of the libraries we build, we define the following
  74 # substituted variables:
  75 #
  76 # foo_PACKAGES:     pkg-config packages this library requires
  77 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  78 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  79 # foo_DEP_LIBS:     All libraries this module requires
  80 # foo_DEP_CFLAGS:   All cflags this module requires
  81
  82
  83 GTK_MAJOR_VERSION=gtk_major_version
  84 GTK_MINOR_VERSION=gtk_minor_version
  85 GTK_MICRO_VERSION=gtk_micro_version
  86 GTK_INTERFACE_AGE=gtk_interface_age
  87 GTK_BINARY_AGE=gtk_binary_age
  88 GTK_VERSION=gtk_version
  89 GTK_API_VERSION=gtk_api_version
  90 GTK_BINARY_VERSION=gtk_binary_version
  91 AC_SUBST(GTK_MAJOR_VERSION)
  92 AC_SUBST(GTK_MINOR_VERSION)
  93 AC_SUBST(GTK_MICRO_VERSION)
  94 AC_SUBST(GTK_INTERFACE_AGE)
  95 AC_SUBST(GTK_BINARY_AGE)
  96 AC_SUBST(GTK_API_VERSION)
  97 AC_SUBST(GTK_VERSION)
  98 AC_SUBST(GTK_BINARY_VERSION)
  99
 100 # libtool versioning
 101 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 102 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 103 #LT_REVISION=$GTK_INTERFACE_AGE
 104 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 105 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 106
 107 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 108 m4_define([lt_revision], [gtk_interface_age])
 109 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 110 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 111 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 112 AC_SUBST(LT_VERSION_INFO)
 113 AC_SUBST(LT_CURRENT_MINUS_AGE)
 114
 115 m4_define([gail_lt_current],[0])
 116 m4_define([gail_lt_revision],[0])
 117 m4_define([gail_lt_age],[0])
 118 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 119 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 120 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 121 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 122
 123 # Checks for programs.
 124 AC_PROG_CC
 125 AC_PROG_CC_C_O
 126 AC_PROG_CC_STDC
 127 AC_PROG_INSTALL
 128 AC_PROG_MAKE_SET
 129
 130
 131 GETTEXT_PACKAGE=gtk30
 132 AC_SUBST(GETTEXT_PACKAGE)
 133 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 134                    [The prefix for our gettext translation domains.])
 135
 136 AC_CANONICAL_HOST
 137
 138 MATH_LIB=-lm
 139 AC_MSG_CHECKING([for native Win32])
 140 LIB_EXE_MACHINE_FLAG=X86
 141 EXE_MANIFEST_ARCHITECTURE=X86
 142 case "$host" in
 143   *-*-mingw*)
 144     os_win32=yes
 145     gio_can_sniff=no
 146     MATH_LIB=
 147     case "$host" in
 148     x86_64-*-*)
 149       LIB_EXE_MACHINE_FLAG=X64
 150       EXE_MANIFEST_ARCHITECTURE=AMD64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     os_win32=no
 156     ;;
 157 esac
 158 AC_MSG_RESULT([$os_win32])
 159
 160 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 161 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 162
 163 case $host in
 164   *-*-linux*)
 165     os_linux=yes
 166     ;;
 167 esac
 168
 169 dnl
 170 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 171 dnl We use this for an automated test for C++ header correctness.
 172 dnl
 173 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 174 AC_LANG_PUSH([C++])
 175
 176 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 177                                    [[class a { int b; } c;]])],
 178                   [],[CXX=])
 179 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 180
 181 gtk_save_cxxflags="$CXXFLAGS"
 182 CXXFLAGS="$CXXFLAGS -x objective-c++"
 183 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 184                                    [[]])],
 185                   [OBJC=yes],[OBJC=no])
 186 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 187 CXXFLAGS="$gtk_save_cxxflags"
 188 AC_LANG_POP([C++])
 189
 190 if test "$os_win32" = "yes"; then
 191   if test x$enable_static = xyes -o x$enable_static = x; then
 192     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 193     enable_static=no
 194   fi
 195   if test x$enable_shared = xno; then
 196     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 197   fi
 198   enable_shared=yes
 199 fi
 200
 201 dnl Initialize libtool
 202 LT_PREREQ([2.2.6])
 203 LT_INIT([disable-static win32-dll])
 204 # Create libtool early, because it's used in configure
 205 LT_OUTPUT
 206
 207 # Make sure we use 64-bit versions of various file stuff.
 208 AC_SYS_LARGEFILE
 209
 210 AM_PROG_AS
 211 AC_PATH_PROG(NM, nm, nm)
 212
 213 AC_MSG_CHECKING([for some Win32 platform])
 214 case "$host" in
 215   *-*-mingw*|*-*-cygwin*)
 216     platform_win32=yes
 217     ;;
 218   *)
 219     platform_win32=no
 220     ;;
 221 esac
 222 AC_MSG_RESULT([$platform_win32])
 223 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 224
 225 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 226 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 227 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 228
 229 if test "$os_win32" = "yes"; then
 230   AC_CHECK_TOOL(WINDRES, windres, no)
 231   if test "$WINDRES" = no; then
 232     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 233   fi
 234   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 235 fi
 236 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 237
 238 m4_define([debug_default],
 239           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 240
 241 dnl declare --enable-* args and collect ac_help strings
 242 AC_ARG_ENABLE(debug,
 243               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 244                               [turn on debugging @<:@default=debug_default@:>@])],,
 245               [enable_debug=debug_default])
 246
 247 AC_ARG_ENABLE(rebuilds,
 248               [AS_HELP_STRING([--disable-rebuilds],
 249                               [disable all source autogeneration rules])],,
 250               [enable_rebuilds=yes])
 251
 252 AC_ARG_ENABLE(gtk2-dependency,
 253               [AS_HELP_STRING([--enable-gtk2-dependency],
 254                               [Do not build gtk-update-icon-cache and other shared tools])],,
 255               [enable_gtk2_dependency=no])
 256
 257 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 258
 259 AC_ARG_ENABLE(xkb,
 260               [AS_HELP_STRING([--enable-xkb],
 261                               [support XKB extension [default=maybe]])],,
 262               [enable_xkb="maybe"])
 263 AC_ARG_ENABLE(xinerama,
 264               [AS_HELP_STRING([--enable-xinerama],
 265                               [support Xinerama extension if available [default=maybe]])],,
 266               [enable_xinerama="maybe"])
 267 AC_ARG_ENABLE(xinput,
 268               [AS_HELP_STRING([--enable-xinput],
 269                               [support XInput extension if available [default=yes]])],,
 270               [enable_xinput="maybe"])
 271 AC_ARG_ENABLE(xrandr,
 272               [AS_HELP_STRING([--enable-xrandr],
 273                               [support XRandR extension if available [default=maybe]])],,
 274               [enable_xrandr="maybe"])
 275 AC_ARG_ENABLE(xfixes,
 276               [AS_HELP_STRING([--enable-xfixes],
 277                               [support XFixes extension if available [default=maybe]])],,
 278               [enable_xfixes="maybe"])
 279 AC_ARG_ENABLE(xcomposite,
 280               [AS_HELP_STRING([--enable-xcomposite],
 281                               [support X Composite extension if available [default=maybe]])],,
 282               [enable_xcomposite="maybe"])
 283 AC_ARG_ENABLE(xdamage,
 284               [AS_HELP_STRING([--enable-xdamage],
 285                               [support X Damage extension if available [default=maybe]])],,
 286               [enable_xdamage="maybe"])
 287
 288 AC_ARG_ENABLE(x11-backend,
 289               [AS_HELP_STRING([--enable-x11-backend],
 290                               [enable the X11 gdk backend])],
 291                               [backend_set=yes])
 292 AC_ARG_ENABLE(win32-backend,
 293               [AS_HELP_STRING([--enable-win32-backend],
 294                               [enable the Win32 gdk backend])],
 295                               [backend_set=yes])
 296 AC_ARG_ENABLE(quartz-backend,
 297               [AS_HELP_STRING([--enable-quartz-backend],
 298                               [enable the quartz gdk backend])],
 299                               [backend_set=yes])
 300 AC_ARG_ENABLE(broadway-backend,
 301               [AC_HELP_STRING([--enable-broadway-backend],
 302                               [enable the broadway (HTML5) gdk backend])],
 303                               [backend_set=yes])
 304 AC_ARG_ENABLE(wayland-backend,
 305               [AC_HELP_STRING([--enable-wayland-backend],
 306                               [enable the wayland gdk backend])],
 307                               [backend_set=yes])
 308
 309 if test -z "$backend_set"; then
 310   if test "$platform_win32" = yes; then
 311     enable_win32_backend=yes
 312   else
 313     enable_x11_backend=yes
 314   fi
 315 fi
 316
 317 cairo_backends=
 318 backend_immodules=
 319 GDK_BACKENDS=
 320 GDK_EXTRA_LIBS=
 321 GDK_EXTRA_CFLAGS=
 322 GDK_WINDOWING=
 323 GIO_PACKAGE=gio-2.0
 324 PANGO_PACKAGES="pango pangocairo"
 325
 326 if test "x$enable_x11_backend" = xyes; then
 327   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 328   # backend names are identical.
 329   cairo_backends="$cairo_backends cairo-xlib"
 330   GDK_BACKENDS="$GDK_BACKENDS x11"
 331   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 332   # gdkapplaunchcontext-x11.c
 333   GIO_PACKAGE=gio-unix-2.0
 334   backend_immodules="$backend_immodules,xim"
 335   GDK_WINDOWING="$GDK_WINDOWING
 336 #define GDK_WINDOWING_X11"
 337 fi
 338
 339 if test "x$enable_win32_backend" = xyes; then
 340   cairo_backends="$cairo_backends cairo-win32"
 341   GDK_BACKENDS="$GDK_BACKENDS win32"
 342   backend_immodules="$backend_immodules,ime"
 343   GDK_WINDOWING="$GDK_WINDOWING
 344 #define GDK_WINDOWING_WIN32"
 345   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 346   AM_CONDITIONAL(USE_WIN32, true)
 347   PANGO_PACKAGES="pangowin32 pangocairo"
 348 else
 349   AM_CONDITIONAL(USE_WIN32, false)
 350 fi
 351
 352 if test "x$enable_quartz_backend" = xyes; then
 353   cairo_backends="$cairo_backends cairo-quartz"
 354   GDK_BACKENDS="$GDK_BACKENDS quartz"
 355   GDK_WINDOWING="$GDK_WINDOWING
 356 #define GDK_WINDOWING_QUARTZ"
 357   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 358   AM_CONDITIONAL(USE_QUARTZ, true)
 359 else
 360   AM_CONDITIONAL(USE_QUARTZ, false)
 361 fi
 362
 363
 364 if test "x$enable_broadway_backend" == xyes; then
 365   GDK_BACKENDS="$GDK_BACKENDS broadway"
 366   cairo_backends="$cairo_backends cairo"
 367   GDK_WINDOWING="$GDK_WINDOWING
 368 #define GDK_WINDOWING_BROADWAY"
 369   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 370   AM_CONDITIONAL(USE_BROADWAY, true)
 371 else
 372   AM_CONDITIONAL(USE_BROADWAY, false)
 373 fi
 374
 375 if test "x$enable_wayland_backend" == "xyes"; then
 376   # Wayland uses cairo-gl
 377   cairo_backends="$cairo_backends cairo-gl"
 378   GDK_BACKENDS="$GDK_BACKENDS wayland"
 379   GIO_PACKAGE=gio-unix-2.0
 380   GDK_WINDOWING="$GDK_WINDOWING
 381 #define GDK_WINDOWING_WAYLAND"
 382   WAYLAND_PACKAGES="wayland-client xkbcommon wayland-egl"
 383   AM_CONDITIONAL(USE_WAYLAND, true)
 384 else
 385   AM_CONDITIONAL(USE_WAYLAND, false)
 386 fi
 387
 388 # strip leading space
 389 GDK_BACKENDS=${GDK_BACKENDS#* }
 390
 391 AC_SUBST(GDK_BACKENDS)
 392
 393 if test -z "$GDK_BACKENDS"; then
 394   AC_MSG_ERROR([No GDK backends selected.])
 395 fi
 396
 397 if test "x$enable_debug" = "xyes"; then
 398   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 399   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 400 else
 401   if test "x$enable_debug" = "xno"; then
 402     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 403   else
 404     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 405   fi
 406 fi
 407
 408
 409 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 410                    [Define if debugging is enabled])
 411
 412
 413 # Build time sanity check...
 414 AM_SANITY_CHECK
 415
 416 changequote(,)dnl
 417 if test "x$GCC" = "xyes"; then
 418   case " $CFLAGS " in
 419   *[\ \ ]-Wall[\ \      ]*) ;;
 420   *) CFLAGS="$CFLAGS -Wall" ;;
 421   esac
 422
 423   if test "x$enable_ansi" = "xyes"; then
 424     case " $CFLAGS " in
 425     *[\ \       ]-ansi[\ \      ]*) ;;
 426     *) CFLAGS="$CFLAGS -ansi" ;;
 427     esac
 428
 429     case " $CFLAGS " in
 430     *[\ \       ]-pedantic[\ \  ]*) ;;
 431     *) CFLAGS="$CFLAGS -pedantic" ;;
 432     esac
 433   fi
 434 fi
 435 changequote([,])dnl
 436
 437 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 438
 439 # Ensure MSVC-compatible struct packing convention is used when
 440 # compiling for Win32 with gcc.
 441 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 442 # gcc2 uses "-fnative-struct".
 443 if test x"$os_win32" = xyes; then
 444   if test x"$GCC" = xyes; then
 445     msnative_struct=''
 446     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 447     if test -z "$ac_cv_prog_CC"; then
 448       our_gcc="$CC"
 449     else
 450       our_gcc="$ac_cv_prog_CC"
 451     fi
 452     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 453       2.)
 454         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 455           msnative_struct='-fnative-struct'
 456         fi
 457         ;;
 458       *)
 459         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 460           msnative_struct='-mms-bitfields'
 461         fi
 462         ;;
 463     esac
 464     if test x"$msnative_struct" = x ; then
 465       AC_MSG_RESULT([no way])
 466       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 467     else
 468       CFLAGS="$CFLAGS $msnative_struct"
 469       AC_MSG_RESULT([${msnative_struct}])
 470     fi
 471   fi
 472 fi
 473
 474 ## Initial sanity check, done here so that users get told they
 475 ## have the wrong dependencies as early in the process as possible.
 476 ## Later on we actually use the cflags/libs from separate pkg-config
 477 ## calls. Oh, also the later pkg-config calls don't include
 478 ## the version requirements since those make the module lists
 479 ## annoying to construct
 480 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 481   [glib-2.0 >= glib_required_version dnl
 482    atk >= atk_required_version dnl
 483    pango >= pango_required_version dnl
 484    cairo >= cairo_required_version dnl
 485    cairo-gobject >= cairo_required_version dnl
 486    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 487
 488 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 489
 490 if test "$os_win32" != yes; then
 491     # libtool option to control which symbols are exported
 492     # right now, symbols starting with _ are not exported
 493     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 494 else
 495     # We currently use .def files on Windows (for gdk and gtk)
 496     LIBTOOL_EXPORT_OPTIONS=
 497 fi
 498 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 499
 500 dnl ******************************************************
 501 dnl * See whether to include shared library dependencies *
 502 dnl ******************************************************
 503
 504 AC_ARG_ENABLE(explicit-deps,
 505               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 506                               [use explicit dependencies in .pc files [default=auto]])],,
 507               [enable_explicit_deps=auto])
 508
 509 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 510 case $enable_explicit_deps in
 511   auto)
 512     export SED
 513     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 514     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 515       enable_explicit_deps=yes
 516     else
 517       enable_explicit_deps=no
 518     fi
 519   ;;
 520   yes|no)
 521   ;;
 522   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 523   ;;
 524 esac
 525 AC_MSG_RESULT($enable_explicit_deps)
 526
 527 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 528
 529 # define a MAINT-like variable REBUILD which is set if Perl
 530 # and awk are found, so autogenerated sources can be rebuilt
 531
 532 AC_PATH_PROGS(PERL, perl5 perl)
 533
 534 # We would like indent, but don't require it.
 535 AC_CHECK_PROG(INDENT, indent, indent)
 536
 537 REBUILD=\#
 538 if test "x$enable_rebuilds" = "xyes" && \
 539      test -n "$PERL" && \
 540      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 541   REBUILD=
 542 fi
 543 AC_SUBST(REBUILD)
 544
 545 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 546 AC_CHECK_FUNCS(localtime_r)
 547
 548 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 549 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 550 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 551                                 [[char c;
 552                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 553                [gtk_ok=yes], [gtk_ok=no])
 554 AC_MSG_RESULT($gtk_ok)
 555 if test "$gtk_ok" = "yes"; then
 556   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 557             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 558 fi
 559
 560 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 561 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 562 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 563                                 [[char c;
 564                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 565                [gtk_ok=yes], [gtk_ok=no])
 566 AC_MSG_RESULT($gtk_ok)
 567 if test "$gtk_ok" = "yes"; then
 568   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 569             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 570 fi
 571
 572 # _NL_PAPER_HEIGHT is an enum and not a define
 573 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 574 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 575                                 [[char c;
 576                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 577                [gtk_ok=yes], [gtk_ok=no])
 578 AC_MSG_RESULT($gtk_ok)
 579 if test "$gtk_ok" = "yes"; then
 580   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 581             [Define if _NL_PAPER_HEIGHT is available])
 582 fi
 583
 584 # _NL_PAPER_WIDTH is an enum and not a define
 585 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 586 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 587                                 [[char c;
 588                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 589                [gtk_ok=yes], [gtk_ok=no])
 590 AC_MSG_RESULT($gtk_ok)
 591 if test "$gtk_ok" = "yes"; then
 592   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 593             [Define if _NL_PAPER_WIDTH is available])
 594 fi
 595
 596 # i18n stuff
 597 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 598 AM_GLIB_GNU_GETTEXT
 599 LIBS="$LIBS $INTLLIBS"
 600 AC_CONFIG_COMMANDS([po-properties],
 601                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 602                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 603                      esac]],
 604                    [[]])
 605
 606 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 607 dnl po-properties/POTFILES during configure; see GNOME #573515.
 608 dnl
 609 dnl Generate list of files to be processed by xgettext which will
 610 dnl be included in po-properties/Makefile.
 611 test -d po-properties || mkdir po-properties
 612 if test "x$srcdir" != "x."; then
 613   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 614     popropsrcprefix="$srcdir/"
 615   else
 616     popropsrcprefix="../$srcdir/"
 617   fi
 618 else
 619   popropsrcprefix="../"
 620 fi
 621 rm -f po-properties/POTFILES
 622 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 623 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 624 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 625
 626 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 627
 628 dnl The DU4 header files don't provide library prototypes unless
 629 dnl -std1 is given to the native cc.
 630 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 631
 632 gtk_save_LIBS=$LIBS
 633 LIBS="$LIBS -lm"
 634 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 635                                 int main (void) { return (log(1) != log(1.)); }]])],
 636               [AC_MSG_RESULT(none needed)],
 637               [gtk_save_CFLAGS="$CFLAGS"
 638                CFLAGS="$CFLAGS -std1"
 639                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 640                                                int main (void) { return (log(1) != log(1.)); }]])],
 641                              [AC_MSG_RESULT(-std1)],
 642                              [AC_MSG_RESULT()
 643                               CFLAGS="$gtk_save_CFLAGS"
 644                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 645                              [true])],
 646               [AC_MSG_RESULT(none needed)])
 647
 648 LIBS=$gtk_save_LIBS
 649
 650 AC_MSG_CHECKING(for the BeOS)
 651 case $host in
 652   *-*-beos*)
 653     AC_MSG_RESULT(yes)
 654     MATH_LIB=
 655   ;;
 656   *)
 657     AC_MSG_RESULT(no)
 658   ;;
 659 esac
 660
 661 AC_SUBST(MATH_LIB)
 662 #
 663 # see bug 162979
 664 #
 665 AC_MSG_CHECKING(for HP-UX)
 666 case $host_os in
 667   hpux9* | hpux10* | hpux11*)
 668     AC_MSG_RESULT(yes)
 669     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 670   ;;
 671   *)
 672     AC_MSG_RESULT(no)
 673   ;;
 674 esac
 675
 676 #
 677 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 678 #
 679
 680 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 681
 682 AM_PATH_GLIB_2_0(glib_required_version, :,
 683   AC_MSG_ERROR([
 684 *** GLIB glib_required_version or better is required. The latest version of
 685 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 686   gobject gmodule-no-export gthread)
 687
 688 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 689 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 690 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 691 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 692   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 693 fi
 694
 695 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 696
 697
 698 dnl
 699 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 700 dnl
 701 gtk_save_LIBS=$LIBS
 702 LIBS="$LIBS $GLIB_LIBS"
 703 AC_CHECK_FUNCS(bind_textdomain_codeset)
 704 LIBS=$gtk_save_LIBS
 705
 706 AC_CHECK_HEADERS(pwd.h,
 707                  AC_DEFINE(HAVE_PWD_H, 1,
 708                            [Define to 1 if pwd.h is available]))
 709 AC_CHECK_HEADERS(sys/time.h,
 710                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 711                            [Define to 1 if time.h is available]))
 712 AC_CHECK_HEADERS(unistd.h,
 713                  AC_DEFINE(HAVE_UNISTD_H, 1,
 714                            [Define to 1 if unistd.h is available]))
 715 AC_CHECK_HEADERS(ftw.h,
 716                  AC_DEFINE(HAVE_FTW_H, 1,
 717                            [Define to 1 if ftw.h is available]))
 718
 719 AC_MSG_CHECKING([for GNU ftw extensions])
 720 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 721                                      #define _GNU_SOURCE
 722                                      #include <ftw.h>]],
 723                                    [[int flags = FTW_ACTIONRETVAL;]])],
 724                   [gtk_ok=yes],[gtk_ok=no])
 725 if test $gtk_ok = yes; then
 726     AC_MSG_RESULT([yes])
 727     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 728 else
 729     AC_MSG_RESULT([no])
 730 fi
 731
 732 saved_cflags="$CFLAGS"
 733 saved_ldflags="$LDFLAGS"
 734
 735
 736 # Checks for library functions.
 737 AC_FUNC_MMAP
 738
 739 AC_CHECK_FUNCS(mallinfo)
 740 AC_CHECK_FUNCS(getresuid)
 741 AC_TYPE_UID_T
 742
 743 # Check for uxtheme.h (for MS-Windows Engine)
 744 AC_MSG_CHECKING(for uxtheme.h)
 745 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <uxtheme.h>]])],
 746                   [gtk_uxtheme_h=yes], [gtk_uxtheme_h=no])
 747 if test $gtk_uxtheme_h = yes; then
 748    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 749 fi
 750 AC_MSG_RESULT($gtk_uxtheme_h)
 751
 752 # Checks for gdkspawn
 753 AC_CHECK_HEADERS(crt_externs.h)
 754 AC_CHECK_FUNCS(_NSGetEnviron)
 755
 756 AC_MSG_CHECKING(whether to build dynamic modules)
 757
 758 AC_ARG_ENABLE(modules,
 759               [AS_HELP_STRING([--disable-modules],
 760                               [disable dynamic module loading])])
 761
 762 dynworks=false
 763 build_dynamic_modules=no
 764 deps=
 765 if test x$enable_modules = xno; then
 766     AC_MSG_RESULT(no)
 767 else
 768     AC_MSG_RESULT(yes)
 769     AC_MSG_CHECKING(whether dynamic modules work)
 770     ## for loop is to strip newline
 771     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 772     for I in $tmp; do
 773         dynworks=$I
 774     done
 775
 776     dnl Now we check to see if our libtool supports shared lib deps
 777     dnl (in a rather ugly way even)
 778     if $dynworks; then
 779         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 780         module_deplibs_check=`$module_libtool_config | \
 781             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 782             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 783         if test "x$module_deplibs_check" = "xnone" || \
 784            test "x$module_deplibs_check" = "xunknown" || \
 785            test "x$module_deplibs_check" = "x"; then
 786             dynworks=false
 787         fi
 788     fi
 789
 790     if $dynworks; then
 791         build_dynamic_modules=yes
 792         AC_DEFINE(USE_GMODULE, 1,
 793                   [Define to 1 if gmodule works and should be used])
 794         AC_MSG_RESULT(yes)
 795     else
 796         build_dynamic_modules=no
 797         AC_MSG_RESULT(no)
 798     fi
 799 fi
 800
 801 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 802
 803 #
 804 # Allow building some or all immodules included
 805 #
 806 AC_MSG_CHECKING(immodules to build)
 807
 808 AC_ARG_WITH(included_immodules,
 809             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 810                             [build the specified input methods into gtk])])
 811
 812 if $dynworks; then
 813    :
 814 else
 815    ## if the option was specified, leave it; otherwise disable included immodules
 816    if test x$with_included_immodules = xno; then
 817            with_included_immodules=yes
 818    fi
 819 fi
 820
 821 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 822
 823 included_immodules=""
 824 # If the switch specified without listing any specific ones, include all
 825 if test "x$with_included_immodules" = xyes ; then
 826   included_immodules="$all_immodules"
 827 else
 828   included_immodules="$with_included_immodules"
 829 fi
 830
 831 AC_MSG_RESULT($included_immodules)
 832 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 833
 834 INCLUDED_IMMODULE_OBJ=
 835 INCLUDED_IMMODULE_DEFINE=
 836
 837 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 838 for immodule in $included_immodules; do
 839  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 840  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 841    :
 842  else
 843    AC_MSG_ERROR([the specified input method $immodule does not exist])
 844  fi
 845
 846  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 847  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 848  eval INCLUDE_$immodule_underscores=yes
 849 done
 850 IFS="$gtk_save_ifs"
 851 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 852 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 853
 854 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 855 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 856 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 857 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 858 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 859 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 860 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 861 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 862 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 863 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 864 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 865 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 866
 867 # Checks to see whether we should include mediaLib
 868 # support.
 869 #
 870 AC_CHECK_HEADER(sys/systeminfo.h,
 871                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 872                           [Define to 1 if sys/systeminfo.h is available]))
 873 AC_CHECK_HEADER(sys/sysinfo.h,
 874                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 875                           [Define to 1 if sys/sysinfo.h is available]))
 876
 877 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 878
 879 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 880
 881 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 882   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 883   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 884     REBUILD_PNGS=#
 885   fi
 886 fi
 887
 888 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 889
 890 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 891
 892 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 893    test "x$REBUILD_PNGS" = "x#" ; then
 894      AC_MSG_ERROR([
 895 *** gtkbuiltincache.h is not in the tree, and cannot be built
 896 *** because you don't have libpng, or (when cross-compiling) you
 897 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 898 fi
 899
 900 ########################################
 901 # Windowing system checks
 902 ########################################
 903
 904 # GTK+ uses some X calls, so needs to link against X directly
 905 GTK_DEP_PACKAGES_FOR_X=
 906 GTK_DEP_LIBS_FOR_X=
 907 X_EXTENSIONS=
 908
 909 if test "x$enable_x11_backend" = xyes; then
 910   X_PACKAGES=fontconfig
 911
 912   #
 913   # We use fontconfig very peripherally when decoding the default
 914   # settings.
 915   #
 916   if $PKG_CONFIG --exists fontconfig; then : ; else
 917     AC_MSG_ERROR([
 918 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 919   fi
 920
 921   #
 922   # Check for basic X packages; we use pkg-config if available
 923   #
 924   if $PKG_CONFIG --exists x11 xext; then
 925     have_base_x_pc=true
 926     X_PACKAGES="$X_PACKAGES x11 xext"
 927     x_libs="`$PKG_CONFIG --libs x11 xext`"
 928     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 929
 930     # Strip out any .la files that pkg-config might give us (this happens
 931     # with -uninstalled.pc files)
 932     x_libs_for_checks=
 933     for I in $x_libs ; do
 934       case $I in
 935         *.la) ;;
 936         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 937       esac
 938     done
 939
 940     GTK_PACKAGES_FOR_X="x11"
 941   else
 942     have_base_x_pc=false
 943     AC_PATH_XTRA
 944     if test x$no_x = xyes ; then
 945       AC_MSG_ERROR([X development libraries not found])
 946     fi
 947
 948     x_cflags="$X_CFLAGS"
 949     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 950
 951     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 952   fi
 953
 954   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 955   x_extra_libs=
 956
 957   gtk_save_cppflags="$CPPFLAGS"
 958   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 959
 960   gtk_save_LIBS=$LIBS
 961   LIBS="$x_libs_for_checks $LIBS"
 962
 963   # Sanity check for the X11 and Xext libraries. While everything we need from
 964   # Xext is optional, the chances a system has *none* of these things is so
 965   # small that we just unconditionally require it.
 966   AC_CHECK_FUNC(XOpenDisplay, :,
 967                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 968   AC_CHECK_FUNC(XextFindDisplay, :,
 969                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 970
 971   # Check for xReply
 972
 973   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 974   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 975                                      [[xReply *rep;]])],
 976                     [AC_MSG_RESULT([no])],
 977                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 978                                                           #include <X11/Xlibint.h>]],
 979                                                         [[xReply *rep;]])],
 980                                        [AC_MSG_RESULT([yes])
 981                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 982                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 983                                        [AC_MSG_RESULT([unknown])
 984                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 985
 986   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 987
 988   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 989
 990   # Generic X11R6 check needed for XIM support; we could
 991   # probably use this to replace the above, but we'll
 992   # leave the separate checks for XConvertCase and XInternAtoms
 993   # for clarity
 994
 995   have_x11r6=false
 996   AC_CHECK_FUNC(XAddConnectionWatch,
 997       have_x11r6=true)
 998
 999   if $have_x11r6; then
1000     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1001   fi
1002   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1003
1004   # Check for XKB support.
1005
1006   if test "x$enable_xkb" = "xyes"; then
1007         AC_CHECK_FUNC(XkbQueryExtension,
1008                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1009                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1010                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1011   elif test "x$enable_xkb" = "xmaybe"; then
1012         AC_CHECK_FUNC(XkbQueryExtension,
1013                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1014                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1015   else
1016         AC_MSG_WARN(XKB support explicitly disabled)
1017   fi
1018
1019   # Check for shaped window extension
1020
1021   AC_CHECK_FUNC(XShapeCombineMask, :,
1022      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1023
1024   # X SYNC check
1025   gtk_save_CFLAGS="$CFLAGS"
1026   CFLAGS="$CFLAGS $x_cflags"
1027
1028   AC_CHECK_FUNC(XSyncQueryExtension,
1029       [AC_CHECK_HEADER(X11/extensions/sync.h,
1030           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1031           :, [#include <X11/Xlib.h>])])
1032
1033   CFLAGS="$gtk_save_CFLAGS"
1034
1035   if test "x$enable_xinerama" != "xno"; then
1036     # Check for Xinerama extension (Solaris impl or Xfree impl)
1037     have_xfree_xinerama=false
1038     have_solaris_xinerama=false
1039
1040     gtk_save_cppflags="$CPPFLAGS"
1041     CPPFLAGS="$CPPFLAGS $x_cflags"
1042
1043     # Check for XFree
1044     AC_MSG_CHECKING(for Xinerama packages)
1045
1046     if $PKG_CONFIG --exists xinerama ; then
1047        AC_MSG_RESULT(yes)
1048        have_xfree_xinerama=true
1049        X_PACKAGES="$X_PACKAGES xinerama"
1050     else
1051        AC_MSG_RESULT(no)
1052        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1053            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1054            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1055            have_xfree_xinerama=true], :,
1056            [#include <X11/Xlib.h>])])
1057     fi
1058
1059     if $have_xfree_xinerama ; then
1060       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1061       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1062                 [Define to 1 if XFree Xinerama is available])
1063       AC_DEFINE(HAVE_XINERAMA, 1,
1064                 [Define to 1 is Xinerama is available])
1065     else
1066       case "$host" in
1067         *-*-solaris*)
1068             # Check for solaris
1069             AC_MSG_CHECKING(for Xinerama support on Solaris)
1070
1071             have_solaris_xinerama=false
1072             AC_CHECK_FUNC(XineramaGetInfo,
1073                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1074                     [have_solaris_xinerama=true], :,
1075                     [#include <X11/Xlib.h>])])
1076
1077             if $have_solaris_xinerama ; then
1078               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1079               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1080                         [Define to 1 if solaris xinerama is available])
1081               AC_DEFINE(HAVE_XINERAMA, 1,
1082                         [Define to 1 if xinerama is available])
1083               AC_MSG_RESULT(yes)
1084             else
1085               AC_MSG_RESULT(no)
1086             fi
1087             ;;
1088         *)
1089             ;;
1090       esac
1091     fi
1092   fi
1093   if test "x$enable_xinerama" = "xyes" ; then
1094     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1095       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1096     fi
1097   fi
1098
1099   # set up things for XInput
1100   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1101     have_xinput=yes
1102
1103     AC_DEFINE(XINPUT_XFREE, 1,
1104               [Define to 1 if XFree XInput should be used])
1105
1106     X_PACKAGES="$X_PACKAGES xi"
1107
1108     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1109                     have_xinput2=yes
1110                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1111                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1112                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1113
1114   else
1115     AC_DEFINE(XINPUT_NONE, 1,
1116               [Define to 1 if no XInput should be used])
1117   fi
1118
1119   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1120   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1121
1122   if test "x$enable_xinput" = "xyes" ; then
1123     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1124       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1125     fi
1126   fi
1127
1128   # Check for the RANDR extension
1129   if test x"$enable_xrandr" != xno; then
1130     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1131       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1132
1133       X_PACKAGES="$X_PACKAGES xrandr"
1134       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1135     elif test x"$enable_xrandr" = xyes; then
1136       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1137     fi
1138   fi
1139
1140   # Checks for Xcursor library
1141
1142   if $PKG_CONFIG --exists xcursor ; then
1143     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1144
1145     X_PACKAGES="$X_PACKAGES xcursor"
1146   fi
1147
1148   # Checks for XFixes extension
1149
1150   if test x"$enable_xfixes" != xno; then
1151     if $PKG_CONFIG --exists xfixes ; then
1152       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1153
1154       X_PACKAGES="$X_PACKAGES xfixes"
1155       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1156       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1157     elif test x"$enable_xfixes" = xyes; then
1158       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1159     fi
1160   fi
1161
1162   # Checks for Xcomposite extension
1163
1164   if test x"$enable_xcomposite" != xno; then
1165     if $PKG_CONFIG --exists xcomposite ; then
1166       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1167
1168       X_PACKAGES="$X_PACKAGES xcomposite"
1169       X_EXTENSIONS="$X_EXTENSIONS Composite"
1170       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1171     elif test x"$enable_xcomposite" = xyes; then
1172       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1173     fi
1174   fi
1175
1176   # Checks for Xdamage extension
1177
1178   if test x"$enable_xdamage" != xno; then
1179     if $PKG_CONFIG --exists xdamage ; then
1180       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1181
1182       X_PACKAGES="$X_PACKAGES xdamage"
1183       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1184       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1185     elif test x"$enable_xdamage" = xyes; then
1186       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1187     fi
1188   fi
1189
1190   if $have_base_x_pc ; then
1191     GDK_EXTRA_LIBS="$x_extra_libs"
1192   else
1193     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1194   fi
1195
1196   CPPFLAGS="$gtk_save_cppflags"
1197   LIBS="$gtk_save_libs"
1198
1199   AM_CONDITIONAL(USE_X11, true)
1200
1201   # strip leading space
1202   X_EXTENSIONS=${X_EXTENSIONS#* }
1203
1204 else
1205   XPACKAGES=
1206
1207   AM_CONDITIONAL(XINPUT_XFREE, false)
1208   AM_CONDITIONAL(XINPUT_2, false)
1209   AM_CONDITIONAL(USE_X11, false)
1210   AM_CONDITIONAL(HAVE_X11R6, false)
1211 fi
1212
1213 # Check for Pango flags
1214
1215 AC_MSG_CHECKING(Pango flags)
1216 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1217         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1218         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1219
1220         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1221 else
1222         AC_MSG_ERROR([
1223 *** Pango not found. Pango built with Cairo support is required
1224 *** to build GTK+. See http://www.pango.org for Pango information.
1225 ])
1226 fi
1227
1228 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1229
1230 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1231         :
1232 else
1233         gtk_save_LIBS="$LIBS"
1234         LIBS="$PANGO_LIBS $LIBS"
1235         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1236 *** Can't link to Pango. Pango is required to build
1237 *** GTK+. For more information see http://www.pango.org]))
1238         LIBS="$gtk_save_LIBS"
1239 fi
1240
1241 CFLAGS="$saved_cflags"
1242 LDFLAGS="$saved_ldflags"
1243
1244 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1245
1246 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1247 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1248 #
1249 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1250 # into the pkg-config files
1251 #
1252 if test $enable_explicit_deps != yes ; then
1253   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1254   GDK_EXTRA_LIBS=
1255 fi
1256
1257 AC_SUBST(GDK_PACKAGES)
1258 AC_SUBST(GDK_EXTRA_LIBS)
1259 AC_SUBST(GDK_EXTRA_CFLAGS)
1260 AC_SUBST(GDK_DEP_LIBS)
1261 AC_SUBST(GDK_DEP_CFLAGS)
1262
1263
1264 ########################################
1265 # Check for Accessibility Toolkit flags
1266 ########################################
1267
1268 ATK_PACKAGES=atk
1269 AC_MSG_CHECKING(ATK flags)
1270 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1271         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1272         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1273
1274         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1275 else
1276         AC_MSG_ERROR([
1277 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1278 *** to build GTK+.
1279 ])
1280 fi
1281
1282 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1283         :
1284 else
1285         gtk_save_LIBS="$LIBS"
1286         LIBS="$ATK_LIBS $LIBS"
1287         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1288                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1289                 *** to build GTK+]))
1290         LIBS="$gtk_save_LIBS"
1291 fi
1292
1293 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1294 if test "x$enable_x11_backend" = xyes; then
1295   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1296 fi
1297 GTK_EXTRA_LIBS=
1298 GTK_EXTRA_CFLAGS=
1299 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1300 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1301
1302 if test x"$os_win32" = xyes; then
1303   GTK_EXTRA_CFLAGS="$msnative_struct"
1304 fi
1305
1306 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1307 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1308 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1309 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1310
1311 AC_SUBST(GTK_PACKAGES)
1312 AC_SUBST(GTK_EXTRA_LIBS)
1313 AC_SUBST(GTK_EXTRA_CFLAGS)
1314 AC_SUBST(GTK_DEP_LIBS)
1315 AC_SUBST(GTK_DEP_CFLAGS)
1316
1317 AC_SUBST(GLIB_PREFIX)
1318 AC_SUBST(ATK_PREFIX)
1319 AC_SUBST(PANGO_PREFIX)
1320 AC_SUBST(CAIRO_PREFIX)
1321
1322 AC_SUBST(GTK_DEBUG_FLAGS)
1323 AC_SUBST(GTK_XIM_FLAGS)
1324
1325 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1326 AC_SUBST(GDK_PIXBUF_LIBS)
1327
1328 ########################
1329 # Checks needed for gail
1330 ########################
1331
1332 old_LIBS="$LIBS"
1333 dnl Checks for inet libraries:
1334 AC_SEARCH_LIBS(gethostent, nsl)
1335 AC_SEARCH_LIBS(setsockopt, socket)
1336 AC_SEARCH_LIBS(connect, inet)
1337
1338 dnl check for the sockaddr_un.sun_len member
1339 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1340                 [struct_sockaddr_un_sun_len=true],
1341                 [struct_sockaddr_un_suin_len=false],
1342                 [#include <sys/types.h>
1343                  #include <sys/un.h>]
1344                 )
1345 case $struct_sockaddr_un_sun_len in
1346         true)
1347                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1348                                    [Have the sockaddr_un.sun_len member])
1349                 ;;
1350         *)
1351                 ;;
1352 esac
1353
1354 GAIL_INET_LIBS="$LIBS"
1355 AC_SUBST([GAIL_INET_LIBS])
1356
1357 LIBS="$old_LIBS"
1358
1359 ################################################################
1360 # Printing system checks
1361 ################################################################
1362
1363 PRINT_BACKENDS="file lpr"
1364
1365 AC_ARG_ENABLE(cups,
1366               [AS_HELP_STRING([--disable-cups],
1367                               [disable cups print backend])],,
1368               [enable_cups=auto])
1369
1370 if test "x$enable_cups" = "xno"; then
1371   AM_CONDITIONAL(HAVE_CUPS, false)
1372 else
1373   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1374   if test "x$CUPS_CONFIG" = "xno"; then
1375     if test "x$enable_cups" = "xauto"; then
1376       AM_CONDITIONAL(HAVE_CUPS, false)
1377     else
1378       AC_MSG_ERROR([
1379 *** cups not found.
1380 ])
1381     fi
1382   else
1383     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1384     CUPS_LIBS=`$CUPS_CONFIG --libs`
1385
1386     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1387     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1388     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1389
1390     if test $CUPS_API_MAJOR -gt 1 -o \
1391             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1392       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1393                 [Define to 1 if CUPS 1.2 API is available])
1394     fi
1395
1396     AC_SUBST(CUPS_API_MAJOR)
1397     AC_SUBST(CUPS_API_MINOR)
1398     AC_SUBST(CUPS_CFLAGS)
1399     AC_SUBST(CUPS_LIBS)
1400
1401     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1402
1403     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1404     AM_CONDITIONAL(HAVE_CUPS, true)
1405
1406     gtk_save_cflags="$CFLAGS"
1407     CFLAGS="$CUPS_CFLAGS"
1408     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1409                                        [[http_t http; char *s = http.authstring;]])],
1410                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1411                                  [Define if cups http_t authstring field is accessible])],
1412                       [])
1413     CFLAGS="$gtk_save_cflags"
1414
1415     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1416
1417     gtk_save_libs="$LIBS"
1418     LIBS="$CUPS_LIBS"
1419     AC_CHECK_FUNCS(httpGetAuthString)
1420     LIBS="$gtk_save_libs"
1421   fi
1422 fi
1423
1424 # Checks to see if we should compile with PAPI backend for GTK+
1425 #
1426
1427 AC_ARG_ENABLE(papi,
1428               [AS_HELP_STRING([--disable-papi],
1429                               [disable papi print backend])],,
1430               [enable_papi=auto])
1431
1432 if test "x$enable_papi" = "xno"; then
1433   AM_CONDITIONAL(HAVE_PAPI, false)
1434 else
1435   AC_MSG_CHECKING(libpapi)
1436   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1437   if test $have_papi = yes; then
1438     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1439     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1440   fi
1441   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1442   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1443     AC_MSG_ERROR([
1444 *** papi not found.
1445 ])
1446   fi
1447 fi
1448
1449 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1450
1451 gtk_save_cppflags="$CPPFLAGS"
1452 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1453
1454 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1455 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1456 *** backend enabled.]))
1457
1458 if test "$os_win32" != "yes"; then
1459   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1460 *** Can't find cairo-ps.h. You must build Cairo with the
1461 *** postscript backend enabled.]))
1462
1463   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1464 *** Cannot find cairo-svg.h. You must build Cairo with the
1465 *** svg backend enabled.]))
1466 fi
1467
1468 CPPFLAGS="$gtk_save_cppflags"
1469
1470
1471 AC_ARG_ENABLE(test-print-backend,
1472               [AS_HELP_STRING([--enable-test-print-backend],
1473                               [build test print backend])],,
1474               [enable_test_print_backend=no])
1475 if test "x$enable_test_print_backend" != "xno" ; then
1476   PRINT_BACKENDS="$PRINT_BACKENDS test"
1477 fi
1478 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1479
1480
1481 ################################################################
1482 # Strip -export-dynamic from the link lines of various libraries
1483 ################################################################
1484
1485 #
1486 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1487 #  but this flag is only meaningful for executables. For libraries
1488 #  the effect is undefined; what it causes on Linux is that the
1489 #  export list from -export-symbols-regex is ignored and everything
1490 #  is exported
1491 #
1492 # We are using gmodule-no-export now, but I'm leaving the stripping
1493 # code in place for now, since pango and atk still require gmodule.
1494 export SED
1495 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1496 if test -n "$export_dynamic"; then
1497   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1498   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1499 fi
1500
1501 #############
1502 # GSettings #
1503 #############
1504
1505 GLIB_GSETTINGS
1506
1507 ##################################################
1508 # GObject introspection
1509 ##################################################
1510
1511 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1512
1513 ##################################################
1514 # Packagekit module
1515 #################################################
1516
1517 AC_ARG_ENABLE(packagekit,
1518               [AS_HELP_STRING([--disable-packagekit],
1519                               [build packagekit open-with module])])
1520
1521 build_packagekit=no
1522 if test "os_win32" != "yes"; then
1523         if test "x$enable_packagekit" != "xno"; then
1524                 build_packagekit=yes
1525                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1526         fi
1527 fi
1528
1529 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1530
1531 ##################################################
1532 # Checks for gtk-doc and docbook-tools
1533 ##################################################
1534
1535 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1536
1537 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1538 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1539
1540 AC_ARG_ENABLE(man,
1541               [AS_HELP_STRING([--enable-man],
1542                               [regenerate man pages from Docbook [default=no]])],
1543               [enable_man=yes],
1544               [enable_man=no])
1545
1546 if test "${enable_man}" != no; then
1547   dnl
1548   dnl Check for xsltproc
1549   dnl
1550   AC_PATH_PROG([XSLTPROC], [xsltproc])
1551   if test -z "$XSLTPROC"; then
1552     enable_man=no
1553   fi
1554
1555   dnl check for DocBook DTD and stylesheets in the local catalog.
1556   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1557      [DocBook XML DTD V4.1.2],,enable_man=no)
1558   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1559      [DocBook XSL Stylesheets],,enable_man=no)
1560 fi
1561
1562 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1563
1564
1565 ##################################################
1566 # Output commands
1567 ##################################################
1568
1569 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1570         outfile=gdkconfig.h-tmp
1571         cat > $outfile <<\_______EOF
1572 /* gdkconfig.h
1573  *
1574  * This is a generated file.  Please modify `configure.ac'
1575  */
1576
1577 #ifndef __GDKCONFIG_H__
1578 #define __GDKCONFIG_H__
1579
1580 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1581 #error "Only <gdk/gdk.h> can be included directly."
1582 #endif
1583
1584 #include <glib.h>
1585
1586 G_BEGIN_DECLS
1587
1588 _______EOF
1589
1590         cat >>$outfile <<_______EOF
1591 $gdk_windowing
1592 _______EOF
1593
1594         cat >>$outfile <<_______EOF
1595
1596 G_END_DECLS
1597
1598 #endif  /* __GDKCONFIG_H__ */
1599 _______EOF
1600
1601
1602         if cmp -s $outfile gdk/gdkconfig.h; then
1603           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1604           rm -f $outfile
1605         else
1606           mv $outfile gdk/gdkconfig.h
1607         fi
1608 ],[
1609 gdk_windowing='$GDK_WINDOWING'
1610 ])
1611
1612 dnl
1613 dnl Check for -Bsymbolic-functions linker flag used to avoid
1614 dnl intra-library PLT jumps, if available.
1615 dnl
1616 AC_ARG_ENABLE(Bsymbolic,
1617               [AS_HELP_STRING([--disable-Bsymbolic],
1618                               [avoid linking with -Bsymbolic])],,
1619               [SAVED_LDFLAGS="${LDFLAGS}"
1620                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1621                LDFLAGS=-Wl,-Bsymbolic-functions
1622                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1623                                                [[int main (void) { return 0; }]])],
1624                               [AC_MSG_RESULT(yes)
1625                                enable_Bsymbolic=yes],
1626                               [AC_MSG_RESULT(no)
1627                                enable_Bsymbolic=no])
1628                LDFLAGS="${SAVED_LDFLAGS}"])
1629
1630 if test "x${enable_Bsymbolic}" = "xyes" ; then
1631   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1632 fi
1633 AC_SUBST(GTK_LINK_FLAGS)
1634
1635 AC_CONFIG_FILES([
1636 config.h.win32
1637 gtk-zip.sh
1638 Makefile
1639 gdk-3.0.pc
1640 gtk+-3.0.pc
1641 gtk+-unix-print-3.0.pc
1642 gail-3.0.pc
1643 gtk+-3.0-uninstalled.pc
1644 gail-3.0-uninstalled.pc
1645 m4macros/Makefile
1646 po/Makefile.in
1647 po-properties/Makefile.in
1648 demos/Makefile
1649 demos/gtk-demo/Makefile
1650 demos/gtk-demo/geninclude.pl
1651 examples/Makefile
1652 tests/Makefile
1653 tests/reftests/Makefile
1654 docs/Makefile
1655 docs/reference/Makefile
1656 docs/reference/gdk/Makefile
1657 docs/reference/gdk/version.xml
1658 docs/reference/gtk/Makefile
1659 docs/reference/gtk/version.xml
1660 docs/reference/libgail-util/Makefile
1661 docs/reference/libgail-util/version.xml
1662 docs/tools/Makefile
1663 build/Makefile
1664 build/win32/Makefile
1665 build/win32/vs9/Makefile
1666 build/win32/vs10/Makefile
1667 gdk/Makefile
1668 gdk/broadway/Makefile
1669 gdk/x11/Makefile
1670 gdk/win32/Makefile
1671 gdk/win32/rc/Makefile
1672 gdk/win32/rc/gdk.rc
1673 gdk/quartz/Makefile
1674 gdk/wayland/Makefile
1675 gdk/tests/Makefile
1676 gtk/Makefile
1677 gtk/makefile.msc
1678 gtk/gtkversion.h
1679 gtk/gtk-win32.rc
1680 gtk/tests/Makefile
1681 modules/Makefile
1682 modules/other/Makefile
1683 modules/other/gail/Makefile
1684 modules/other/gail/libgail-util/Makefile
1685 modules/other/gail/tests/Makefile
1686 modules/engines/Makefile
1687 modules/engines/pixbuf/Makefile
1688 modules/engines/ms-windows/Makefile
1689 modules/engines/ms-windows/Theme/Makefile
1690 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1691 modules/input/Makefile
1692 modules/printbackends/Makefile
1693 modules/printbackends/cups/Makefile
1694 modules/printbackends/lpr/Makefile
1695 modules/printbackends/file/Makefile
1696 modules/printbackends/papi/Makefile
1697 modules/printbackends/test/Makefile
1698 perf/Makefile
1699 ])
1700
1701 AC_OUTPUT
1702
1703 # beautify the immodule list a bit
1704 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1705 if test -z "${included_immodules}"; then included_immodules="none"; fi
1706
1707 echo ""
1708 echo "        GTK+ $GTK_VERSION"
1709 echo "        ==========="
1710 echo ""
1711 echo "        GDK backends:         $GDK_BACKENDS"
1712 if test "x$enable_x11_backend" = "xyes"; then
1713 echo "        X11 extensions:       $X_EXTENSIONS"
1714 fi
1715 echo "        Print backends:       $PRINT_BACKENDS"
1716 echo "        Dynamic modules:      $build_dynamic_modules"
1717 echo "        Included immodules:   $included_immodules"
1718 echo "        PackageKit support:   $build_packagekit"
1719 echo "        Introspection:        $found_introspection"
1720 echo "        Debugging:            $enable_debug"
1721 echo "        Documentation:        $enable_gtk_doc"