Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [2])
  12 m4_define([gtk_minor_version], [99])
  13 m4_define([gtk_micro_version], [4])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.27.5])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.29.2])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.21.0])
  46 GLIB_REQUIRED_VERSION=glib_required_version
  47 PANGO_REQUIRED_VERSION=pango_required_version
  48 ATK_REQUIRED_VERSION=atk_required_version
  49 CAIRO_REQUIRED_VERSION=cairo_required_version
  50 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  51 AC_SUBST(GLIB_REQUIRED_VERSION)
  52 AC_SUBST(PANGO_REQUIRED_VERSION)
  53 AC_SUBST(ATK_REQUIRED_VERSION)
  54 AC_SUBST(CAIRO_REQUIRED_VERSION)
  55 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  56
  57
  58 # Save this value here, since automake will set cflags later
  59 cflags_set=${CFLAGS+set}
  60
  61 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  62 AM_MAINTAINER_MODE([enable])
  63
  64 # Support silent build rules, requires at least automake-1.11. Disable
  65 # by either passing --disable-silent-rules to configure or passing V=1
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 #
  70 # For each of the libraries we build, we define the following
  71 # substituted variables:
  72 #
  73 # foo_PACKAGES:     pkg-config packages this library requires
  74 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  75 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  76 # foo_DEP_LIBS:     All libraries this module requires
  77 # foo_DEP_CFLAGS:   All cflags this module requires
  78
  79
  80 GTK_MAJOR_VERSION=gtk_major_version
  81 GTK_MINOR_VERSION=gtk_minor_version
  82 GTK_MICRO_VERSION=gtk_micro_version
  83 GTK_INTERFACE_AGE=gtk_interface_age
  84 GTK_BINARY_AGE=gtk_binary_age
  85 GTK_VERSION=gtk_version
  86 GTK_API_VERSION=gtk_api_version
  87 GTK_BINARY_VERSION=gtk_binary_version
  88 AC_SUBST(GTK_MAJOR_VERSION)
  89 AC_SUBST(GTK_MINOR_VERSION)
  90 AC_SUBST(GTK_MICRO_VERSION)
  91 AC_SUBST(GTK_INTERFACE_AGE)
  92 AC_SUBST(GTK_BINARY_AGE)
  93 AC_SUBST(GTK_API_VERSION)
  94 AC_SUBST(GTK_VERSION)
  95 AC_SUBST(GTK_BINARY_VERSION)
  96
  97 # libtool versioning
  98 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  99 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 100 #LT_REVISION=$GTK_INTERFACE_AGE
 101 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 102 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 103
 104 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 105 m4_define([lt_revision], [gtk_interface_age])
 106 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 107 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 108 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 109 AC_SUBST(LT_VERSION_INFO)
 110 AC_SUBST(LT_CURRENT_MINUS_AGE)
 111
 112 m4_define([gail_lt_current],[0])
 113 m4_define([gail_lt_revision],[0])
 114 m4_define([gail_lt_age],[0])
 115 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 116 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 117 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 118 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 119
 120 # Checks for programs.
 121 AC_PROG_CC
 122 AC_PROG_CC_C_O
 123 AC_PROG_CC_STDC
 124 AC_PROG_INSTALL
 125 AC_PROG_MAKE_SET
 126
 127
 128 GETTEXT_PACKAGE=gtk30
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 131                    [The prefix for our gettext translation domains.])
 132
 133 AC_CANONICAL_HOST
 134
 135 MATH_LIB=-lm
 136 AC_MSG_CHECKING([for native Win32])
 137 LIB_EXE_MACHINE_FLAG=X86
 138 EXE_MANIFEST_ARCHITECTURE=X86
 139 case "$host" in
 140   *-*-mingw*)
 141     os_win32=yes
 142     gio_can_sniff=no
 143     MATH_LIB=
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       EXE_MANIFEST_ARCHITECTURE=AMD64
 148       ;;
 149     esac
 150     ;;
 151   *)
 152     os_win32=no
 153     ;;
 154 esac
 155 AC_MSG_RESULT([$os_win32])
 156
 157 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 158 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 159
 160 case $host in
 161   *-*-linux*)
 162     os_linux=yes
 163     ;;
 164 esac
 165
 166 dnl
 167 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 168 dnl We use this for an automated test for C++ header correctness.
 169 dnl
 170 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 171 AC_LANG_PUSH([C++])
 172
 173 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 174 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 175
 176 gtk_save_cxxflags="$CXXFLAGS"
 177 CXXFLAGS="$CXXFLAGS -x objective-c++"
 178 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 179 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 180 CXXFLAGS="$gtk_save_cxxflags"
 181 AC_LANG_POP([C++])
 182
 183 if test "$os_win32" = "yes"; then
 184   if test x$enable_static = xyes -o x$enable_static = x; then
 185     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 186     enable_static=no
 187   fi
 188   if test x$enable_shared = xno; then
 189     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 190   fi
 191   enable_shared=yes
 192 fi
 193
 194 dnl Initialize libtool
 195 LT_PREREQ([2.2.6])
 196 LT_INIT([disable-static win32-dll])
 197 # Create libtool early, because it's used in configure
 198 LT_OUTPUT
 199
 200 # Make sure we use 64-bit versions of various file stuff.
 201 AC_SYS_LARGEFILE
 202
 203 AM_PROG_AS
 204 AC_PATH_PROG(NM, nm, nm)
 205
 206 AC_MSG_CHECKING([for some Win32 platform])
 207 case "$host" in
 208   *-*-mingw*|*-*-cygwin*)
 209     platform_win32=yes
 210     ;;
 211   *)
 212     platform_win32=no
 213     ;;
 214 esac
 215 AC_MSG_RESULT([$platform_win32])
 216 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 217
 218 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 219 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 220 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 221
 222 if test "$os_win32" = "yes"; then
 223   AC_CHECK_TOOL(WINDRES, windres, no)
 224   if test "$WINDRES" = no; then
 225     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 226   fi
 227   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 228 fi
 229 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 230
 231 m4_define([debug_default],
 232           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 233
 234 dnl declare --enable-* args and collect ac_help strings
 235 AC_ARG_ENABLE(debug,
 236               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 237                              [turn on debugging @<:@default=debug_default@:>@]),,
 238               enable_debug=debug_default)
 239
 240 AC_ARG_ENABLE(rebuilds,
 241               [AC_HELP_STRING([--disable-rebuilds],
 242                               [disable all source autogeneration rules])],,
 243               [enable_rebuilds=yes])
 244
 245 AC_ARG_ENABLE(gtk2-dependency,
 246               AC_HELP_STRING([--enable-gtk2-dependency],
 247                              [Do not build gtk-update-icon-cache and other shared tools]),,
 248               [enable_gtk2_dependency=no])
 249
 250 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 251
 252 AC_ARG_ENABLE(xkb,
 253               [AC_HELP_STRING([--enable-xkb],
 254                               [support XKB extension [default=maybe]])],,
 255               [enable_xkb="maybe"])
 256 AC_ARG_ENABLE(xinerama,
 257               [AC_HELP_STRING([--enable-xinerama],
 258                               [support Xinerama extension if available [default=maybe]])],,
 259               [enable_xinerama="maybe"])
 260 AC_ARG_ENABLE(xinput,
 261               [AC_HELP_STRING([--enable-xinput],
 262                               [support XInput extension if available [default=yes]])],,
 263               [enable_xinput="maybe"])
 264 AC_ARG_ENABLE(xrandr,
 265               [AC_HELP_STRING([--enable-xrandr],
 266                               [support XRandR extension if available [default=maybe]])],,
 267               [enable_xrandr="maybe"])
 268 AC_ARG_ENABLE(xfixes,
 269               [AC_HELP_STRING([--enable-xfixes],
 270                               [support XFixes extension if available [default=maybe]])],,
 271               [enable_xfixes="maybe"])
 272 AC_ARG_ENABLE(xcomposite,
 273               [AC_HELP_STRING([--enable-xcomposite],
 274                               [support X Composite extension if available [default=maybe]])],,
 275               [enable_xcomposite="maybe"])
 276 AC_ARG_ENABLE(xdamage,
 277               [AC_HELP_STRING([--enable-xdamage],
 278                               [support X Damage extension if available [default=maybe]])],,
 279               [enable_xdamage="maybe"])
 280
 281 AC_ARG_ENABLE(x11-backend,
 282               [AC_HELP_STRING([--enable-x11-backend],
 283                               [enable the X11 gdk backend])],
 284                               [backend_set=yes])
 285 AC_ARG_ENABLE(win32-backend,
 286               [AC_HELP_STRING([--enable-win32-backend],
 287                               [enable the Win32 gdk backend])],
 288                               [backend_set=yes])
 289 AC_ARG_ENABLE(quartz-backend,
 290               [AC_HELP_STRING([--enable-quartz-backend],
 291                               [enable the quartz gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(wayland-backend,
 294               [AC_HELP_STRING([--enable-wayland-backend],
 295                               [enable the wayland gdk backend])],
 296                               [backend_set=yes])
 297
 298 if test -z "$backend_set"; then
 299   if test "$platform_win32" = yes; then
 300     enable_win32_backend=yes
 301   else
 302     enable_x11_backend=yes
 303   fi
 304 fi
 305
 306 cairo_backends=
 307 backend_immodules=
 308 GDK_BACKENDS=
 309 GDK_EXTRA_LIBS=
 310 GDK_EXTRA_CFLAGS=
 311 GDK_WINDOWING=
 312 GIO_PACKAGE=gio-2.0
 313 PANGO_PACKAGES="pango pangocairo"
 314
 315 if test "x$enable_x11_backend" == xyes; then
 316   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 317   # backend names are identical.
 318   cairo_backends="$cairo_backends cairo-xlib"
 319   GDK_BACKENDS="$GDK_BACKENDS x11"
 320   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 321   # gdkapplaunchcontext-x11.c
 322   GIO_PACKAGE=gio-unix-2.0
 323   backend_immodules="$backend_immodules,xim"
 324   GDK_WINDOWING="$GDK_WINDOWING
 325 #define GDK_WINDOWING_X11"
 326 fi
 327
 328 if test "x$enable_win32_backend" == xyes; then
 329   cairo_backends="$cairo_backends cairo-win32"
 330   GDK_BACKENDS="$GDK_BACKENDS win32"
 331   backend_immodules="$backend_immodules,ime"
 332   GDK_WINDOWING="$GDK_WINDOWING
 333 #define GDK_WINDOWING_WIN32"
 334   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 335   AM_CONDITIONAL(USE_WIN32, true)
 336   PANGO_PACKAGES="pangowin32 pangocairo"
 337 else
 338   AM_CONDITIONAL(USE_WIN32, false)
 339 fi
 340
 341 if test "x$enable_quartz_backend" == xyes; then
 342   cairo_backends="$cairo_backends cairo-quartz"
 343   GDK_BACKENDS="$GDK_BACKENDS quartz"
 344   GDK_WINDOWING="$GDK_WINDOWING
 345 #define GDK_WINDOWING_QUARTZ"
 346   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 347   AM_CONDITIONAL(USE_QUARTZ, true)
 348 else
 349   AM_CONDITIONAL(USE_QUARTZ, false)
 350 fi
 351
 352 if test "x$enable_wayland_backend" == "xyes"; then
 353   # Wayland uses cairo-gl
 354   cairo_backends="$cairo_backends cairo-gl"
 355   GDK_BACKENDS="$GDK_BACKENDS wayland"
 356   GIO_PACKAGE=gio-unix-2.0
 357   GDK_WINDOWING="$GDK_WINDOWING
 358 #define GDK_WINDOWING_WAYLAND"
 359   WAYLAND_PACKAGES="wayland-client xkbcommon"
 360   AM_CONDITIONAL(USE_WAYLAND, true)
 361 else
 362   AM_CONDITIONAL(USE_WAYLAND, false)
 363 fi
 364
 365 # strip leading space
 366 GDK_BACKENDS=${GDK_BACKENDS/# }
 367
 368 AC_SUBST(GDK_BACKENDS)
 369
 370 if test -z "$GDK_BACKENDS"; then
 371   AC_MSG_ERROR([No GDK backends selected.])
 372 fi
 373
 374 if test "x$enable_debug" = "xyes"; then
 375   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 376   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 377 else
 378   if test "x$enable_debug" = "xno"; then
 379     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 380   else
 381     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 382   fi
 383 fi
 384
 385
 386 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 387                    [Define if debugging is enabled])
 388
 389
 390 # Build time sanity check...
 391 AM_SANITY_CHECK
 392
 393 changequote(,)dnl
 394 if test "x$GCC" = "xyes"; then
 395   case " $CFLAGS " in
 396   *[\ \ ]-Wall[\ \      ]*) ;;
 397   *) CFLAGS="$CFLAGS -Wall" ;;
 398   esac
 399
 400   if test "x$enable_ansi" = "xyes"; then
 401     case " $CFLAGS " in
 402     *[\ \       ]-ansi[\ \      ]*) ;;
 403     *) CFLAGS="$CFLAGS -ansi" ;;
 404     esac
 405
 406     case " $CFLAGS " in
 407     *[\ \       ]-pedantic[\ \  ]*) ;;
 408     *) CFLAGS="$CFLAGS -pedantic" ;;
 409     esac
 410   fi
 411 fi
 412 changequote([,])dnl
 413
 414 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 415
 416 # Ensure MSVC-compatible struct packing convention is used when
 417 # compiling for Win32 with gcc.
 418 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 419 # gcc2 uses "-fnative-struct".
 420 if test x"$os_win32" = xyes; then
 421   if test x"$GCC" = xyes; then
 422     msnative_struct=''
 423     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 424     if test -z "$ac_cv_prog_CC"; then
 425       our_gcc="$CC"
 426     else
 427       our_gcc="$ac_cv_prog_CC"
 428     fi
 429     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 430       2.)
 431         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 432           msnative_struct='-fnative-struct'
 433         fi
 434         ;;
 435       *)
 436         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 437           msnative_struct='-mms-bitfields'
 438         fi
 439         ;;
 440     esac
 441     if test x"$msnative_struct" = x ; then
 442       AC_MSG_RESULT([no way])
 443       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 444     else
 445       CFLAGS="$CFLAGS $msnative_struct"
 446       AC_MSG_RESULT([${msnative_struct}])
 447     fi
 448   fi
 449 fi
 450
 451 ## Initial sanity check, done here so that users get told they
 452 ## have the wrong dependencies as early in the process as possible.
 453 ## Later on we actually use the cflags/libs from separate pkg-config
 454 ## calls. Oh, also the later pkg-config calls don't include
 455 ## the version requirements since those make the module lists
 456 ## annoying to construct
 457 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 458   [glib-2.0 >= glib_required_version dnl
 459    atk >= atk_required_version dnl
 460    pango >= pango_required_version dnl
 461    cairo >= cairo_required_version dnl
 462    cairo-gobject >= cairo_required_version dnl
 463    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 464
 465 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 466
 467 if test "$os_win32" != yes; then
 468     # libtool option to control which symbols are exported
 469     # right now, symbols starting with _ are not exported
 470     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 471 else
 472     # We currently use .def files on Windows (for gdk and gtk)
 473     LIBTOOL_EXPORT_OPTIONS=
 474 fi
 475 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 476
 477 dnl ******************************************************
 478 dnl * See whether to include shared library dependencies *
 479 dnl ******************************************************
 480
 481 AC_ARG_ENABLE(explicit-deps,
 482               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 483                               [use explicit dependencies in .pc files [default=auto]])],,
 484               [enable_explicit_deps=auto])
 485
 486 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 487 case $enable_explicit_deps in
 488   auto)
 489     export SED
 490     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 491     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 492       enable_explicit_deps=yes
 493     else
 494       enable_explicit_deps=no
 495     fi
 496   ;;
 497   yes|no)
 498   ;;
 499   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 500   ;;
 501 esac
 502 AC_MSG_RESULT($enable_explicit_deps)
 503
 504 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 505
 506 # define a MAINT-like variable REBUILD which is set if Perl
 507 # and awk are found, so autogenerated sources can be rebuilt
 508
 509 AC_PATH_PROGS(PERL, perl5 perl)
 510
 511 # We would like indent, but don't require it.
 512 AC_CHECK_PROG(INDENT, indent, indent)
 513
 514 REBUILD=\#
 515 if test "x$enable_rebuilds" = "xyes" && \
 516      test -n "$PERL" && \
 517      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 518   REBUILD=
 519 fi
 520 AC_SUBST(REBUILD)
 521
 522 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 523 AC_CHECK_FUNCS(localtime_r)
 524
 525 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 526 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 527 AC_TRY_LINK([#include <langinfo.h>], [
 528 char c;
 529 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 530 ], gtk_ok=yes, gtk_ok=no)
 531 AC_MSG_RESULT($gtk_ok)
 532 if test "$gtk_ok" = "yes"; then
 533   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 534             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 535 fi
 536
 537 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 538 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 539 AC_TRY_LINK([#include <langinfo.h>], [
 540 char c;
 541 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 542 ], gtk_ok=yes, gtk_ok=no)
 543 AC_MSG_RESULT($gtk_ok)
 544 if test "$gtk_ok" = "yes"; then
 545   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 546             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 547 fi
 548
 549 # _NL_PAPER_HEIGHT is an enum and not a define
 550 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 551 AC_TRY_LINK([#include <langinfo.h>], [
 552 char c;
 553 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 554 ], gtk_ok=yes, gtk_ok=no)
 555 AC_MSG_RESULT($gtk_ok)
 556 if test "$gtk_ok" = "yes"; then
 557   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 558             [Define if _NL_PAPER_HEIGHT is available])
 559 fi
 560
 561 # _NL_PAPER_WIDTH is an enum and not a define
 562 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 563 AC_TRY_LINK([#include <langinfo.h>], [
 564 char c;
 565 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 566 ], gtk_ok=yes, gtk_ok=no)
 567 AC_MSG_RESULT($gtk_ok)
 568 if test "$gtk_ok" = "yes"; then
 569   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 570             [Define if _NL_PAPER_WIDTH is available])
 571 fi
 572
 573 # i18n stuff
 574 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 575 AM_GLIB_GNU_GETTEXT
 576 LIBS="$LIBS $INTLLIBS"
 577 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 578         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 579       esac])
 580
 581 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 582 dnl po-properties/POTFILES during configure; see GNOME #573515.
 583 dnl
 584 dnl Generate list of files to be processed by xgettext which will
 585 dnl be included in po-properties/Makefile.
 586 test -d po-properties || mkdir po-properties
 587 if test "x$srcdir" != "x."; then
 588   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 589     popropsrcprefix="$srcdir/"
 590   else
 591     popropsrcprefix="../$srcdir/"
 592   fi
 593 else
 594   popropsrcprefix="../"
 595 fi
 596 rm -f po-properties/POTFILES
 597 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 598 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 599 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 600
 601 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 602
 603 dnl The DU4 header files don't provide library prototypes unless
 604 dnl -std1 is given to the native cc.
 605 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 606
 607 gtk_save_LIBS=$LIBS
 608 LIBS="$LIBS -lm"
 609 AC_TRY_RUN([#include <math.h>
 610              int main (void) { return (log(1) != log(1.)); }],
 611      AC_MSG_RESULT(none needed),
 612      gtk_save_CFLAGS="$CFLAGS"
 613      CFLAGS="$CFLAGS -std1"
 614      AC_TRY_RUN([#include <math.h>
 615                  int main (void) { return (log(1) != log(1.)); }],
 616          AC_MSG_RESULT(-std1),
 617          AC_MSG_RESULT()
 618          CFLAGS="$gtk_save_CFLAGS"
 619          AC_MSG_WARN(
 620                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 621          true
 622      ),
 623      AC_MSG_RESULT(none needed)
 624 )
 625 LIBS=$gtk_save_LIBS
 626
 627 AC_MSG_CHECKING(for the BeOS)
 628 case $host in
 629   *-*-beos*)
 630     AC_MSG_RESULT(yes)
 631     MATH_LIB=
 632   ;;
 633   *)
 634     AC_MSG_RESULT(no)
 635   ;;
 636 esac
 637
 638 AC_SUBST(MATH_LIB)
 639 #
 640 # see bug 162979
 641 #
 642 AC_MSG_CHECKING(for HP-UX)
 643 case $host_os in
 644   hpux9* | hpux10* | hpux11*)
 645     AC_MSG_RESULT(yes)
 646     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 647   ;;
 648   *)
 649     AC_MSG_RESULT(no)
 650   ;;
 651 esac
 652
 653 dnl NeXTStep cc seems to need this
 654 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 655 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 656   AC_MSG_RESULT(none needed),
 657   gtk_save_CFLAGS="$CFLAGS"
 658   CFLAGS="$CFLAGS -posix"
 659   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 660     AC_MSG_RESULT(-posix),
 661     AC_MSG_RESULT()
 662     CFLAGS="$gtk_save_CFLAGS"
 663     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 664
 665 #
 666 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 667 #
 668
 669 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 670
 671 AM_PATH_GLIB_2_0(glib_required_version, :,
 672   AC_MSG_ERROR([
 673 *** GLIB glib_required_version or better is required. The latest version of
 674 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 675   gobject gmodule-no-export gthread)
 676
 677 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 678 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 679 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 680 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 681   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 682 fi
 683
 684 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 685
 686
 687 dnl
 688 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 689 dnl
 690 gtk_save_LIBS=$LIBS
 691 LIBS="$LIBS $GLIB_LIBS"
 692 AC_CHECK_FUNCS(bind_textdomain_codeset)
 693 LIBS=$gtk_save_LIBS
 694
 695 AC_CHECK_HEADERS(pwd.h,
 696                  AC_DEFINE(HAVE_PWD_H, 1,
 697                            [Define to 1 if pwd.h is available]))
 698 AC_CHECK_HEADERS(sys/time.h,
 699                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 700                            [Define to 1 if time.h is available]))
 701 AC_CHECK_HEADERS(unistd.h,
 702                  AC_DEFINE(HAVE_UNISTD_H, 1,
 703                            [Define to 1 if unistd.h is available]))
 704 AC_CHECK_HEADERS(ftw.h,
 705                  AC_DEFINE(HAVE_FTW_H, 1,
 706                            [Define to 1 if ftw.h is available]))
 707
 708 AC_MSG_CHECKING([for GNU ftw extensions])
 709 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 710 #define _GNU_SOURCE
 711 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 712 if test $gtk_ok = yes; then
 713     AC_MSG_RESULT([yes])
 714     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 715 else
 716     AC_MSG_RESULT([no])
 717 fi
 718
 719 saved_cflags="$CFLAGS"
 720 saved_ldflags="$LDFLAGS"
 721
 722
 723 # Checks for header files.
 724 AC_HEADER_STDC
 725
 726 # Checks for typedefs, structures, and compiler characteristics.
 727 AC_C_CONST
 728
 729 # Checks for library functions.
 730 AC_TYPE_SIGNAL
 731 AC_FUNC_MMAP
 732
 733 AC_CHECK_FUNCS(mallinfo)
 734 AC_CHECK_FUNCS(getresuid)
 735 AC_TYPE_UID_T
 736
 737 # Check if <sys/select.h> needs to be included for fd_set
 738 AC_MSG_CHECKING([for fd_set])
 739 AC_TRY_COMPILE([#include <sys/types.h>],
 740         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 741 if test $gtk_ok = yes; then
 742     AC_MSG_RESULT([yes, found in sys/types.h])
 743 else
 744     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 745     if test $gtk_ok = yes; then
 746         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 747                   [Define to 1 if sys/select.h is available])
 748         AC_MSG_RESULT([yes, found in sys/select.h])
 749     else
 750         AC_DEFINE(NO_FD_SET, 1,
 751                   [Define to 1 if fd_set is not available])
 752         AC_MSG_RESULT(no)
 753     fi
 754 fi
 755
 756 # Check for uxtheme.h (for MS-Windows Engine)
 757 AC_MSG_CHECKING(for uxtheme.h)
 758 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 759 if test $gtk_uxtheme_h = yes; then
 760    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 761 fi
 762 AC_MSG_RESULT($gtk_uxtheme_h)
 763
 764 # Checks for gdkspawn
 765 AC_CHECK_HEADERS(crt_externs.h)
 766 AC_CHECK_FUNCS(_NSGetEnviron)
 767
 768 AC_MSG_CHECKING(whether to build dynamic modules)
 769
 770 AC_ARG_ENABLE(modules,
 771               [AC_HELP_STRING([--disable-modules],
 772                               [disable dynamic module loading])])
 773
 774 dynworks=false
 775 build_dynamic_modules=no
 776 deps=
 777 if test x$enable_modules = xno; then
 778     AC_MSG_RESULT(no)
 779 else
 780     AC_MSG_RESULT(yes)
 781     AC_MSG_CHECKING(whether dynamic modules work)
 782     ## for loop is to strip newline
 783     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 784     for I in $tmp; do
 785         dynworks=$I
 786     done
 787
 788     dnl Now we check to see if our libtool supports shared lib deps
 789     dnl (in a rather ugly way even)
 790     if $dynworks; then
 791         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 792         module_deplibs_check=`$module_libtool_config | \
 793             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 794             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 795         if test "x$module_deplibs_check" = "xnone" || \
 796            test "x$module_deplibs_check" = "xunknown" || \
 797            test "x$module_deplibs_check" = "x"; then
 798             dynworks=false
 799         fi
 800     fi
 801
 802     if $dynworks; then
 803         build_dynamic_modules=yes
 804         AC_DEFINE(USE_GMODULE, 1,
 805                   [Define to 1 if gmodule works and should be used])
 806         AC_MSG_RESULT(yes)
 807     else
 808         build_dynamic_modules=no
 809         AC_MSG_RESULT(no)
 810     fi
 811 fi
 812
 813 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 814
 815 #
 816 # Allow building some or all immodules included
 817 #
 818 AC_MSG_CHECKING(immodules to build)
 819
 820 dnl due to an autoconf bug, commas in the first arg to
 821 dnl AC_HELP_STRING cause problems.
 822 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 823 dnl                [build the specified input method modules into gtk])
 824 AC_ARG_WITH(included_immodules,
 825             AC_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 826                            [build the specified input methods into gtk]))
 827
 828 if $dynworks; then
 829    :
 830 else
 831    ## if the option was specified, leave it; otherwise disable included immodules
 832    if test x$with_included_immodules = xno; then
 833            with_included_immodules=yes
 834    fi
 835 fi
 836
 837 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 838
 839 included_immodules=""
 840 # If the switch specified without listing any specific ones, include all
 841 if test "x$with_included_immodules" = xyes ; then
 842   included_immodules="$all_immodules"
 843 else
 844   included_immodules="$with_included_immodules"
 845 fi
 846
 847 AC_MSG_RESULT($included_immodules)
 848 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 849
 850 INCLUDED_IMMODULE_OBJ=
 851 INCLUDED_IMMODULE_DEFINE=
 852
 853 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 854 for immodule in $included_immodules; do
 855  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 856  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 857    :
 858  else
 859    AC_MSG_ERROR([the specified input method $immodule does not exist])
 860  fi
 861
 862  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 863  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 864  eval INCLUDE_$immodule_underscores=yes
 865 done
 866 IFS="$gtk_save_ifs"
 867 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 868 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 869
 870 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 871 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 872 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 873 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 874 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 875 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 876 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 877 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 878 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 879 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 880 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 881 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 882
 883 AC_HEADER_SYS_WAIT
 884
 885 AC_TYPE_SIGNAL
 886
 887 # Checks to see whether we should include mediaLib
 888 # support.
 889 #
 890 AC_CHECK_HEADER(sys/systeminfo.h,
 891                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 892                           [Define to 1 if sys/systeminfo.h is available]))
 893 AC_CHECK_HEADER(sys/sysinfo.h,
 894                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 895                           [Define to 1 if sys/sysinfo.h is available]))
 896
 897 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 898
 899 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 900
 901 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 902   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 903   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 904     REBUILD_PNGS=#
 905   fi
 906 fi
 907
 908 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 909
 910 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 911
 912 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 913    test "x$REBUILD_PNGS" = "x#" ; then
 914      AC_MSG_ERROR([
 915 *** gtkbuiltincache.h is not in the tree, and cannot be built
 916 *** because you don't have libpng, or (when cross-compiling) you
 917 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 918 fi
 919
 920 ########################################
 921 # Windowing system checks
 922 ########################################
 923
 924 # GTK+ uses some X calls, so needs to link against X directly
 925 GTK_DEP_PACKAGES_FOR_X=
 926 GTK_DEP_LIBS_FOR_X=
 927 X_EXTENSIONS=
 928
 929 if test "x$enable_x11_backend" == xyes; then
 930   X_PACKAGES=fontconfig
 931
 932   #
 933   # We use fontconfig very peripherally when decoding the default
 934   # settings.
 935   #
 936   if $PKG_CONFIG --exists fontconfig; then : ; else
 937     AC_MSG_ERROR([
 938 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 939   fi
 940
 941   #
 942   # Check for basic X packages; we use pkg-config if available
 943   #
 944   if $PKG_CONFIG --exists x11 xext; then
 945     have_base_x_pc=true
 946     X_PACKAGES="$X_PACKAGES x11 xext"
 947     x_libs="`$PKG_CONFIG --libs x11 xext`"
 948     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 949
 950     # Strip out any .la files that pkg-config might give us (this happens
 951     # with -uninstalled.pc files)
 952     x_libs_for_checks=
 953     for I in $x_libs ; do
 954       case $I in
 955         *.la) ;;
 956         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 957       esac
 958     done
 959
 960     GTK_PACKAGES_FOR_X="x11"
 961   else
 962     have_base_x_pc=false
 963     AC_PATH_XTRA
 964     if test x$no_x = xyes ; then
 965       AC_MSG_ERROR([X development libraries not found])
 966     fi
 967
 968     x_cflags="$X_CFLAGS"
 969     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 970
 971     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 972   fi
 973
 974   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 975   x_extra_libs=
 976
 977   gtk_save_cppflags="$CPPFLAGS"
 978   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 979
 980   gtk_save_LIBS=$LIBS
 981   LIBS="$x_libs_for_checks $LIBS"
 982
 983   # Sanity check for the X11 and Xext libraries. While everything we need from
 984   # Xext is optional, the chances a system has *none* of these things is so
 985   # small that we just unconditionally require it.
 986   AC_CHECK_FUNC(XOpenDisplay, :,
 987                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 988   AC_CHECK_FUNC(XextFindDisplay, :,
 989                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 990
 991   # Check for xReply
 992
 993   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 994   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 995       [xReply *rep;],
 996       [AC_MSG_RESULT([no])],
 997       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 998 #include <X11/Xlibint.h>],
 999            [xReply *rep;],
1000            [AC_MSG_RESULT([yes])
1001             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1002                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
1003            [AC_MSG_RESULT([unknown])
1004             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1005
1006   # Check for XConvertCase, XInternAtoms (X11R6 specific)
1007
1008   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1009
1010   # Generic X11R6 check needed for XIM support; we could
1011   # probably use this to replace the above, but we'll
1012   # leave the separate checks for XConvertCase and XInternAtoms
1013   # for clarity
1014
1015   have_x11r6=false
1016   AC_CHECK_FUNC(XAddConnectionWatch,
1017       have_x11r6=true)
1018
1019   if $have_x11r6; then
1020     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1021   fi
1022   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1023
1024   # Check for XKB support.
1025
1026   if test "x$enable_xkb" = "xyes"; then
1027         AC_CHECK_FUNC(XkbQueryExtension,
1028                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1029                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1030                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1031   elif test "x$enable_xkb" = "xmaybe"; then
1032         AC_CHECK_FUNC(XkbQueryExtension,
1033                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1034                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1035   else
1036         AC_MSG_WARN(XKB support explicitly disabled)
1037   fi
1038
1039   # Check for shaped window extension
1040
1041   AC_CHECK_FUNC(XShapeCombineMask, :,
1042      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1043
1044   # X SYNC check
1045   gtk_save_CFLAGS="$CFLAGS"
1046   CFLAGS="$CFLAGS $x_cflags"
1047
1048   AC_CHECK_FUNC(XSyncQueryExtension,
1049       [AC_CHECK_HEADER(X11/extensions/sync.h,
1050           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1051           :, [#include <X11/Xlib.h>])])
1052
1053   CFLAGS="$gtk_save_CFLAGS"
1054
1055   if test "x$enable_xinerama" != "xno"; then
1056     # Check for Xinerama extension (Solaris impl or Xfree impl)
1057     have_xfree_xinerama=false
1058     have_solaris_xinerama=false
1059
1060     gtk_save_cppflags="$CPPFLAGS"
1061     CPPFLAGS="$CPPFLAGS $x_cflags"
1062
1063     # Check for XFree
1064     AC_MSG_CHECKING(for Xinerama packages)
1065
1066     if $PKG_CONFIG --exists xinerama ; then
1067        AC_MSG_RESULT(yes)
1068        have_xfree_xinerama=true
1069        X_PACKAGES="$X_PACKAGES xinerama"
1070     else
1071        AC_MSG_RESULT(no)
1072        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1073            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1074            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1075            have_xfree_xinerama=true], :,
1076            [#include <X11/Xlib.h>])])
1077     fi
1078
1079     if $have_xfree_xinerama ; then
1080       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1081       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1082                 [Define to 1 if XFree Xinerama is available])
1083       AC_DEFINE(HAVE_XINERAMA, 1,
1084                 [Define to 1 is Xinerama is available])
1085     else
1086       case "$host" in
1087         *-*-solaris*)
1088             # Check for solaris
1089             AC_MSG_CHECKING(for Xinerama support on Solaris)
1090
1091             have_solaris_xinerama=false
1092             AC_CHECK_FUNC(XineramaGetInfo,
1093                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1094                     [have_solaris_xinerama=true], :,
1095                     [#include <X11/Xlib.h>])])
1096
1097             if $have_solaris_xinerama ; then
1098               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1099               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1100                         [Define to 1 if solaris xinerama is available])
1101               AC_DEFINE(HAVE_XINERAMA, 1,
1102                         [Define to 1 if xinerama is available])
1103               AC_MSG_RESULT(yes)
1104             else
1105               AC_MSG_RESULT(no)
1106             fi
1107             ;;
1108         *)
1109             ;;
1110       esac
1111     fi
1112   fi
1113   if test "x$enable_xinerama" = "xyes" ; then
1114     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1115       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1116     fi
1117   fi
1118
1119   # set up things for XInput
1120   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1121     have_xinput=yes
1122
1123     AC_DEFINE(XINPUT_XFREE, 1,
1124               [Define to 1 if XFree XInput should be used])
1125
1126     X_PACKAGES="$X_PACKAGES xi"
1127
1128     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1129                     have_xinput2=yes
1130                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1131                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1132                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1133
1134   else
1135     AC_DEFINE(XINPUT_NONE, 1,
1136               [Define to 1 if no XInput should be used])
1137   fi
1138
1139   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1140   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1141
1142   if test "x$enable_xinput" = "xyes" ; then
1143     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1144       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1145     fi
1146   fi
1147
1148   # Check for the RANDR extension
1149   if test x"$enable_xrandr" != xno; then
1150     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1151       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1152
1153       X_PACKAGES="$X_PACKAGES xrandr"
1154       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1155     elif test x"$enable_xrandr" = xyes; then
1156       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1157     fi
1158   fi
1159
1160   # Checks for Xcursor library
1161
1162   if $PKG_CONFIG --exists xcursor ; then
1163     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1164
1165     X_PACKAGES="$X_PACKAGES xcursor"
1166   fi
1167
1168   # Checks for XFixes extension
1169
1170   if test x"$enable_xfixes" != xno; then
1171     if $PKG_CONFIG --exists xfixes ; then
1172       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1173
1174       X_PACKAGES="$X_PACKAGES xfixes"
1175       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1176       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1177     elif test x"$enable_xfixes" = xyes; then
1178       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1179     fi
1180   fi
1181
1182   # Checks for Xcomposite extension
1183
1184   if test x"$enable_xcomposite" != xno; then
1185     if $PKG_CONFIG --exists xcomposite ; then
1186       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1187
1188       X_PACKAGES="$X_PACKAGES xcomposite"
1189       X_EXTENSIONS="$X_EXTENSIONS Composite"
1190       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1191     elif test x"$enable_xcomposite" = xyes; then
1192       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1193     fi
1194   fi
1195
1196   # Checks for Xdamage extension
1197
1198   if test x"$enable_xdamage" != xno; then
1199     if $PKG_CONFIG --exists xdamage ; then
1200       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1201
1202       X_PACKAGES="$X_PACKAGES xdamage"
1203       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1204       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1205     elif test x"$enable_xdamage" = xyes; then
1206       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1207     fi
1208   fi
1209
1210   if $have_base_x_pc ; then
1211     GDK_EXTRA_LIBS="$x_extra_libs"
1212   else
1213     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1214   fi
1215
1216   CPPFLAGS="$gtk_save_cppflags"
1217   LIBS="$gtk_save_libs"
1218
1219   AM_CONDITIONAL(USE_X11, true)
1220
1221   # strip leading space
1222   X_EXTENSIONS=${X_EXTENSIONS/# }
1223
1224 else
1225   XPACKAGES=
1226
1227   AM_CONDITIONAL(XINPUT_XFREE, false)
1228   AM_CONDITIONAL(XINPUT_2, false)
1229   AM_CONDITIONAL(USE_X11, false)
1230   AM_CONDITIONAL(HAVE_X11R6, false)
1231 fi
1232
1233 # Check for Pango flags
1234
1235 AC_MSG_CHECKING(Pango flags)
1236 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1237         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1238         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1239
1240         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1241 else
1242         AC_MSG_ERROR([
1243 *** Pango not found. Pango built with Cairo support is required
1244 *** to build GTK+. See http://www.pango.org for Pango information.
1245 ])
1246 fi
1247
1248 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1249
1250 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1251         :
1252 else
1253         gtk_save_LIBS="$LIBS"
1254         LIBS="$PANGO_LIBS $LIBS"
1255         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1256 *** Can't link to Pango. Pango is required to build
1257 *** GTK+. For more information see http://www.pango.org]))
1258         LIBS="$gtk_save_LIBS"
1259 fi
1260
1261 CFLAGS="$saved_cflags"
1262 LDFLAGS="$saved_ldflags"
1263
1264 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1265
1266 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1267 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1268 #
1269 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1270 # into the pkg-config files
1271 #
1272 if test $enable_explicit_deps != yes ; then
1273   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1274   GDK_EXTRA_LIBS=
1275 fi
1276
1277 AC_SUBST(GDK_PACKAGES)
1278 AC_SUBST(GDK_EXTRA_LIBS)
1279 AC_SUBST(GDK_EXTRA_CFLAGS)
1280 AC_SUBST(GDK_DEP_LIBS)
1281 AC_SUBST(GDK_DEP_CFLAGS)
1282
1283
1284 ########################################
1285 # Check for Accessibility Toolkit flags
1286 ########################################
1287
1288 ATK_PACKAGES=atk
1289 AC_MSG_CHECKING(ATK flags)
1290 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1291         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1292         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1293
1294         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1295 else
1296         AC_MSG_ERROR([
1297 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1298 *** to build GTK+.
1299 ])
1300 fi
1301
1302 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1303         :
1304 else
1305         gtk_save_LIBS="$LIBS"
1306         LIBS="$ATK_LIBS $LIBS"
1307         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1308                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1309                 *** to build GTK+]))
1310         LIBS="$gtk_save_LIBS"
1311 fi
1312
1313 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1314 if test "x$enable_x11_backend" == xyes; then
1315   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1316 fi
1317 GTK_EXTRA_LIBS=
1318 GTK_EXTRA_CFLAGS=
1319 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1320 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1321
1322 if test x"$os_win32" = xyes; then
1323   GTK_EXTRA_CFLAGS="$msnative_struct"
1324 fi
1325
1326 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1327 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1328 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1329 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1330
1331 AC_SUBST(GTK_PACKAGES)
1332 AC_SUBST(GTK_EXTRA_LIBS)
1333 AC_SUBST(GTK_EXTRA_CFLAGS)
1334 AC_SUBST(GTK_DEP_LIBS)
1335 AC_SUBST(GTK_DEP_CFLAGS)
1336
1337 AC_SUBST(GLIB_PREFIX)
1338 AC_SUBST(ATK_PREFIX)
1339 AC_SUBST(PANGO_PREFIX)
1340 AC_SUBST(CAIRO_PREFIX)
1341
1342 AC_SUBST(GTK_DEBUG_FLAGS)
1343 AC_SUBST(GTK_XIM_FLAGS)
1344
1345 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1346 AC_SUBST(GDK_PIXBUF_LIBS)
1347
1348 ########################
1349 # Checks needed for gail
1350 ########################
1351
1352 old_LIBS="$LIBS"
1353 dnl Checks for inet libraries:
1354 AC_SEARCH_LIBS(gethostent, nsl)
1355 AC_SEARCH_LIBS(setsockopt, socket)
1356 AC_SEARCH_LIBS(connect, inet)
1357
1358 dnl check for the sockaddr_un.sun_len member
1359 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1360                 [struct_sockaddr_un_sun_len=true],
1361                 [struct_sockaddr_un_suin_len=false],
1362                 [#include <sys/types.h>
1363                  #include <sys/un.h>]
1364                 )
1365 case $struct_sockaddr_un_sun_len in
1366         true)
1367                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1368                                    [Have the sockaddr_un.sun_len member])
1369                 ;;
1370         *)
1371                 ;;
1372 esac
1373
1374 GAIL_INET_LIBS="$LIBS"
1375 AC_SUBST([GAIL_INET_LIBS])
1376
1377 LIBS="$old_LIBS"
1378
1379 ################################################################
1380 # Printing system checks
1381 ################################################################
1382
1383 PRINT_BACKENDS="file lpr"
1384
1385 AC_ARG_ENABLE(cups,
1386               [AC_HELP_STRING([--disable-cups],
1387                               [disable cups print backend])],,
1388               [enable_cups=auto])
1389
1390 if test "x$enable_cups" = "xno"; then
1391   AM_CONDITIONAL(HAVE_CUPS, false)
1392 else
1393   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1394   if test "x$CUPS_CONFIG" = "xno"; then
1395     if test "x$enable_cups" = "xauto"; then
1396       AM_CONDITIONAL(HAVE_CUPS, false)
1397     else
1398       AC_MSG_ERROR([
1399 *** cups not found.
1400 ])
1401     fi
1402   else
1403     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1404     CUPS_LIBS=`$CUPS_CONFIG --libs`
1405
1406     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1407     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1408     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1409
1410     if test $CUPS_API_MAJOR -gt 1 -o \
1411             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1412       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1413                 [Define to 1 if CUPS 1.2 API is available])
1414     fi
1415
1416     AC_SUBST(CUPS_API_MAJOR)
1417     AC_SUBST(CUPS_API_MINOR)
1418     AC_SUBST(CUPS_CFLAGS)
1419     AC_SUBST(CUPS_LIBS)
1420
1421     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1422
1423     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1424     AM_CONDITIONAL(HAVE_CUPS, true)
1425
1426     gtk_save_cflags="$CFLAGS"
1427     CFLAGS="$CUPS_CFLAGS"
1428     AC_TRY_COMPILE([#include <cups/http.h>],
1429                    [http_t http; char *s = http.authstring;],
1430                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1431                               [Define if cups http_t authstring field is accessible])],)
1432     CFLAGS="$gtk_save_cflags"
1433
1434     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1435
1436     gtk_save_libs="$LIBS"
1437     LIBS="$CUPS_LIBS"
1438     AC_CHECK_FUNCS(httpGetAuthString)
1439     LIBS="$gtk_save_libs"
1440   fi
1441 fi
1442
1443 # Checks to see if we should compile with PAPI backend for GTK+
1444 #
1445
1446 AC_ARG_ENABLE(papi,
1447               [AC_HELP_STRING([--disable-papi],
1448                               [disable papi print backend])],,
1449              [enable_papi=auto])
1450
1451 if test "x$enable_papi" = "xno"; then
1452   AM_CONDITIONAL(HAVE_PAPI, false)
1453 else
1454   AC_MSG_CHECKING(libpapi)
1455   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1456   if test $have_papi = yes; then
1457     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1458     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1459   fi
1460   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1461   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1462     AC_MSG_ERROR([
1463 *** papi not found.
1464 ])
1465   fi
1466 fi
1467
1468 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1469
1470 gtk_save_cppflags="$CPPFLAGS"
1471 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1472
1473 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1474 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1475 *** backend enabled.]))
1476
1477 if test "$os_win32" != "yes"; then
1478   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1479 *** Can't find cairo-ps.h. You must build Cairo with the
1480 *** postscript backend enabled.]))
1481
1482   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1483 *** Cannot find cairo-svg.h. You must build Cairo with the
1484 *** svg backend enabled.]))
1485 fi
1486
1487 CPPFLAGS="$gtk_save_cppflags"
1488
1489
1490 AC_ARG_ENABLE(test-print-backend,
1491               [AC_HELP_STRING([--enable-test-print-backend],
1492                               [build test print backend])],,
1493               [enable_test_print_backend=no])
1494 if test "x$enable_test_print_backend" != "xno" ; then
1495   PRINT_BACKENDS="$PRINT_BACKENDS test"
1496 fi
1497 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1498
1499
1500 ################################################################
1501 # Strip -export-dynamic from the link lines of various libraries
1502 ################################################################
1503
1504 #
1505 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1506 #  but this flag is only meaningful for executables. For libraries
1507 #  the effect is undefined; what it causes on Linux is that the
1508 #  export list from -export-symbols-regex is ignored and everything
1509 #  is exported
1510 #
1511 # We are using gmodule-no-export now, but I'm leaving the stripping
1512 # code in place for now, since pango and atk still require gmodule.
1513 export SED
1514 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1515 if test -n "$export_dynamic"; then
1516   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1517   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1518 fi
1519
1520 #############
1521 # GSettings #
1522 #############
1523
1524 GLIB_GSETTINGS
1525
1526 ##################################################
1527 # GObject introspection
1528 ##################################################
1529
1530 GOBJECT_INTROSPECTION_CHECK([0.10.1])
1531
1532 ##################################################
1533 # Packagekit module
1534 #################################################
1535
1536 AC_ARG_ENABLE(packagekit,
1537               AC_HELP_STRING([--disable-packagekit],
1538                              [build packagekit open-with module]))
1539
1540 build_packagekit=no
1541 if test "os_win32" != "yes"; then
1542         if test "x$enable_packagekit" != "xno"; then
1543                 build_packagekit=yes
1544                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1545         fi
1546 fi
1547
1548 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1549
1550 ##################################################
1551 # Checks for gtk-doc and docbook-tools
1552 ##################################################
1553
1554 GTK_DOC_CHECK([1.11])
1555
1556 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1557 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1558
1559 AC_ARG_ENABLE(man,
1560               [AC_HELP_STRING([--enable-man],
1561                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1562               enable_man=no)
1563
1564 if test "${enable_man}" != no; then
1565   dnl
1566   dnl Check for xsltproc
1567   dnl
1568   AC_PATH_PROG([XSLTPROC], [xsltproc])
1569   if test -z "$XSLTPROC"; then
1570     enable_man=no
1571   fi
1572
1573   dnl check for DocBook DTD and stylesheets in the local catalog.
1574   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1575      [DocBook XML DTD V4.1.2],,enable_man=no)
1576   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1577      [DocBook XSL Stylesheets],,enable_man=no)
1578 fi
1579
1580 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1581
1582
1583 ##################################################
1584 # Output commands
1585 ##################################################
1586
1587 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1588         outfile=gdkconfig.h-tmp
1589         cat > $outfile <<\_______EOF
1590 /* gdkconfig.h
1591  *
1592  * This is a generated file.  Please modify `configure.ac'
1593  */
1594
1595 #ifndef __GDKCONFIG_H__
1596 #define __GDKCONFIG_H__
1597
1598 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1599 #error "Only <gdk/gdk.h> can be included directly."
1600 #endif
1601
1602 #include <glib.h>
1603
1604 G_BEGIN_DECLS
1605
1606 _______EOF
1607
1608         cat >>$outfile <<_______EOF
1609 $gdk_windowing
1610 _______EOF
1611
1612         cat >>$outfile <<_______EOF
1613
1614 G_END_DECLS
1615
1616 #endif  /* __GDKCONFIG_H__ */
1617 _______EOF
1618
1619
1620         if cmp -s $outfile gdk/gdkconfig.h; then
1621           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1622           rm -f $outfile
1623         else
1624           mv $outfile gdk/gdkconfig.h
1625         fi
1626 ],[
1627 gdk_windowing='$GDK_WINDOWING'
1628 ])
1629
1630 dnl
1631 dnl Check for -Bsymbolic-functions linker flag used to avoid
1632 dnl intra-library PLT jumps, if available.
1633 dnl
1634 AC_ARG_ENABLE(Bsymbolic,
1635               [AC_HELP_STRING([--disable-Bsymbolic],
1636                               [avoid linking with -Bsymbolic])],,
1637               [SAVED_LDFLAGS="${LDFLAGS}"
1638                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1639                LDFLAGS=-Wl,-Bsymbolic-functions
1640                AC_TRY_LINK([], [int main (void) { return 0; }],
1641                            AC_MSG_RESULT(yes)
1642                            enable_Bsymbolic=yes,
1643                            AC_MSG_RESULT(no)
1644                            enable_Bsymbolic=no)
1645                LDFLAGS="${SAVED_LDFLAGS}"])
1646
1647 if test "x${enable_Bsymbolic}" = "xyes" ; then
1648   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1649 fi
1650 AC_SUBST(GTK_LINK_FLAGS)
1651
1652 AC_CONFIG_FILES([
1653 config.h.win32
1654 gtk-zip.sh
1655 Makefile
1656 gdk-3.0.pc
1657 gtk+-3.0.pc
1658 gtk+-unix-print-3.0.pc
1659 gail-3.0.pc
1660 gtk+-3.0-uninstalled.pc
1661 gail-3.0-uninstalled.pc
1662 m4macros/Makefile
1663 po/Makefile.in
1664 po-properties/Makefile.in
1665 demos/Makefile
1666 demos/gtk-demo/Makefile
1667 demos/gtk-demo/geninclude.pl
1668 examples/Makefile
1669 tests/Makefile
1670 docs/Makefile
1671 docs/reference/Makefile
1672 docs/reference/gdk/Makefile
1673 docs/reference/gdk/version.xml
1674 docs/reference/gtk/Makefile
1675 docs/reference/gtk/version.xml
1676 docs/reference/libgail-util/Makefile
1677 docs/reference/libgail-util/version.xml
1678 docs/tools/Makefile
1679 build/Makefile
1680 build/win32/Makefile
1681 build/win32/vs9/Makefile
1682 gdk/Makefile
1683 gdk/x11/Makefile
1684 gdk/win32/Makefile
1685 gdk/win32/rc/Makefile
1686 gdk/win32/rc/gdk.rc
1687 gdk/quartz/Makefile
1688 gdk/wayland/Makefile
1689 gdk/tests/Makefile
1690 gtk/Makefile
1691 gtk/makefile.msc
1692 gtk/gtkversion.h
1693 gtk/gtk-win32.rc
1694 gtk/tests/Makefile
1695 modules/Makefile
1696 modules/other/Makefile
1697 modules/other/gail/Makefile
1698 modules/other/gail/libgail-util/Makefile
1699 modules/other/gail/tests/Makefile
1700 modules/engines/Makefile
1701 modules/engines/pixbuf/Makefile
1702 modules/engines/ms-windows/Makefile
1703 modules/engines/ms-windows/Theme/Makefile
1704 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1705 modules/input/Makefile
1706 modules/printbackends/Makefile
1707 modules/printbackends/cups/Makefile
1708 modules/printbackends/lpr/Makefile
1709 modules/printbackends/file/Makefile
1710 modules/printbackends/papi/Makefile
1711 modules/printbackends/test/Makefile
1712 perf/Makefile
1713 ])
1714
1715 AC_OUTPUT
1716
1717 # beautify the immodule list a bit
1718 included_immodules=${included_immodules//,/ }
1719 included_immodules=${included_immodules:-none}
1720
1721 echo ""
1722 echo "        GTK+ $GTK_VERSION"
1723 echo "        ==========="
1724 echo ""
1725 echo "        GDK backends:         $GDK_BACKENDS"
1726 if test "x$enable_x11_backend" = "xyes"; then
1727 echo "        X11 extensions:       $X_EXTENSIONS"
1728 fi
1729 echo "        Print backends:       $PRINT_BACKENDS"
1730 echo "        Dynamic modules:      $build_dynamic_modules"
1731 echo "        Included immodules:   $included_immodules"
1732 echo "        PackageKit support:   $build_packagekit"
1733 echo "        Introspection:        $found_introspection"
1734 echo "        Debugging:            $enable_debug"
1735 echo "        Documentation:        $enable_gtk_doc"