Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [5])
  13 m4_define([gtk_micro_version], [11])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.33.1])
  43 m4_define([pango_required_version], [1.30.0])
  44 m4_define([atk_required_version], [2.5.3])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.26.0])
  47 m4_define([introspection_required_version], [1.32.0])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_MKDIR_P
 129 AC_PROG_INSTALL
 130 AC_PROG_MAKE_SET
 131
 132
 133 GETTEXT_PACKAGE=gtk30
 134 AC_SUBST(GETTEXT_PACKAGE)
 135 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 136                    [The prefix for our gettext translation domains.])
 137
 138 AC_CANONICAL_HOST
 139
 140 MATH_LIB=-lm
 141 AC_MSG_CHECKING([for native Win32])
 142 LIB_EXE_MACHINE_FLAG=X86
 143 EXE_MANIFEST_ARCHITECTURE=X86
 144 DISABLE_ON_W32=''
 145 case "$host" in
 146   *-*-mingw*)
 147     dnl Comment-out certain gtk3.types.in lines
 148     DISABLE_ON_W32='%'
 149     os_win32=yes
 150     gio_can_sniff=no
 151     MATH_LIB=
 152     case "$host" in
 153     x86_64-*-*)
 154       LIB_EXE_MACHINE_FLAG=X64
 155       EXE_MANIFEST_ARCHITECTURE=AMD64
 156       ;;
 157     esac
 158     ;;
 159   *)
 160     os_win32=no
 161     ;;
 162 esac
 163 AC_MSG_RESULT([$os_win32])
 164
 165 AC_SUBST(DISABLE_ON_W32)
 166 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 167 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 168
 169 case $host in
 170   *-*-linux*)
 171     os_linux=yes
 172     ;;
 173 esac
 174
 175 dnl
 176 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 177 dnl We use this for an automated test for C++ header correctness.
 178 dnl
 179 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 180 AC_LANG_PUSH([C++])
 181
 182 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 183                                    [[class a { int b; } c;]])],
 184                   [],[CXX=])
 185 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 186
 187 gtk_save_cxxflags="$CXXFLAGS"
 188 CXXFLAGS="$CXXFLAGS -x objective-c++"
 189 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 190                                    [[]])],
 191                   [OBJC=yes],[OBJC=no])
 192 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 193 CXXFLAGS="$gtk_save_cxxflags"
 194 AC_LANG_POP([C++])
 195
 196 if test "$os_win32" = "yes"; then
 197   if test x$enable_static = xyes -o x$enable_static = x; then
 198     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 199     enable_static=no
 200   fi
 201   if test x$enable_shared = xno; then
 202     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 203   fi
 204   enable_shared=yes
 205 fi
 206
 207 dnl Initialize libtool
 208 LT_PREREQ([2.2.6])
 209 LT_INIT([disable-static win32-dll])
 210 # Create libtool early, because it's used in configure
 211 LT_OUTPUT
 212
 213 # Make sure we use 64-bit versions of various file stuff.
 214 AC_SYS_LARGEFILE
 215
 216 AM_PROG_AS
 217 AC_PATH_PROG(NM, nm, nm)
 218
 219 AC_MSG_CHECKING([for some Win32 platform])
 220 case "$host" in
 221   *-*-mingw*|*-*-cygwin*)
 222     platform_win32=yes
 223     ;;
 224   *)
 225     platform_win32=no
 226     ;;
 227 esac
 228 AC_MSG_RESULT([$platform_win32])
 229 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 230
 231 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 232 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 233 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 234
 235 if test "$os_win32" = "yes"; then
 236   AC_CHECK_TOOL(WINDRES, windres, no)
 237   if test "$WINDRES" = no; then
 238     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 239   fi
 240   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 241 fi
 242 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 243
 244 m4_define([debug_default],
 245           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 246
 247 dnl declare --enable-* args and collect ac_help strings
 248 AC_ARG_ENABLE(debug,
 249               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 250                               [turn on debugging @<:@default=debug_default@:>@])],,
 251               [enable_debug=debug_default])
 252
 253 AC_ARG_ENABLE(rebuilds,
 254               [AS_HELP_STRING([--disable-rebuilds],
 255                               [disable all source autogeneration rules])],,
 256               [enable_rebuilds=yes])
 257
 258 AC_ARG_ENABLE(gtk2-dependency,
 259               [AS_HELP_STRING([--enable-gtk2-dependency],
 260                               [Do not build gtk-update-icon-cache and other shared tools])],,
 261               [enable_gtk2_dependency=no])
 262
 263 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 264
 265 AC_ARG_ENABLE(xkb,
 266               [AS_HELP_STRING([--enable-xkb],
 267                               [support XKB extension [default=maybe]])],,
 268               [enable_xkb="maybe"])
 269 AC_ARG_ENABLE(xinerama,
 270               [AS_HELP_STRING([--enable-xinerama],
 271                               [support Xinerama extension [default=maybe]])],,
 272               [enable_xinerama="maybe"])
 273 AC_ARG_ENABLE(xrandr,
 274               [AS_HELP_STRING([--enable-xrandr],
 275                               [support XRandR extension [default=maybe]])],,
 276               [enable_xrandr="maybe"])
 277 AC_ARG_ENABLE(xfixes,
 278               [AS_HELP_STRING([--enable-xfixes],
 279                               [support XFixes extension [default=maybe]])],,
 280               [enable_xfixes="maybe"])
 281 AC_ARG_ENABLE(xcomposite,
 282               [AS_HELP_STRING([--enable-xcomposite],
 283                               [support X Composite extension [default=maybe]])],,
 284               [enable_xcomposite="maybe"])
 285 AC_ARG_ENABLE(xdamage,
 286               [AS_HELP_STRING([--enable-xdamage],
 287                               [support X Damage extension [default=maybe]])],,
 288               [enable_xdamage="maybe"])
 289
 290 AC_ARG_ENABLE(x11-backend,
 291               [AS_HELP_STRING([--enable-x11-backend],
 292                               [enable the X11 gdk backend])],
 293                               [backend_set=yes])
 294 AC_ARG_ENABLE(win32-backend,
 295               [AS_HELP_STRING([--enable-win32-backend],
 296                               [enable the Win32 gdk backend])],
 297                               [backend_set=yes])
 298 AC_ARG_ENABLE(quartz-backend,
 299               [AS_HELP_STRING([--enable-quartz-backend],
 300                               [enable the quartz gdk backend])],
 301                               [backend_set=yes])
 302 AC_ARG_ENABLE(broadway-backend,
 303               [AS_HELP_STRING([--enable-broadway-backend],
 304                               [enable the broadway (HTML5) gdk backend])],
 305                               [backend_set=yes])
 306 AC_ARG_ENABLE(wayland-backend,
 307               [AS_HELP_STRING([--enable-wayland-backend],
 308                               [enable the wayland gdk backend])],
 309                               [backend_set=yes])
 310
 311 if test -z "$backend_set"; then
 312   if test "$platform_win32" = yes; then
 313     enable_win32_backend=yes
 314   else
 315     enable_x11_backend=yes
 316   fi
 317 fi
 318
 319 AC_ARG_ENABLE(quartz-relocation,
 320               [AS_HELP_STRING([--enable-quartz-relocation],
 321                               [enable bundle-based relocation functions])],
 322                               [quartz_relocation=yes])
 323
 324 AC_ARG_ENABLE(wayland-cairo-gl,
 325               AS_HELP_STRING([--enable-wayland-cairo-gl],
 326                              [enable the use of Cairo GL in the Wayland backend]),
 327               [enable_wayland_cairo_gl=yes])
 328
 329
 330 cairo_backends=
 331 backend_immodules=
 332 have_gio_unix=no
 333 GDK_BACKENDS=
 334 GDK_EXTRA_LIBS=
 335 GDK_EXTRA_CFLAGS=
 336 GDK_WINDOWING=
 337 PANGO_PACKAGES="pango pangocairo"
 338
 339 if test "$enable_x11_backend" = "yes"; then
 340   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 341   # backend names are identical.
 342   cairo_backends="$cairo_backends cairo-xlib"
 343   GDK_BACKENDS="$GDK_BACKENDS x11"
 344   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 345   # gdkapplaunchcontext-x11.c
 346   have_gio_unix=yes
 347   backend_immodules="$backend_immodules,xim"
 348   GDK_WINDOWING="$GDK_WINDOWING
 349 #define GDK_WINDOWING_X11"
 350 fi
 351
 352 if test "$enable_win32_backend" = "yes"; then
 353   cairo_backends="$cairo_backends cairo-win32"
 354   GDK_BACKENDS="$GDK_BACKENDS win32"
 355   backend_immodules="$backend_immodules,ime"
 356   GDK_WINDOWING="$GDK_WINDOWING
 357 #define GDK_WINDOWING_WIN32"
 358   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 359   AM_CONDITIONAL(USE_WIN32, true)
 360   PANGO_PACKAGES="pangowin32 pangocairo"
 361 else
 362   AM_CONDITIONAL(USE_WIN32, false)
 363 fi
 364
 365 DISABLE_ON_QUARTZ=''
 366 if test "x$enable_quartz_backend" = xyes; then
 367   cairo_backends="$cairo_backends cairo-quartz"
 368   GDK_BACKENDS="$GDK_BACKENDS quartz"
 369   GDK_WINDOWING="$GDK_WINDOWING
 370 #define GDK_WINDOWING_QUARTZ"
 371   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 372   DISABLE_ON_QUARTZ='%'
 373   AM_CONDITIONAL(USE_QUARTZ, true)
 374   if test "x$quartz_relocation" = xyes; then
 375     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 376   fi
 377   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 378   # gdkapplaunchcontext-x11.c
 379   have_gio_unix=yes
 380
 381 else
 382   AM_CONDITIONAL(USE_QUARTZ, false)
 383 fi
 384 AC_SUBST(DISABLE_ON_QUARTZ)
 385
 386 if test "x$enable_broadway_backend" == xyes; then
 387   GDK_BACKENDS="$GDK_BACKENDS broadway"
 388   cairo_backends="$cairo_backends cairo"
 389   GDK_WINDOWING="$GDK_WINDOWING
 390 #define GDK_WINDOWING_BROADWAY"
 391   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 392   AM_CONDITIONAL(USE_BROADWAY, true)
 393 else
 394   AM_CONDITIONAL(USE_BROADWAY, false)
 395 fi
 396
 397 if test "x$enable_wayland_backend" == "xyes"; then
 398   if test "x$enable_wayland_cairo_gl" == "xyes"; then
 399     # Wayland can use cairo-gl
 400     cairo_backends="$cairo_backends cairo-gl"
 401     AC_DEFINE(GDK_WAYLAND_USE_EGL, [1], [Whether to use EGL in Wayland backend])
 402   else
 403     # For the cairo image backend
 404     cairo_backends="$cairo_backends cairo"
 405   fi
 406   GDK_BACKENDS="$GDK_BACKENDS wayland"
 407   have_gio_unix=yes
 408   GDK_WINDOWING="$GDK_WINDOWING
 409 #define GDK_WINDOWING_WAYLAND"
 410   WAYLAND_PACKAGES="wayland-client xkbcommon wayland-cursor"
 411   if test "x$enable_wayland_cairo_gl" == "xyes"; then
 412     WAYLAND_PACKAGES="$WAYLAND_PACKAGES wayland-egl egl"
 413   fi
 414   AM_CONDITIONAL(USE_WAYLAND, true)
 415 else
 416   AM_CONDITIONAL(USE_WAYLAND, false)
 417 fi
 418
 419 # strip leading space
 420 GDK_BACKENDS=${GDK_BACKENDS#* }
 421
 422 AC_SUBST(GDK_BACKENDS)
 423
 424 if test -z "$GDK_BACKENDS"; then
 425   AC_MSG_ERROR([No GDK backends selected.])
 426 fi
 427
 428 if test "x$enable_debug" = "xyes"; then
 429   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 430   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 431 else
 432   if test "x$enable_debug" = "xno"; then
 433     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 434   else
 435     GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"
 436   fi
 437 fi
 438
 439
 440 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 441                    [Define if debugging is enabled])
 442
 443
 444 # Build time sanity check...
 445 AM_SANITY_CHECK
 446
 447 changequote(,)dnl
 448 if test "x$GCC" = "xyes"; then
 449   case " $CFLAGS " in
 450   *[\ \ ]-Wall[\ \      ]*) ;;
 451   *) CFLAGS="$CFLAGS -Wall" ;;
 452   esac
 453
 454   if test "x$enable_ansi" = "xyes"; then
 455     case " $CFLAGS " in
 456     *[\ \       ]-ansi[\ \      ]*) ;;
 457     *) CFLAGS="$CFLAGS -ansi" ;;
 458     esac
 459
 460     case " $CFLAGS " in
 461     *[\ \       ]-pedantic[\ \  ]*) ;;
 462     *) CFLAGS="$CFLAGS -pedantic" ;;
 463     esac
 464   fi
 465 fi
 466 changequote([,])dnl
 467
 468 # Ensure MSVC-compatible struct packing convention is used when
 469 # compiling for Win32 with gcc.
 470 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 471 # gcc2 uses "-fnative-struct".
 472 if test x"$os_win32" = xyes; then
 473   if test x"$GCC" = xyes; then
 474     msnative_struct=''
 475     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 476     if test -z "$ac_cv_prog_CC"; then
 477       our_gcc="$CC"
 478     else
 479       our_gcc="$ac_cv_prog_CC"
 480     fi
 481     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 482       2.)
 483         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 484           msnative_struct='-fnative-struct'
 485         fi
 486         ;;
 487       *)
 488         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 489           msnative_struct='-mms-bitfields'
 490         fi
 491         ;;
 492     esac
 493     if test x"$msnative_struct" = x ; then
 494       AC_MSG_RESULT([no way])
 495       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 496     else
 497       CFLAGS="$CFLAGS $msnative_struct"
 498       AC_MSG_RESULT([${msnative_struct}])
 499     fi
 500   fi
 501 fi
 502
 503 ## Initial sanity check, done here so that users get told they
 504 ## have the wrong dependencies as early in the process as possible.
 505 ## Later on we actually use the cflags/libs from separate pkg-config
 506 ## calls. Oh, also the later pkg-config calls don't include
 507 ## the version requirements since those make the module lists
 508 ## annoying to construct
 509 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 510   [glib-2.0 >= glib_required_version dnl
 511    atk >= atk_required_version dnl
 512    pango >= pango_required_version dnl
 513    cairo >= cairo_required_version dnl
 514    cairo-gobject >= cairo_required_version dnl
 515    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 516
 517 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 518
 519 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0])
 520
 521 if test "$os_win32" != yes; then
 522     # libtool option to control which symbols are exported
 523     # right now, symbols starting with _ are not exported
 524     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 525 else
 526     # We currently use .def files on Windows (for gdk and gtk)
 527     LIBTOOL_EXPORT_OPTIONS=
 528 fi
 529 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 530
 531 dnl ******************************************************
 532 dnl * See whether to include shared library dependencies *
 533 dnl ******************************************************
 534
 535 AC_ARG_ENABLE(explicit-deps,
 536               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 537                               [use explicit dependencies in .pc files [default=auto]])],,
 538               [enable_explicit_deps=auto])
 539
 540 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 541 case $enable_explicit_deps in
 542   auto)
 543     export SED
 544     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 545     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 546       enable_explicit_deps=yes
 547     else
 548       enable_explicit_deps=no
 549     fi
 550   ;;
 551   yes|no)
 552   ;;
 553   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 554   ;;
 555 esac
 556 AC_MSG_RESULT($enable_explicit_deps)
 557
 558 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 559
 560 # define a MAINT-like variable REBUILD which is set if Perl
 561 # and awk are found, so autogenerated sources can be rebuilt
 562
 563 AC_PATH_PROGS(PERL, perl5 perl)
 564
 565 # We would like indent, but don't require it.
 566 AC_CHECK_PROG(INDENT, indent, indent)
 567
 568 REBUILD=\#
 569 if test "x$enable_rebuilds" = "xyes" && \
 570      test -n "$PERL" && \
 571      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 572   REBUILD=
 573 fi
 574 AC_SUBST(REBUILD)
 575
 576 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 577 AC_CHECK_FUNCS(localtime_r)
 578
 579 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 580 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 581 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 582                                 [[char c;
 583                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 584                [gtk_ok=yes], [gtk_ok=no])
 585 AC_MSG_RESULT($gtk_ok)
 586 if test "$gtk_ok" = "yes"; then
 587   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 588             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 589 fi
 590
 591 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 592 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 593 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 594                                 [[char c;
 595                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 596                [gtk_ok=yes], [gtk_ok=no])
 597 AC_MSG_RESULT($gtk_ok)
 598 if test "$gtk_ok" = "yes"; then
 599   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 600             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 601 fi
 602
 603 # _NL_PAPER_HEIGHT is an enum and not a define
 604 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 605 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 606                                 [[char c;
 607                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 608                [gtk_ok=yes], [gtk_ok=no])
 609 AC_MSG_RESULT($gtk_ok)
 610 if test "$gtk_ok" = "yes"; then
 611   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 612             [Define if _NL_PAPER_HEIGHT is available])
 613 fi
 614
 615 # _NL_PAPER_WIDTH is an enum and not a define
 616 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 617 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 618                                 [[char c;
 619                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 620                [gtk_ok=yes], [gtk_ok=no])
 621 AC_MSG_RESULT($gtk_ok)
 622 if test "$gtk_ok" = "yes"; then
 623   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 624             [Define if _NL_PAPER_WIDTH is available])
 625 fi
 626
 627 # i18n stuff
 628 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 629 AM_GLIB_GNU_GETTEXT
 630 LIBS="$LIBS $INTLLIBS"
 631 AC_CONFIG_COMMANDS([po-properties],
 632                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 633                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 634                      esac]],
 635                    [[]])
 636
 637 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 638 dnl po-properties/POTFILES during configure; see GNOME #573515.
 639 dnl
 640 dnl Generate list of files to be processed by xgettext which will
 641 dnl be included in po-properties/Makefile.
 642 test -d po-properties || mkdir po-properties
 643 if test "x$srcdir" != "x."; then
 644   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 645     popropsrcprefix="$srcdir/"
 646   else
 647     popropsrcprefix="../$srcdir/"
 648   fi
 649 else
 650   popropsrcprefix="../"
 651 fi
 652 rm -f po-properties/POTFILES
 653 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 654 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 655 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 656
 657 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 658
 659 dnl The DU4 header files don't provide library prototypes unless
 660 dnl -std1 is given to the native cc.
 661 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 662
 663 gtk_save_LIBS=$LIBS
 664 LIBS="$LIBS -lm"
 665 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 666                                 int main (void) { return (log(1) != log(1.)); }]])],
 667               [AC_MSG_RESULT(none needed)],
 668               [gtk_save_CFLAGS="$CFLAGS"
 669                CFLAGS="$CFLAGS -std1"
 670                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 671                                                int main (void) { return (log(1) != log(1.)); }]])],
 672                              [AC_MSG_RESULT(-std1)],
 673                              [AC_MSG_RESULT()
 674                               CFLAGS="$gtk_save_CFLAGS"
 675                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 676                              [true])],
 677               [AC_MSG_RESULT(none needed)])
 678
 679 LIBS=$gtk_save_LIBS
 680
 681 AC_MSG_CHECKING(for the BeOS)
 682 case $host in
 683   *-*-beos*)
 684     AC_MSG_RESULT(yes)
 685     MATH_LIB=
 686   ;;
 687   *)
 688     AC_MSG_RESULT(no)
 689   ;;
 690 esac
 691
 692 AC_SUBST(MATH_LIB)
 693 #
 694 # see bug 162979
 695 #
 696 AC_MSG_CHECKING(for HP-UX)
 697 case $host_os in
 698   hpux9* | hpux10* | hpux11*)
 699     AC_MSG_RESULT(yes)
 700     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 701   ;;
 702   *)
 703     AC_MSG_RESULT(no)
 704   ;;
 705 esac
 706
 707 #
 708 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 709 #
 710
 711 AM_PATH_GLIB_2_0(glib_required_version, :,
 712   AC_MSG_ERROR([
 713 *** GLIB glib_required_version or better is required. The latest version of
 714 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 715   gobject gmodule-no-export)
 716
 717 dnl
 718 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 719 dnl
 720 gtk_save_LIBS=$LIBS
 721 LIBS="$LIBS $GLIB_LIBS"
 722 AC_CHECK_FUNCS(bind_textdomain_codeset)
 723 LIBS=$gtk_save_LIBS
 724
 725 AC_CHECK_HEADERS(pwd.h,
 726                  AC_DEFINE(HAVE_PWD_H, 1,
 727                            [Define to 1 if pwd.h is available]))
 728 AC_CHECK_HEADERS(sys/time.h,
 729                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 730                            [Define to 1 if time.h is available]))
 731 AC_CHECK_HEADERS(unistd.h,
 732                  AC_DEFINE(HAVE_UNISTD_H, 1,
 733                            [Define to 1 if unistd.h is available]))
 734 AC_CHECK_HEADERS(ftw.h,
 735                  AC_DEFINE(HAVE_FTW_H, 1,
 736                            [Define to 1 if ftw.h is available]))
 737
 738 AC_MSG_CHECKING([for GNU ftw extensions])
 739 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 740                                      #define _GNU_SOURCE
 741                                      #include <ftw.h>]],
 742                                    [[int flags = FTW_ACTIONRETVAL;]])],
 743                   [gtk_ok=yes],[gtk_ok=no])
 744 if test $gtk_ok = yes; then
 745     AC_MSG_RESULT([yes])
 746     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 747 else
 748     AC_MSG_RESULT([no])
 749 fi
 750
 751 saved_cflags="$CFLAGS"
 752 saved_ldflags="$LDFLAGS"
 753
 754
 755 # Checks for library functions.
 756 AC_FUNC_MMAP
 757
 758 AC_CHECK_FUNCS(mallinfo)
 759 AC_CHECK_FUNCS(getresuid)
 760 AC_TYPE_UID_T
 761
 762 # Check for round(), rint(), isnan(), isinf() and nearbyint()
 763 AC_CHECK_LIB(m,round,,)
 764 AC_CHECK_FUNCS(round rint nearbyint)
 765 AC_CHECK_DECLS([isnan, isinf], [], [], [[#include <math.h>]])
 766
 767 # Checks for gdkspawn
 768 AC_CHECK_HEADERS(crt_externs.h)
 769 AC_CHECK_FUNCS(_NSGetEnviron)
 770
 771 AC_MSG_CHECKING(whether to build dynamic modules)
 772
 773 AC_ARG_ENABLE(modules,
 774               [AS_HELP_STRING([--disable-modules],
 775                               [disable dynamic module loading])])
 776
 777 dynworks=false
 778 build_dynamic_modules=no
 779 deps=
 780 if test x$enable_modules = xno; then
 781     AC_MSG_RESULT(no)
 782 else
 783     AC_MSG_RESULT(yes)
 784     AC_MSG_CHECKING(whether dynamic modules work)
 785     ## for loop is to strip newline
 786     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 787     for I in $tmp; do
 788         dynworks=$I
 789     done
 790
 791     dnl Now we check to see if our libtool supports shared lib deps
 792     dnl (in a rather ugly way even)
 793     if $dynworks; then
 794         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 795         module_deplibs_check=`$module_libtool_config | \
 796             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 797             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 798         if test "x$module_deplibs_check" = "xnone" || \
 799            test "x$module_deplibs_check" = "xunknown" || \
 800            test "x$module_deplibs_check" = "x"; then
 801             dynworks=false
 802         fi
 803     fi
 804
 805     if $dynworks; then
 806         build_dynamic_modules=yes
 807         AC_DEFINE(USE_GMODULE, 1,
 808                   [Define to 1 if gmodule works and should be used])
 809         AC_MSG_RESULT(yes)
 810     else
 811         build_dynamic_modules=no
 812         AC_MSG_RESULT(no)
 813     fi
 814 fi
 815
 816 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 817
 818 #
 819 # Allow building some or all immodules included
 820 #
 821 AC_MSG_CHECKING(immodules to build)
 822
 823 AC_ARG_WITH(included_immodules,
 824             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 825                             [build the specified input methods into gtk])])
 826
 827 if $dynworks; then
 828    :
 829 else
 830    ## if the option was specified, leave it; otherwise disable included immodules
 831    if test x$with_included_immodules = xno; then
 832            with_included_immodules=yes
 833    fi
 834 fi
 835
 836 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 837
 838 included_immodules=""
 839 # If the switch specified without listing any specific ones, include all
 840 if test "x$with_included_immodules" = xyes ; then
 841   included_immodules="$all_immodules"
 842 else
 843   included_immodules="$with_included_immodules"
 844 fi
 845
 846 AC_MSG_RESULT($included_immodules)
 847 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 848
 849 INCLUDED_IMMODULE_OBJ=
 850 INCLUDED_IMMODULE_DEFINE=
 851
 852 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 853 for immodule in $included_immodules; do
 854  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 855  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 856    :
 857  else
 858    AC_MSG_ERROR([the specified input method $immodule does not exist])
 859  fi
 860
 861  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 862  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 863  eval INCLUDE_$immodule_underscores=yes
 864 done
 865 IFS="$gtk_save_ifs"
 866 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 867 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 868
 869 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 870 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 871 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 872 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 873 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 874 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 875 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 876 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 877 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 878 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 879 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 880 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 881
 882 # Checks to see whether we should include mediaLib
 883 # support.
 884 #
 885 AC_CHECK_HEADER(sys/systeminfo.h,
 886                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 887                           [Define to 1 if sys/systeminfo.h is available]))
 888 AC_CHECK_HEADER(sys/sysinfo.h,
 889                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 890                           [Define to 1 if sys/sysinfo.h is available]))
 891
 892 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 893
 894 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 895
 896 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 897   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 898   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 899     REBUILD_PNGS=#
 900   fi
 901 fi
 902
 903 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 904
 905 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 906
 907 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 908    test "x$REBUILD_PNGS" = "x#" ; then
 909      AC_MSG_ERROR([
 910 *** gtkbuiltincache.h is not in the tree, and cannot be built
 911 *** because you don't have libpng, or (when cross-compiling) you
 912 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 913 fi
 914
 915 ########################################
 916 # Windowing system checks
 917 ########################################
 918
 919 # GTK+ uses some X calls, so needs to link against X directly
 920 GTK_DEP_PACKAGES_FOR_X=
 921 GTK_DEP_LIBS_FOR_X=
 922 X_EXTENSIONS=
 923
 924 if test "x$enable_x11_backend" = xyes; then
 925   X_PACKAGES=fontconfig
 926
 927   #
 928   # We use fontconfig very peripherally when decoding the default
 929   # settings.
 930   #
 931   if $PKG_CONFIG --exists fontconfig; then : ; else
 932     AC_MSG_ERROR([
 933 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 934   fi
 935
 936   #
 937   # Check for basic X packages; we use pkg-config if available
 938   #
 939   if $PKG_CONFIG --exists x11 xext; then
 940     have_base_x_pc=true
 941     X_PACKAGES="$X_PACKAGES x11 xext"
 942     x_libs="`$PKG_CONFIG --libs x11 xext`"
 943     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 944
 945     # Strip out any .la files that pkg-config might give us (this happens
 946     # with -uninstalled.pc files)
 947     x_libs_for_checks=
 948     for I in $x_libs ; do
 949       case $I in
 950         *.la) ;;
 951         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 952       esac
 953     done
 954
 955     GTK_PACKAGES_FOR_X="x11"
 956   else
 957     have_base_x_pc=false
 958     AC_PATH_XTRA
 959     if test x$no_x = xyes ; then
 960       AC_MSG_ERROR([X development libraries not found])
 961     fi
 962
 963     x_cflags="$X_CFLAGS"
 964     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 965
 966     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 967   fi
 968
 969   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 970   x_extra_libs=
 971
 972   gtk_save_cppflags="$CPPFLAGS"
 973   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 974
 975   gtk_save_LIBS=$LIBS
 976   LIBS="$x_libs_for_checks $LIBS"
 977
 978   # Sanity check for the X11 and Xext libraries. While everything we need from
 979   # Xext is optional, the chances a system has *none* of these things is so
 980   # small that we just unconditionally require it.
 981   AC_CHECK_FUNC(XOpenDisplay, :,
 982                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 983   AC_CHECK_FUNC(XextFindDisplay, :,
 984                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
 985
 986   # Check for xReply
 987
 988   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 989   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 990                                      [[xReply *rep = NULL;
 991                                        rep = rep;]])],
 992                     [AC_MSG_RESULT([no])],
 993                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 994                                                           #include <X11/Xlibint.h>]],
 995                                                         [[xReply *rep = NULL;
 996                                                           rep = rep;]])],
 997                                        [AC_MSG_RESULT([yes])
 998                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 999                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
1000                                        [AC_MSG_RESULT([unknown])
1001                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1002
1003   # Check for XKB support.
1004
1005   if test "x$enable_xkb" = "xyes"; then
1006         AC_CHECK_FUNC(XkbQueryExtension,
1007                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1008                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1009                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1010   elif test "x$enable_xkb" = "xmaybe"; then
1011         AC_CHECK_FUNC(XkbQueryExtension,
1012                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1013                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1014   else
1015         AC_MSG_WARN(XKB support explicitly disabled)
1016   fi
1017
1018   # Check for shaped window extension
1019
1020   AC_CHECK_FUNC(XShapeCombineMask, :,
1021      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1022
1023   # X SYNC check
1024   gtk_save_CFLAGS="$CFLAGS"
1025   CFLAGS="$CFLAGS $x_cflags"
1026
1027   AC_CHECK_FUNC(XSyncQueryExtension,
1028       [AC_CHECK_HEADER(X11/extensions/sync.h,
1029           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1030           :, [#include <X11/Xlib.h>])])
1031
1032   CFLAGS="$gtk_save_CFLAGS"
1033
1034   if test "x$enable_xinerama" != "xno"; then
1035     # Check for Xinerama extension (Solaris impl or Xfree impl)
1036     have_xfree_xinerama=false
1037     have_solaris_xinerama=false
1038
1039     gtk_save_cppflags="$CPPFLAGS"
1040     CPPFLAGS="$CPPFLAGS $x_cflags"
1041
1042     # Check for XFree
1043     AC_MSG_CHECKING(for Xinerama packages)
1044
1045     if $PKG_CONFIG --exists xinerama ; then
1046        AC_MSG_RESULT(yes)
1047        have_xfree_xinerama=true
1048        X_PACKAGES="$X_PACKAGES xinerama"
1049     else
1050        AC_MSG_RESULT(no)
1051        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1052            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1053            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1054            have_xfree_xinerama=true], :,
1055            [#include <X11/Xlib.h>])])
1056     fi
1057
1058     if $have_xfree_xinerama ; then
1059       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1060       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1061                 [Define to 1 if XFree Xinerama is available])
1062       AC_DEFINE(HAVE_XINERAMA, 1,
1063                 [Define to 1 is Xinerama is available])
1064     else
1065       case "$host" in
1066         *-*-solaris*)
1067             # Check for solaris
1068             AC_MSG_CHECKING(for Xinerama support on Solaris)
1069
1070             have_solaris_xinerama=false
1071             AC_CHECK_FUNC(XineramaGetInfo,
1072                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1073                     [have_solaris_xinerama=true], :,
1074                     [#include <X11/Xlib.h>])])
1075
1076             if $have_solaris_xinerama ; then
1077               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1078               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1079                         [Define to 1 if solaris xinerama is available])
1080               AC_DEFINE(HAVE_XINERAMA, 1,
1081                         [Define to 1 if xinerama is available])
1082               AC_MSG_RESULT(yes)
1083             else
1084               AC_MSG_RESULT(no)
1085             fi
1086             ;;
1087         *)
1088             ;;
1089       esac
1090     fi
1091   fi
1092   if test "x$enable_xinerama" = "xyes" ; then
1093     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1094       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1095     fi
1096   fi
1097
1098   # Check for XGetEventData for GenericEvents
1099   AC_CHECK_FUNC(XGetEventData,
1100                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1101
1102   # set up things for XInput
1103   if $PKG_CONFIG --exists "xi" ; then
1104
1105     X_PACKAGES="$X_PACKAGES xi"
1106     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xi"
1107
1108     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1109                     have_xinput2=yes
1110                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1111
1112     gtk_save_LIBS="$LIBS"
1113     LIBS="$LIBS -lXi"
1114
1115     # Note that we also check that the XIScrollClassInfo struct is defined,
1116     # because at least Ubuntu Oneiric seems to have XIAllowTouchEvents(), but not the XIScrollClassInfo struct.
1117     AC_CHECK_FUNC([XIAllowTouchEvents],
1118       [AC_CHECK_MEMBER([XIScrollClassInfo.number],
1119                        have_xinput2_2=yes
1120                        AC_DEFINE(XINPUT_2_2, 1, [Define to 1 if XInput 2.2 is available]),
1121                        have_xinput2_2=no,
1122                        [[#include <X11/extensions/XInput2.h>]])])
1123     LIBS="$gtk_save_LIBS"
1124
1125     if test "x$have_xinput2_2" = "xyes"; then
1126       X_EXTENSIONS="$X_EXTENSIONS XI2.2"
1127     else
1128       X_EXTENSIONS="$X_EXTENSIONS XI2"
1129     fi
1130   fi
1131
1132   AS_IF([test "x$have_xinput2" != "xyes"],
1133         [AC_MSG_ERROR([*** XInput2 extension not found. Check 'config.log' for more details.])])
1134
1135   # Check for the RANDR extension
1136   if test x"$enable_xrandr" != xno; then
1137     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1138       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1139
1140       X_PACKAGES="$X_PACKAGES xrandr"
1141       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1142     elif test x"$enable_xrandr" = xyes; then
1143       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1144     fi
1145   fi
1146
1147   # Checks for Xcursor library
1148
1149   if $PKG_CONFIG --exists xcursor ; then
1150     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1151
1152     X_PACKAGES="$X_PACKAGES xcursor"
1153   fi
1154
1155   # Checks for XFixes extension
1156
1157   if test x"$enable_xfixes" != xno; then
1158     if $PKG_CONFIG --exists xfixes ; then
1159       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1160
1161       X_PACKAGES="$X_PACKAGES xfixes"
1162       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1163       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1164     elif test x"$enable_xfixes" = xyes; then
1165       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1166     fi
1167   fi
1168
1169   # Checks for Xcomposite extension
1170
1171   if test x"$enable_xcomposite" != xno; then
1172     if $PKG_CONFIG --exists xcomposite ; then
1173       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1174
1175       X_PACKAGES="$X_PACKAGES xcomposite"
1176       X_EXTENSIONS="$X_EXTENSIONS Composite"
1177       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1178     elif test x"$enable_xcomposite" = xyes; then
1179       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1180     fi
1181   fi
1182
1183   # Checks for Xdamage extension
1184
1185   if test x"$enable_xdamage" != xno; then
1186     if $PKG_CONFIG --exists xdamage ; then
1187       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1188
1189       X_PACKAGES="$X_PACKAGES xdamage"
1190       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1191       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1192     elif test x"$enable_xdamage" = xyes; then
1193       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1194     fi
1195   fi
1196
1197   if $have_base_x_pc ; then
1198     GDK_EXTRA_LIBS="$x_extra_libs"
1199   else
1200     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1201   fi
1202
1203   CPPFLAGS="$gtk_save_cppflags"
1204   LIBS="$gtk_save_libs"
1205
1206   AM_CONDITIONAL(USE_X11, true)
1207
1208   # strip leading space
1209   X_EXTENSIONS=${X_EXTENSIONS#* }
1210
1211 else
1212   XPACKAGES=
1213
1214   AM_CONDITIONAL(USE_X11, false)
1215 fi
1216
1217 # Check for gio-unix
1218 if test "$have_gio_unix" = "yes"; then
1219   GDK_GIO_PACKAGE=gio-unix-2.0
1220   AC_DEFINE([HAVE_GIO_UNIX], [1],
1221             [Define if gio-unix is available])
1222 else
1223   GDK_GIO_PACKAGE=gio-2.0
1224 fi
1225
1226 # Check for Pango flags
1227
1228 AC_MSG_CHECKING(Pango flags)
1229 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1230         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1231         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1232
1233         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1234 else
1235         AC_MSG_ERROR([
1236 *** Pango not found. Pango built with Cairo support is required
1237 *** to build GTK+. See http://www.pango.org for Pango information.
1238 ])
1239 fi
1240
1241 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1242
1243 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1244         :
1245 else
1246         gtk_save_LIBS="$LIBS"
1247         LIBS="$PANGO_LIBS $LIBS"
1248         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1249 *** Can't link to Pango. Pango is required to build
1250 *** GTK+. For more information see http://www.pango.org]))
1251         LIBS="$gtk_save_LIBS"
1252 fi
1253
1254 CFLAGS="$saved_cflags"
1255 LDFLAGS="$saved_ldflags"
1256
1257 GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo cairo-gobject"
1258 GDK_PRIVATE_PACKAGES="$GDK_GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES $cairo_backends"
1259 if test "x$enable_x11_backend" = xyes; then
1260   GDK_PRIVATE_PACKAGES="$GDK_PRIVATE_PACKAGES pangoft2"
1261 fi
1262
1263 PKG_CHECK_MODULES(GDK_DEP, $GDK_PACKAGES $GDK_PRIVATE_PACKAGES)
1264 GDK_DEP_LIBS="$GDK_EXTRA_LIBS $GDK_DEP_LIBS $MATH_LIB"
1265 GDK_DEP_CFLAGS="$GDK_DEP_CFLAGS $GDK_EXTRA_CFLAGS"
1266 #
1267 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1268 # into the pkg-config files
1269 #
1270 if test $enable_explicit_deps != yes ; then
1271   GDK_EXTRA_LIBS=
1272 fi
1273
1274 AC_SUBST(GDK_PACKAGES)
1275 AC_SUBST(GDK_PRIVATE_PACKAGES)
1276 AC_SUBST(GDK_EXTRA_LIBS)
1277 AC_SUBST(GDK_EXTRA_CFLAGS)
1278 AC_SUBST(GDK_DEP_LIBS)
1279 AC_SUBST(GDK_DEP_CFLAGS)
1280
1281
1282 ########################################
1283 # Check for Accessibility Toolkit flags
1284 ########################################
1285
1286 if test x$enable_x11_backend = xyes; then
1287    ATK_PACKAGES="atk atk-bridge-2.0"
1288 else
1289    ATK_PACKAGES="atk"
1290 fi
1291
1292 PKG_CHECK_MODULES(ATK, $ATK_PACKAGES)
1293
1294 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1295 GTK_PRIVATE_PACKAGES="$ATK_PACKAGES"
1296 if test "x$enable_x11_backend" = xyes; then
1297   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES pangoft2"
1298 fi
1299 if test "$have_gio_unix" = "yes"; then
1300   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES gio-unix-2.0"
1301 fi
1302 GTK_EXTRA_LIBS=
1303
1304 GTK_EXTRA_CFLAGS=
1305 PKG_CHECK_MODULES(GTK_DEP, $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES $GTK_PRIVATE_PACKAGES)
1306 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X $GTK_DEP_LIBS $GTK_EXTRA_LIBS $MATH_LIB"
1307 GTK_DEP_CFLAGS="$GTK_DEP_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1308
1309 if test x"$os_win32" = xyes; then
1310   GTK_EXTRA_CFLAGS="$msnative_struct"
1311 fi
1312
1313 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1314 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1315 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1316 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1317
1318 AC_SUBST(GTK_PACKAGES)
1319 AC_SUBST(GTK_PRIVATE_PACKAGES)
1320 AC_SUBST(GTK_EXTRA_LIBS)
1321 AC_SUBST(GTK_EXTRA_CFLAGS)
1322 AC_SUBST(GTK_DEP_LIBS)
1323 AC_SUBST(GTK_DEP_CFLAGS)
1324
1325 AC_SUBST(GLIB_PREFIX)
1326 AC_SUBST(ATK_PREFIX)
1327 AC_SUBST(PANGO_PREFIX)
1328 AC_SUBST(CAIRO_PREFIX)
1329
1330 AC_SUBST(GTK_DEBUG_FLAGS)
1331 AC_SUBST(GTK_XIM_FLAGS)
1332
1333 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1334 AC_SUBST(GDK_PIXBUF_LIBS)
1335
1336 ########################
1337 # Checks needed for gail
1338 ########################
1339
1340 old_LIBS="$LIBS"
1341 dnl Checks for inet libraries:
1342 AC_SEARCH_LIBS(gethostent, nsl)
1343 AC_SEARCH_LIBS(setsockopt, socket)
1344 AC_SEARCH_LIBS(connect, inet)
1345
1346 dnl check for the sockaddr_un.sun_len member
1347 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1348                 [struct_sockaddr_un_sun_len=true],
1349                 [struct_sockaddr_un_suin_len=false],
1350                 [#include <sys/types.h>
1351                  #include <sys/un.h>]
1352                 )
1353 case $struct_sockaddr_un_sun_len in
1354         true)
1355                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1356                                    [Have the sockaddr_un.sun_len member])
1357                 ;;
1358         *)
1359                 ;;
1360 esac
1361
1362 GAIL_INET_LIBS="$LIBS"
1363 AC_SUBST([GAIL_INET_LIBS])
1364
1365 LIBS="$old_LIBS"
1366
1367 ################################################################
1368 # Printing system checks
1369 ################################################################
1370
1371 PRINT_BACKENDS="file lpr"
1372
1373 AC_ARG_ENABLE(cups,
1374               [AS_HELP_STRING([--disable-cups],
1375                               [disable cups print backend])],,
1376               [enable_cups=auto])
1377
1378 if test "x$enable_cups" = "xno"; then
1379   AM_CONDITIONAL(HAVE_CUPS, false)
1380 else
1381   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1382   if test "x$CUPS_CONFIG" = "xno"; then
1383     if test "x$enable_cups" = "xauto"; then
1384       AM_CONDITIONAL(HAVE_CUPS, false)
1385     else
1386       AC_MSG_ERROR([
1387 *** cups not found.
1388 ])
1389     fi
1390   else
1391     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1392     CUPS_LIBS=`$CUPS_CONFIG --libs`
1393
1394     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1395     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1396     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1397
1398     if test $CUPS_API_MAJOR -gt 1 -o \
1399             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -lt 2; then
1400       AC_MSG_ERROR([CUPS >= 1.2 not found])
1401     fi
1402     if test $CUPS_API_MAJOR -gt 1 -o \
1403             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 6; then
1404       AC_DEFINE(HAVE_CUPS_API_1_6, 1,
1405                 [Define to 1 if CUPS 1.6 API is available])
1406
1407     fi
1408
1409     AC_SUBST(CUPS_API_MAJOR)
1410     AC_SUBST(CUPS_API_MINOR)
1411     AC_SUBST(CUPS_CFLAGS)
1412     AC_SUBST(CUPS_LIBS)
1413
1414     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1415
1416     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1417     AM_CONDITIONAL(HAVE_CUPS, true)
1418
1419     gtk_save_cflags="$CFLAGS"
1420     CFLAGS="$CUPS_CFLAGS"
1421     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1422                                        [[http_t http; char *s = http.authstring;]])],
1423                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1424                                  [Define if cups http_t authstring field is accessible])],
1425                       [])
1426     CFLAGS="$gtk_save_cflags"
1427
1428     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1429
1430     gtk_save_libs="$LIBS"
1431     LIBS="$CUPS_LIBS"
1432     AC_CHECK_FUNCS(httpGetAuthString)
1433     LIBS="$gtk_save_libs"
1434   fi
1435 fi
1436
1437 # Checks to see if we should compile with PAPI backend for GTK+
1438 #
1439
1440 AC_ARG_ENABLE(papi,
1441               [AS_HELP_STRING([--disable-papi],
1442                               [disable papi print backend])],,
1443               [enable_papi=auto])
1444
1445 if test "x$enable_papi" = "xno"; then
1446   AM_CONDITIONAL(HAVE_PAPI, false)
1447 else
1448   AC_MSG_CHECKING(libpapi)
1449   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1450   if test $have_papi = yes; then
1451     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1452     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1453   fi
1454   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1455   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1456     AC_MSG_ERROR([
1457 *** papi not found.
1458 ])
1459   fi
1460 fi
1461
1462 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1463
1464 gtk_save_cppflags="$CPPFLAGS"
1465 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1466
1467 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1468 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1469 *** backend enabled.]))
1470
1471 if test "$os_win32" != "yes"; then
1472   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1473 *** Can't find cairo-ps.h. You must build Cairo with the
1474 *** postscript backend enabled.]))
1475
1476   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1477 *** Cannot find cairo-svg.h. You must build Cairo with the
1478 *** svg backend enabled.]))
1479 fi
1480
1481 CPPFLAGS="$gtk_save_cppflags"
1482
1483
1484 AC_ARG_ENABLE(test-print-backend,
1485               [AS_HELP_STRING([--enable-test-print-backend],
1486                               [build test print backend])],,
1487               [enable_test_print_backend=no])
1488 if test "x$enable_test_print_backend" != "xno" ; then
1489   PRINT_BACKENDS="$PRINT_BACKENDS test"
1490 fi
1491 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1492
1493 if test "$os_win32" = "yes"; then
1494   AC_CHECK_TYPES([IPrintDialogCallback],[],[],[[#include <windows.h>]])
1495 fi
1496
1497 ################################################################
1498 # Strip -export-dynamic from the link lines of various libraries
1499 ################################################################
1500
1501 #
1502 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1503 #  but this flag is only meaningful for executables. For libraries
1504 #  the effect is undefined; what it causes on Linux is that the
1505 #  export list from -export-symbols-regex is ignored and everything
1506 #  is exported
1507 #
1508 # We are using gmodule-no-export now, but I'm leaving the stripping
1509 # code in place for now, since pango and atk still require gmodule.
1510 export SED
1511 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1512 if test -n "$export_dynamic"; then
1513   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1514   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1515 fi
1516
1517 #############
1518 # GSettings #
1519 #############
1520
1521 GLIB_GSETTINGS
1522
1523 ##################################################
1524 # GObject introspection
1525 ##################################################
1526
1527 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1528
1529 ##################################################
1530 # Packagekit module
1531 #################################################
1532
1533 AC_ARG_ENABLE(packagekit,
1534               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1535                               [build PackageKit open-with module [default=auto]])],
1536               [enable_packagekit="$enableval"],
1537               [enable_packagekit=auto])
1538 if test "$enable_packagekit" = "auto"; then
1539   if test "$os_win32" = "yes"; then
1540     enable_packagekit=no
1541   else
1542     enable_packagekit=yes
1543   fi
1544 fi
1545
1546 AC_MSG_CHECKING([whether to use PackageKit])
1547 build_packagekit=no
1548 if test "x$enable_packagekit" != "xno"; then
1549   if test "$os_win32" != "yes"; then
1550     build_packagekit=yes
1551     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1552   else
1553     AC_MSG_ERROR([packagekit support is not available on win32])
1554   fi
1555 fi
1556 AC_MSG_RESULT([$build_packagekit])
1557
1558 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1559
1560 ##################################################
1561 # colord module
1562 #################################################
1563
1564 AC_ARG_ENABLE(colord,
1565               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1566                               [build colord support code [default=auto]])],
1567               [enable_colord="$enableval"],
1568               [enable_colord=auto])
1569
1570 AC_MSG_CHECKING([whether to use colord])
1571 if test "$enable_colord" = "auto"; then
1572   if test "$os_win32" = "yes"; then
1573     enable_colord=no
1574   fi
1575 fi
1576 if test "$enable_colord" != "no"; then
1577   AC_MSG_RESULT([yes])
1578 else
1579   AC_MSG_RESULT([no])
1580 fi
1581
1582 have_colord=no
1583 if test "$enable_colord" != "no"; then
1584         if test "$os_win32" != "yes"; then
1585                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1586                                   have_colord=yes, have_colord=no)
1587                 if test "$enable_colord" = "yes"; then
1588                         if test "$have_colord" = "no"; then
1589                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1590                         fi
1591                 fi
1592         else
1593                 AC_MSG_ERROR([colord support is not available on win32])
1594         fi
1595 fi
1596
1597 if test "$have_colord" = "yes"; then
1598         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1599 fi
1600 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1601
1602 ##################################################
1603 # Checks for gtk-doc and docbook-tools
1604 ##################################################
1605
1606 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1607
1608 AC_ARG_ENABLE(man,
1609               [AS_HELP_STRING([--enable-man],
1610                               [generate man pages [default=auto]])],,
1611               enable_man=maybe)
1612
1613 if test "$enable_man" != no; then
1614   AC_PATH_PROG([XSLTPROC], [xsltproc])
1615   if test -z "$XSLTPROC"; then
1616     if test "$enable_man" = yes ; then
1617       AC_MSG_ERROR([xsltproc is required for --enable-man])
1618     fi
1619     enable_man=no
1620   fi
1621 fi
1622
1623 if test "$enable_man" != no; then
1624   dnl check for DocBook DTD in the local catalog
1625   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1626      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
1627   if test "$have_docbook_dtd" != yes; then
1628     if test "$enable_man" = yes ; then
1629       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
1630     fi
1631     enable_man=no
1632   fi
1633 fi
1634
1635 if test "$enable_man" != no; then
1636   dnl check for DocBook XSL stylesheets in the local catalog
1637   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1638      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
1639   if test "$have_docbook_dtd" != yes; then
1640     if test "$enable_man" = yes ; then
1641       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
1642     fi
1643     enable_man=no
1644   fi
1645 fi
1646
1647 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
1648
1649 AC_MSG_CHECKING([whether to generate man pages])
1650 if test "$enable_man" != no; then
1651   AC_MSG_RESULT([yes])
1652 else
1653   AC_MSG_RESULT([no])
1654 fi
1655
1656 ##################################################
1657 # Output commands
1658 ##################################################
1659
1660 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1661         outfile=gdkconfig.h-tmp
1662         cat > $outfile <<\_______EOF
1663 /* gdkconfig.h
1664  *
1665  * This is a generated file.  Please modify `configure.ac'
1666  */
1667
1668 #ifndef __GDKCONFIG_H__
1669 #define __GDKCONFIG_H__
1670
1671 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1672 #error "Only <gdk/gdk.h> can be included directly."
1673 #endif
1674
1675 #include <glib.h>
1676
1677 G_BEGIN_DECLS
1678
1679 _______EOF
1680
1681         cat >>$outfile <<_______EOF
1682 $gdk_windowing
1683 _______EOF
1684
1685         cat >>$outfile <<_______EOF
1686
1687 G_END_DECLS
1688
1689 #endif  /* __GDKCONFIG_H__ */
1690 _______EOF
1691
1692
1693         if cmp -s $outfile gdk/gdkconfig.h; then
1694           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1695           rm -f $outfile
1696         else
1697           mv $outfile gdk/gdkconfig.h
1698         fi
1699 ],[
1700 gdk_windowing='$GDK_WINDOWING'
1701 ])
1702
1703 dnl
1704 dnl Check for -Bsymbolic-functions linker flag used to avoid
1705 dnl intra-library PLT jumps, if available.
1706 dnl
1707 AC_ARG_ENABLE(Bsymbolic,
1708               [AS_HELP_STRING([--disable-Bsymbolic],
1709                               [avoid linking with -Bsymbolic])],,
1710               [SAVED_LDFLAGS="${LDFLAGS}"
1711                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1712                LDFLAGS=-Wl,-Bsymbolic-functions
1713                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1714                                                [[int main (void) { return 0; }]])],
1715                               [AC_MSG_RESULT(yes)
1716                                enable_Bsymbolic=yes],
1717                               [AC_MSG_RESULT(no)
1718                                enable_Bsymbolic=no])
1719                LDFLAGS="${SAVED_LDFLAGS}"])
1720
1721 if test "x${enable_Bsymbolic}" = "xyes" ; then
1722   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1723 fi
1724 AC_SUBST(GTK_LINK_FLAGS)
1725
1726 AC_CONFIG_FILES([
1727 config.h.win32
1728 gtk-zip.sh
1729 Makefile
1730 gdk-3.0.pc
1731 gtk+-3.0.pc
1732 gtk+-unix-print-3.0.pc
1733 gail-3.0.pc
1734 m4macros/Makefile
1735 po/Makefile.in
1736 po-properties/Makefile.in
1737 demos/Makefile
1738 demos/gtk-demo/Makefile
1739 demos/gtk-demo/geninclude.pl
1740 demos/pixbuf-demo/Makefile
1741 demos/widget-factory/Makefile
1742 examples/Makefile
1743 tests/Makefile
1744 tests/a11y/Makefile
1745 tests/css/Makefile
1746 tests/css/parser/Makefile
1747 tests/reftests/Makefile
1748 tests/visuals/Makefile
1749 docs/Makefile
1750 docs/reference/Makefile
1751 docs/reference/gdk/Makefile
1752 docs/reference/gdk/version.xml
1753 docs/reference/gtk/Makefile
1754 docs/reference/gtk/gtk3.types
1755 docs/reference/gtk/version.xml
1756 docs/reference/libgail-util/Makefile
1757 docs/reference/libgail-util/version.xml
1758 docs/tools/Makefile
1759 build/Makefile
1760 build/win32/Makefile
1761 build/win32/vs9/Makefile
1762 build/win32/vs10/Makefile
1763 gdk/Makefile
1764 gdk/broadway/Makefile
1765 gdk/x11/Makefile
1766 gdk/win32/Makefile
1767 gdk/win32/rc/Makefile
1768 gdk/win32/rc/gdk.rc
1769 gdk/quartz/Makefile
1770 gdk/wayland/Makefile
1771 gdk/tests/Makefile
1772 gdk/gdkversionmacros.h
1773 gtk/Makefile
1774 gtk/makefile.msc
1775 gtk/gtkversion.h
1776 gtk/gtk-win32.rc
1777 gtk/a11y/Makefile
1778 gtk/tests/Makefile
1779 libgail-util/Makefile
1780 modules/Makefile
1781 modules/engines/Makefile
1782 modules/engines/pixbuf/Makefile
1783 modules/input/Makefile
1784 modules/printbackends/Makefile
1785 modules/printbackends/cups/Makefile
1786 modules/printbackends/lpr/Makefile
1787 modules/printbackends/file/Makefile
1788 modules/printbackends/papi/Makefile
1789 modules/printbackends/test/Makefile
1790 perf/Makefile
1791 ])
1792
1793 AC_OUTPUT
1794
1795 # beautify the immodule list a bit
1796 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1797 if test -z "${included_immodules}"; then included_immodules="none"; fi
1798
1799 echo ""
1800 echo "        GTK+ $GTK_VERSION"
1801 echo "        ==========="
1802 echo ""
1803 echo "        GDK backends:         $GDK_BACKENDS"
1804 if test "$enable_x11_backend" = "yes"; then
1805 echo "        X11 extensions:       $X_EXTENSIONS"
1806 fi
1807 echo "        Print backends:       $PRINT_BACKENDS"
1808 echo "        Dynamic modules:      $build_dynamic_modules"
1809 echo "        Included immodules:   $included_immodules"
1810 echo "        PackageKit support:   $build_packagekit"
1811 echo "        colord support:       $have_colord"
1812 echo "        Introspection:        $found_introspection"
1813 echo "        Debugging:            $enable_debug"
1814 echo "        Documentation:        $enable_gtk_doc"