Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [3])
  13 m4_define([gtk_micro_version], [17])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.31.18])
  43 m4_define([pango_required_version], [1.29.0])
  44 m4_define([atk_required_version], [2.1.5])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.25.2])
  47 m4_define([introspection_required_version], [0.10.1])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_INSTALL
 129 AC_PROG_MAKE_SET
 130
 131
 132 GETTEXT_PACKAGE=gtk30
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 135                    [The prefix for our gettext translation domains.])
 136
 137 AC_CANONICAL_HOST
 138
 139 MATH_LIB=-lm
 140 AC_MSG_CHECKING([for native Win32])
 141 LIB_EXE_MACHINE_FLAG=X86
 142 EXE_MANIFEST_ARCHITECTURE=X86
 143 case "$host" in
 144   *-*-mingw*)
 145     os_win32=yes
 146     gio_can_sniff=no
 147     MATH_LIB=
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       EXE_MANIFEST_ARCHITECTURE=AMD64
 152       ;;
 153     esac
 154     ;;
 155   *)
 156     os_win32=no
 157     ;;
 158 esac
 159 AC_MSG_RESULT([$os_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 163
 164 case $host in
 165   *-*-linux*)
 166     os_linux=yes
 167     ;;
 168 esac
 169
 170 dnl
 171 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 172 dnl We use this for an automated test for C++ header correctness.
 173 dnl
 174 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 175 AC_LANG_PUSH([C++])
 176
 177 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 178                                    [[class a { int b; } c;]])],
 179                   [],[CXX=])
 180 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 181
 182 gtk_save_cxxflags="$CXXFLAGS"
 183 CXXFLAGS="$CXXFLAGS -x objective-c++"
 184 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 185                                    [[]])],
 186                   [OBJC=yes],[OBJC=no])
 187 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 188 CXXFLAGS="$gtk_save_cxxflags"
 189 AC_LANG_POP([C++])
 190
 191 if test "$os_win32" = "yes"; then
 192   if test x$enable_static = xyes -o x$enable_static = x; then
 193     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 194     enable_static=no
 195   fi
 196   if test x$enable_shared = xno; then
 197     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 198   fi
 199   enable_shared=yes
 200 fi
 201
 202 dnl Initialize libtool
 203 LT_PREREQ([2.2.6])
 204 LT_INIT([disable-static win32-dll])
 205 # Create libtool early, because it's used in configure
 206 LT_OUTPUT
 207
 208 # Make sure we use 64-bit versions of various file stuff.
 209 AC_SYS_LARGEFILE
 210
 211 AM_PROG_AS
 212 AC_PATH_PROG(NM, nm, nm)
 213
 214 AC_MSG_CHECKING([for some Win32 platform])
 215 case "$host" in
 216   *-*-mingw*|*-*-cygwin*)
 217     platform_win32=yes
 218     ;;
 219   *)
 220     platform_win32=no
 221     ;;
 222 esac
 223 AC_MSG_RESULT([$platform_win32])
 224 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 225
 226 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 227 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 228 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 229
 230 if test "$os_win32" = "yes"; then
 231   AC_CHECK_TOOL(WINDRES, windres, no)
 232   if test "$WINDRES" = no; then
 233     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 234   fi
 235   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 236 fi
 237 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 238
 239 m4_define([debug_default],
 240           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 241
 242 dnl declare --enable-* args and collect ac_help strings
 243 AC_ARG_ENABLE(debug,
 244               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 245                               [turn on debugging @<:@default=debug_default@:>@])],,
 246               [enable_debug=debug_default])
 247
 248 AC_ARG_ENABLE(rebuilds,
 249               [AS_HELP_STRING([--disable-rebuilds],
 250                               [disable all source autogeneration rules])],,
 251               [enable_rebuilds=yes])
 252
 253 AC_ARG_ENABLE(gtk2-dependency,
 254               [AS_HELP_STRING([--enable-gtk2-dependency],
 255                               [Do not build gtk-update-icon-cache and other shared tools])],,
 256               [enable_gtk2_dependency=no])
 257
 258 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 259
 260 AC_ARG_ENABLE(xkb,
 261               [AS_HELP_STRING([--enable-xkb],
 262                               [support XKB extension [default=maybe]])],,
 263               [enable_xkb="maybe"])
 264 AC_ARG_ENABLE(xinerama,
 265               [AS_HELP_STRING([--enable-xinerama],
 266                               [support Xinerama extension [default=maybe]])],,
 267               [enable_xinerama="maybe"])
 268 AC_ARG_ENABLE(xinput,
 269               [AS_HELP_STRING([--enable-xinput],
 270                               [support XInput extension [default=yes]])],,
 271               [enable_xinput="maybe"])
 272 AC_ARG_ENABLE(xrandr,
 273               [AS_HELP_STRING([--enable-xrandr],
 274                               [support XRandR extension [default=maybe]])],,
 275               [enable_xrandr="maybe"])
 276 AC_ARG_ENABLE(xfixes,
 277               [AS_HELP_STRING([--enable-xfixes],
 278                               [support XFixes extension [default=maybe]])],,
 279               [enable_xfixes="maybe"])
 280 AC_ARG_ENABLE(xcomposite,
 281               [AS_HELP_STRING([--enable-xcomposite],
 282                               [support X Composite extension [default=maybe]])],,
 283               [enable_xcomposite="maybe"])
 284 AC_ARG_ENABLE(xdamage,
 285               [AS_HELP_STRING([--enable-xdamage],
 286                               [support X Damage extension [default=maybe]])],,
 287               [enable_xdamage="maybe"])
 288
 289 AC_ARG_ENABLE(x11-backend,
 290               [AS_HELP_STRING([--enable-x11-backend],
 291                               [enable the X11 gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(win32-backend,
 294               [AS_HELP_STRING([--enable-win32-backend],
 295                               [enable the Win32 gdk backend])],
 296                               [backend_set=yes])
 297 AC_ARG_ENABLE(quartz-backend,
 298               [AS_HELP_STRING([--enable-quartz-backend],
 299                               [enable the quartz gdk backend])],
 300                               [backend_set=yes])
 301 AC_ARG_ENABLE(broadway-backend,
 302               [AS_HELP_STRING([--enable-broadway-backend],
 303                               [enable the broadway (HTML5) gdk backend])],
 304                               [backend_set=yes])
 305 AC_ARG_ENABLE(wayland-backend,
 306               [AS_HELP_STRING([--enable-wayland-backend],
 307                               [enable the wayland gdk backend])],
 308                               [backend_set=yes])
 309
 310 if test -z "$backend_set"; then
 311   if test "$platform_win32" = yes; then
 312     enable_win32_backend=yes
 313   else
 314     enable_x11_backend=yes
 315   fi
 316 fi
 317
 318 AC_ARG_ENABLE(quartz-relocation,
 319               [AS_HELP_STRING([--enable-quartz-relocation],
 320                               [enable bundle-based relocation functions])],
 321                               [quartz_relocation=yes])
 322
 323 cairo_backends=
 324 backend_immodules=
 325 GDK_BACKENDS=
 326 GDK_EXTRA_LIBS=
 327 GDK_EXTRA_CFLAGS=
 328 GDK_WINDOWING=
 329 GIO_PACKAGE=gio-2.0
 330 PANGO_PACKAGES="pango pangocairo"
 331
 332 if test "$enable_x11_backend" = "yes"; then
 333   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 334   # backend names are identical.
 335   cairo_backends="$cairo_backends cairo-xlib"
 336   GDK_BACKENDS="$GDK_BACKENDS x11"
 337   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 338   # gdkapplaunchcontext-x11.c
 339   GIO_PACKAGE=gio-unix-2.0
 340   backend_immodules="$backend_immodules,xim"
 341   GDK_WINDOWING="$GDK_WINDOWING
 342 #define GDK_WINDOWING_X11"
 343 fi
 344
 345 if test "$enable_win32_backend" = "yes"; then
 346   cairo_backends="$cairo_backends cairo-win32"
 347   GDK_BACKENDS="$GDK_BACKENDS win32"
 348   backend_immodules="$backend_immodules,ime"
 349   GDK_WINDOWING="$GDK_WINDOWING
 350 #define GDK_WINDOWING_WIN32"
 351   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 352   AM_CONDITIONAL(USE_WIN32, true)
 353   PANGO_PACKAGES="pangowin32 pangocairo"
 354 else
 355   AM_CONDITIONAL(USE_WIN32, false)
 356 fi
 357
 358 if test "x$enable_quartz_backend" = xyes; then
 359   cairo_backends="$cairo_backends cairo-quartz"
 360   GDK_BACKENDS="$GDK_BACKENDS quartz"
 361   GDK_WINDOWING="$GDK_WINDOWING
 362 #define GDK_WINDOWING_QUARTZ"
 363   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 364   AM_CONDITIONAL(USE_QUARTZ, true)
 365   if test "x$quartz_relocation" = xyes; then
 366     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 367   fi
 368
 369 else
 370   AM_CONDITIONAL(USE_QUARTZ, false)
 371 fi
 372
 373
 374 if test "x$enable_broadway_backend" == xyes; then
 375   GDK_BACKENDS="$GDK_BACKENDS broadway"
 376   cairo_backends="$cairo_backends cairo"
 377   GDK_WINDOWING="$GDK_WINDOWING
 378 #define GDK_WINDOWING_BROADWAY"
 379   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 380   AM_CONDITIONAL(USE_BROADWAY, true)
 381 else
 382   AM_CONDITIONAL(USE_BROADWAY, false)
 383 fi
 384
 385 if test "x$enable_wayland_backend" == "xyes"; then
 386   # Wayland uses cairo-gl
 387   cairo_backends="$cairo_backends cairo-gl"
 388   GDK_BACKENDS="$GDK_BACKENDS wayland"
 389   GIO_PACKAGE=gio-unix-2.0
 390   GDK_WINDOWING="$GDK_WINDOWING
 391 #define GDK_WINDOWING_WAYLAND"
 392   WAYLAND_PACKAGES="wayland-client xkbcommon wayland-egl egl"
 393   AM_CONDITIONAL(USE_WAYLAND, true)
 394 else
 395   AM_CONDITIONAL(USE_WAYLAND, false)
 396 fi
 397
 398 # strip leading space
 399 GDK_BACKENDS=${GDK_BACKENDS#* }
 400
 401 AC_SUBST(GDK_BACKENDS)
 402
 403 if test -z "$GDK_BACKENDS"; then
 404   AC_MSG_ERROR([No GDK backends selected.])
 405 fi
 406
 407 if test "x$enable_debug" = "xyes"; then
 408   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 409   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 410 else
 411   if test "x$enable_debug" = "xno"; then
 412     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 413   else
 414     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 415   fi
 416 fi
 417
 418
 419 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 420                    [Define if debugging is enabled])
 421
 422
 423 # Build time sanity check...
 424 AM_SANITY_CHECK
 425
 426 changequote(,)dnl
 427 if test "x$GCC" = "xyes"; then
 428   case " $CFLAGS " in
 429   *[\ \ ]-Wall[\ \      ]*) ;;
 430   *) CFLAGS="$CFLAGS -Wall" ;;
 431   esac
 432
 433   if test "x$enable_ansi" = "xyes"; then
 434     case " $CFLAGS " in
 435     *[\ \       ]-ansi[\ \      ]*) ;;
 436     *) CFLAGS="$CFLAGS -ansi" ;;
 437     esac
 438
 439     case " $CFLAGS " in
 440     *[\ \       ]-pedantic[\ \  ]*) ;;
 441     *) CFLAGS="$CFLAGS -pedantic" ;;
 442     esac
 443   fi
 444 fi
 445 changequote([,])dnl
 446
 447 # Ensure MSVC-compatible struct packing convention is used when
 448 # compiling for Win32 with gcc.
 449 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 450 # gcc2 uses "-fnative-struct".
 451 if test x"$os_win32" = xyes; then
 452   if test x"$GCC" = xyes; then
 453     msnative_struct=''
 454     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 455     if test -z "$ac_cv_prog_CC"; then
 456       our_gcc="$CC"
 457     else
 458       our_gcc="$ac_cv_prog_CC"
 459     fi
 460     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 461       2.)
 462         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 463           msnative_struct='-fnative-struct'
 464         fi
 465         ;;
 466       *)
 467         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 468           msnative_struct='-mms-bitfields'
 469         fi
 470         ;;
 471     esac
 472     if test x"$msnative_struct" = x ; then
 473       AC_MSG_RESULT([no way])
 474       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 475     else
 476       CFLAGS="$CFLAGS $msnative_struct"
 477       AC_MSG_RESULT([${msnative_struct}])
 478     fi
 479   fi
 480 fi
 481
 482 ## Initial sanity check, done here so that users get told they
 483 ## have the wrong dependencies as early in the process as possible.
 484 ## Later on we actually use the cflags/libs from separate pkg-config
 485 ## calls. Oh, also the later pkg-config calls don't include
 486 ## the version requirements since those make the module lists
 487 ## annoying to construct
 488 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 489   [glib-2.0 >= glib_required_version dnl
 490    atk >= atk_required_version dnl
 491    pango >= pango_required_version dnl
 492    cairo >= cairo_required_version dnl
 493    cairo-gobject >= cairo_required_version dnl
 494    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 495
 496 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 497
 498 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0])
 499
 500 if test "$os_win32" != yes; then
 501     # libtool option to control which symbols are exported
 502     # right now, symbols starting with _ are not exported
 503     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 504 else
 505     # We currently use .def files on Windows (for gdk and gtk)
 506     LIBTOOL_EXPORT_OPTIONS=
 507 fi
 508 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 509
 510 dnl ******************************************************
 511 dnl * See whether to include shared library dependencies *
 512 dnl ******************************************************
 513
 514 AC_ARG_ENABLE(explicit-deps,
 515               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 516                               [use explicit dependencies in .pc files [default=auto]])],,
 517               [enable_explicit_deps=auto])
 518
 519 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 520 case $enable_explicit_deps in
 521   auto)
 522     export SED
 523     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 524     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 525       enable_explicit_deps=yes
 526     else
 527       enable_explicit_deps=no
 528     fi
 529   ;;
 530   yes|no)
 531   ;;
 532   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 533   ;;
 534 esac
 535 AC_MSG_RESULT($enable_explicit_deps)
 536
 537 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 538
 539 # define a MAINT-like variable REBUILD which is set if Perl
 540 # and awk are found, so autogenerated sources can be rebuilt
 541
 542 AC_PATH_PROGS(PERL, perl5 perl)
 543
 544 # We would like indent, but don't require it.
 545 AC_CHECK_PROG(INDENT, indent, indent)
 546
 547 REBUILD=\#
 548 if test "x$enable_rebuilds" = "xyes" && \
 549      test -n "$PERL" && \
 550      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 551   REBUILD=
 552 fi
 553 AC_SUBST(REBUILD)
 554
 555 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 556 AC_CHECK_FUNCS(localtime_r)
 557
 558 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 559 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 560 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 561                                 [[char c;
 562                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 563                [gtk_ok=yes], [gtk_ok=no])
 564 AC_MSG_RESULT($gtk_ok)
 565 if test "$gtk_ok" = "yes"; then
 566   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 567             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 568 fi
 569
 570 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 571 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 572 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 573                                 [[char c;
 574                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 575                [gtk_ok=yes], [gtk_ok=no])
 576 AC_MSG_RESULT($gtk_ok)
 577 if test "$gtk_ok" = "yes"; then
 578   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 579             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 580 fi
 581
 582 # _NL_PAPER_HEIGHT is an enum and not a define
 583 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 584 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 585                                 [[char c;
 586                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 587                [gtk_ok=yes], [gtk_ok=no])
 588 AC_MSG_RESULT($gtk_ok)
 589 if test "$gtk_ok" = "yes"; then
 590   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 591             [Define if _NL_PAPER_HEIGHT is available])
 592 fi
 593
 594 # _NL_PAPER_WIDTH is an enum and not a define
 595 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 596 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 597                                 [[char c;
 598                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 599                [gtk_ok=yes], [gtk_ok=no])
 600 AC_MSG_RESULT($gtk_ok)
 601 if test "$gtk_ok" = "yes"; then
 602   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 603             [Define if _NL_PAPER_WIDTH is available])
 604 fi
 605
 606 # i18n stuff
 607 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 608 AM_GLIB_GNU_GETTEXT
 609 LIBS="$LIBS $INTLLIBS"
 610 AC_CONFIG_COMMANDS([po-properties],
 611                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 612                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 613                      esac]],
 614                    [[]])
 615
 616 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 617 dnl po-properties/POTFILES during configure; see GNOME #573515.
 618 dnl
 619 dnl Generate list of files to be processed by xgettext which will
 620 dnl be included in po-properties/Makefile.
 621 test -d po-properties || mkdir po-properties
 622 if test "x$srcdir" != "x."; then
 623   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 624     popropsrcprefix="$srcdir/"
 625   else
 626     popropsrcprefix="../$srcdir/"
 627   fi
 628 else
 629   popropsrcprefix="../"
 630 fi
 631 rm -f po-properties/POTFILES
 632 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 633 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 634 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 635
 636 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 637
 638 dnl The DU4 header files don't provide library prototypes unless
 639 dnl -std1 is given to the native cc.
 640 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 641
 642 gtk_save_LIBS=$LIBS
 643 LIBS="$LIBS -lm"
 644 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 645                                 int main (void) { return (log(1) != log(1.)); }]])],
 646               [AC_MSG_RESULT(none needed)],
 647               [gtk_save_CFLAGS="$CFLAGS"
 648                CFLAGS="$CFLAGS -std1"
 649                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 650                                                int main (void) { return (log(1) != log(1.)); }]])],
 651                              [AC_MSG_RESULT(-std1)],
 652                              [AC_MSG_RESULT()
 653                               CFLAGS="$gtk_save_CFLAGS"
 654                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 655                              [true])],
 656               [AC_MSG_RESULT(none needed)])
 657
 658 LIBS=$gtk_save_LIBS
 659
 660 AC_MSG_CHECKING(for the BeOS)
 661 case $host in
 662   *-*-beos*)
 663     AC_MSG_RESULT(yes)
 664     MATH_LIB=
 665   ;;
 666   *)
 667     AC_MSG_RESULT(no)
 668   ;;
 669 esac
 670
 671 AC_SUBST(MATH_LIB)
 672 #
 673 # see bug 162979
 674 #
 675 AC_MSG_CHECKING(for HP-UX)
 676 case $host_os in
 677   hpux9* | hpux10* | hpux11*)
 678     AC_MSG_RESULT(yes)
 679     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 680   ;;
 681   *)
 682     AC_MSG_RESULT(no)
 683   ;;
 684 esac
 685
 686 #
 687 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 688 #
 689
 690 AM_PATH_GLIB_2_0(glib_required_version, :,
 691   AC_MSG_ERROR([
 692 *** GLIB glib_required_version or better is required. The latest version of
 693 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 694   gobject gmodule-no-export)
 695
 696 dnl
 697 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 698 dnl
 699 gtk_save_LIBS=$LIBS
 700 LIBS="$LIBS $GLIB_LIBS"
 701 AC_CHECK_FUNCS(bind_textdomain_codeset)
 702 LIBS=$gtk_save_LIBS
 703
 704 AC_CHECK_HEADERS(pwd.h,
 705                  AC_DEFINE(HAVE_PWD_H, 1,
 706                            [Define to 1 if pwd.h is available]))
 707 AC_CHECK_HEADERS(sys/time.h,
 708                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 709                            [Define to 1 if time.h is available]))
 710 AC_CHECK_HEADERS(unistd.h,
 711                  AC_DEFINE(HAVE_UNISTD_H, 1,
 712                            [Define to 1 if unistd.h is available]))
 713 AC_CHECK_HEADERS(ftw.h,
 714                  AC_DEFINE(HAVE_FTW_H, 1,
 715                            [Define to 1 if ftw.h is available]))
 716
 717 AC_MSG_CHECKING([for GNU ftw extensions])
 718 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 719                                      #define _GNU_SOURCE
 720                                      #include <ftw.h>]],
 721                                    [[int flags = FTW_ACTIONRETVAL;]])],
 722                   [gtk_ok=yes],[gtk_ok=no])
 723 if test $gtk_ok = yes; then
 724     AC_MSG_RESULT([yes])
 725     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 726 else
 727     AC_MSG_RESULT([no])
 728 fi
 729
 730 saved_cflags="$CFLAGS"
 731 saved_ldflags="$LDFLAGS"
 732
 733
 734 # Checks for library functions.
 735 AC_FUNC_MMAP
 736
 737 AC_CHECK_FUNCS(mallinfo)
 738 AC_CHECK_FUNCS(getresuid)
 739 AC_TYPE_UID_T
 740
 741 # Check for uxtheme.h (for MS-Windows Engine)
 742 AC_MSG_CHECKING(for uxtheme.h)
 743 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <uxtheme.h>]])],
 744                   [gtk_uxtheme_h=yes], [gtk_uxtheme_h=no])
 745 if test $gtk_uxtheme_h = yes; then
 746    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 747 fi
 748 AC_MSG_RESULT($gtk_uxtheme_h)
 749
 750 # Check for round()
 751 AC_CHECK_LIB(m,round,have_round=yes,have_round=no)
 752 if test $have_round = yes; then
 753     AC_DEFINE(HAVE_ROUND, 1, [Define to 1 if round() is available])
 754 fi
 755
 756 # Check for rint()
 757 AC_CHECK_LIB(m,rint,have_rint=yes,have_rint=no)
 758 if test $have_rint = yes; then
 759     AC_DEFINE(HAVE_RINT, 1, [Define to 1 if rint() is available])
 760 fi
 761
 762 # Checks for gdkspawn
 763 AC_CHECK_HEADERS(crt_externs.h)
 764 AC_CHECK_FUNCS(_NSGetEnviron)
 765
 766 AC_MSG_CHECKING(whether to build dynamic modules)
 767
 768 AC_ARG_ENABLE(modules,
 769               [AS_HELP_STRING([--disable-modules],
 770                               [disable dynamic module loading])])
 771
 772 dynworks=false
 773 build_dynamic_modules=no
 774 deps=
 775 if test x$enable_modules = xno; then
 776     AC_MSG_RESULT(no)
 777 else
 778     AC_MSG_RESULT(yes)
 779     AC_MSG_CHECKING(whether dynamic modules work)
 780     ## for loop is to strip newline
 781     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 782     for I in $tmp; do
 783         dynworks=$I
 784     done
 785
 786     dnl Now we check to see if our libtool supports shared lib deps
 787     dnl (in a rather ugly way even)
 788     if $dynworks; then
 789         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 790         module_deplibs_check=`$module_libtool_config | \
 791             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 792             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 793         if test "x$module_deplibs_check" = "xnone" || \
 794            test "x$module_deplibs_check" = "xunknown" || \
 795            test "x$module_deplibs_check" = "x"; then
 796             dynworks=false
 797         fi
 798     fi
 799
 800     if $dynworks; then
 801         build_dynamic_modules=yes
 802         AC_DEFINE(USE_GMODULE, 1,
 803                   [Define to 1 if gmodule works and should be used])
 804         AC_MSG_RESULT(yes)
 805     else
 806         build_dynamic_modules=no
 807         AC_MSG_RESULT(no)
 808     fi
 809 fi
 810
 811 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 812
 813 #
 814 # Allow building some or all immodules included
 815 #
 816 AC_MSG_CHECKING(immodules to build)
 817
 818 AC_ARG_WITH(included_immodules,
 819             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 820                             [build the specified input methods into gtk])])
 821
 822 if $dynworks; then
 823    :
 824 else
 825    ## if the option was specified, leave it; otherwise disable included immodules
 826    if test x$with_included_immodules = xno; then
 827            with_included_immodules=yes
 828    fi
 829 fi
 830
 831 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 832
 833 included_immodules=""
 834 # If the switch specified without listing any specific ones, include all
 835 if test "x$with_included_immodules" = xyes ; then
 836   included_immodules="$all_immodules"
 837 else
 838   included_immodules="$with_included_immodules"
 839 fi
 840
 841 AC_MSG_RESULT($included_immodules)
 842 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 843
 844 INCLUDED_IMMODULE_OBJ=
 845 INCLUDED_IMMODULE_DEFINE=
 846
 847 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 848 for immodule in $included_immodules; do
 849  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 850  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 851    :
 852  else
 853    AC_MSG_ERROR([the specified input method $immodule does not exist])
 854  fi
 855
 856  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 857  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 858  eval INCLUDE_$immodule_underscores=yes
 859 done
 860 IFS="$gtk_save_ifs"
 861 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 862 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 863
 864 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 865 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 866 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 867 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 868 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 869 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 870 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 871 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 872 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 873 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 874 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 875 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 876
 877 # Checks to see whether we should include mediaLib
 878 # support.
 879 #
 880 AC_CHECK_HEADER(sys/systeminfo.h,
 881                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 882                           [Define to 1 if sys/systeminfo.h is available]))
 883 AC_CHECK_HEADER(sys/sysinfo.h,
 884                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 885                           [Define to 1 if sys/sysinfo.h is available]))
 886
 887 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 888
 889 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 890
 891 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 892   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 893   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 894     REBUILD_PNGS=#
 895   fi
 896 fi
 897
 898 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 899
 900 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 901
 902 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 903    test "x$REBUILD_PNGS" = "x#" ; then
 904      AC_MSG_ERROR([
 905 *** gtkbuiltincache.h is not in the tree, and cannot be built
 906 *** because you don't have libpng, or (when cross-compiling) you
 907 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 908 fi
 909
 910 ########################################
 911 # Windowing system checks
 912 ########################################
 913
 914 # GTK+ uses some X calls, so needs to link against X directly
 915 GTK_DEP_PACKAGES_FOR_X=
 916 GTK_DEP_LIBS_FOR_X=
 917 X_EXTENSIONS=
 918
 919 if test "x$enable_x11_backend" = xyes; then
 920   X_PACKAGES=fontconfig
 921
 922   #
 923   # We use fontconfig very peripherally when decoding the default
 924   # settings.
 925   #
 926   if $PKG_CONFIG --exists fontconfig; then : ; else
 927     AC_MSG_ERROR([
 928 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 929   fi
 930
 931   #
 932   # Check for basic X packages; we use pkg-config if available
 933   #
 934   if $PKG_CONFIG --exists x11 xext; then
 935     have_base_x_pc=true
 936     X_PACKAGES="$X_PACKAGES x11 xext"
 937     x_libs="`$PKG_CONFIG --libs x11 xext`"
 938     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext` -DXINPUT2_1_USE_UNSTABLE_PROTOCOL -DXINPUT2_2_USE_UNSTABLE_PROTOCOL"
 939
 940     # Strip out any .la files that pkg-config might give us (this happens
 941     # with -uninstalled.pc files)
 942     x_libs_for_checks=
 943     for I in $x_libs ; do
 944       case $I in
 945         *.la) ;;
 946         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 947       esac
 948     done
 949
 950     GTK_PACKAGES_FOR_X="x11"
 951   else
 952     have_base_x_pc=false
 953     AC_PATH_XTRA
 954     if test x$no_x = xyes ; then
 955       AC_MSG_ERROR([X development libraries not found])
 956     fi
 957
 958     x_cflags="$X_CFLAGS"
 959     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 960
 961     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 962   fi
 963
 964   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 965   x_extra_libs=
 966
 967   gtk_save_cppflags="$CPPFLAGS"
 968   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 969
 970   gtk_save_LIBS=$LIBS
 971   LIBS="$x_libs_for_checks $LIBS"
 972
 973   # Sanity check for the X11 and Xext libraries. While everything we need from
 974   # Xext is optional, the chances a system has *none* of these things is so
 975   # small that we just unconditionally require it.
 976   AC_CHECK_FUNC(XOpenDisplay, :,
 977                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 978   AC_CHECK_FUNC(XextFindDisplay, :,
 979                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 980
 981   # Check for xReply
 982
 983   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 984   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 985                                      [[xReply *rep;]])],
 986                     [AC_MSG_RESULT([no])],
 987                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 988                                                           #include <X11/Xlibint.h>]],
 989                                                         [[xReply *rep;]])],
 990                                        [AC_MSG_RESULT([yes])
 991                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 992                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 993                                        [AC_MSG_RESULT([unknown])
 994                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 995
 996   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 997
 998   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 999
1000   # Generic X11R6 check needed for XIM support; we could
1001   # probably use this to replace the above, but we'll
1002   # leave the separate checks for XConvertCase and XInternAtoms
1003   # for clarity
1004
1005   have_x11r6=false
1006   AC_CHECK_FUNC(XAddConnectionWatch,
1007       have_x11r6=true)
1008
1009   if $have_x11r6; then
1010     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1011   fi
1012   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1013
1014   # Check for XKB support.
1015
1016   if test "x$enable_xkb" = "xyes"; then
1017         AC_CHECK_FUNC(XkbQueryExtension,
1018                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1019                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1020                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1021   elif test "x$enable_xkb" = "xmaybe"; then
1022         AC_CHECK_FUNC(XkbQueryExtension,
1023                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1024                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1025   else
1026         AC_MSG_WARN(XKB support explicitly disabled)
1027   fi
1028
1029   # Check for shaped window extension
1030
1031   AC_CHECK_FUNC(XShapeCombineMask, :,
1032      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1033
1034   # X SYNC check
1035   gtk_save_CFLAGS="$CFLAGS"
1036   CFLAGS="$CFLAGS $x_cflags"
1037
1038   AC_CHECK_FUNC(XSyncQueryExtension,
1039       [AC_CHECK_HEADER(X11/extensions/sync.h,
1040           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1041           :, [#include <X11/Xlib.h>])])
1042
1043   CFLAGS="$gtk_save_CFLAGS"
1044
1045   if test "x$enable_xinerama" != "xno"; then
1046     # Check for Xinerama extension (Solaris impl or Xfree impl)
1047     have_xfree_xinerama=false
1048     have_solaris_xinerama=false
1049
1050     gtk_save_cppflags="$CPPFLAGS"
1051     CPPFLAGS="$CPPFLAGS $x_cflags"
1052
1053     # Check for XFree
1054     AC_MSG_CHECKING(for Xinerama packages)
1055
1056     if $PKG_CONFIG --exists xinerama ; then
1057        AC_MSG_RESULT(yes)
1058        have_xfree_xinerama=true
1059        X_PACKAGES="$X_PACKAGES xinerama"
1060     else
1061        AC_MSG_RESULT(no)
1062        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1063            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1064            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1065            have_xfree_xinerama=true], :,
1066            [#include <X11/Xlib.h>])])
1067     fi
1068
1069     if $have_xfree_xinerama ; then
1070       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1071       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1072                 [Define to 1 if XFree Xinerama is available])
1073       AC_DEFINE(HAVE_XINERAMA, 1,
1074                 [Define to 1 is Xinerama is available])
1075     else
1076       case "$host" in
1077         *-*-solaris*)
1078             # Check for solaris
1079             AC_MSG_CHECKING(for Xinerama support on Solaris)
1080
1081             have_solaris_xinerama=false
1082             AC_CHECK_FUNC(XineramaGetInfo,
1083                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1084                     [have_solaris_xinerama=true], :,
1085                     [#include <X11/Xlib.h>])])
1086
1087             if $have_solaris_xinerama ; then
1088               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1089               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1090                         [Define to 1 if solaris xinerama is available])
1091               AC_DEFINE(HAVE_XINERAMA, 1,
1092                         [Define to 1 if xinerama is available])
1093               AC_MSG_RESULT(yes)
1094             else
1095               AC_MSG_RESULT(no)
1096             fi
1097             ;;
1098         *)
1099             ;;
1100       esac
1101     fi
1102   fi
1103   if test "x$enable_xinerama" = "xyes" ; then
1104     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1105       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1106     fi
1107   fi
1108
1109   # Check for XGetEventData for GenericEvents
1110   AC_CHECK_FUNC(XGetEventData,
1111                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1112
1113   # set up things for XInput
1114   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1115     have_xinput=yes
1116
1117     AC_DEFINE(XINPUT_XFREE, 1,
1118               [Define to 1 if XFree XInput should be used])
1119
1120     X_PACKAGES="$X_PACKAGES xi"
1121     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xi"
1122
1123     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1124                     have_xinput2=yes
1125                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1126                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1127                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1128
1129     gtk_save_LIBS="$LIBS"
1130     LIBS="$LIBS -lXi"
1131     AC_CHECK_FUNC(XIAllowTouchEvents, AC_DEFINE(XINPUT_2_2, 1, [Define to 1 if XInput 2.2 is available]))
1132     LIBS="$gtk_save_LIBS"
1133   else
1134     AC_DEFINE(XINPUT_NONE, 1,
1135               [Define to 1 if no XInput should be used])
1136   fi
1137
1138   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1139   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1140
1141   if test "x$enable_xinput" = "xyes" ; then
1142     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1143       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1144     fi
1145   fi
1146
1147   # Check for the RANDR extension
1148   if test x"$enable_xrandr" != xno; then
1149     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1150       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1151
1152       X_PACKAGES="$X_PACKAGES xrandr"
1153       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1154     elif test x"$enable_xrandr" = xyes; then
1155       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1156     fi
1157   fi
1158
1159   # Checks for Xcursor library
1160
1161   if $PKG_CONFIG --exists xcursor ; then
1162     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1163
1164     X_PACKAGES="$X_PACKAGES xcursor"
1165   fi
1166
1167   # Checks for XFixes extension
1168
1169   if test x"$enable_xfixes" != xno; then
1170     if $PKG_CONFIG --exists xfixes ; then
1171       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1172
1173       X_PACKAGES="$X_PACKAGES xfixes"
1174       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1175       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1176     elif test x"$enable_xfixes" = xyes; then
1177       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1178     fi
1179   fi
1180
1181   # Checks for Xcomposite extension
1182
1183   if test x"$enable_xcomposite" != xno; then
1184     if $PKG_CONFIG --exists xcomposite ; then
1185       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1186
1187       X_PACKAGES="$X_PACKAGES xcomposite"
1188       X_EXTENSIONS="$X_EXTENSIONS Composite"
1189       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1190     elif test x"$enable_xcomposite" = xyes; then
1191       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1192     fi
1193   fi
1194
1195   # Checks for Xdamage extension
1196
1197   if test x"$enable_xdamage" != xno; then
1198     if $PKG_CONFIG --exists xdamage ; then
1199       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1200
1201       X_PACKAGES="$X_PACKAGES xdamage"
1202       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1203       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1204     elif test x"$enable_xdamage" = xyes; then
1205       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1206     fi
1207   fi
1208
1209   if $have_base_x_pc ; then
1210     GDK_EXTRA_LIBS="$x_extra_libs"
1211   else
1212     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1213   fi
1214
1215   CPPFLAGS="$gtk_save_cppflags"
1216   LIBS="$gtk_save_libs"
1217
1218   AM_CONDITIONAL(USE_X11, true)
1219
1220   # strip leading space
1221   X_EXTENSIONS=${X_EXTENSIONS#* }
1222
1223 else
1224   XPACKAGES=
1225
1226   AM_CONDITIONAL(XINPUT_XFREE, false)
1227   AM_CONDITIONAL(XINPUT_2, false)
1228   AM_CONDITIONAL(USE_X11, false)
1229   AM_CONDITIONAL(HAVE_X11R6, false)
1230 fi
1231
1232 # Check for Pango flags
1233
1234 AC_MSG_CHECKING(Pango flags)
1235 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1236         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1237         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1238
1239         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1240 else
1241         AC_MSG_ERROR([
1242 *** Pango not found. Pango built with Cairo support is required
1243 *** to build GTK+. See http://www.pango.org for Pango information.
1244 ])
1245 fi
1246
1247 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1248
1249 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1250         :
1251 else
1252         gtk_save_LIBS="$LIBS"
1253         LIBS="$PANGO_LIBS $LIBS"
1254         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1255 *** Can't link to Pango. Pango is required to build
1256 *** GTK+. For more information see http://www.pango.org]))
1257         LIBS="$gtk_save_LIBS"
1258 fi
1259
1260 CFLAGS="$saved_cflags"
1261 LDFLAGS="$saved_ldflags"
1262
1263 GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo cairo-gobject"
1264 GDK_PRIVATE_PACKAGES="$GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES $cairo_backends"
1265 if test "x$enable_x11_backend" = xyes; then
1266   GDK_PRIVATE_PACKAGES="$GDK_PRIVATE_PACKAGES pangoft2"
1267 fi
1268
1269 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES $GDK_PRIVATE_PACKAGES` $MATH_LIB"
1270 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PACKAGES $GDK_PRIVATE_PACKAGES` $GDK_EXTRA_CFLAGS"
1271 #
1272 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1273 # into the pkg-config files
1274 #
1275 if test $enable_explicit_deps != yes ; then
1276   GDK_EXTRA_LIBS=
1277 fi
1278
1279 AC_SUBST(GDK_PACKAGES)
1280 AC_SUBST(GDK_PRIVATE_PACKAGES)
1281 AC_SUBST(GDK_EXTRA_LIBS)
1282 AC_SUBST(GDK_EXTRA_CFLAGS)
1283 AC_SUBST(GDK_DEP_LIBS)
1284 AC_SUBST(GDK_DEP_CFLAGS)
1285
1286
1287 ########################################
1288 # Check for Accessibility Toolkit flags
1289 ########################################
1290
1291 ATK_PACKAGES=atk
1292 AC_MSG_CHECKING(ATK flags)
1293 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1294         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1295         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1296
1297         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1298 else
1299         AC_MSG_ERROR([
1300 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1301 *** to build GTK+.
1302 ])
1303 fi
1304
1305 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1306         :
1307 else
1308         gtk_save_LIBS="$LIBS"
1309         LIBS="$ATK_LIBS $LIBS"
1310         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1311                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1312                 *** to build GTK+]))
1313         LIBS="$gtk_save_LIBS"
1314 fi
1315
1316 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1317 GTK_PRIVATE_PACKAGES=""
1318 if test "x$enable_x11_backend" = xyes; then
1319   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES pangoft2"
1320 fi
1321 GTK_EXTRA_LIBS=
1322
1323 GTK_EXTRA_CFLAGS=
1324 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES $GTK_PRIVATE_PACKAGES` $GTK_EXTRA_LIBS $MATH_LIB"
1325 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PACKAGES $GTK_PACKAGES $GTK_PRIVATE_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1326
1327 if test x"$os_win32" = xyes; then
1328   GTK_EXTRA_CFLAGS="$msnative_struct"
1329 fi
1330
1331 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1332 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1333 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1334 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1335
1336 AC_SUBST(GTK_PACKAGES)
1337 AC_SUBST(GTK_PRIVATE_PACKAGES)
1338 AC_SUBST(GTK_EXTRA_LIBS)
1339 AC_SUBST(GTK_EXTRA_CFLAGS)
1340 AC_SUBST(GTK_DEP_LIBS)
1341 AC_SUBST(GTK_DEP_CFLAGS)
1342
1343 AC_SUBST(GLIB_PREFIX)
1344 AC_SUBST(ATK_PREFIX)
1345 AC_SUBST(PANGO_PREFIX)
1346 AC_SUBST(CAIRO_PREFIX)
1347
1348 AC_SUBST(GTK_DEBUG_FLAGS)
1349 AC_SUBST(GTK_XIM_FLAGS)
1350
1351 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1352 AC_SUBST(GDK_PIXBUF_LIBS)
1353
1354 ########################
1355 # Checks needed for gail
1356 ########################
1357
1358 old_LIBS="$LIBS"
1359 dnl Checks for inet libraries:
1360 AC_SEARCH_LIBS(gethostent, nsl)
1361 AC_SEARCH_LIBS(setsockopt, socket)
1362 AC_SEARCH_LIBS(connect, inet)
1363
1364 dnl check for the sockaddr_un.sun_len member
1365 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1366                 [struct_sockaddr_un_sun_len=true],
1367                 [struct_sockaddr_un_suin_len=false],
1368                 [#include <sys/types.h>
1369                  #include <sys/un.h>]
1370                 )
1371 case $struct_sockaddr_un_sun_len in
1372         true)
1373                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1374                                    [Have the sockaddr_un.sun_len member])
1375                 ;;
1376         *)
1377                 ;;
1378 esac
1379
1380 GAIL_INET_LIBS="$LIBS"
1381 AC_SUBST([GAIL_INET_LIBS])
1382
1383 LIBS="$old_LIBS"
1384
1385 ################################################################
1386 # Printing system checks
1387 ################################################################
1388
1389 PRINT_BACKENDS="file lpr"
1390
1391 AC_ARG_ENABLE(cups,
1392               [AS_HELP_STRING([--disable-cups],
1393                               [disable cups print backend])],,
1394               [enable_cups=auto])
1395
1396 if test "x$enable_cups" = "xno"; then
1397   AM_CONDITIONAL(HAVE_CUPS, false)
1398 else
1399   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1400   if test "x$CUPS_CONFIG" = "xno"; then
1401     if test "x$enable_cups" = "xauto"; then
1402       AM_CONDITIONAL(HAVE_CUPS, false)
1403     else
1404       AC_MSG_ERROR([
1405 *** cups not found.
1406 ])
1407     fi
1408   else
1409     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1410     CUPS_LIBS=`$CUPS_CONFIG --libs`
1411
1412     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1413     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1414     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1415
1416     if test $CUPS_API_MAJOR -gt 1 -o \
1417             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1418       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1419                 [Define to 1 if CUPS 1.2 API is available])
1420     fi
1421
1422     AC_SUBST(CUPS_API_MAJOR)
1423     AC_SUBST(CUPS_API_MINOR)
1424     AC_SUBST(CUPS_CFLAGS)
1425     AC_SUBST(CUPS_LIBS)
1426
1427     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1428
1429     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1430     AM_CONDITIONAL(HAVE_CUPS, true)
1431
1432     gtk_save_cflags="$CFLAGS"
1433     CFLAGS="$CUPS_CFLAGS"
1434     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1435                                        [[http_t http; char *s = http.authstring;]])],
1436                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1437                                  [Define if cups http_t authstring field is accessible])],
1438                       [])
1439     CFLAGS="$gtk_save_cflags"
1440
1441     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1442
1443     gtk_save_libs="$LIBS"
1444     LIBS="$CUPS_LIBS"
1445     AC_CHECK_FUNCS(httpGetAuthString)
1446     LIBS="$gtk_save_libs"
1447   fi
1448 fi
1449
1450 # Checks to see if we should compile with PAPI backend for GTK+
1451 #
1452
1453 AC_ARG_ENABLE(papi,
1454               [AS_HELP_STRING([--disable-papi],
1455                               [disable papi print backend])],,
1456               [enable_papi=auto])
1457
1458 if test "x$enable_papi" = "xno"; then
1459   AM_CONDITIONAL(HAVE_PAPI, false)
1460 else
1461   AC_MSG_CHECKING(libpapi)
1462   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1463   if test $have_papi = yes; then
1464     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1465     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1466   fi
1467   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1468   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1469     AC_MSG_ERROR([
1470 *** papi not found.
1471 ])
1472   fi
1473 fi
1474
1475 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1476
1477 gtk_save_cppflags="$CPPFLAGS"
1478 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1479
1480 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1481 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1482 *** backend enabled.]))
1483
1484 if test "$os_win32" != "yes"; then
1485   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1486 *** Can't find cairo-ps.h. You must build Cairo with the
1487 *** postscript backend enabled.]))
1488
1489   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1490 *** Cannot find cairo-svg.h. You must build Cairo with the
1491 *** svg backend enabled.]))
1492 fi
1493
1494 CPPFLAGS="$gtk_save_cppflags"
1495
1496
1497 AC_ARG_ENABLE(test-print-backend,
1498               [AS_HELP_STRING([--enable-test-print-backend],
1499                               [build test print backend])],,
1500               [enable_test_print_backend=no])
1501 if test "x$enable_test_print_backend" != "xno" ; then
1502   PRINT_BACKENDS="$PRINT_BACKENDS test"
1503 fi
1504 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1505
1506 if test "$os_win32" = "yes"; then
1507   AC_CHECK_TYPES([IPrintDialogCallback],[],[],[[#include <windows.h>]])
1508 fi
1509
1510 ################################################################
1511 # Strip -export-dynamic from the link lines of various libraries
1512 ################################################################
1513
1514 #
1515 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1516 #  but this flag is only meaningful for executables. For libraries
1517 #  the effect is undefined; what it causes on Linux is that the
1518 #  export list from -export-symbols-regex is ignored and everything
1519 #  is exported
1520 #
1521 # We are using gmodule-no-export now, but I'm leaving the stripping
1522 # code in place for now, since pango and atk still require gmodule.
1523 export SED
1524 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1525 if test -n "$export_dynamic"; then
1526   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1527   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1528 fi
1529
1530 #############
1531 # GSettings #
1532 #############
1533
1534 GLIB_GSETTINGS
1535
1536 #############
1537 # Resources #
1538 #############
1539
1540 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG --variable glib_compile_resources gio-2.0`
1541 AC_SUBST(GLIB_COMPILE_RESOURCES)
1542
1543 ##################################################
1544 # GObject introspection
1545 ##################################################
1546
1547 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1548
1549 ##################################################
1550 # Packagekit module
1551 #################################################
1552
1553 AC_ARG_ENABLE(packagekit,
1554               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1555                               [build PackageKit open-with module [default=auto]])],
1556               [enable_packagekit="$enableval"],
1557               [enable_packagekit=auto])
1558 if test "$enable_packagekit" = "auto"; then
1559   if test "$os_win32" = "yes"; then
1560     enable_packagekit=no
1561   else
1562     enable_packagekit=yes
1563   fi
1564 fi
1565
1566 AC_MSG_CHECKING([whether to use PackageKit])
1567 build_packagekit=no
1568 if test "x$enable_packagekit" != "xno"; then
1569   if test "$os_win32" != "yes"; then
1570     build_packagekit=yes
1571     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1572   else
1573     AC_MSG_ERROR([packagekit support is not available on win32])
1574   fi
1575 fi
1576 AC_MSG_RESULT([$build_packagekit])
1577
1578 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1579
1580 ##################################################
1581 # colord module
1582 #################################################
1583
1584 AC_ARG_ENABLE(colord,
1585               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1586                               [build colord support code [default=auto]])],
1587               [enable_colord="$enableval"],
1588               [enable_colord=auto])
1589
1590 AC_MSG_CHECKING([whether to use colord])
1591 if test "$enable_colord" = "auto"; then
1592   if test "$os_win32" = "yes"; then
1593     enable_colord=no
1594   fi
1595 fi
1596 if test "$enable_colord" != "no"; then
1597   AC_MSG_RESULT([yes])
1598 else
1599   AC_MSG_RESULT([no])
1600 fi
1601
1602 have_colord=no
1603 if test "$enable_colord" != "no"; then
1604         if test "$os_win32" != "yes"; then
1605                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1606                                   have_colord=yes, have_colord=no)
1607                 if test "$enable_colord" = "yes"; then
1608                         if test "$have_colord" = "no"; then
1609                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1610                         fi
1611                 fi
1612         else
1613                 AC_MSG_ERROR([colord support is not available on win32])
1614         fi
1615 fi
1616
1617 if test "$have_colord" = "yes"; then
1618         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1619 fi
1620 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1621
1622 ##################################################
1623 # Checks for gtk-doc and docbook-tools
1624 ##################################################
1625
1626 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1627
1628 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1629 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1630
1631 AC_ARG_ENABLE(man,
1632               [AS_HELP_STRING([--enable-man],
1633                               [regenerate man pages from Docbook [default=no]])],
1634               [enable_man=yes],
1635               [enable_man=no])
1636
1637 if test "${enable_man}" != no; then
1638   dnl
1639   dnl Check for xsltproc
1640   dnl
1641   AC_PATH_PROG([XSLTPROC], [xsltproc])
1642   if test -z "$XSLTPROC"; then
1643     enable_man=no
1644   fi
1645
1646   dnl check for DocBook DTD and stylesheets in the local catalog.
1647   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1648      [DocBook XML DTD V4.1.2],,enable_man=no)
1649   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1650      [DocBook XSL Stylesheets],,enable_man=no)
1651 fi
1652
1653 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1654
1655
1656 ##################################################
1657 # Output commands
1658 ##################################################
1659
1660 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1661         outfile=gdkconfig.h-tmp
1662         cat > $outfile <<\_______EOF
1663 /* gdkconfig.h
1664  *
1665  * This is a generated file.  Please modify `configure.ac'
1666  */
1667
1668 #ifndef __GDKCONFIG_H__
1669 #define __GDKCONFIG_H__
1670
1671 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1672 #error "Only <gdk/gdk.h> can be included directly."
1673 #endif
1674
1675 #include <glib.h>
1676
1677 G_BEGIN_DECLS
1678
1679 _______EOF
1680
1681         cat >>$outfile <<_______EOF
1682 $gdk_windowing
1683 _______EOF
1684
1685         cat >>$outfile <<_______EOF
1686
1687 G_END_DECLS
1688
1689 #endif  /* __GDKCONFIG_H__ */
1690 _______EOF
1691
1692
1693         if cmp -s $outfile gdk/gdkconfig.h; then
1694           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1695           rm -f $outfile
1696         else
1697           mv $outfile gdk/gdkconfig.h
1698         fi
1699 ],[
1700 gdk_windowing='$GDK_WINDOWING'
1701 ])
1702
1703 dnl
1704 dnl Check for -Bsymbolic-functions linker flag used to avoid
1705 dnl intra-library PLT jumps, if available.
1706 dnl
1707 AC_ARG_ENABLE(Bsymbolic,
1708               [AS_HELP_STRING([--disable-Bsymbolic],
1709                               [avoid linking with -Bsymbolic])],,
1710               [SAVED_LDFLAGS="${LDFLAGS}"
1711                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1712                LDFLAGS=-Wl,-Bsymbolic-functions
1713                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1714                                                [[int main (void) { return 0; }]])],
1715                               [AC_MSG_RESULT(yes)
1716                                enable_Bsymbolic=yes],
1717                               [AC_MSG_RESULT(no)
1718                                enable_Bsymbolic=no])
1719                LDFLAGS="${SAVED_LDFLAGS}"])
1720
1721 if test "x${enable_Bsymbolic}" = "xyes" ; then
1722   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1723 fi
1724 AC_SUBST(GTK_LINK_FLAGS)
1725
1726 AC_CONFIG_FILES([
1727 config.h.win32
1728 gtk-zip.sh
1729 Makefile
1730 gdk-3.0.pc
1731 gtk+-3.0.pc
1732 gtk+-unix-print-3.0.pc
1733 gail-3.0.pc
1734 m4macros/Makefile
1735 po/Makefile.in
1736 po-properties/Makefile.in
1737 demos/Makefile
1738 demos/gtk-demo/Makefile
1739 demos/gtk-demo/geninclude.pl
1740 demos/pixbuf-demo/Makefile
1741 demos/widget-factory/Makefile
1742 examples/Makefile
1743 tests/Makefile
1744 tests/a11y/Makefile
1745 tests/css/Makefile
1746 tests/css/parser/Makefile
1747 tests/reftests/Makefile
1748 tests/visuals/Makefile
1749 docs/Makefile
1750 docs/reference/Makefile
1751 docs/reference/gdk/Makefile
1752 docs/reference/gdk/version.xml
1753 docs/reference/gtk/Makefile
1754 docs/reference/gtk/version.xml
1755 docs/reference/libgail-util/Makefile
1756 docs/reference/libgail-util/version.xml
1757 docs/tools/Makefile
1758 build/Makefile
1759 build/win32/Makefile
1760 build/win32/vs9/Makefile
1761 build/win32/vs10/Makefile
1762 gdk/Makefile
1763 gdk/broadway/Makefile
1764 gdk/x11/Makefile
1765 gdk/win32/Makefile
1766 gdk/win32/rc/Makefile
1767 gdk/win32/rc/gdk.rc
1768 gdk/quartz/Makefile
1769 gdk/wayland/Makefile
1770 gdk/tests/Makefile
1771 gdk/gdkversionmacros.h
1772 gtk/Makefile
1773 gtk/makefile.msc
1774 gtk/gtkversion.h
1775 gtk/gtk-win32.rc
1776 gtk/a11y/Makefile
1777 gtk/tests/Makefile
1778 libgail-util/Makefile
1779 modules/Makefile
1780 modules/engines/Makefile
1781 modules/engines/pixbuf/Makefile
1782 modules/engines/ms-windows/Makefile
1783 modules/engines/ms-windows/Theme/Makefile
1784 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1785 modules/input/Makefile
1786 modules/printbackends/Makefile
1787 modules/printbackends/cups/Makefile
1788 modules/printbackends/lpr/Makefile
1789 modules/printbackends/file/Makefile
1790 modules/printbackends/papi/Makefile
1791 modules/printbackends/test/Makefile
1792 perf/Makefile
1793 ])
1794
1795 AC_OUTPUT
1796
1797 # beautify the immodule list a bit
1798 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1799 if test -z "${included_immodules}"; then included_immodules="none"; fi
1800
1801 echo ""
1802 echo "        GTK+ $GTK_VERSION"
1803 echo "        ==========="
1804 echo ""
1805 echo "        GDK backends:         $GDK_BACKENDS"
1806 if test "$enable_x11_backend" = "yes"; then
1807 echo "        X11 extensions:       $X_EXTENSIONS"
1808 fi
1809 echo "        Print backends:       $PRINT_BACKENDS"
1810 echo "        Dynamic modules:      $build_dynamic_modules"
1811 echo "        Included immodules:   $included_immodules"
1812 echo "        PackageKit support:   $build_packagekit"
1813 echo "        colord support:       $have_colord"
1814 echo "        Introspection:        $found_introspection"
1815 echo "        Debugging:            $enable_debug"
1816 echo "        Documentation:        $enable_gtk_doc"