Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [5])
  13 m4_define([gtk_micro_version], [3])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.33.1])
  43 m4_define([pango_required_version], [1.30.0])
  44 m4_define([atk_required_version], [2.2.0])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.26.0])
  47 m4_define([introspection_required_version], [1.32.0])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_INSTALL
 129 AC_PROG_MAKE_SET
 130
 131
 132 GETTEXT_PACKAGE=gtk30
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 135                    [The prefix for our gettext translation domains.])
 136
 137 AC_CANONICAL_HOST
 138
 139 MATH_LIB=-lm
 140 AC_MSG_CHECKING([for native Win32])
 141 LIB_EXE_MACHINE_FLAG=X86
 142 EXE_MANIFEST_ARCHITECTURE=X86
 143 case "$host" in
 144   *-*-mingw*)
 145     os_win32=yes
 146     gio_can_sniff=no
 147     MATH_LIB=
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       EXE_MANIFEST_ARCHITECTURE=AMD64
 152       ;;
 153     esac
 154     ;;
 155   *)
 156     os_win32=no
 157     ;;
 158 esac
 159 AC_MSG_RESULT([$os_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 163
 164 case $host in
 165   *-*-linux*)
 166     os_linux=yes
 167     ;;
 168 esac
 169
 170 dnl
 171 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 172 dnl We use this for an automated test for C++ header correctness.
 173 dnl
 174 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 175 AC_LANG_PUSH([C++])
 176
 177 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 178                                    [[class a { int b; } c;]])],
 179                   [],[CXX=])
 180 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 181
 182 gtk_save_cxxflags="$CXXFLAGS"
 183 CXXFLAGS="$CXXFLAGS -x objective-c++"
 184 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 185                                    [[]])],
 186                   [OBJC=yes],[OBJC=no])
 187 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 188 CXXFLAGS="$gtk_save_cxxflags"
 189 AC_LANG_POP([C++])
 190
 191 if test "$os_win32" = "yes"; then
 192   if test x$enable_static = xyes -o x$enable_static = x; then
 193     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 194     enable_static=no
 195   fi
 196   if test x$enable_shared = xno; then
 197     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 198   fi
 199   enable_shared=yes
 200 fi
 201
 202 dnl Initialize libtool
 203 LT_PREREQ([2.2.6])
 204 LT_INIT([disable-static win32-dll])
 205 # Create libtool early, because it's used in configure
 206 LT_OUTPUT
 207
 208 # Make sure we use 64-bit versions of various file stuff.
 209 AC_SYS_LARGEFILE
 210
 211 AM_PROG_AS
 212 AC_PATH_PROG(NM, nm, nm)
 213
 214 AC_MSG_CHECKING([for some Win32 platform])
 215 case "$host" in
 216   *-*-mingw*|*-*-cygwin*)
 217     platform_win32=yes
 218     ;;
 219   *)
 220     platform_win32=no
 221     ;;
 222 esac
 223 AC_MSG_RESULT([$platform_win32])
 224 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 225
 226 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 227 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 228 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 229
 230 if test "$os_win32" = "yes"; then
 231   AC_CHECK_TOOL(WINDRES, windres, no)
 232   if test "$WINDRES" = no; then
 233     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 234   fi
 235   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 236 fi
 237 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 238
 239 m4_define([debug_default],
 240           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 241
 242 dnl declare --enable-* args and collect ac_help strings
 243 AC_ARG_ENABLE(debug,
 244               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 245                               [turn on debugging @<:@default=debug_default@:>@])],,
 246               [enable_debug=debug_default])
 247
 248 AC_ARG_ENABLE(rebuilds,
 249               [AS_HELP_STRING([--disable-rebuilds],
 250                               [disable all source autogeneration rules])],,
 251               [enable_rebuilds=yes])
 252
 253 AC_ARG_ENABLE(gtk2-dependency,
 254               [AS_HELP_STRING([--enable-gtk2-dependency],
 255                               [Do not build gtk-update-icon-cache and other shared tools])],,
 256               [enable_gtk2_dependency=no])
 257
 258 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 259
 260 AC_ARG_ENABLE(xkb,
 261               [AS_HELP_STRING([--enable-xkb],
 262                               [support XKB extension [default=maybe]])],,
 263               [enable_xkb="maybe"])
 264 AC_ARG_ENABLE(xinerama,
 265               [AS_HELP_STRING([--enable-xinerama],
 266                               [support Xinerama extension [default=maybe]])],,
 267               [enable_xinerama="maybe"])
 268 AC_ARG_ENABLE(xrandr,
 269               [AS_HELP_STRING([--enable-xrandr],
 270                               [support XRandR extension [default=maybe]])],,
 271               [enable_xrandr="maybe"])
 272 AC_ARG_ENABLE(xfixes,
 273               [AS_HELP_STRING([--enable-xfixes],
 274                               [support XFixes extension [default=maybe]])],,
 275               [enable_xfixes="maybe"])
 276 AC_ARG_ENABLE(xcomposite,
 277               [AS_HELP_STRING([--enable-xcomposite],
 278                               [support X Composite extension [default=maybe]])],,
 279               [enable_xcomposite="maybe"])
 280 AC_ARG_ENABLE(xdamage,
 281               [AS_HELP_STRING([--enable-xdamage],
 282                               [support X Damage extension [default=maybe]])],,
 283               [enable_xdamage="maybe"])
 284
 285 AC_ARG_ENABLE(x11-backend,
 286               [AS_HELP_STRING([--enable-x11-backend],
 287                               [enable the X11 gdk backend])],
 288                               [backend_set=yes])
 289 AC_ARG_ENABLE(win32-backend,
 290               [AS_HELP_STRING([--enable-win32-backend],
 291                               [enable the Win32 gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(quartz-backend,
 294               [AS_HELP_STRING([--enable-quartz-backend],
 295                               [enable the quartz gdk backend])],
 296                               [backend_set=yes])
 297 AC_ARG_ENABLE(broadway-backend,
 298               [AS_HELP_STRING([--enable-broadway-backend],
 299                               [enable the broadway (HTML5) gdk backend])],
 300                               [backend_set=yes])
 301 AC_ARG_ENABLE(wayland-backend,
 302               [AS_HELP_STRING([--enable-wayland-backend],
 303                               [enable the wayland gdk backend])],
 304                               [backend_set=yes])
 305
 306 if test -z "$backend_set"; then
 307   if test "$platform_win32" = yes; then
 308     enable_win32_backend=yes
 309   else
 310     enable_x11_backend=yes
 311   fi
 312 fi
 313
 314 AC_ARG_ENABLE(quartz-relocation,
 315               [AS_HELP_STRING([--enable-quartz-relocation],
 316                               [enable bundle-based relocation functions])],
 317                               [quartz_relocation=yes])
 318
 319 AC_ARG_ENABLE(wayland-cairo-gl,
 320               AS_HELP_STRING([--enable-wayland-cairo-gl],
 321                              [enable the use of Cairo GL in the Wayland backend]),
 322               [enable_wayland_cairo_gl=yes])
 323
 324
 325 cairo_backends=
 326 backend_immodules=
 327 have_gio_unix=no
 328 GDK_BACKENDS=
 329 GDK_EXTRA_LIBS=
 330 GDK_EXTRA_CFLAGS=
 331 GDK_WINDOWING=
 332 PANGO_PACKAGES="pango pangocairo"
 333
 334 if test "$enable_x11_backend" = "yes"; then
 335   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 336   # backend names are identical.
 337   cairo_backends="$cairo_backends cairo-xlib"
 338   GDK_BACKENDS="$GDK_BACKENDS x11"
 339   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 340   # gdkapplaunchcontext-x11.c
 341   have_gio_unix=yes
 342   backend_immodules="$backend_immodules,xim"
 343   GDK_WINDOWING="$GDK_WINDOWING
 344 #define GDK_WINDOWING_X11"
 345 fi
 346
 347 if test "$enable_win32_backend" = "yes"; then
 348   cairo_backends="$cairo_backends cairo-win32"
 349   GDK_BACKENDS="$GDK_BACKENDS win32"
 350   backend_immodules="$backend_immodules,ime"
 351   GDK_WINDOWING="$GDK_WINDOWING
 352 #define GDK_WINDOWING_WIN32"
 353   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 354   AM_CONDITIONAL(USE_WIN32, true)
 355   PANGO_PACKAGES="pangowin32 pangocairo"
 356 else
 357   AM_CONDITIONAL(USE_WIN32, false)
 358 fi
 359
 360 if test "x$enable_quartz_backend" = xyes; then
 361   cairo_backends="$cairo_backends cairo-quartz"
 362   GDK_BACKENDS="$GDK_BACKENDS quartz"
 363   GDK_WINDOWING="$GDK_WINDOWING
 364 #define GDK_WINDOWING_QUARTZ"
 365   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 366   AM_CONDITIONAL(USE_QUARTZ, true)
 367   if test "x$quartz_relocation" = xyes; then
 368     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 369   fi
 370
 371 else
 372   AM_CONDITIONAL(USE_QUARTZ, false)
 373 fi
 374
 375
 376 if test "x$enable_broadway_backend" == xyes; then
 377   GDK_BACKENDS="$GDK_BACKENDS broadway"
 378   cairo_backends="$cairo_backends cairo"
 379   GDK_WINDOWING="$GDK_WINDOWING
 380 #define GDK_WINDOWING_BROADWAY"
 381   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 382   AM_CONDITIONAL(USE_BROADWAY, true)
 383 else
 384   AM_CONDITIONAL(USE_BROADWAY, false)
 385 fi
 386
 387 if test "x$enable_wayland_backend" == "xyes"; then
 388   if test "x$enable_wayland_cairo_gl" == "xyes"; then
 389     # Wayland can use cairo-gl
 390     cairo_backends="$cairo_backends cairo-gl"
 391     AC_DEFINE(GDK_WAYLAND_USE_EGL, [1], [Whether to use EGL in Wayland backend])
 392   else
 393     # For the cairo image backend
 394     cairo_backends="$cairo_backends cairo"
 395   fi
 396   GDK_BACKENDS="$GDK_BACKENDS wayland"
 397   have_gio_unix=yes
 398   GDK_WINDOWING="$GDK_WINDOWING
 399 #define GDK_WINDOWING_WAYLAND"
 400   WAYLAND_PACKAGES="wayland-client xkbcommon "
 401   if test "x$enable_wayland_cairo_gl" == "xyes"; then
 402     WAYLAND_PACKAGES="$WAYLAND_PACKAGES wayland-egl egl"
 403   fi
 404   AM_CONDITIONAL(USE_WAYLAND, true)
 405 else
 406   AM_CONDITIONAL(USE_WAYLAND, false)
 407 fi
 408
 409 # strip leading space
 410 GDK_BACKENDS=${GDK_BACKENDS#* }
 411
 412 AC_SUBST(GDK_BACKENDS)
 413
 414 if test -z "$GDK_BACKENDS"; then
 415   AC_MSG_ERROR([No GDK backends selected.])
 416 fi
 417
 418 if test "x$enable_debug" = "xyes"; then
 419   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 420   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 421 else
 422   if test "x$enable_debug" = "xno"; then
 423     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 424   else
 425     GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"
 426   fi
 427 fi
 428
 429
 430 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 431                    [Define if debugging is enabled])
 432
 433
 434 # Build time sanity check...
 435 AM_SANITY_CHECK
 436
 437 changequote(,)dnl
 438 if test "x$GCC" = "xyes"; then
 439   case " $CFLAGS " in
 440   *[\ \ ]-Wall[\ \      ]*) ;;
 441   *) CFLAGS="$CFLAGS -Wall" ;;
 442   esac
 443
 444   if test "x$enable_ansi" = "xyes"; then
 445     case " $CFLAGS " in
 446     *[\ \       ]-ansi[\ \      ]*) ;;
 447     *) CFLAGS="$CFLAGS -ansi" ;;
 448     esac
 449
 450     case " $CFLAGS " in
 451     *[\ \       ]-pedantic[\ \  ]*) ;;
 452     *) CFLAGS="$CFLAGS -pedantic" ;;
 453     esac
 454   fi
 455 fi
 456 changequote([,])dnl
 457
 458 # Ensure MSVC-compatible struct packing convention is used when
 459 # compiling for Win32 with gcc.
 460 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 461 # gcc2 uses "-fnative-struct".
 462 if test x"$os_win32" = xyes; then
 463   if test x"$GCC" = xyes; then
 464     msnative_struct=''
 465     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 466     if test -z "$ac_cv_prog_CC"; then
 467       our_gcc="$CC"
 468     else
 469       our_gcc="$ac_cv_prog_CC"
 470     fi
 471     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 472       2.)
 473         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 474           msnative_struct='-fnative-struct'
 475         fi
 476         ;;
 477       *)
 478         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 479           msnative_struct='-mms-bitfields'
 480         fi
 481         ;;
 482     esac
 483     if test x"$msnative_struct" = x ; then
 484       AC_MSG_RESULT([no way])
 485       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 486     else
 487       CFLAGS="$CFLAGS $msnative_struct"
 488       AC_MSG_RESULT([${msnative_struct}])
 489     fi
 490   fi
 491 fi
 492
 493 ## Initial sanity check, done here so that users get told they
 494 ## have the wrong dependencies as early in the process as possible.
 495 ## Later on we actually use the cflags/libs from separate pkg-config
 496 ## calls. Oh, also the later pkg-config calls don't include
 497 ## the version requirements since those make the module lists
 498 ## annoying to construct
 499 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 500   [glib-2.0 >= glib_required_version dnl
 501    atk >= atk_required_version dnl
 502    pango >= pango_required_version dnl
 503    cairo >= cairo_required_version dnl
 504    cairo-gobject >= cairo_required_version dnl
 505    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 506
 507 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 508
 509 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0])
 510
 511 if test "$os_win32" != yes; then
 512     # libtool option to control which symbols are exported
 513     # right now, symbols starting with _ are not exported
 514     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 515 else
 516     # We currently use .def files on Windows (for gdk and gtk)
 517     LIBTOOL_EXPORT_OPTIONS=
 518 fi
 519 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 520
 521 dnl ******************************************************
 522 dnl * See whether to include shared library dependencies *
 523 dnl ******************************************************
 524
 525 AC_ARG_ENABLE(explicit-deps,
 526               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 527                               [use explicit dependencies in .pc files [default=auto]])],,
 528               [enable_explicit_deps=auto])
 529
 530 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 531 case $enable_explicit_deps in
 532   auto)
 533     export SED
 534     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 535     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 536       enable_explicit_deps=yes
 537     else
 538       enable_explicit_deps=no
 539     fi
 540   ;;
 541   yes|no)
 542   ;;
 543   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 544   ;;
 545 esac
 546 AC_MSG_RESULT($enable_explicit_deps)
 547
 548 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 549
 550 # define a MAINT-like variable REBUILD which is set if Perl
 551 # and awk are found, so autogenerated sources can be rebuilt
 552
 553 AC_PATH_PROGS(PERL, perl5 perl)
 554
 555 # We would like indent, but don't require it.
 556 AC_CHECK_PROG(INDENT, indent, indent)
 557
 558 REBUILD=\#
 559 if test "x$enable_rebuilds" = "xyes" && \
 560      test -n "$PERL" && \
 561      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 562   REBUILD=
 563 fi
 564 AC_SUBST(REBUILD)
 565
 566 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 567 AC_CHECK_FUNCS(localtime_r)
 568
 569 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 570 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 571 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 572                                 [[char c;
 573                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 574                [gtk_ok=yes], [gtk_ok=no])
 575 AC_MSG_RESULT($gtk_ok)
 576 if test "$gtk_ok" = "yes"; then
 577   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 578             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 579 fi
 580
 581 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 582 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 583 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 584                                 [[char c;
 585                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 586                [gtk_ok=yes], [gtk_ok=no])
 587 AC_MSG_RESULT($gtk_ok)
 588 if test "$gtk_ok" = "yes"; then
 589   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 590             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 591 fi
 592
 593 # _NL_PAPER_HEIGHT is an enum and not a define
 594 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 595 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 596                                 [[char c;
 597                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 598                [gtk_ok=yes], [gtk_ok=no])
 599 AC_MSG_RESULT($gtk_ok)
 600 if test "$gtk_ok" = "yes"; then
 601   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 602             [Define if _NL_PAPER_HEIGHT is available])
 603 fi
 604
 605 # _NL_PAPER_WIDTH is an enum and not a define
 606 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 607 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 608                                 [[char c;
 609                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 610                [gtk_ok=yes], [gtk_ok=no])
 611 AC_MSG_RESULT($gtk_ok)
 612 if test "$gtk_ok" = "yes"; then
 613   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 614             [Define if _NL_PAPER_WIDTH is available])
 615 fi
 616
 617 # i18n stuff
 618 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 619 AM_GLIB_GNU_GETTEXT
 620 LIBS="$LIBS $INTLLIBS"
 621 AC_CONFIG_COMMANDS([po-properties],
 622                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 623                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 624                      esac]],
 625                    [[]])
 626
 627 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 628 dnl po-properties/POTFILES during configure; see GNOME #573515.
 629 dnl
 630 dnl Generate list of files to be processed by xgettext which will
 631 dnl be included in po-properties/Makefile.
 632 test -d po-properties || mkdir po-properties
 633 if test "x$srcdir" != "x."; then
 634   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 635     popropsrcprefix="$srcdir/"
 636   else
 637     popropsrcprefix="../$srcdir/"
 638   fi
 639 else
 640   popropsrcprefix="../"
 641 fi
 642 rm -f po-properties/POTFILES
 643 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 644 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 645 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 646
 647 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 648
 649 dnl The DU4 header files don't provide library prototypes unless
 650 dnl -std1 is given to the native cc.
 651 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 652
 653 gtk_save_LIBS=$LIBS
 654 LIBS="$LIBS -lm"
 655 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 656                                 int main (void) { return (log(1) != log(1.)); }]])],
 657               [AC_MSG_RESULT(none needed)],
 658               [gtk_save_CFLAGS="$CFLAGS"
 659                CFLAGS="$CFLAGS -std1"
 660                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 661                                                int main (void) { return (log(1) != log(1.)); }]])],
 662                              [AC_MSG_RESULT(-std1)],
 663                              [AC_MSG_RESULT()
 664                               CFLAGS="$gtk_save_CFLAGS"
 665                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 666                              [true])],
 667               [AC_MSG_RESULT(none needed)])
 668
 669 LIBS=$gtk_save_LIBS
 670
 671 AC_MSG_CHECKING(for the BeOS)
 672 case $host in
 673   *-*-beos*)
 674     AC_MSG_RESULT(yes)
 675     MATH_LIB=
 676   ;;
 677   *)
 678     AC_MSG_RESULT(no)
 679   ;;
 680 esac
 681
 682 AC_SUBST(MATH_LIB)
 683 #
 684 # see bug 162979
 685 #
 686 AC_MSG_CHECKING(for HP-UX)
 687 case $host_os in
 688   hpux9* | hpux10* | hpux11*)
 689     AC_MSG_RESULT(yes)
 690     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 691   ;;
 692   *)
 693     AC_MSG_RESULT(no)
 694   ;;
 695 esac
 696
 697 #
 698 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 699 #
 700
 701 AM_PATH_GLIB_2_0(glib_required_version, :,
 702   AC_MSG_ERROR([
 703 *** GLIB glib_required_version or better is required. The latest version of
 704 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 705   gobject gmodule-no-export)
 706
 707 dnl
 708 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 709 dnl
 710 gtk_save_LIBS=$LIBS
 711 LIBS="$LIBS $GLIB_LIBS"
 712 AC_CHECK_FUNCS(bind_textdomain_codeset)
 713 LIBS=$gtk_save_LIBS
 714
 715 AC_CHECK_HEADERS(pwd.h,
 716                  AC_DEFINE(HAVE_PWD_H, 1,
 717                            [Define to 1 if pwd.h is available]))
 718 AC_CHECK_HEADERS(sys/time.h,
 719                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 720                            [Define to 1 if time.h is available]))
 721 AC_CHECK_HEADERS(unistd.h,
 722                  AC_DEFINE(HAVE_UNISTD_H, 1,
 723                            [Define to 1 if unistd.h is available]))
 724 AC_CHECK_HEADERS(ftw.h,
 725                  AC_DEFINE(HAVE_FTW_H, 1,
 726                            [Define to 1 if ftw.h is available]))
 727
 728 AC_MSG_CHECKING([for GNU ftw extensions])
 729 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 730                                      #define _GNU_SOURCE
 731                                      #include <ftw.h>]],
 732                                    [[int flags = FTW_ACTIONRETVAL;]])],
 733                   [gtk_ok=yes],[gtk_ok=no])
 734 if test $gtk_ok = yes; then
 735     AC_MSG_RESULT([yes])
 736     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 737 else
 738     AC_MSG_RESULT([no])
 739 fi
 740
 741 saved_cflags="$CFLAGS"
 742 saved_ldflags="$LDFLAGS"
 743
 744
 745 # Checks for library functions.
 746 AC_FUNC_MMAP
 747
 748 AC_CHECK_FUNCS(mallinfo)
 749 AC_CHECK_FUNCS(getresuid)
 750 AC_TYPE_UID_T
 751
 752 # Check for round(), rint(), isnan(), isinf() and nearbyint()
 753 AC_CHECK_LIB(m,round,,)
 754 AC_CHECK_FUNCS(round rint isnan isinf nearbyint)
 755
 756 # Checks for gdkspawn
 757 AC_CHECK_HEADERS(crt_externs.h)
 758 AC_CHECK_FUNCS(_NSGetEnviron)
 759
 760 AC_MSG_CHECKING(whether to build dynamic modules)
 761
 762 AC_ARG_ENABLE(modules,
 763               [AS_HELP_STRING([--disable-modules],
 764                               [disable dynamic module loading])])
 765
 766 dynworks=false
 767 build_dynamic_modules=no
 768 deps=
 769 if test x$enable_modules = xno; then
 770     AC_MSG_RESULT(no)
 771 else
 772     AC_MSG_RESULT(yes)
 773     AC_MSG_CHECKING(whether dynamic modules work)
 774     ## for loop is to strip newline
 775     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 776     for I in $tmp; do
 777         dynworks=$I
 778     done
 779
 780     dnl Now we check to see if our libtool supports shared lib deps
 781     dnl (in a rather ugly way even)
 782     if $dynworks; then
 783         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 784         module_deplibs_check=`$module_libtool_config | \
 785             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 786             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 787         if test "x$module_deplibs_check" = "xnone" || \
 788            test "x$module_deplibs_check" = "xunknown" || \
 789            test "x$module_deplibs_check" = "x"; then
 790             dynworks=false
 791         fi
 792     fi
 793
 794     if $dynworks; then
 795         build_dynamic_modules=yes
 796         AC_DEFINE(USE_GMODULE, 1,
 797                   [Define to 1 if gmodule works and should be used])
 798         AC_MSG_RESULT(yes)
 799     else
 800         build_dynamic_modules=no
 801         AC_MSG_RESULT(no)
 802     fi
 803 fi
 804
 805 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 806
 807 #
 808 # Allow building some or all immodules included
 809 #
 810 AC_MSG_CHECKING(immodules to build)
 811
 812 AC_ARG_WITH(included_immodules,
 813             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 814                             [build the specified input methods into gtk])])
 815
 816 if $dynworks; then
 817    :
 818 else
 819    ## if the option was specified, leave it; otherwise disable included immodules
 820    if test x$with_included_immodules = xno; then
 821            with_included_immodules=yes
 822    fi
 823 fi
 824
 825 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 826
 827 included_immodules=""
 828 # If the switch specified without listing any specific ones, include all
 829 if test "x$with_included_immodules" = xyes ; then
 830   included_immodules="$all_immodules"
 831 else
 832   included_immodules="$with_included_immodules"
 833 fi
 834
 835 AC_MSG_RESULT($included_immodules)
 836 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 837
 838 INCLUDED_IMMODULE_OBJ=
 839 INCLUDED_IMMODULE_DEFINE=
 840
 841 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 842 for immodule in $included_immodules; do
 843  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 844  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 845    :
 846  else
 847    AC_MSG_ERROR([the specified input method $immodule does not exist])
 848  fi
 849
 850  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 851  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 852  eval INCLUDE_$immodule_underscores=yes
 853 done
 854 IFS="$gtk_save_ifs"
 855 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 856 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 857
 858 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 859 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 860 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 861 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 862 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 863 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 864 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 865 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 866 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 867 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 868 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 869 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 870
 871 # Checks to see whether we should include mediaLib
 872 # support.
 873 #
 874 AC_CHECK_HEADER(sys/systeminfo.h,
 875                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 876                           [Define to 1 if sys/systeminfo.h is available]))
 877 AC_CHECK_HEADER(sys/sysinfo.h,
 878                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 879                           [Define to 1 if sys/sysinfo.h is available]))
 880
 881 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 882
 883 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 884
 885 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 886   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 887   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 888     REBUILD_PNGS=#
 889   fi
 890 fi
 891
 892 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 893
 894 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 895
 896 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 897    test "x$REBUILD_PNGS" = "x#" ; then
 898      AC_MSG_ERROR([
 899 *** gtkbuiltincache.h is not in the tree, and cannot be built
 900 *** because you don't have libpng, or (when cross-compiling) you
 901 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 902 fi
 903
 904 ########################################
 905 # Windowing system checks
 906 ########################################
 907
 908 # GTK+ uses some X calls, so needs to link against X directly
 909 GTK_DEP_PACKAGES_FOR_X=
 910 GTK_DEP_LIBS_FOR_X=
 911 X_EXTENSIONS=
 912
 913 if test "x$enable_x11_backend" = xyes; then
 914   X_PACKAGES=fontconfig
 915
 916   #
 917   # We use fontconfig very peripherally when decoding the default
 918   # settings.
 919   #
 920   if $PKG_CONFIG --exists fontconfig; then : ; else
 921     AC_MSG_ERROR([
 922 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 923   fi
 924
 925   #
 926   # Check for basic X packages; we use pkg-config if available
 927   #
 928   if $PKG_CONFIG --exists x11 xext; then
 929     have_base_x_pc=true
 930     X_PACKAGES="$X_PACKAGES x11 xext"
 931     x_libs="`$PKG_CONFIG --libs x11 xext`"
 932     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 933
 934     # Strip out any .la files that pkg-config might give us (this happens
 935     # with -uninstalled.pc files)
 936     x_libs_for_checks=
 937     for I in $x_libs ; do
 938       case $I in
 939         *.la) ;;
 940         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 941       esac
 942     done
 943
 944     GTK_PACKAGES_FOR_X="x11"
 945   else
 946     have_base_x_pc=false
 947     AC_PATH_XTRA
 948     if test x$no_x = xyes ; then
 949       AC_MSG_ERROR([X development libraries not found])
 950     fi
 951
 952     x_cflags="$X_CFLAGS"
 953     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 954
 955     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 956   fi
 957
 958   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 959   x_extra_libs=
 960
 961   gtk_save_cppflags="$CPPFLAGS"
 962   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 963
 964   gtk_save_LIBS=$LIBS
 965   LIBS="$x_libs_for_checks $LIBS"
 966
 967   # Sanity check for the X11 and Xext libraries. While everything we need from
 968   # Xext is optional, the chances a system has *none* of these things is so
 969   # small that we just unconditionally require it.
 970   AC_CHECK_FUNC(XOpenDisplay, :,
 971                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 972   AC_CHECK_FUNC(XextFindDisplay, :,
 973                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 974
 975   # Check for xReply
 976
 977   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 978   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 979                                      [[xReply *rep;]])],
 980                     [AC_MSG_RESULT([no])],
 981                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 982                                                           #include <X11/Xlibint.h>]],
 983                                                         [[xReply *rep;]])],
 984                                        [AC_MSG_RESULT([yes])
 985                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 986                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 987                                        [AC_MSG_RESULT([unknown])
 988                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 989
 990   # Check for XKB support.
 991
 992   if test "x$enable_xkb" = "xyes"; then
 993         AC_CHECK_FUNC(XkbQueryExtension,
 994                       X_EXTENSIONS="$X_EXTENSIONS XKB"
 995                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
 996                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
 997   elif test "x$enable_xkb" = "xmaybe"; then
 998         AC_CHECK_FUNC(XkbQueryExtension,
 999                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1000                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1001   else
1002         AC_MSG_WARN(XKB support explicitly disabled)
1003   fi
1004
1005   # Check for shaped window extension
1006
1007   AC_CHECK_FUNC(XShapeCombineMask, :,
1008      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1009
1010   # X SYNC check
1011   gtk_save_CFLAGS="$CFLAGS"
1012   CFLAGS="$CFLAGS $x_cflags"
1013
1014   AC_CHECK_FUNC(XSyncQueryExtension,
1015       [AC_CHECK_HEADER(X11/extensions/sync.h,
1016           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1017           :, [#include <X11/Xlib.h>])])
1018
1019   CFLAGS="$gtk_save_CFLAGS"
1020
1021   if test "x$enable_xinerama" != "xno"; then
1022     # Check for Xinerama extension (Solaris impl or Xfree impl)
1023     have_xfree_xinerama=false
1024     have_solaris_xinerama=false
1025
1026     gtk_save_cppflags="$CPPFLAGS"
1027     CPPFLAGS="$CPPFLAGS $x_cflags"
1028
1029     # Check for XFree
1030     AC_MSG_CHECKING(for Xinerama packages)
1031
1032     if $PKG_CONFIG --exists xinerama ; then
1033        AC_MSG_RESULT(yes)
1034        have_xfree_xinerama=true
1035        X_PACKAGES="$X_PACKAGES xinerama"
1036     else
1037        AC_MSG_RESULT(no)
1038        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1039            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1040            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1041            have_xfree_xinerama=true], :,
1042            [#include <X11/Xlib.h>])])
1043     fi
1044
1045     if $have_xfree_xinerama ; then
1046       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1047       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1048                 [Define to 1 if XFree Xinerama is available])
1049       AC_DEFINE(HAVE_XINERAMA, 1,
1050                 [Define to 1 is Xinerama is available])
1051     else
1052       case "$host" in
1053         *-*-solaris*)
1054             # Check for solaris
1055             AC_MSG_CHECKING(for Xinerama support on Solaris)
1056
1057             have_solaris_xinerama=false
1058             AC_CHECK_FUNC(XineramaGetInfo,
1059                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1060                     [have_solaris_xinerama=true], :,
1061                     [#include <X11/Xlib.h>])])
1062
1063             if $have_solaris_xinerama ; then
1064               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1065               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1066                         [Define to 1 if solaris xinerama is available])
1067               AC_DEFINE(HAVE_XINERAMA, 1,
1068                         [Define to 1 if xinerama is available])
1069               AC_MSG_RESULT(yes)
1070             else
1071               AC_MSG_RESULT(no)
1072             fi
1073             ;;
1074         *)
1075             ;;
1076       esac
1077     fi
1078   fi
1079   if test "x$enable_xinerama" = "xyes" ; then
1080     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1081       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1082     fi
1083   fi
1084
1085   # Check for XGetEventData for GenericEvents
1086   AC_CHECK_FUNC(XGetEventData,
1087                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1088
1089   # set up things for XInput
1090   if $PKG_CONFIG --exists "xi" ; then
1091
1092     X_PACKAGES="$X_PACKAGES xi"
1093     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xi"
1094
1095     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1096                     have_xinput2=yes
1097                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1098
1099     gtk_save_LIBS="$LIBS"
1100     LIBS="$LIBS -lXi"
1101
1102     # Note that we also check that the XIScrollClassInfo struct is defined,
1103     # because at least Ubuntu Oneiric seems to have XIAllowTouchEvents(), but not the XIScrollClassInfo struct.
1104     AC_CHECK_FUNC([XIAllowTouchEvents],
1105       [AC_CHECK_MEMBER([XIScrollClassInfo.number],
1106                        have_xinput2_2=yes
1107                        AC_DEFINE(XINPUT_2_2, 1, [Define to 1 if XInput 2.2 is available]),
1108                        have_xinput2_2=no,
1109                        [[#include <X11/extensions/XInput2.h>]])])
1110     LIBS="$gtk_save_LIBS"
1111
1112     if test "x$have_xinput2_2" = "xyes"; then
1113       X_EXTENSIONS="$X_EXTENSIONS XI2.2"
1114     else
1115       X_EXTENSIONS="$X_EXTENSIONS XI2"
1116     fi
1117   fi
1118
1119   AS_IF([test "x$have_xinput2" != "xyes"],
1120         [AC_MSG_ERROR([*** XInput2 extension not found. Check 'config.log' for more details.])])
1121
1122   # Check for the RANDR extension
1123   if test x"$enable_xrandr" != xno; then
1124     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1125       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1126
1127       X_PACKAGES="$X_PACKAGES xrandr"
1128       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1129     elif test x"$enable_xrandr" = xyes; then
1130       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1131     fi
1132   fi
1133
1134   # Checks for Xcursor library
1135
1136   if $PKG_CONFIG --exists xcursor ; then
1137     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1138
1139     X_PACKAGES="$X_PACKAGES xcursor"
1140   fi
1141
1142   # Checks for XFixes extension
1143
1144   if test x"$enable_xfixes" != xno; then
1145     if $PKG_CONFIG --exists xfixes ; then
1146       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1147
1148       X_PACKAGES="$X_PACKAGES xfixes"
1149       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1150       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1151     elif test x"$enable_xfixes" = xyes; then
1152       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1153     fi
1154   fi
1155
1156   # Checks for Xcomposite extension
1157
1158   if test x"$enable_xcomposite" != xno; then
1159     if $PKG_CONFIG --exists xcomposite ; then
1160       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1161
1162       X_PACKAGES="$X_PACKAGES xcomposite"
1163       X_EXTENSIONS="$X_EXTENSIONS Composite"
1164       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1165     elif test x"$enable_xcomposite" = xyes; then
1166       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1167     fi
1168   fi
1169
1170   # Checks for Xdamage extension
1171
1172   if test x"$enable_xdamage" != xno; then
1173     if $PKG_CONFIG --exists xdamage ; then
1174       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1175
1176       X_PACKAGES="$X_PACKAGES xdamage"
1177       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1178       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1179     elif test x"$enable_xdamage" = xyes; then
1180       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1181     fi
1182   fi
1183
1184   if $have_base_x_pc ; then
1185     GDK_EXTRA_LIBS="$x_extra_libs"
1186   else
1187     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1188   fi
1189
1190   CPPFLAGS="$gtk_save_cppflags"
1191   LIBS="$gtk_save_libs"
1192
1193   AM_CONDITIONAL(USE_X11, true)
1194
1195   # strip leading space
1196   X_EXTENSIONS=${X_EXTENSIONS#* }
1197
1198 else
1199   XPACKAGES=
1200
1201   AM_CONDITIONAL(USE_X11, false)
1202 fi
1203
1204 # Check for gio-unix
1205 if test "$have_gio_unix" = "yes"; then
1206   GDK_GIO_PACKAGE=gio-unix-2.0
1207   AC_DEFINE([HAVE_GIO_UNIX], [1],
1208             [Define if gio-unix is available])
1209 else
1210   GDK_GIO_PACKAGE=gio-2.0
1211 fi
1212
1213 # Check for Pango flags
1214
1215 AC_MSG_CHECKING(Pango flags)
1216 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1217         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1218         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1219
1220         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1221 else
1222         AC_MSG_ERROR([
1223 *** Pango not found. Pango built with Cairo support is required
1224 *** to build GTK+. See http://www.pango.org for Pango information.
1225 ])
1226 fi
1227
1228 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1229
1230 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1231         :
1232 else
1233         gtk_save_LIBS="$LIBS"
1234         LIBS="$PANGO_LIBS $LIBS"
1235         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1236 *** Can't link to Pango. Pango is required to build
1237 *** GTK+. For more information see http://www.pango.org]))
1238         LIBS="$gtk_save_LIBS"
1239 fi
1240
1241 CFLAGS="$saved_cflags"
1242 LDFLAGS="$saved_ldflags"
1243
1244 GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo cairo-gobject"
1245 GDK_PRIVATE_PACKAGES="$GDK_GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES $cairo_backends"
1246 if test "x$enable_x11_backend" = xyes; then
1247   GDK_PRIVATE_PACKAGES="$GDK_PRIVATE_PACKAGES pangoft2"
1248 fi
1249
1250 PKG_CHECK_MODULES(GDK_DEP, $GDK_PACKAGES $GDK_PRIVATE_PACKAGES)
1251 GDK_DEP_LIBS="$GDK_EXTRA_LIBS $GDK_DEP_LIBS $MATH_LIB"
1252 GDK_DEP_CFLAGS="$GDK_DEP_CFLAGS $GDK_EXTRA_CFLAGS"
1253 #
1254 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1255 # into the pkg-config files
1256 #
1257 if test $enable_explicit_deps != yes ; then
1258   GDK_EXTRA_LIBS=
1259 fi
1260
1261 AC_SUBST(GDK_PACKAGES)
1262 AC_SUBST(GDK_PRIVATE_PACKAGES)
1263 AC_SUBST(GDK_EXTRA_LIBS)
1264 AC_SUBST(GDK_EXTRA_CFLAGS)
1265 AC_SUBST(GDK_DEP_LIBS)
1266 AC_SUBST(GDK_DEP_CFLAGS)
1267
1268
1269 ########################################
1270 # Check for Accessibility Toolkit flags
1271 ########################################
1272
1273 ATK_PACKAGES=atk
1274 PKG_CHECK_MODULES(ATK, $ATK_PACKAGES)
1275
1276 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1277 GTK_PRIVATE_PACKAGES=""
1278 if test "x$enable_x11_backend" = xyes; then
1279   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES pangoft2"
1280 fi
1281 if test "$have_gio_unix" = "yes"; then
1282   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES gio-unix-2.0"
1283 fi
1284 GTK_EXTRA_LIBS=
1285
1286 GTK_EXTRA_CFLAGS=
1287 PKG_CHECK_MODULES(GTK_DEP, $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES $GTK_PRIVATE_PACKAGES)
1288 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X $GTK_DEP_LIBS $GTK_EXTRA_LIBS $MATH_LIB"
1289 GTK_DEP_CFLAGS="$GTK_DEP_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1290
1291 if test x"$os_win32" = xyes; then
1292   GTK_EXTRA_CFLAGS="$msnative_struct"
1293 fi
1294
1295 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1296 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1297 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1298 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1299
1300 AC_SUBST(GTK_PACKAGES)
1301 AC_SUBST(GTK_PRIVATE_PACKAGES)
1302 AC_SUBST(GTK_EXTRA_LIBS)
1303 AC_SUBST(GTK_EXTRA_CFLAGS)
1304 AC_SUBST(GTK_DEP_LIBS)
1305 AC_SUBST(GTK_DEP_CFLAGS)
1306
1307 AC_SUBST(GLIB_PREFIX)
1308 AC_SUBST(ATK_PREFIX)
1309 AC_SUBST(PANGO_PREFIX)
1310 AC_SUBST(CAIRO_PREFIX)
1311
1312 AC_SUBST(GTK_DEBUG_FLAGS)
1313 AC_SUBST(GTK_XIM_FLAGS)
1314
1315 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1316 AC_SUBST(GDK_PIXBUF_LIBS)
1317
1318 ########################
1319 # Checks needed for gail
1320 ########################
1321
1322 old_LIBS="$LIBS"
1323 dnl Checks for inet libraries:
1324 AC_SEARCH_LIBS(gethostent, nsl)
1325 AC_SEARCH_LIBS(setsockopt, socket)
1326 AC_SEARCH_LIBS(connect, inet)
1327
1328 dnl check for the sockaddr_un.sun_len member
1329 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1330                 [struct_sockaddr_un_sun_len=true],
1331                 [struct_sockaddr_un_suin_len=false],
1332                 [#include <sys/types.h>
1333                  #include <sys/un.h>]
1334                 )
1335 case $struct_sockaddr_un_sun_len in
1336         true)
1337                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1338                                    [Have the sockaddr_un.sun_len member])
1339                 ;;
1340         *)
1341                 ;;
1342 esac
1343
1344 GAIL_INET_LIBS="$LIBS"
1345 AC_SUBST([GAIL_INET_LIBS])
1346
1347 LIBS="$old_LIBS"
1348
1349 ################################################################
1350 # Printing system checks
1351 ################################################################
1352
1353 PRINT_BACKENDS="file lpr"
1354
1355 AC_ARG_ENABLE(cups,
1356               [AS_HELP_STRING([--disable-cups],
1357                               [disable cups print backend])],,
1358               [enable_cups=auto])
1359
1360 if test "x$enable_cups" = "xno"; then
1361   AM_CONDITIONAL(HAVE_CUPS, false)
1362 else
1363   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1364   if test "x$CUPS_CONFIG" = "xno"; then
1365     if test "x$enable_cups" = "xauto"; then
1366       AM_CONDITIONAL(HAVE_CUPS, false)
1367     else
1368       AC_MSG_ERROR([
1369 *** cups not found.
1370 ])
1371     fi
1372   else
1373     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1374     CUPS_LIBS=`$CUPS_CONFIG --libs`
1375
1376     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1377     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1378     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1379
1380     if test $CUPS_API_MAJOR -gt 1 -o \
1381             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -lt 2; then
1382       AC_MSG_ERROR([CUPS >= 1.2 not found])
1383     fi
1384     if test $CUPS_API_MAJOR -gt 1 -o \
1385             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 6; then
1386       AC_DEFINE(HAVE_CUPS_API_1_6, 1,
1387                 [Define to 1 if CUPS 1.6 API is available])
1388
1389     fi
1390
1391     AC_SUBST(CUPS_API_MAJOR)
1392     AC_SUBST(CUPS_API_MINOR)
1393     AC_SUBST(CUPS_CFLAGS)
1394     AC_SUBST(CUPS_LIBS)
1395
1396     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1397
1398     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1399     AM_CONDITIONAL(HAVE_CUPS, true)
1400
1401     gtk_save_cflags="$CFLAGS"
1402     CFLAGS="$CUPS_CFLAGS"
1403     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1404                                        [[http_t http; char *s = http.authstring;]])],
1405                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1406                                  [Define if cups http_t authstring field is accessible])],
1407                       [])
1408     CFLAGS="$gtk_save_cflags"
1409
1410     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1411
1412     gtk_save_libs="$LIBS"
1413     LIBS="$CUPS_LIBS"
1414     AC_CHECK_FUNCS(httpGetAuthString)
1415     LIBS="$gtk_save_libs"
1416   fi
1417 fi
1418
1419 # Checks to see if we should compile with PAPI backend for GTK+
1420 #
1421
1422 AC_ARG_ENABLE(papi,
1423               [AS_HELP_STRING([--disable-papi],
1424                               [disable papi print backend])],,
1425               [enable_papi=auto])
1426
1427 if test "x$enable_papi" = "xno"; then
1428   AM_CONDITIONAL(HAVE_PAPI, false)
1429 else
1430   AC_MSG_CHECKING(libpapi)
1431   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1432   if test $have_papi = yes; then
1433     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1434     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1435   fi
1436   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1437   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1438     AC_MSG_ERROR([
1439 *** papi not found.
1440 ])
1441   fi
1442 fi
1443
1444 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1445
1446 gtk_save_cppflags="$CPPFLAGS"
1447 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1448
1449 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1450 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1451 *** backend enabled.]))
1452
1453 if test "$os_win32" != "yes"; then
1454   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1455 *** Can't find cairo-ps.h. You must build Cairo with the
1456 *** postscript backend enabled.]))
1457
1458   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1459 *** Cannot find cairo-svg.h. You must build Cairo with the
1460 *** svg backend enabled.]))
1461 fi
1462
1463 CPPFLAGS="$gtk_save_cppflags"
1464
1465
1466 AC_ARG_ENABLE(test-print-backend,
1467               [AS_HELP_STRING([--enable-test-print-backend],
1468                               [build test print backend])],,
1469               [enable_test_print_backend=no])
1470 if test "x$enable_test_print_backend" != "xno" ; then
1471   PRINT_BACKENDS="$PRINT_BACKENDS test"
1472 fi
1473 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1474
1475 if test "$os_win32" = "yes"; then
1476   AC_CHECK_TYPES([IPrintDialogCallback],[],[],[[#include <windows.h>]])
1477 fi
1478
1479 ################################################################
1480 # Strip -export-dynamic from the link lines of various libraries
1481 ################################################################
1482
1483 #
1484 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1485 #  but this flag is only meaningful for executables. For libraries
1486 #  the effect is undefined; what it causes on Linux is that the
1487 #  export list from -export-symbols-regex is ignored and everything
1488 #  is exported
1489 #
1490 # We are using gmodule-no-export now, but I'm leaving the stripping
1491 # code in place for now, since pango and atk still require gmodule.
1492 export SED
1493 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1494 if test -n "$export_dynamic"; then
1495   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1496   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1497 fi
1498
1499 #############
1500 # GSettings #
1501 #############
1502
1503 GLIB_GSETTINGS
1504
1505 ##################################################
1506 # GObject introspection
1507 ##################################################
1508
1509 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1510
1511 ##################################################
1512 # Packagekit module
1513 #################################################
1514
1515 AC_ARG_ENABLE(packagekit,
1516               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1517                               [build PackageKit open-with module [default=auto]])],
1518               [enable_packagekit="$enableval"],
1519               [enable_packagekit=auto])
1520 if test "$enable_packagekit" = "auto"; then
1521   if test "$os_win32" = "yes"; then
1522     enable_packagekit=no
1523   else
1524     enable_packagekit=yes
1525   fi
1526 fi
1527
1528 AC_MSG_CHECKING([whether to use PackageKit])
1529 build_packagekit=no
1530 if test "x$enable_packagekit" != "xno"; then
1531   if test "$os_win32" != "yes"; then
1532     build_packagekit=yes
1533     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1534   else
1535     AC_MSG_ERROR([packagekit support is not available on win32])
1536   fi
1537 fi
1538 AC_MSG_RESULT([$build_packagekit])
1539
1540 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1541
1542 ##################################################
1543 # colord module
1544 #################################################
1545
1546 AC_ARG_ENABLE(colord,
1547               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1548                               [build colord support code [default=auto]])],
1549               [enable_colord="$enableval"],
1550               [enable_colord=auto])
1551
1552 AC_MSG_CHECKING([whether to use colord])
1553 if test "$enable_colord" = "auto"; then
1554   if test "$os_win32" = "yes"; then
1555     enable_colord=no
1556   fi
1557 fi
1558 if test "$enable_colord" != "no"; then
1559   AC_MSG_RESULT([yes])
1560 else
1561   AC_MSG_RESULT([no])
1562 fi
1563
1564 have_colord=no
1565 if test "$enable_colord" != "no"; then
1566         if test "$os_win32" != "yes"; then
1567                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1568                                   have_colord=yes, have_colord=no)
1569                 if test "$enable_colord" = "yes"; then
1570                         if test "$have_colord" = "no"; then
1571                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1572                         fi
1573                 fi
1574         else
1575                 AC_MSG_ERROR([colord support is not available on win32])
1576         fi
1577 fi
1578
1579 if test "$have_colord" = "yes"; then
1580         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1581 fi
1582 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1583
1584 ##################################################
1585 # Checks for gtk-doc and docbook-tools
1586 ##################################################
1587
1588 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1589
1590 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1591 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1592
1593 AC_ARG_ENABLE(man,
1594               [AS_HELP_STRING([--enable-man],
1595                               [regenerate man pages from Docbook [default=no]])],
1596               [enable_man=yes],
1597               [enable_man=no])
1598
1599 if test "${enable_man}" != no; then
1600   dnl
1601   dnl Check for xsltproc
1602   dnl
1603   AC_PATH_PROG([XSLTPROC], [xsltproc])
1604   if test -z "$XSLTPROC"; then
1605     enable_man=no
1606   fi
1607
1608   dnl check for DocBook DTD and stylesheets in the local catalog.
1609   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1610      [DocBook XML DTD V4.1.2],,enable_man=no)
1611   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1612      [DocBook XSL Stylesheets],,enable_man=no)
1613 fi
1614
1615 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1616
1617
1618 ##################################################
1619 # Output commands
1620 ##################################################
1621
1622 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1623         outfile=gdkconfig.h-tmp
1624         cat > $outfile <<\_______EOF
1625 /* gdkconfig.h
1626  *
1627  * This is a generated file.  Please modify `configure.ac'
1628  */
1629
1630 #ifndef __GDKCONFIG_H__
1631 #define __GDKCONFIG_H__
1632
1633 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1634 #error "Only <gdk/gdk.h> can be included directly."
1635 #endif
1636
1637 #include <glib.h>
1638
1639 G_BEGIN_DECLS
1640
1641 _______EOF
1642
1643         cat >>$outfile <<_______EOF
1644 $gdk_windowing
1645 _______EOF
1646
1647         cat >>$outfile <<_______EOF
1648
1649 G_END_DECLS
1650
1651 #endif  /* __GDKCONFIG_H__ */
1652 _______EOF
1653
1654
1655         if cmp -s $outfile gdk/gdkconfig.h; then
1656           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1657           rm -f $outfile
1658         else
1659           mv $outfile gdk/gdkconfig.h
1660         fi
1661 ],[
1662 gdk_windowing='$GDK_WINDOWING'
1663 ])
1664
1665 dnl
1666 dnl Check for -Bsymbolic-functions linker flag used to avoid
1667 dnl intra-library PLT jumps, if available.
1668 dnl
1669 AC_ARG_ENABLE(Bsymbolic,
1670               [AS_HELP_STRING([--disable-Bsymbolic],
1671                               [avoid linking with -Bsymbolic])],,
1672               [SAVED_LDFLAGS="${LDFLAGS}"
1673                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1674                LDFLAGS=-Wl,-Bsymbolic-functions
1675                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1676                                                [[int main (void) { return 0; }]])],
1677                               [AC_MSG_RESULT(yes)
1678                                enable_Bsymbolic=yes],
1679                               [AC_MSG_RESULT(no)
1680                                enable_Bsymbolic=no])
1681                LDFLAGS="${SAVED_LDFLAGS}"])
1682
1683 if test "x${enable_Bsymbolic}" = "xyes" ; then
1684   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1685 fi
1686 AC_SUBST(GTK_LINK_FLAGS)
1687
1688 AC_CONFIG_FILES([
1689 config.h.win32
1690 gtk-zip.sh
1691 Makefile
1692 gdk-3.0.pc
1693 gtk+-3.0.pc
1694 gtk+-unix-print-3.0.pc
1695 gail-3.0.pc
1696 m4macros/Makefile
1697 po/Makefile.in
1698 po-properties/Makefile.in
1699 demos/Makefile
1700 demos/gtk-demo/Makefile
1701 demos/gtk-demo/geninclude.pl
1702 demos/pixbuf-demo/Makefile
1703 demos/widget-factory/Makefile
1704 examples/Makefile
1705 tests/Makefile
1706 tests/a11y/Makefile
1707 tests/css/Makefile
1708 tests/css/parser/Makefile
1709 tests/reftests/Makefile
1710 tests/visuals/Makefile
1711 docs/Makefile
1712 docs/reference/Makefile
1713 docs/reference/gdk/Makefile
1714 docs/reference/gdk/version.xml
1715 docs/reference/gtk/Makefile
1716 docs/reference/gtk/version.xml
1717 docs/reference/libgail-util/Makefile
1718 docs/reference/libgail-util/version.xml
1719 docs/tools/Makefile
1720 build/Makefile
1721 build/win32/Makefile
1722 build/win32/vs9/Makefile
1723 build/win32/vs10/Makefile
1724 gdk/Makefile
1725 gdk/broadway/Makefile
1726 gdk/x11/Makefile
1727 gdk/win32/Makefile
1728 gdk/win32/rc/Makefile
1729 gdk/win32/rc/gdk.rc
1730 gdk/quartz/Makefile
1731 gdk/wayland/Makefile
1732 gdk/tests/Makefile
1733 gdk/gdkversionmacros.h
1734 gtk/Makefile
1735 gtk/makefile.msc
1736 gtk/gtkversion.h
1737 gtk/gtk-win32.rc
1738 gtk/a11y/Makefile
1739 gtk/tests/Makefile
1740 libgail-util/Makefile
1741 modules/Makefile
1742 modules/engines/Makefile
1743 modules/engines/pixbuf/Makefile
1744 modules/input/Makefile
1745 modules/printbackends/Makefile
1746 modules/printbackends/cups/Makefile
1747 modules/printbackends/lpr/Makefile
1748 modules/printbackends/file/Makefile
1749 modules/printbackends/papi/Makefile
1750 modules/printbackends/test/Makefile
1751 perf/Makefile
1752 ])
1753
1754 AC_OUTPUT
1755
1756 # beautify the immodule list a bit
1757 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1758 if test -z "${included_immodules}"; then included_immodules="none"; fi
1759
1760 echo ""
1761 echo "        GTK+ $GTK_VERSION"
1762 echo "        ==========="
1763 echo ""
1764 echo "        GDK backends:         $GDK_BACKENDS"
1765 if test "$enable_x11_backend" = "yes"; then
1766 echo "        X11 extensions:       $X_EXTENSIONS"
1767 fi
1768 echo "        Print backends:       $PRINT_BACKENDS"
1769 echo "        Dynamic modules:      $build_dynamic_modules"
1770 echo "        Included immodules:   $included_immodules"
1771 echo "        PackageKit support:   $build_packagekit"
1772 echo "        colord support:       $have_colord"
1773 echo "        Introspection:        $found_introspection"
1774 echo "        Debugging:            $enable_debug"
1775 echo "        Documentation:        $enable_gtk_doc"