Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [4])
  13 m4_define([gtk_micro_version], [1])
  14 m4_define([gtk_interface_age], [1])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.32.0])
  43 m4_define([pango_required_version], [1.30.0])
  44 m4_define([atk_required_version], [2.2.0])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.26.0])
  47 m4_define([introspection_required_version], [1.32.0])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_INSTALL
 129 AC_PROG_MAKE_SET
 130
 131
 132 GETTEXT_PACKAGE=gtk30
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 135                    [The prefix for our gettext translation domains.])
 136
 137 AC_CANONICAL_HOST
 138
 139 MATH_LIB=-lm
 140 AC_MSG_CHECKING([for native Win32])
 141 LIB_EXE_MACHINE_FLAG=X86
 142 EXE_MANIFEST_ARCHITECTURE=X86
 143 case "$host" in
 144   *-*-mingw*)
 145     os_win32=yes
 146     gio_can_sniff=no
 147     MATH_LIB=
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       EXE_MANIFEST_ARCHITECTURE=AMD64
 152       ;;
 153     esac
 154     ;;
 155   *)
 156     os_win32=no
 157     ;;
 158 esac
 159 AC_MSG_RESULT([$os_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 163
 164 case $host in
 165   *-*-linux*)
 166     os_linux=yes
 167     ;;
 168 esac
 169
 170 dnl
 171 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 172 dnl We use this for an automated test for C++ header correctness.
 173 dnl
 174 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 175 AC_LANG_PUSH([C++])
 176
 177 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 178                                    [[class a { int b; } c;]])],
 179                   [],[CXX=])
 180 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 181
 182 gtk_save_cxxflags="$CXXFLAGS"
 183 CXXFLAGS="$CXXFLAGS -x objective-c++"
 184 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 185                                    [[]])],
 186                   [OBJC=yes],[OBJC=no])
 187 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 188 CXXFLAGS="$gtk_save_cxxflags"
 189 AC_LANG_POP([C++])
 190
 191 if test "$os_win32" = "yes"; then
 192   if test x$enable_static = xyes -o x$enable_static = x; then
 193     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 194     enable_static=no
 195   fi
 196   if test x$enable_shared = xno; then
 197     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 198   fi
 199   enable_shared=yes
 200 fi
 201
 202 dnl Initialize libtool
 203 LT_PREREQ([2.2.6])
 204 LT_INIT([disable-static win32-dll])
 205 # Create libtool early, because it's used in configure
 206 LT_OUTPUT
 207
 208 # Make sure we use 64-bit versions of various file stuff.
 209 AC_SYS_LARGEFILE
 210
 211 AM_PROG_AS
 212 AC_PATH_PROG(NM, nm, nm)
 213
 214 AC_MSG_CHECKING([for some Win32 platform])
 215 case "$host" in
 216   *-*-mingw*|*-*-cygwin*)
 217     platform_win32=yes
 218     ;;
 219   *)
 220     platform_win32=no
 221     ;;
 222 esac
 223 AC_MSG_RESULT([$platform_win32])
 224 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 225
 226 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 227 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 228 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 229
 230 if test "$os_win32" = "yes"; then
 231   AC_CHECK_TOOL(WINDRES, windres, no)
 232   if test "$WINDRES" = no; then
 233     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 234   fi
 235   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 236 fi
 237 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 238
 239 m4_define([debug_default],
 240           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 241
 242 dnl declare --enable-* args and collect ac_help strings
 243 AC_ARG_ENABLE(debug,
 244               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 245                               [turn on debugging @<:@default=debug_default@:>@])],,
 246               [enable_debug=debug_default])
 247
 248 AC_ARG_ENABLE(rebuilds,
 249               [AS_HELP_STRING([--disable-rebuilds],
 250                               [disable all source autogeneration rules])],,
 251               [enable_rebuilds=yes])
 252
 253 AC_ARG_ENABLE(gtk2-dependency,
 254               [AS_HELP_STRING([--enable-gtk2-dependency],
 255                               [Do not build gtk-update-icon-cache and other shared tools])],,
 256               [enable_gtk2_dependency=no])
 257
 258 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 259
 260 AC_ARG_ENABLE(xkb,
 261               [AS_HELP_STRING([--enable-xkb],
 262                               [support XKB extension [default=maybe]])],,
 263               [enable_xkb="maybe"])
 264 AC_ARG_ENABLE(xinerama,
 265               [AS_HELP_STRING([--enable-xinerama],
 266                               [support Xinerama extension [default=maybe]])],,
 267               [enable_xinerama="maybe"])
 268 AC_ARG_ENABLE(xrandr,
 269               [AS_HELP_STRING([--enable-xrandr],
 270                               [support XRandR extension [default=maybe]])],,
 271               [enable_xrandr="maybe"])
 272 AC_ARG_ENABLE(xfixes,
 273               [AS_HELP_STRING([--enable-xfixes],
 274                               [support XFixes extension [default=maybe]])],,
 275               [enable_xfixes="maybe"])
 276 AC_ARG_ENABLE(xcomposite,
 277               [AS_HELP_STRING([--enable-xcomposite],
 278                               [support X Composite extension [default=maybe]])],,
 279               [enable_xcomposite="maybe"])
 280 AC_ARG_ENABLE(xdamage,
 281               [AS_HELP_STRING([--enable-xdamage],
 282                               [support X Damage extension [default=maybe]])],,
 283               [enable_xdamage="maybe"])
 284
 285 AC_ARG_ENABLE(x11-backend,
 286               [AS_HELP_STRING([--enable-x11-backend],
 287                               [enable the X11 gdk backend])],
 288                               [backend_set=yes])
 289 AC_ARG_ENABLE(win32-backend,
 290               [AS_HELP_STRING([--enable-win32-backend],
 291                               [enable the Win32 gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(quartz-backend,
 294               [AS_HELP_STRING([--enable-quartz-backend],
 295                               [enable the quartz gdk backend])],
 296                               [backend_set=yes])
 297 AC_ARG_ENABLE(broadway-backend,
 298               [AS_HELP_STRING([--enable-broadway-backend],
 299                               [enable the broadway (HTML5) gdk backend])],
 300                               [backend_set=yes])
 301 AC_ARG_ENABLE(wayland-backend,
 302               [AS_HELP_STRING([--enable-wayland-backend],
 303                               [enable the wayland gdk backend])],
 304                               [backend_set=yes])
 305
 306 if test -z "$backend_set"; then
 307   if test "$platform_win32" = yes; then
 308     enable_win32_backend=yes
 309   else
 310     enable_x11_backend=yes
 311   fi
 312 fi
 313
 314 AC_ARG_ENABLE(quartz-relocation,
 315               [AS_HELP_STRING([--enable-quartz-relocation],
 316                               [enable bundle-based relocation functions])],
 317                               [quartz_relocation=yes])
 318
 319 cairo_backends=
 320 backend_immodules=
 321 have_gio_unix=no
 322 GDK_BACKENDS=
 323 GDK_EXTRA_LIBS=
 324 GDK_EXTRA_CFLAGS=
 325 GDK_WINDOWING=
 326 PANGO_PACKAGES="pango pangocairo"
 327
 328 if test "$enable_x11_backend" = "yes"; then
 329   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 330   # backend names are identical.
 331   cairo_backends="$cairo_backends cairo-xlib"
 332   GDK_BACKENDS="$GDK_BACKENDS x11"
 333   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 334   # gdkapplaunchcontext-x11.c
 335   have_gio_unix=yes
 336   backend_immodules="$backend_immodules,xim"
 337   GDK_WINDOWING="$GDK_WINDOWING
 338 #define GDK_WINDOWING_X11"
 339 fi
 340
 341 if test "$enable_win32_backend" = "yes"; then
 342   cairo_backends="$cairo_backends cairo-win32"
 343   GDK_BACKENDS="$GDK_BACKENDS win32"
 344   backend_immodules="$backend_immodules,ime"
 345   GDK_WINDOWING="$GDK_WINDOWING
 346 #define GDK_WINDOWING_WIN32"
 347   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 348   AM_CONDITIONAL(USE_WIN32, true)
 349   PANGO_PACKAGES="pangowin32 pangocairo"
 350 else
 351   AM_CONDITIONAL(USE_WIN32, false)
 352 fi
 353
 354 if test "x$enable_quartz_backend" = xyes; then
 355   cairo_backends="$cairo_backends cairo-quartz"
 356   GDK_BACKENDS="$GDK_BACKENDS quartz"
 357   GDK_WINDOWING="$GDK_WINDOWING
 358 #define GDK_WINDOWING_QUARTZ"
 359   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 360   AM_CONDITIONAL(USE_QUARTZ, true)
 361   if test "x$quartz_relocation" = xyes; then
 362     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 363   fi
 364
 365 else
 366   AM_CONDITIONAL(USE_QUARTZ, false)
 367 fi
 368
 369
 370 if test "x$enable_broadway_backend" == xyes; then
 371   GDK_BACKENDS="$GDK_BACKENDS broadway"
 372   cairo_backends="$cairo_backends cairo"
 373   GDK_WINDOWING="$GDK_WINDOWING
 374 #define GDK_WINDOWING_BROADWAY"
 375   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 376   AM_CONDITIONAL(USE_BROADWAY, true)
 377 else
 378   AM_CONDITIONAL(USE_BROADWAY, false)
 379 fi
 380
 381 if test "x$enable_wayland_backend" == "xyes"; then
 382   # Wayland uses cairo-gl
 383   cairo_backends="$cairo_backends cairo-gl"
 384   GDK_BACKENDS="$GDK_BACKENDS wayland"
 385   have_gio_unix=yes
 386   GDK_WINDOWING="$GDK_WINDOWING
 387 #define GDK_WINDOWING_WAYLAND"
 388   WAYLAND_PACKAGES="wayland-client xkbcommon wayland-egl egl"
 389   AM_CONDITIONAL(USE_WAYLAND, true)
 390 else
 391   AM_CONDITIONAL(USE_WAYLAND, false)
 392 fi
 393
 394 # strip leading space
 395 GDK_BACKENDS=${GDK_BACKENDS#* }
 396
 397 AC_SUBST(GDK_BACKENDS)
 398
 399 if test -z "$GDK_BACKENDS"; then
 400   AC_MSG_ERROR([No GDK backends selected.])
 401 fi
 402
 403 if test "x$enable_debug" = "xyes"; then
 404   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 405   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 406 else
 407   if test "x$enable_debug" = "xno"; then
 408     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 409   else
 410     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 411   fi
 412 fi
 413
 414
 415 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 416                    [Define if debugging is enabled])
 417
 418
 419 # Build time sanity check...
 420 AM_SANITY_CHECK
 421
 422 changequote(,)dnl
 423 if test "x$GCC" = "xyes"; then
 424   case " $CFLAGS " in
 425   *[\ \ ]-Wall[\ \      ]*) ;;
 426   *) CFLAGS="$CFLAGS -Wall" ;;
 427   esac
 428
 429   if test "x$enable_ansi" = "xyes"; then
 430     case " $CFLAGS " in
 431     *[\ \       ]-ansi[\ \      ]*) ;;
 432     *) CFLAGS="$CFLAGS -ansi" ;;
 433     esac
 434
 435     case " $CFLAGS " in
 436     *[\ \       ]-pedantic[\ \  ]*) ;;
 437     *) CFLAGS="$CFLAGS -pedantic" ;;
 438     esac
 439   fi
 440 fi
 441 changequote([,])dnl
 442
 443 # Ensure MSVC-compatible struct packing convention is used when
 444 # compiling for Win32 with gcc.
 445 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 446 # gcc2 uses "-fnative-struct".
 447 if test x"$os_win32" = xyes; then
 448   if test x"$GCC" = xyes; then
 449     msnative_struct=''
 450     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 451     if test -z "$ac_cv_prog_CC"; then
 452       our_gcc="$CC"
 453     else
 454       our_gcc="$ac_cv_prog_CC"
 455     fi
 456     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 457       2.)
 458         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 459           msnative_struct='-fnative-struct'
 460         fi
 461         ;;
 462       *)
 463         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 464           msnative_struct='-mms-bitfields'
 465         fi
 466         ;;
 467     esac
 468     if test x"$msnative_struct" = x ; then
 469       AC_MSG_RESULT([no way])
 470       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 471     else
 472       CFLAGS="$CFLAGS $msnative_struct"
 473       AC_MSG_RESULT([${msnative_struct}])
 474     fi
 475   fi
 476 fi
 477
 478 ## Initial sanity check, done here so that users get told they
 479 ## have the wrong dependencies as early in the process as possible.
 480 ## Later on we actually use the cflags/libs from separate pkg-config
 481 ## calls. Oh, also the later pkg-config calls don't include
 482 ## the version requirements since those make the module lists
 483 ## annoying to construct
 484 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 485   [glib-2.0 >= glib_required_version dnl
 486    atk >= atk_required_version dnl
 487    pango >= pango_required_version dnl
 488    cairo >= cairo_required_version dnl
 489    cairo-gobject >= cairo_required_version dnl
 490    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 491
 492 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 493
 494 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0])
 495
 496 if test "$os_win32" != yes; then
 497     # libtool option to control which symbols are exported
 498     # right now, symbols starting with _ are not exported
 499     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 500 else
 501     # We currently use .def files on Windows (for gdk and gtk)
 502     LIBTOOL_EXPORT_OPTIONS=
 503 fi
 504 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 505
 506 dnl ******************************************************
 507 dnl * See whether to include shared library dependencies *
 508 dnl ******************************************************
 509
 510 AC_ARG_ENABLE(explicit-deps,
 511               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 512                               [use explicit dependencies in .pc files [default=auto]])],,
 513               [enable_explicit_deps=auto])
 514
 515 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 516 case $enable_explicit_deps in
 517   auto)
 518     export SED
 519     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 520     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 521       enable_explicit_deps=yes
 522     else
 523       enable_explicit_deps=no
 524     fi
 525   ;;
 526   yes|no)
 527   ;;
 528   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 529   ;;
 530 esac
 531 AC_MSG_RESULT($enable_explicit_deps)
 532
 533 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 534
 535 # define a MAINT-like variable REBUILD which is set if Perl
 536 # and awk are found, so autogenerated sources can be rebuilt
 537
 538 AC_PATH_PROGS(PERL, perl5 perl)
 539
 540 # We would like indent, but don't require it.
 541 AC_CHECK_PROG(INDENT, indent, indent)
 542
 543 REBUILD=\#
 544 if test "x$enable_rebuilds" = "xyes" && \
 545      test -n "$PERL" && \
 546      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 547   REBUILD=
 548 fi
 549 AC_SUBST(REBUILD)
 550
 551 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 552 AC_CHECK_FUNCS(localtime_r)
 553
 554 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 555 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 556 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 557                                 [[char c;
 558                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 559                [gtk_ok=yes], [gtk_ok=no])
 560 AC_MSG_RESULT($gtk_ok)
 561 if test "$gtk_ok" = "yes"; then
 562   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 563             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 564 fi
 565
 566 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 567 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 568 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 569                                 [[char c;
 570                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 571                [gtk_ok=yes], [gtk_ok=no])
 572 AC_MSG_RESULT($gtk_ok)
 573 if test "$gtk_ok" = "yes"; then
 574   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 575             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 576 fi
 577
 578 # _NL_PAPER_HEIGHT is an enum and not a define
 579 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 580 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 581                                 [[char c;
 582                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 583                [gtk_ok=yes], [gtk_ok=no])
 584 AC_MSG_RESULT($gtk_ok)
 585 if test "$gtk_ok" = "yes"; then
 586   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 587             [Define if _NL_PAPER_HEIGHT is available])
 588 fi
 589
 590 # _NL_PAPER_WIDTH is an enum and not a define
 591 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 592 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 593                                 [[char c;
 594                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 595                [gtk_ok=yes], [gtk_ok=no])
 596 AC_MSG_RESULT($gtk_ok)
 597 if test "$gtk_ok" = "yes"; then
 598   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 599             [Define if _NL_PAPER_WIDTH is available])
 600 fi
 601
 602 # i18n stuff
 603 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 604 AM_GLIB_GNU_GETTEXT
 605 LIBS="$LIBS $INTLLIBS"
 606 AC_CONFIG_COMMANDS([po-properties],
 607                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 608                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 609                      esac]],
 610                    [[]])
 611
 612 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 613 dnl po-properties/POTFILES during configure; see GNOME #573515.
 614 dnl
 615 dnl Generate list of files to be processed by xgettext which will
 616 dnl be included in po-properties/Makefile.
 617 test -d po-properties || mkdir po-properties
 618 if test "x$srcdir" != "x."; then
 619   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 620     popropsrcprefix="$srcdir/"
 621   else
 622     popropsrcprefix="../$srcdir/"
 623   fi
 624 else
 625   popropsrcprefix="../"
 626 fi
 627 rm -f po-properties/POTFILES
 628 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 629 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 630 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 631
 632 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 633
 634 dnl The DU4 header files don't provide library prototypes unless
 635 dnl -std1 is given to the native cc.
 636 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 637
 638 gtk_save_LIBS=$LIBS
 639 LIBS="$LIBS -lm"
 640 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 641                                 int main (void) { return (log(1) != log(1.)); }]])],
 642               [AC_MSG_RESULT(none needed)],
 643               [gtk_save_CFLAGS="$CFLAGS"
 644                CFLAGS="$CFLAGS -std1"
 645                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 646                                                int main (void) { return (log(1) != log(1.)); }]])],
 647                              [AC_MSG_RESULT(-std1)],
 648                              [AC_MSG_RESULT()
 649                               CFLAGS="$gtk_save_CFLAGS"
 650                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 651                              [true])],
 652               [AC_MSG_RESULT(none needed)])
 653
 654 LIBS=$gtk_save_LIBS
 655
 656 AC_MSG_CHECKING(for the BeOS)
 657 case $host in
 658   *-*-beos*)
 659     AC_MSG_RESULT(yes)
 660     MATH_LIB=
 661   ;;
 662   *)
 663     AC_MSG_RESULT(no)
 664   ;;
 665 esac
 666
 667 AC_SUBST(MATH_LIB)
 668 #
 669 # see bug 162979
 670 #
 671 AC_MSG_CHECKING(for HP-UX)
 672 case $host_os in
 673   hpux9* | hpux10* | hpux11*)
 674     AC_MSG_RESULT(yes)
 675     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 676   ;;
 677   *)
 678     AC_MSG_RESULT(no)
 679   ;;
 680 esac
 681
 682 #
 683 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 684 #
 685
 686 AM_PATH_GLIB_2_0(glib_required_version, :,
 687   AC_MSG_ERROR([
 688 *** GLIB glib_required_version or better is required. The latest version of
 689 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 690   gobject gmodule-no-export)
 691
 692 dnl
 693 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 694 dnl
 695 gtk_save_LIBS=$LIBS
 696 LIBS="$LIBS $GLIB_LIBS"
 697 AC_CHECK_FUNCS(bind_textdomain_codeset)
 698 LIBS=$gtk_save_LIBS
 699
 700 AC_CHECK_HEADERS(pwd.h,
 701                  AC_DEFINE(HAVE_PWD_H, 1,
 702                            [Define to 1 if pwd.h is available]))
 703 AC_CHECK_HEADERS(sys/time.h,
 704                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 705                            [Define to 1 if time.h is available]))
 706 AC_CHECK_HEADERS(unistd.h,
 707                  AC_DEFINE(HAVE_UNISTD_H, 1,
 708                            [Define to 1 if unistd.h is available]))
 709 AC_CHECK_HEADERS(ftw.h,
 710                  AC_DEFINE(HAVE_FTW_H, 1,
 711                            [Define to 1 if ftw.h is available]))
 712
 713 AC_MSG_CHECKING([for GNU ftw extensions])
 714 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 715                                      #define _GNU_SOURCE
 716                                      #include <ftw.h>]],
 717                                    [[int flags = FTW_ACTIONRETVAL;]])],
 718                   [gtk_ok=yes],[gtk_ok=no])
 719 if test $gtk_ok = yes; then
 720     AC_MSG_RESULT([yes])
 721     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 722 else
 723     AC_MSG_RESULT([no])
 724 fi
 725
 726 saved_cflags="$CFLAGS"
 727 saved_ldflags="$LDFLAGS"
 728
 729
 730 # Checks for library functions.
 731 AC_FUNC_MMAP
 732
 733 AC_CHECK_FUNCS(mallinfo)
 734 AC_CHECK_FUNCS(getresuid)
 735 AC_TYPE_UID_T
 736
 737 # Check for round()
 738 AC_CHECK_LIB(m,round,have_round=yes,have_round=no)
 739 if test $have_round = yes; then
 740     AC_DEFINE(HAVE_ROUND, 1, [Define to 1 if round() is available])
 741 fi
 742
 743 # Check for rint()
 744 AC_CHECK_LIB(m,rint,have_rint=yes,have_rint=no)
 745 if test $have_rint = yes; then
 746     AC_DEFINE(HAVE_RINT, 1, [Define to 1 if rint() is available])
 747 fi
 748
 749 # Checks for gdkspawn
 750 AC_CHECK_HEADERS(crt_externs.h)
 751 AC_CHECK_FUNCS(_NSGetEnviron)
 752
 753 AC_MSG_CHECKING(whether to build dynamic modules)
 754
 755 AC_ARG_ENABLE(modules,
 756               [AS_HELP_STRING([--disable-modules],
 757                               [disable dynamic module loading])])
 758
 759 dynworks=false
 760 build_dynamic_modules=no
 761 deps=
 762 if test x$enable_modules = xno; then
 763     AC_MSG_RESULT(no)
 764 else
 765     AC_MSG_RESULT(yes)
 766     AC_MSG_CHECKING(whether dynamic modules work)
 767     ## for loop is to strip newline
 768     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 769     for I in $tmp; do
 770         dynworks=$I
 771     done
 772
 773     dnl Now we check to see if our libtool supports shared lib deps
 774     dnl (in a rather ugly way even)
 775     if $dynworks; then
 776         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 777         module_deplibs_check=`$module_libtool_config | \
 778             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 779             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 780         if test "x$module_deplibs_check" = "xnone" || \
 781            test "x$module_deplibs_check" = "xunknown" || \
 782            test "x$module_deplibs_check" = "x"; then
 783             dynworks=false
 784         fi
 785     fi
 786
 787     if $dynworks; then
 788         build_dynamic_modules=yes
 789         AC_DEFINE(USE_GMODULE, 1,
 790                   [Define to 1 if gmodule works and should be used])
 791         AC_MSG_RESULT(yes)
 792     else
 793         build_dynamic_modules=no
 794         AC_MSG_RESULT(no)
 795     fi
 796 fi
 797
 798 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 799
 800 #
 801 # Allow building some or all immodules included
 802 #
 803 AC_MSG_CHECKING(immodules to build)
 804
 805 AC_ARG_WITH(included_immodules,
 806             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 807                             [build the specified input methods into gtk])])
 808
 809 if $dynworks; then
 810    :
 811 else
 812    ## if the option was specified, leave it; otherwise disable included immodules
 813    if test x$with_included_immodules = xno; then
 814            with_included_immodules=yes
 815    fi
 816 fi
 817
 818 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 819
 820 included_immodules=""
 821 # If the switch specified without listing any specific ones, include all
 822 if test "x$with_included_immodules" = xyes ; then
 823   included_immodules="$all_immodules"
 824 else
 825   included_immodules="$with_included_immodules"
 826 fi
 827
 828 AC_MSG_RESULT($included_immodules)
 829 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 830
 831 INCLUDED_IMMODULE_OBJ=
 832 INCLUDED_IMMODULE_DEFINE=
 833
 834 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 835 for immodule in $included_immodules; do
 836  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 837  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 838    :
 839  else
 840    AC_MSG_ERROR([the specified input method $immodule does not exist])
 841  fi
 842
 843  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 844  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 845  eval INCLUDE_$immodule_underscores=yes
 846 done
 847 IFS="$gtk_save_ifs"
 848 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 849 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 850
 851 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 852 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 853 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 854 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 855 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 856 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 857 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 858 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 859 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 860 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 861 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 862 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 863
 864 # Checks to see whether we should include mediaLib
 865 # support.
 866 #
 867 AC_CHECK_HEADER(sys/systeminfo.h,
 868                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 869                           [Define to 1 if sys/systeminfo.h is available]))
 870 AC_CHECK_HEADER(sys/sysinfo.h,
 871                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 872                           [Define to 1 if sys/sysinfo.h is available]))
 873
 874 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 875
 876 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 877
 878 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 879   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 880   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 881     REBUILD_PNGS=#
 882   fi
 883 fi
 884
 885 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 886
 887 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 888
 889 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 890    test "x$REBUILD_PNGS" = "x#" ; then
 891      AC_MSG_ERROR([
 892 *** gtkbuiltincache.h is not in the tree, and cannot be built
 893 *** because you don't have libpng, or (when cross-compiling) you
 894 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 895 fi
 896
 897 ########################################
 898 # Windowing system checks
 899 ########################################
 900
 901 # GTK+ uses some X calls, so needs to link against X directly
 902 GTK_DEP_PACKAGES_FOR_X=
 903 GTK_DEP_LIBS_FOR_X=
 904 X_EXTENSIONS=
 905
 906 if test "x$enable_x11_backend" = xyes; then
 907   X_PACKAGES=fontconfig
 908
 909   #
 910   # We use fontconfig very peripherally when decoding the default
 911   # settings.
 912   #
 913   if $PKG_CONFIG --exists fontconfig; then : ; else
 914     AC_MSG_ERROR([
 915 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 916   fi
 917
 918   #
 919   # Check for basic X packages; we use pkg-config if available
 920   #
 921   if $PKG_CONFIG --exists x11 xext; then
 922     have_base_x_pc=true
 923     X_PACKAGES="$X_PACKAGES x11 xext"
 924     x_libs="`$PKG_CONFIG --libs x11 xext`"
 925     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 926
 927     # Strip out any .la files that pkg-config might give us (this happens
 928     # with -uninstalled.pc files)
 929     x_libs_for_checks=
 930     for I in $x_libs ; do
 931       case $I in
 932         *.la) ;;
 933         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 934       esac
 935     done
 936
 937     GTK_PACKAGES_FOR_X="x11"
 938   else
 939     have_base_x_pc=false
 940     AC_PATH_XTRA
 941     if test x$no_x = xyes ; then
 942       AC_MSG_ERROR([X development libraries not found])
 943     fi
 944
 945     x_cflags="$X_CFLAGS"
 946     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 947
 948     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 949   fi
 950
 951   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 952   x_extra_libs=
 953
 954   gtk_save_cppflags="$CPPFLAGS"
 955   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 956
 957   gtk_save_LIBS=$LIBS
 958   LIBS="$x_libs_for_checks $LIBS"
 959
 960   # Sanity check for the X11 and Xext libraries. While everything we need from
 961   # Xext is optional, the chances a system has *none* of these things is so
 962   # small that we just unconditionally require it.
 963   AC_CHECK_FUNC(XOpenDisplay, :,
 964                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 965   AC_CHECK_FUNC(XextFindDisplay, :,
 966                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 967
 968   # Check for xReply
 969
 970   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 971   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 972                                      [[xReply *rep;]])],
 973                     [AC_MSG_RESULT([no])],
 974                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 975                                                           #include <X11/Xlibint.h>]],
 976                                                         [[xReply *rep;]])],
 977                                        [AC_MSG_RESULT([yes])
 978                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 979                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 980                                        [AC_MSG_RESULT([unknown])
 981                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 982
 983   # Check for XKB support.
 984
 985   if test "x$enable_xkb" = "xyes"; then
 986         AC_CHECK_FUNC(XkbQueryExtension,
 987                       X_EXTENSIONS="$X_EXTENSIONS XKB"
 988                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
 989                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
 990   elif test "x$enable_xkb" = "xmaybe"; then
 991         AC_CHECK_FUNC(XkbQueryExtension,
 992                       X_EXTENSIONS="$X_EXTENSIONS XKB"
 993                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
 994   else
 995         AC_MSG_WARN(XKB support explicitly disabled)
 996   fi
 997
 998   # Check for shaped window extension
 999
1000   AC_CHECK_FUNC(XShapeCombineMask, :,
1001      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1002
1003   # X SYNC check
1004   gtk_save_CFLAGS="$CFLAGS"
1005   CFLAGS="$CFLAGS $x_cflags"
1006
1007   AC_CHECK_FUNC(XSyncQueryExtension,
1008       [AC_CHECK_HEADER(X11/extensions/sync.h,
1009           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1010           :, [#include <X11/Xlib.h>])])
1011
1012   CFLAGS="$gtk_save_CFLAGS"
1013
1014   if test "x$enable_xinerama" != "xno"; then
1015     # Check for Xinerama extension (Solaris impl or Xfree impl)
1016     have_xfree_xinerama=false
1017     have_solaris_xinerama=false
1018
1019     gtk_save_cppflags="$CPPFLAGS"
1020     CPPFLAGS="$CPPFLAGS $x_cflags"
1021
1022     # Check for XFree
1023     AC_MSG_CHECKING(for Xinerama packages)
1024
1025     if $PKG_CONFIG --exists xinerama ; then
1026        AC_MSG_RESULT(yes)
1027        have_xfree_xinerama=true
1028        X_PACKAGES="$X_PACKAGES xinerama"
1029     else
1030        AC_MSG_RESULT(no)
1031        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1032            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1033            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1034            have_xfree_xinerama=true], :,
1035            [#include <X11/Xlib.h>])])
1036     fi
1037
1038     if $have_xfree_xinerama ; then
1039       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1040       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1041                 [Define to 1 if XFree Xinerama is available])
1042       AC_DEFINE(HAVE_XINERAMA, 1,
1043                 [Define to 1 is Xinerama is available])
1044     else
1045       case "$host" in
1046         *-*-solaris*)
1047             # Check for solaris
1048             AC_MSG_CHECKING(for Xinerama support on Solaris)
1049
1050             have_solaris_xinerama=false
1051             AC_CHECK_FUNC(XineramaGetInfo,
1052                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1053                     [have_solaris_xinerama=true], :,
1054                     [#include <X11/Xlib.h>])])
1055
1056             if $have_solaris_xinerama ; then
1057               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1058               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1059                         [Define to 1 if solaris xinerama is available])
1060               AC_DEFINE(HAVE_XINERAMA, 1,
1061                         [Define to 1 if xinerama is available])
1062               AC_MSG_RESULT(yes)
1063             else
1064               AC_MSG_RESULT(no)
1065             fi
1066             ;;
1067         *)
1068             ;;
1069       esac
1070     fi
1071   fi
1072   if test "x$enable_xinerama" = "xyes" ; then
1073     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1074       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1075     fi
1076   fi
1077
1078   # Check for XGetEventData for GenericEvents
1079   AC_CHECK_FUNC(XGetEventData,
1080                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1081
1082   # set up things for XInput
1083   if $PKG_CONFIG --exists "xi" ; then
1084
1085     X_PACKAGES="$X_PACKAGES xi"
1086     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xi"
1087
1088     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1089                     have_xinput2=yes
1090                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1091
1092     gtk_save_LIBS="$LIBS"
1093     LIBS="$LIBS -lXi"
1094
1095     # Note that we also check that the XIScrollClassInfo struct is defined,
1096     # because at least Ubuntu Oneiric seems to have XIAllowTouchEvents(), but not the XIScrollClassInfo struct.
1097     AC_CHECK_FUNC([XIAllowTouchEvents],
1098       [AC_CHECK_MEMBER([XIScrollClassInfo.number],
1099                        have_xinput2_2=yes
1100                        AC_DEFINE(XINPUT_2_2, 1, [Define to 1 if XInput 2.2 is available]),
1101                        have_xinput2_2=no,
1102                        [[#include <X11/extensions/XInput2.h>]])])
1103     LIBS="$gtk_save_LIBS"
1104
1105     if test "x$have_xinput2_2" = "xyes"; then
1106       X_EXTENSIONS="$X_EXTENSIONS XI2.2"
1107     else
1108       X_EXTENSIONS="$X_EXTENSIONS XI2"
1109     fi
1110   fi
1111
1112   AS_IF([test "x$have_xinput2" != "xyes"],
1113         [AC_MSG_ERROR([*** XInput2 extension not found. Check 'config.log' for more details.])])
1114
1115   # Check for the RANDR extension
1116   if test x"$enable_xrandr" != xno; then
1117     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1118       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1119
1120       X_PACKAGES="$X_PACKAGES xrandr"
1121       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1122     elif test x"$enable_xrandr" = xyes; then
1123       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1124     fi
1125   fi
1126
1127   # Checks for Xcursor library
1128
1129   if $PKG_CONFIG --exists xcursor ; then
1130     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1131
1132     X_PACKAGES="$X_PACKAGES xcursor"
1133   fi
1134
1135   # Checks for XFixes extension
1136
1137   if test x"$enable_xfixes" != xno; then
1138     if $PKG_CONFIG --exists xfixes ; then
1139       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1140
1141       X_PACKAGES="$X_PACKAGES xfixes"
1142       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1143       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1144     elif test x"$enable_xfixes" = xyes; then
1145       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1146     fi
1147   fi
1148
1149   # Checks for Xcomposite extension
1150
1151   if test x"$enable_xcomposite" != xno; then
1152     if $PKG_CONFIG --exists xcomposite ; then
1153       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1154
1155       X_PACKAGES="$X_PACKAGES xcomposite"
1156       X_EXTENSIONS="$X_EXTENSIONS Composite"
1157       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1158     elif test x"$enable_xcomposite" = xyes; then
1159       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1160     fi
1161   fi
1162
1163   # Checks for Xdamage extension
1164
1165   if test x"$enable_xdamage" != xno; then
1166     if $PKG_CONFIG --exists xdamage ; then
1167       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1168
1169       X_PACKAGES="$X_PACKAGES xdamage"
1170       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1171       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1172     elif test x"$enable_xdamage" = xyes; then
1173       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1174     fi
1175   fi
1176
1177   if $have_base_x_pc ; then
1178     GDK_EXTRA_LIBS="$x_extra_libs"
1179   else
1180     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1181   fi
1182
1183   CPPFLAGS="$gtk_save_cppflags"
1184   LIBS="$gtk_save_libs"
1185
1186   AM_CONDITIONAL(USE_X11, true)
1187
1188   # strip leading space
1189   X_EXTENSIONS=${X_EXTENSIONS#* }
1190
1191 else
1192   XPACKAGES=
1193
1194   AM_CONDITIONAL(USE_X11, false)
1195 fi
1196
1197 # Check for gio-unix
1198 if test "$have_gio_unix" = "yes"; then
1199   GDK_GIO_PACKAGE=gio-unix-2.0
1200   AC_DEFINE([HAVE_GIO_UNIX], [1],
1201             [Define if gio-unix is available])
1202 else
1203   GDK_GIO_PACKAGE=gio-2.0
1204 fi
1205
1206 # Check for Pango flags
1207
1208 AC_MSG_CHECKING(Pango flags)
1209 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1210         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1211         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1212
1213         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1214 else
1215         AC_MSG_ERROR([
1216 *** Pango not found. Pango built with Cairo support is required
1217 *** to build GTK+. See http://www.pango.org for Pango information.
1218 ])
1219 fi
1220
1221 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1222
1223 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1224         :
1225 else
1226         gtk_save_LIBS="$LIBS"
1227         LIBS="$PANGO_LIBS $LIBS"
1228         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1229 *** Can't link to Pango. Pango is required to build
1230 *** GTK+. For more information see http://www.pango.org]))
1231         LIBS="$gtk_save_LIBS"
1232 fi
1233
1234 CFLAGS="$saved_cflags"
1235 LDFLAGS="$saved_ldflags"
1236
1237 GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo cairo-gobject"
1238 GDK_PRIVATE_PACKAGES="$GDK_GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES $cairo_backends"
1239 if test "x$enable_x11_backend" = xyes; then
1240   GDK_PRIVATE_PACKAGES="$GDK_PRIVATE_PACKAGES pangoft2"
1241 fi
1242
1243 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES $GDK_PRIVATE_PACKAGES` $MATH_LIB"
1244 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PACKAGES $GDK_PRIVATE_PACKAGES` $GDK_EXTRA_CFLAGS"
1245 #
1246 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1247 # into the pkg-config files
1248 #
1249 if test $enable_explicit_deps != yes ; then
1250   GDK_EXTRA_LIBS=
1251 fi
1252
1253 AC_SUBST(GDK_PACKAGES)
1254 AC_SUBST(GDK_PRIVATE_PACKAGES)
1255 AC_SUBST(GDK_EXTRA_LIBS)
1256 AC_SUBST(GDK_EXTRA_CFLAGS)
1257 AC_SUBST(GDK_DEP_LIBS)
1258 AC_SUBST(GDK_DEP_CFLAGS)
1259
1260
1261 ########################################
1262 # Check for Accessibility Toolkit flags
1263 ########################################
1264
1265 ATK_PACKAGES=atk
1266 AC_MSG_CHECKING(ATK flags)
1267 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1268         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1269         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1270
1271         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1272 else
1273         AC_MSG_ERROR([
1274 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1275 *** to build GTK+.
1276 ])
1277 fi
1278
1279 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1280         :
1281 else
1282         gtk_save_LIBS="$LIBS"
1283         LIBS="$ATK_LIBS $LIBS"
1284         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1285                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1286                 *** to build GTK+]))
1287         LIBS="$gtk_save_LIBS"
1288 fi
1289
1290 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1291 GTK_PRIVATE_PACKAGES=""
1292 if test "x$enable_x11_backend" = xyes; then
1293   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES pangoft2"
1294 fi
1295 GTK_EXTRA_LIBS=
1296
1297 GTK_EXTRA_CFLAGS=
1298 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES $GTK_PRIVATE_PACKAGES` $GTK_EXTRA_LIBS $MATH_LIB"
1299 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PACKAGES $GTK_PACKAGES $GTK_PRIVATE_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1300
1301 if test x"$os_win32" = xyes; then
1302   GTK_EXTRA_CFLAGS="$msnative_struct"
1303 fi
1304
1305 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1306 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1307 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1308 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1309
1310 AC_SUBST(GTK_PACKAGES)
1311 AC_SUBST(GTK_PRIVATE_PACKAGES)
1312 AC_SUBST(GTK_EXTRA_LIBS)
1313 AC_SUBST(GTK_EXTRA_CFLAGS)
1314 AC_SUBST(GTK_DEP_LIBS)
1315 AC_SUBST(GTK_DEP_CFLAGS)
1316
1317 AC_SUBST(GLIB_PREFIX)
1318 AC_SUBST(ATK_PREFIX)
1319 AC_SUBST(PANGO_PREFIX)
1320 AC_SUBST(CAIRO_PREFIX)
1321
1322 AC_SUBST(GTK_DEBUG_FLAGS)
1323 AC_SUBST(GTK_XIM_FLAGS)
1324
1325 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1326 AC_SUBST(GDK_PIXBUF_LIBS)
1327
1328 ########################
1329 # Checks needed for gail
1330 ########################
1331
1332 old_LIBS="$LIBS"
1333 dnl Checks for inet libraries:
1334 AC_SEARCH_LIBS(gethostent, nsl)
1335 AC_SEARCH_LIBS(setsockopt, socket)
1336 AC_SEARCH_LIBS(connect, inet)
1337
1338 dnl check for the sockaddr_un.sun_len member
1339 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1340                 [struct_sockaddr_un_sun_len=true],
1341                 [struct_sockaddr_un_suin_len=false],
1342                 [#include <sys/types.h>
1343                  #include <sys/un.h>]
1344                 )
1345 case $struct_sockaddr_un_sun_len in
1346         true)
1347                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1348                                    [Have the sockaddr_un.sun_len member])
1349                 ;;
1350         *)
1351                 ;;
1352 esac
1353
1354 GAIL_INET_LIBS="$LIBS"
1355 AC_SUBST([GAIL_INET_LIBS])
1356
1357 LIBS="$old_LIBS"
1358
1359 ################################################################
1360 # Printing system checks
1361 ################################################################
1362
1363 PRINT_BACKENDS="file lpr"
1364
1365 AC_ARG_ENABLE(cups,
1366               [AS_HELP_STRING([--disable-cups],
1367                               [disable cups print backend])],,
1368               [enable_cups=auto])
1369
1370 if test "x$enable_cups" = "xno"; then
1371   AM_CONDITIONAL(HAVE_CUPS, false)
1372 else
1373   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1374   if test "x$CUPS_CONFIG" = "xno"; then
1375     if test "x$enable_cups" = "xauto"; then
1376       AM_CONDITIONAL(HAVE_CUPS, false)
1377     else
1378       AC_MSG_ERROR([
1379 *** cups not found.
1380 ])
1381     fi
1382   else
1383     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1384     CUPS_LIBS=`$CUPS_CONFIG --libs`
1385
1386     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1387     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1388     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1389
1390     if test $CUPS_API_MAJOR -gt 1 -o \
1391             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -lt 2; then
1392       AC_MSG_ERROR([CUPS >= 1.2 not found])
1393     fi
1394
1395     AC_SUBST(CUPS_API_MAJOR)
1396     AC_SUBST(CUPS_API_MINOR)
1397     AC_SUBST(CUPS_CFLAGS)
1398     AC_SUBST(CUPS_LIBS)
1399
1400     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1401
1402     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1403     AM_CONDITIONAL(HAVE_CUPS, true)
1404
1405     gtk_save_cflags="$CFLAGS"
1406     CFLAGS="$CUPS_CFLAGS"
1407     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1408                                        [[http_t http; char *s = http.authstring;]])],
1409                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1410                                  [Define if cups http_t authstring field is accessible])],
1411                       [])
1412     CFLAGS="$gtk_save_cflags"
1413
1414     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1415
1416     gtk_save_libs="$LIBS"
1417     LIBS="$CUPS_LIBS"
1418     AC_CHECK_FUNCS(httpGetAuthString)
1419     LIBS="$gtk_save_libs"
1420   fi
1421 fi
1422
1423 # Checks to see if we should compile with PAPI backend for GTK+
1424 #
1425
1426 AC_ARG_ENABLE(papi,
1427               [AS_HELP_STRING([--disable-papi],
1428                               [disable papi print backend])],,
1429               [enable_papi=auto])
1430
1431 if test "x$enable_papi" = "xno"; then
1432   AM_CONDITIONAL(HAVE_PAPI, false)
1433 else
1434   AC_MSG_CHECKING(libpapi)
1435   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1436   if test $have_papi = yes; then
1437     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1438     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1439   fi
1440   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1441   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1442     AC_MSG_ERROR([
1443 *** papi not found.
1444 ])
1445   fi
1446 fi
1447
1448 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1449
1450 gtk_save_cppflags="$CPPFLAGS"
1451 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1452
1453 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1454 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1455 *** backend enabled.]))
1456
1457 if test "$os_win32" != "yes"; then
1458   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1459 *** Can't find cairo-ps.h. You must build Cairo with the
1460 *** postscript backend enabled.]))
1461
1462   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1463 *** Cannot find cairo-svg.h. You must build Cairo with the
1464 *** svg backend enabled.]))
1465 fi
1466
1467 CPPFLAGS="$gtk_save_cppflags"
1468
1469
1470 AC_ARG_ENABLE(test-print-backend,
1471               [AS_HELP_STRING([--enable-test-print-backend],
1472                               [build test print backend])],,
1473               [enable_test_print_backend=no])
1474 if test "x$enable_test_print_backend" != "xno" ; then
1475   PRINT_BACKENDS="$PRINT_BACKENDS test"
1476 fi
1477 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1478
1479 if test "$os_win32" = "yes"; then
1480   AC_CHECK_TYPES([IPrintDialogCallback],[],[],[[#include <windows.h>]])
1481 fi
1482
1483 ################################################################
1484 # Strip -export-dynamic from the link lines of various libraries
1485 ################################################################
1486
1487 #
1488 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1489 #  but this flag is only meaningful for executables. For libraries
1490 #  the effect is undefined; what it causes on Linux is that the
1491 #  export list from -export-symbols-regex is ignored and everything
1492 #  is exported
1493 #
1494 # We are using gmodule-no-export now, but I'm leaving the stripping
1495 # code in place for now, since pango and atk still require gmodule.
1496 export SED
1497 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1498 if test -n "$export_dynamic"; then
1499   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1500   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1501 fi
1502
1503 #############
1504 # GSettings #
1505 #############
1506
1507 GLIB_GSETTINGS
1508
1509 ##################################################
1510 # GObject introspection
1511 ##################################################
1512
1513 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1514
1515 ##################################################
1516 # Packagekit module
1517 #################################################
1518
1519 AC_ARG_ENABLE(packagekit,
1520               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1521                               [build PackageKit open-with module [default=auto]])],
1522               [enable_packagekit="$enableval"],
1523               [enable_packagekit=auto])
1524 if test "$enable_packagekit" = "auto"; then
1525   if test "$os_win32" = "yes"; then
1526     enable_packagekit=no
1527   else
1528     enable_packagekit=yes
1529   fi
1530 fi
1531
1532 AC_MSG_CHECKING([whether to use PackageKit])
1533 build_packagekit=no
1534 if test "x$enable_packagekit" != "xno"; then
1535   if test "$os_win32" != "yes"; then
1536     build_packagekit=yes
1537     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1538   else
1539     AC_MSG_ERROR([packagekit support is not available on win32])
1540   fi
1541 fi
1542 AC_MSG_RESULT([$build_packagekit])
1543
1544 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1545
1546 ##################################################
1547 # colord module
1548 #################################################
1549
1550 AC_ARG_ENABLE(colord,
1551               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1552                               [build colord support code [default=auto]])],
1553               [enable_colord="$enableval"],
1554               [enable_colord=auto])
1555
1556 AC_MSG_CHECKING([whether to use colord])
1557 if test "$enable_colord" = "auto"; then
1558   if test "$os_win32" = "yes"; then
1559     enable_colord=no
1560   fi
1561 fi
1562 if test "$enable_colord" != "no"; then
1563   AC_MSG_RESULT([yes])
1564 else
1565   AC_MSG_RESULT([no])
1566 fi
1567
1568 have_colord=no
1569 if test "$enable_colord" != "no"; then
1570         if test "$os_win32" != "yes"; then
1571                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1572                                   have_colord=yes, have_colord=no)
1573                 if test "$enable_colord" = "yes"; then
1574                         if test "$have_colord" = "no"; then
1575                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1576                         fi
1577                 fi
1578         else
1579                 AC_MSG_ERROR([colord support is not available on win32])
1580         fi
1581 fi
1582
1583 if test "$have_colord" = "yes"; then
1584         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1585 fi
1586 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1587
1588 ##################################################
1589 # Checks for gtk-doc and docbook-tools
1590 ##################################################
1591
1592 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1593
1594 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1595 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1596
1597 AC_ARG_ENABLE(man,
1598               [AS_HELP_STRING([--enable-man],
1599                               [regenerate man pages from Docbook [default=no]])],
1600               [enable_man=yes],
1601               [enable_man=no])
1602
1603 if test "${enable_man}" != no; then
1604   dnl
1605   dnl Check for xsltproc
1606   dnl
1607   AC_PATH_PROG([XSLTPROC], [xsltproc])
1608   if test -z "$XSLTPROC"; then
1609     enable_man=no
1610   fi
1611
1612   dnl check for DocBook DTD and stylesheets in the local catalog.
1613   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1614      [DocBook XML DTD V4.1.2],,enable_man=no)
1615   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1616      [DocBook XSL Stylesheets],,enable_man=no)
1617 fi
1618
1619 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1620
1621
1622 ##################################################
1623 # Output commands
1624 ##################################################
1625
1626 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1627         outfile=gdkconfig.h-tmp
1628         cat > $outfile <<\_______EOF
1629 /* gdkconfig.h
1630  *
1631  * This is a generated file.  Please modify `configure.ac'
1632  */
1633
1634 #ifndef __GDKCONFIG_H__
1635 #define __GDKCONFIG_H__
1636
1637 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1638 #error "Only <gdk/gdk.h> can be included directly."
1639 #endif
1640
1641 #include <glib.h>
1642
1643 G_BEGIN_DECLS
1644
1645 _______EOF
1646
1647         cat >>$outfile <<_______EOF
1648 $gdk_windowing
1649 _______EOF
1650
1651         cat >>$outfile <<_______EOF
1652
1653 G_END_DECLS
1654
1655 #endif  /* __GDKCONFIG_H__ */
1656 _______EOF
1657
1658
1659         if cmp -s $outfile gdk/gdkconfig.h; then
1660           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1661           rm -f $outfile
1662         else
1663           mv $outfile gdk/gdkconfig.h
1664         fi
1665 ],[
1666 gdk_windowing='$GDK_WINDOWING'
1667 ])
1668
1669 dnl
1670 dnl Check for -Bsymbolic-functions linker flag used to avoid
1671 dnl intra-library PLT jumps, if available.
1672 dnl
1673 AC_ARG_ENABLE(Bsymbolic,
1674               [AS_HELP_STRING([--disable-Bsymbolic],
1675                               [avoid linking with -Bsymbolic])],,
1676               [SAVED_LDFLAGS="${LDFLAGS}"
1677                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1678                LDFLAGS=-Wl,-Bsymbolic-functions
1679                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1680                                                [[int main (void) { return 0; }]])],
1681                               [AC_MSG_RESULT(yes)
1682                                enable_Bsymbolic=yes],
1683                               [AC_MSG_RESULT(no)
1684                                enable_Bsymbolic=no])
1685                LDFLAGS="${SAVED_LDFLAGS}"])
1686
1687 if test "x${enable_Bsymbolic}" = "xyes" ; then
1688   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1689 fi
1690 AC_SUBST(GTK_LINK_FLAGS)
1691
1692 AC_CONFIG_FILES([
1693 config.h.win32
1694 gtk-zip.sh
1695 Makefile
1696 gdk-3.0.pc
1697 gtk+-3.0.pc
1698 gtk+-unix-print-3.0.pc
1699 gail-3.0.pc
1700 m4macros/Makefile
1701 po/Makefile.in
1702 po-properties/Makefile.in
1703 demos/Makefile
1704 demos/gtk-demo/Makefile
1705 demos/gtk-demo/geninclude.pl
1706 demos/pixbuf-demo/Makefile
1707 demos/widget-factory/Makefile
1708 examples/Makefile
1709 tests/Makefile
1710 tests/a11y/Makefile
1711 tests/css/Makefile
1712 tests/css/parser/Makefile
1713 tests/reftests/Makefile
1714 tests/visuals/Makefile
1715 docs/Makefile
1716 docs/reference/Makefile
1717 docs/reference/gdk/Makefile
1718 docs/reference/gdk/version.xml
1719 docs/reference/gtk/Makefile
1720 docs/reference/gtk/version.xml
1721 docs/reference/libgail-util/Makefile
1722 docs/reference/libgail-util/version.xml
1723 docs/tools/Makefile
1724 build/Makefile
1725 build/win32/Makefile
1726 build/win32/vs9/Makefile
1727 build/win32/vs10/Makefile
1728 gdk/Makefile
1729 gdk/broadway/Makefile
1730 gdk/x11/Makefile
1731 gdk/win32/Makefile
1732 gdk/win32/rc/Makefile
1733 gdk/win32/rc/gdk.rc
1734 gdk/quartz/Makefile
1735 gdk/wayland/Makefile
1736 gdk/tests/Makefile
1737 gdk/gdkversionmacros.h
1738 gtk/Makefile
1739 gtk/makefile.msc
1740 gtk/gtkversion.h
1741 gtk/gtk-win32.rc
1742 gtk/a11y/Makefile
1743 gtk/tests/Makefile
1744 libgail-util/Makefile
1745 modules/Makefile
1746 modules/engines/Makefile
1747 modules/engines/pixbuf/Makefile
1748 modules/input/Makefile
1749 modules/printbackends/Makefile
1750 modules/printbackends/cups/Makefile
1751 modules/printbackends/lpr/Makefile
1752 modules/printbackends/file/Makefile
1753 modules/printbackends/papi/Makefile
1754 modules/printbackends/test/Makefile
1755 perf/Makefile
1756 ])
1757
1758 AC_OUTPUT
1759
1760 # beautify the immodule list a bit
1761 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1762 if test -z "${included_immodules}"; then included_immodules="none"; fi
1763
1764 echo ""
1765 echo "        GTK+ $GTK_VERSION"
1766 echo "        ==========="
1767 echo ""
1768 echo "        GDK backends:         $GDK_BACKENDS"
1769 if test "$enable_x11_backend" = "yes"; then
1770 echo "        X11 extensions:       $X_EXTENSIONS"
1771 fi
1772 echo "        Print backends:       $PRINT_BACKENDS"
1773 echo "        Dynamic modules:      $build_dynamic_modules"
1774 echo "        Included immodules:   $included_immodules"
1775 echo "        PackageKit support:   $build_packagekit"
1776 echo "        colord support:       $have_colord"
1777 echo "        Introspection:        $found_introspection"
1778 echo "        Debugging:            $enable_debug"
1779 echo "        Documentation:        $enable_gtk_doc"