Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [1])
  13 m4_define([gtk_micro_version], [16])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.29.14])
  43 m4_define([pango_required_version], [1.29.0])
  44 m4_define([atk_required_version], [2.1.5])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.23.5])
  47 m4_define([introspection_required_version], [0.10.1])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_INSTALL
 129 AC_PROG_MAKE_SET
 130
 131
 132 GETTEXT_PACKAGE=gtk30
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 135                    [The prefix for our gettext translation domains.])
 136
 137 AC_CANONICAL_HOST
 138
 139 MATH_LIB=-lm
 140 AC_MSG_CHECKING([for native Win32])
 141 LIB_EXE_MACHINE_FLAG=X86
 142 EXE_MANIFEST_ARCHITECTURE=X86
 143 case "$host" in
 144   *-*-mingw*)
 145     os_win32=yes
 146     gio_can_sniff=no
 147     MATH_LIB=
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       EXE_MANIFEST_ARCHITECTURE=AMD64
 152       ;;
 153     esac
 154     ;;
 155   *)
 156     os_win32=no
 157     ;;
 158 esac
 159 AC_MSG_RESULT([$os_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 163
 164 case $host in
 165   *-*-linux*)
 166     os_linux=yes
 167     ;;
 168   *-*-openbsd*)
 169     os_openbsd=yes
 170     ;;
 171 esac
 172
 173 dnl
 174 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 175 dnl We use this for an automated test for C++ header correctness.
 176 dnl
 177 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 178 AC_LANG_PUSH([C++])
 179
 180 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 181                                    [[class a { int b; } c;]])],
 182                   [],[CXX=])
 183 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 184
 185 gtk_save_cxxflags="$CXXFLAGS"
 186 CXXFLAGS="$CXXFLAGS -x objective-c++"
 187 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 188                                    [[]])],
 189                   [OBJC=yes],[OBJC=no])
 190 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 191 CXXFLAGS="$gtk_save_cxxflags"
 192 AC_LANG_POP([C++])
 193
 194 if test "$os_win32" = "yes"; then
 195   if test x$enable_static = xyes -o x$enable_static = x; then
 196     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 197     enable_static=no
 198   fi
 199   if test x$enable_shared = xno; then
 200     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 201   fi
 202   enable_shared=yes
 203 fi
 204
 205 dnl Initialize libtool
 206 LT_PREREQ([2.2.6])
 207 LT_INIT([disable-static win32-dll])
 208 # Create libtool early, because it's used in configure
 209 LT_OUTPUT
 210
 211 # Make sure we use 64-bit versions of various file stuff.
 212 AC_SYS_LARGEFILE
 213
 214 AM_PROG_AS
 215 AC_PATH_PROG(NM, nm, nm)
 216
 217 AC_MSG_CHECKING([for some Win32 platform])
 218 case "$host" in
 219   *-*-mingw*|*-*-cygwin*)
 220     platform_win32=yes
 221     ;;
 222   *)
 223     platform_win32=no
 224     ;;
 225 esac
 226 AC_MSG_RESULT([$platform_win32])
 227 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 228
 229 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 230 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 231 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 232
 233 if test "$os_win32" = "yes"; then
 234   AC_CHECK_TOOL(WINDRES, windres, no)
 235   if test "$WINDRES" = no; then
 236     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 237   fi
 238   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 239 fi
 240 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 241
 242 m4_define([debug_default],
 243           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 244
 245 dnl declare --enable-* args and collect ac_help strings
 246 AC_ARG_ENABLE(debug,
 247               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 248                               [turn on debugging @<:@default=debug_default@:>@])],,
 249               [enable_debug=debug_default])
 250
 251 AC_ARG_ENABLE(rebuilds,
 252               [AS_HELP_STRING([--disable-rebuilds],
 253                               [disable all source autogeneration rules])],,
 254               [enable_rebuilds=yes])
 255
 256 AC_ARG_ENABLE(gtk2-dependency,
 257               [AS_HELP_STRING([--enable-gtk2-dependency],
 258                               [Do not build gtk-update-icon-cache and other shared tools])],,
 259               [enable_gtk2_dependency=no])
 260
 261 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 262
 263 AC_ARG_ENABLE(xkb,
 264               [AS_HELP_STRING([--enable-xkb],
 265                               [support XKB extension [default=maybe]])],,
 266               [enable_xkb="maybe"])
 267 AC_ARG_ENABLE(xinerama,
 268               [AS_HELP_STRING([--enable-xinerama],
 269                               [support Xinerama extension if available [default=maybe]])],,
 270               [enable_xinerama="maybe"])
 271 AC_ARG_ENABLE(xinput,
 272               [AS_HELP_STRING([--enable-xinput],
 273                               [support XInput extension if available [default=yes]])],,
 274               [enable_xinput="maybe"])
 275 AC_ARG_ENABLE(xrandr,
 276               [AS_HELP_STRING([--enable-xrandr],
 277                               [support XRandR extension if available [default=maybe]])],,
 278               [enable_xrandr="maybe"])
 279 AC_ARG_ENABLE(xfixes,
 280               [AS_HELP_STRING([--enable-xfixes],
 281                               [support XFixes extension if available [default=maybe]])],,
 282               [enable_xfixes="maybe"])
 283 AC_ARG_ENABLE(xcomposite,
 284               [AS_HELP_STRING([--enable-xcomposite],
 285                               [support X Composite extension if available [default=maybe]])],,
 286               [enable_xcomposite="maybe"])
 287 AC_ARG_ENABLE(xdamage,
 288               [AS_HELP_STRING([--enable-xdamage],
 289                               [support X Damage extension if available [default=maybe]])],,
 290               [enable_xdamage="maybe"])
 291
 292 AC_ARG_ENABLE(x11-backend,
 293               [AS_HELP_STRING([--enable-x11-backend],
 294                               [enable the X11 gdk backend])],
 295                               [backend_set=yes])
 296 AC_ARG_ENABLE(win32-backend,
 297               [AS_HELP_STRING([--enable-win32-backend],
 298                               [enable the Win32 gdk backend])],
 299                               [backend_set=yes])
 300 AC_ARG_ENABLE(quartz-backend,
 301               [AS_HELP_STRING([--enable-quartz-backend],
 302                               [enable the quartz gdk backend])],
 303                               [backend_set=yes])
 304 AC_ARG_ENABLE(broadway-backend,
 305               [AS_HELP_STRING([--enable-broadway-backend],
 306                               [enable the broadway (HTML5) gdk backend])],
 307                               [backend_set=yes])
 308 AC_ARG_ENABLE(wayland-backend,
 309               [AS_HELP_STRING([--enable-wayland-backend],
 310                               [enable the wayland gdk backend])],
 311                               [backend_set=yes])
 312
 313 if test -z "$backend_set"; then
 314   if test "$platform_win32" = yes; then
 315     enable_win32_backend=yes
 316   else
 317     enable_x11_backend=yes
 318   fi
 319 fi
 320
 321 cairo_backends=
 322 backend_immodules=
 323 GDK_BACKENDS=
 324 GDK_EXTRA_LIBS=
 325 GDK_EXTRA_CFLAGS=
 326 GDK_WINDOWING=
 327 GIO_PACKAGE=gio-2.0
 328 PANGO_PACKAGES="pango pangocairo"
 329
 330 if test "x$enable_x11_backend" = xyes; then
 331   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 332   # backend names are identical.
 333   cairo_backends="$cairo_backends cairo-xlib"
 334   GDK_BACKENDS="$GDK_BACKENDS x11"
 335   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 336   # gdkapplaunchcontext-x11.c
 337   GIO_PACKAGE=gio-unix-2.0
 338   backend_immodules="$backend_immodules,xim"
 339   GDK_WINDOWING="$GDK_WINDOWING
 340 #define GDK_WINDOWING_X11"
 341 fi
 342
 343 if test "x$enable_win32_backend" = xyes; then
 344   cairo_backends="$cairo_backends cairo-win32"
 345   GDK_BACKENDS="$GDK_BACKENDS win32"
 346   backend_immodules="$backend_immodules,ime"
 347   GDK_WINDOWING="$GDK_WINDOWING
 348 #define GDK_WINDOWING_WIN32"
 349   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 350   AM_CONDITIONAL(USE_WIN32, true)
 351   PANGO_PACKAGES="pangowin32 pangocairo"
 352 else
 353   AM_CONDITIONAL(USE_WIN32, false)
 354 fi
 355
 356 if test "x$enable_quartz_backend" = xyes; then
 357   cairo_backends="$cairo_backends cairo-quartz"
 358   GDK_BACKENDS="$GDK_BACKENDS quartz"
 359   GDK_WINDOWING="$GDK_WINDOWING
 360 #define GDK_WINDOWING_QUARTZ"
 361   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 362   AM_CONDITIONAL(USE_QUARTZ, true)
 363 else
 364   AM_CONDITIONAL(USE_QUARTZ, false)
 365 fi
 366
 367
 368 if test "x$enable_broadway_backend" == xyes; then
 369   GDK_BACKENDS="$GDK_BACKENDS broadway"
 370   cairo_backends="$cairo_backends cairo"
 371   GDK_WINDOWING="$GDK_WINDOWING
 372 #define GDK_WINDOWING_BROADWAY"
 373   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 374   AM_CONDITIONAL(USE_BROADWAY, true)
 375 else
 376   AM_CONDITIONAL(USE_BROADWAY, false)
 377 fi
 378
 379 if test "x$enable_wayland_backend" == "xyes"; then
 380   # Wayland uses cairo-gl
 381   cairo_backends="$cairo_backends cairo-gl"
 382   GDK_BACKENDS="$GDK_BACKENDS wayland"
 383   GIO_PACKAGE=gio-unix-2.0
 384   GDK_WINDOWING="$GDK_WINDOWING
 385 #define GDK_WINDOWING_WAYLAND"
 386   WAYLAND_PACKAGES="wayland-client xkbcommon wayland-egl egl"
 387   AM_CONDITIONAL(USE_WAYLAND, true)
 388 else
 389   AM_CONDITIONAL(USE_WAYLAND, false)
 390 fi
 391
 392 # strip leading space
 393 GDK_BACKENDS=${GDK_BACKENDS#* }
 394
 395 AC_SUBST(GDK_BACKENDS)
 396
 397 if test -z "$GDK_BACKENDS"; then
 398   AC_MSG_ERROR([No GDK backends selected.])
 399 fi
 400
 401 if test "x$enable_debug" = "xyes"; then
 402   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 403   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 404 else
 405   if test "x$enable_debug" = "xno"; then
 406     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 407   else
 408     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 409   fi
 410 fi
 411
 412
 413 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 414                    [Define if debugging is enabled])
 415
 416
 417 # Build time sanity check...
 418 AM_SANITY_CHECK
 419
 420 changequote(,)dnl
 421 if test "x$GCC" = "xyes"; then
 422   case " $CFLAGS " in
 423   *[\ \ ]-Wall[\ \      ]*) ;;
 424   *) CFLAGS="$CFLAGS -Wall" ;;
 425   esac
 426
 427   if test "x$enable_ansi" = "xyes"; then
 428     case " $CFLAGS " in
 429     *[\ \       ]-ansi[\ \      ]*) ;;
 430     *) CFLAGS="$CFLAGS -ansi" ;;
 431     esac
 432
 433     case " $CFLAGS " in
 434     *[\ \       ]-pedantic[\ \  ]*) ;;
 435     *) CFLAGS="$CFLAGS -pedantic" ;;
 436     esac
 437   fi
 438 fi
 439 changequote([,])dnl
 440
 441 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 442
 443 # Ensure MSVC-compatible struct packing convention is used when
 444 # compiling for Win32 with gcc.
 445 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 446 # gcc2 uses "-fnative-struct".
 447 if test x"$os_win32" = xyes; then
 448   if test x"$GCC" = xyes; then
 449     msnative_struct=''
 450     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 451     if test -z "$ac_cv_prog_CC"; then
 452       our_gcc="$CC"
 453     else
 454       our_gcc="$ac_cv_prog_CC"
 455     fi
 456     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 457       2.)
 458         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 459           msnative_struct='-fnative-struct'
 460         fi
 461         ;;
 462       *)
 463         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 464           msnative_struct='-mms-bitfields'
 465         fi
 466         ;;
 467     esac
 468     if test x"$msnative_struct" = x ; then
 469       AC_MSG_RESULT([no way])
 470       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 471     else
 472       CFLAGS="$CFLAGS $msnative_struct"
 473       AC_MSG_RESULT([${msnative_struct}])
 474     fi
 475   fi
 476 fi
 477
 478 ## Initial sanity check, done here so that users get told they
 479 ## have the wrong dependencies as early in the process as possible.
 480 ## Later on we actually use the cflags/libs from separate pkg-config
 481 ## calls. Oh, also the later pkg-config calls don't include
 482 ## the version requirements since those make the module lists
 483 ## annoying to construct
 484 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 485   [glib-2.0 >= glib_required_version dnl
 486    atk >= atk_required_version dnl
 487    pango >= pango_required_version dnl
 488    cairo >= cairo_required_version dnl
 489    cairo-gobject >= cairo_required_version dnl
 490    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 491
 492 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 493
 494 if test "$os_win32" != yes; then
 495     # libtool option to control which symbols are exported
 496     # right now, symbols starting with _ are not exported
 497     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 498 else
 499     # We currently use .def files on Windows (for gdk and gtk)
 500     LIBTOOL_EXPORT_OPTIONS=
 501 fi
 502 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 503
 504 dnl ******************************************************
 505 dnl * See whether to include shared library dependencies *
 506 dnl ******************************************************
 507
 508 AC_ARG_ENABLE(explicit-deps,
 509               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 510                               [use explicit dependencies in .pc files [default=auto]])],,
 511               [enable_explicit_deps=auto])
 512
 513 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 514 case $enable_explicit_deps in
 515   auto)
 516     export SED
 517     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 518     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 519       enable_explicit_deps=yes
 520     else
 521       enable_explicit_deps=no
 522     fi
 523   ;;
 524   yes|no)
 525   ;;
 526   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 527   ;;
 528 esac
 529 AC_MSG_RESULT($enable_explicit_deps)
 530
 531 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 532
 533 # define a MAINT-like variable REBUILD which is set if Perl
 534 # and awk are found, so autogenerated sources can be rebuilt
 535
 536 AC_PATH_PROGS(PERL, perl5 perl)
 537
 538 # We would like indent, but don't require it.
 539 AC_CHECK_PROG(INDENT, indent, indent)
 540
 541 REBUILD=\#
 542 if test "x$enable_rebuilds" = "xyes" && \
 543      test -n "$PERL" && \
 544      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 545   REBUILD=
 546 fi
 547 AC_SUBST(REBUILD)
 548
 549 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 550 AC_CHECK_FUNCS(localtime_r)
 551
 552 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 553 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 554 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 555                                 [[char c;
 556                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 557                [gtk_ok=yes], [gtk_ok=no])
 558 AC_MSG_RESULT($gtk_ok)
 559 if test "$gtk_ok" = "yes"; then
 560   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 561             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 562 fi
 563
 564 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 565 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 566 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 567                                 [[char c;
 568                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 569                [gtk_ok=yes], [gtk_ok=no])
 570 AC_MSG_RESULT($gtk_ok)
 571 if test "$gtk_ok" = "yes"; then
 572   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 573             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 574 fi
 575
 576 # _NL_PAPER_HEIGHT is an enum and not a define
 577 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 578 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 579                                 [[char c;
 580                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 581                [gtk_ok=yes], [gtk_ok=no])
 582 AC_MSG_RESULT($gtk_ok)
 583 if test "$gtk_ok" = "yes"; then
 584   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 585             [Define if _NL_PAPER_HEIGHT is available])
 586 fi
 587
 588 # _NL_PAPER_WIDTH is an enum and not a define
 589 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 590 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 591                                 [[char c;
 592                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 593                [gtk_ok=yes], [gtk_ok=no])
 594 AC_MSG_RESULT($gtk_ok)
 595 if test "$gtk_ok" = "yes"; then
 596   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 597             [Define if _NL_PAPER_WIDTH is available])
 598 fi
 599
 600 # i18n stuff
 601 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 602 AM_GLIB_GNU_GETTEXT
 603 LIBS="$LIBS $INTLLIBS"
 604 AC_CONFIG_COMMANDS([po-properties],
 605                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 606                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 607                      esac]],
 608                    [[]])
 609
 610 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 611 dnl po-properties/POTFILES during configure; see GNOME #573515.
 612 dnl
 613 dnl Generate list of files to be processed by xgettext which will
 614 dnl be included in po-properties/Makefile.
 615 test -d po-properties || mkdir po-properties
 616 if test "x$srcdir" != "x."; then
 617   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 618     popropsrcprefix="$srcdir/"
 619   else
 620     popropsrcprefix="../$srcdir/"
 621   fi
 622 else
 623   popropsrcprefix="../"
 624 fi
 625 rm -f po-properties/POTFILES
 626 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 627 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 628 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 629
 630 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 631
 632 dnl The DU4 header files don't provide library prototypes unless
 633 dnl -std1 is given to the native cc.
 634 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 635
 636 gtk_save_LIBS=$LIBS
 637 LIBS="$LIBS -lm"
 638 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 639                                 int main (void) { return (log(1) != log(1.)); }]])],
 640               [AC_MSG_RESULT(none needed)],
 641               [gtk_save_CFLAGS="$CFLAGS"
 642                CFLAGS="$CFLAGS -std1"
 643                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 644                                                int main (void) { return (log(1) != log(1.)); }]])],
 645                              [AC_MSG_RESULT(-std1)],
 646                              [AC_MSG_RESULT()
 647                               CFLAGS="$gtk_save_CFLAGS"
 648                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 649                              [true])],
 650               [AC_MSG_RESULT(none needed)])
 651
 652 LIBS=$gtk_save_LIBS
 653
 654 AC_MSG_CHECKING(for the BeOS)
 655 case $host in
 656   *-*-beos*)
 657     AC_MSG_RESULT(yes)
 658     MATH_LIB=
 659   ;;
 660   *)
 661     AC_MSG_RESULT(no)
 662   ;;
 663 esac
 664
 665 AC_SUBST(MATH_LIB)
 666 #
 667 # see bug 162979
 668 #
 669 AC_MSG_CHECKING(for HP-UX)
 670 case $host_os in
 671   hpux9* | hpux10* | hpux11*)
 672     AC_MSG_RESULT(yes)
 673     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 674   ;;
 675   *)
 676     AC_MSG_RESULT(no)
 677   ;;
 678 esac
 679
 680 #
 681 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 682 #
 683
 684 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 685
 686 AM_PATH_GLIB_2_0(glib_required_version, :,
 687   AC_MSG_ERROR([
 688 *** GLIB glib_required_version or better is required. The latest version of
 689 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 690   gobject gmodule-no-export gthread)
 691
 692 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 693 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 694 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 695 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 696   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 697 fi
 698
 699 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 700
 701
 702 dnl
 703 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 704 dnl
 705 gtk_save_LIBS=$LIBS
 706 LIBS="$LIBS $GLIB_LIBS"
 707 AC_CHECK_FUNCS(bind_textdomain_codeset)
 708 LIBS=$gtk_save_LIBS
 709
 710 AC_CHECK_HEADERS(pwd.h,
 711                  AC_DEFINE(HAVE_PWD_H, 1,
 712                            [Define to 1 if pwd.h is available]))
 713 AC_CHECK_HEADERS(sys/time.h,
 714                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 715                            [Define to 1 if time.h is available]))
 716 AC_CHECK_HEADERS(unistd.h,
 717                  AC_DEFINE(HAVE_UNISTD_H, 1,
 718                            [Define to 1 if unistd.h is available]))
 719 AC_CHECK_HEADERS(ftw.h,
 720                  AC_DEFINE(HAVE_FTW_H, 1,
 721                            [Define to 1 if ftw.h is available]))
 722
 723 AC_MSG_CHECKING([for GNU ftw extensions])
 724 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 725                                      #define _GNU_SOURCE
 726                                      #include <ftw.h>]],
 727                                    [[int flags = FTW_ACTIONRETVAL;]])],
 728                   [gtk_ok=yes],[gtk_ok=no])
 729 if test $gtk_ok = yes; then
 730     AC_MSG_RESULT([yes])
 731     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 732 else
 733     AC_MSG_RESULT([no])
 734 fi
 735
 736 saved_cflags="$CFLAGS"
 737 saved_ldflags="$LDFLAGS"
 738
 739
 740 # Checks for library functions.
 741 AC_FUNC_MMAP
 742
 743 AC_CHECK_FUNCS(mallinfo)
 744 AC_CHECK_FUNCS(getresuid)
 745 AC_TYPE_UID_T
 746
 747 # Check for uxtheme.h (for MS-Windows Engine)
 748 AC_MSG_CHECKING(for uxtheme.h)
 749 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <uxtheme.h>]])],
 750                   [gtk_uxtheme_h=yes], [gtk_uxtheme_h=no])
 751 if test $gtk_uxtheme_h = yes; then
 752    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 753 fi
 754 AC_MSG_RESULT($gtk_uxtheme_h)
 755
 756 # Check for round()
 757 AC_CHECK_LIB(m,round,have_round=yes,have_round=no)
 758 if test $have_round = yes; then
 759     AC_DEFINE(HAVE_ROUND, 1, [Define to 1 if round() is available])
 760 fi
 761
 762 # Check for rint()
 763 AC_CHECK_LIB(m,rint,have_rint=yes,have_rint=no)
 764 if test $have_rint = yes; then
 765     AC_DEFINE(HAVE_RINT, 1, [Define to 1 if rint() is available])
 766 fi
 767
 768 # Checks for gdkspawn
 769 AC_CHECK_HEADERS(crt_externs.h)
 770 AC_CHECK_FUNCS(_NSGetEnviron)
 771
 772 AC_MSG_CHECKING(whether to build dynamic modules)
 773
 774 AC_ARG_ENABLE(modules,
 775               [AS_HELP_STRING([--disable-modules],
 776                               [disable dynamic module loading])])
 777
 778 dynworks=false
 779 build_dynamic_modules=no
 780 deps=
 781 if test x$enable_modules = xno; then
 782     AC_MSG_RESULT(no)
 783 else
 784     AC_MSG_RESULT(yes)
 785     AC_MSG_CHECKING(whether dynamic modules work)
 786     ## for loop is to strip newline
 787     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 788     for I in $tmp; do
 789         dynworks=$I
 790     done
 791
 792     dnl Now we check to see if our libtool supports shared lib deps
 793     dnl (in a rather ugly way even)
 794     if $dynworks; then
 795         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 796         module_deplibs_check=`$module_libtool_config | \
 797             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 798             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 799         if test "x$module_deplibs_check" = "xnone" || \
 800            test "x$module_deplibs_check" = "xunknown" || \
 801            test "x$module_deplibs_check" = "x"; then
 802             dynworks=false
 803         fi
 804     fi
 805
 806     if $dynworks; then
 807         build_dynamic_modules=yes
 808         AC_DEFINE(USE_GMODULE, 1,
 809                   [Define to 1 if gmodule works and should be used])
 810         AC_MSG_RESULT(yes)
 811     else
 812         build_dynamic_modules=no
 813         AC_MSG_RESULT(no)
 814     fi
 815 fi
 816
 817 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 818
 819 #
 820 # Allow building some or all immodules included
 821 #
 822 AC_MSG_CHECKING(immodules to build)
 823
 824 AC_ARG_WITH(included_immodules,
 825             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 826                             [build the specified input methods into gtk])])
 827
 828 if $dynworks; then
 829    :
 830 else
 831    ## if the option was specified, leave it; otherwise disable included immodules
 832    if test x$with_included_immodules = xno; then
 833            with_included_immodules=yes
 834    fi
 835 fi
 836
 837 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 838
 839 included_immodules=""
 840 # If the switch specified without listing any specific ones, include all
 841 if test "x$with_included_immodules" = xyes ; then
 842   included_immodules="$all_immodules"
 843 else
 844   included_immodules="$with_included_immodules"
 845 fi
 846
 847 AC_MSG_RESULT($included_immodules)
 848 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 849
 850 INCLUDED_IMMODULE_OBJ=
 851 INCLUDED_IMMODULE_DEFINE=
 852
 853 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 854 for immodule in $included_immodules; do
 855  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 856  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 857    :
 858  else
 859    AC_MSG_ERROR([the specified input method $immodule does not exist])
 860  fi
 861
 862  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 863  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 864  eval INCLUDE_$immodule_underscores=yes
 865 done
 866 IFS="$gtk_save_ifs"
 867 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 868 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 869
 870 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 871 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 872 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 873 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 874 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 875 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 876 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 877 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 878 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 879 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 880 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 881 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 882
 883 # Checks to see whether we should include mediaLib
 884 # support.
 885 #
 886 AC_CHECK_HEADER(sys/systeminfo.h,
 887                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 888                           [Define to 1 if sys/systeminfo.h is available]))
 889 AC_CHECK_HEADER(sys/sysinfo.h,
 890                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 891                           [Define to 1 if sys/sysinfo.h is available]))
 892
 893 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 894
 895 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 896
 897 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 898   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 899   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 900     REBUILD_PNGS=#
 901   fi
 902 fi
 903
 904 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 905
 906 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 907
 908 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 909    test "x$REBUILD_PNGS" = "x#" ; then
 910      AC_MSG_ERROR([
 911 *** gtkbuiltincache.h is not in the tree, and cannot be built
 912 *** because you don't have libpng, or (when cross-compiling) you
 913 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 914 fi
 915
 916 ########################################
 917 # Windowing system checks
 918 ########################################
 919
 920 # GTK+ uses some X calls, so needs to link against X directly
 921 GTK_DEP_PACKAGES_FOR_X=
 922 GTK_DEP_LIBS_FOR_X=
 923 X_EXTENSIONS=
 924
 925 if test "x$enable_x11_backend" = xyes; then
 926   X_PACKAGES=fontconfig
 927
 928   #
 929   # We use fontconfig very peripherally when decoding the default
 930   # settings.
 931   #
 932   if $PKG_CONFIG --exists fontconfig; then : ; else
 933     AC_MSG_ERROR([
 934 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 935   fi
 936
 937   #
 938   # Check for basic X packages; we use pkg-config if available
 939   #
 940   if $PKG_CONFIG --exists x11 xext; then
 941     have_base_x_pc=true
 942     X_PACKAGES="$X_PACKAGES x11 xext"
 943     x_libs="`$PKG_CONFIG --libs x11 xext`"
 944     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 945
 946     # Strip out any .la files that pkg-config might give us (this happens
 947     # with -uninstalled.pc files)
 948     x_libs_for_checks=
 949     for I in $x_libs ; do
 950       case $I in
 951         *.la) ;;
 952         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 953       esac
 954     done
 955
 956     GTK_PACKAGES_FOR_X="x11"
 957   else
 958     have_base_x_pc=false
 959     AC_PATH_XTRA
 960     if test x$no_x = xyes ; then
 961       AC_MSG_ERROR([X development libraries not found])
 962     fi
 963
 964     x_cflags="$X_CFLAGS"
 965     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 966
 967     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 968   fi
 969
 970   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 971   x_extra_libs=
 972
 973   gtk_save_cppflags="$CPPFLAGS"
 974   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 975
 976   gtk_save_LIBS=$LIBS
 977   LIBS="$x_libs_for_checks $LIBS"
 978
 979   # Sanity check for the X11 and Xext libraries. While everything we need from
 980   # Xext is optional, the chances a system has *none* of these things is so
 981   # small that we just unconditionally require it.
 982   AC_CHECK_FUNC(XOpenDisplay, :,
 983                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 984   AC_CHECK_FUNC(XextFindDisplay, :,
 985                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 986
 987   # Check for xReply
 988
 989   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 990   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 991                                      [[xReply *rep;]])],
 992                     [AC_MSG_RESULT([no])],
 993                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 994                                                           #include <X11/Xlibint.h>]],
 995                                                         [[xReply *rep;]])],
 996                                        [AC_MSG_RESULT([yes])
 997                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 998                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 999                                        [AC_MSG_RESULT([unknown])
1000                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1001
1002   # Check for XConvertCase, XInternAtoms (X11R6 specific)
1003
1004   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1005
1006   # Generic X11R6 check needed for XIM support; we could
1007   # probably use this to replace the above, but we'll
1008   # leave the separate checks for XConvertCase and XInternAtoms
1009   # for clarity
1010
1011   have_x11r6=false
1012   AC_CHECK_FUNC(XAddConnectionWatch,
1013       have_x11r6=true)
1014
1015   if $have_x11r6; then
1016     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1017   fi
1018   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1019
1020   # Check for XKB support.
1021
1022   if test "x$enable_xkb" = "xyes"; then
1023         AC_CHECK_FUNC(XkbQueryExtension,
1024                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1025                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1026                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1027   elif test "x$enable_xkb" = "xmaybe"; then
1028         AC_CHECK_FUNC(XkbQueryExtension,
1029                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1030                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1031   else
1032         AC_MSG_WARN(XKB support explicitly disabled)
1033   fi
1034
1035   # Check for shaped window extension
1036
1037   AC_CHECK_FUNC(XShapeCombineMask, :,
1038      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1039
1040   # X SYNC check
1041   gtk_save_CFLAGS="$CFLAGS"
1042   CFLAGS="$CFLAGS $x_cflags"
1043
1044   AC_CHECK_FUNC(XSyncQueryExtension,
1045       [AC_CHECK_HEADER(X11/extensions/sync.h,
1046           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1047           :, [#include <X11/Xlib.h>])])
1048
1049   CFLAGS="$gtk_save_CFLAGS"
1050
1051   if test "x$enable_xinerama" != "xno"; then
1052     # Check for Xinerama extension (Solaris impl or Xfree impl)
1053     have_xfree_xinerama=false
1054     have_solaris_xinerama=false
1055
1056     gtk_save_cppflags="$CPPFLAGS"
1057     CPPFLAGS="$CPPFLAGS $x_cflags"
1058
1059     # Check for XFree
1060     AC_MSG_CHECKING(for Xinerama packages)
1061
1062     if $PKG_CONFIG --exists xinerama ; then
1063        AC_MSG_RESULT(yes)
1064        have_xfree_xinerama=true
1065        X_PACKAGES="$X_PACKAGES xinerama"
1066     else
1067        AC_MSG_RESULT(no)
1068        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1069            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1070            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1071            have_xfree_xinerama=true], :,
1072            [#include <X11/Xlib.h>])])
1073     fi
1074
1075     if $have_xfree_xinerama ; then
1076       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1077       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1078                 [Define to 1 if XFree Xinerama is available])
1079       AC_DEFINE(HAVE_XINERAMA, 1,
1080                 [Define to 1 is Xinerama is available])
1081     else
1082       case "$host" in
1083         *-*-solaris*)
1084             # Check for solaris
1085             AC_MSG_CHECKING(for Xinerama support on Solaris)
1086
1087             have_solaris_xinerama=false
1088             AC_CHECK_FUNC(XineramaGetInfo,
1089                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1090                     [have_solaris_xinerama=true], :,
1091                     [#include <X11/Xlib.h>])])
1092
1093             if $have_solaris_xinerama ; then
1094               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1095               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1096                         [Define to 1 if solaris xinerama is available])
1097               AC_DEFINE(HAVE_XINERAMA, 1,
1098                         [Define to 1 if xinerama is available])
1099               AC_MSG_RESULT(yes)
1100             else
1101               AC_MSG_RESULT(no)
1102             fi
1103             ;;
1104         *)
1105             ;;
1106       esac
1107     fi
1108   fi
1109   if test "x$enable_xinerama" = "xyes" ; then
1110     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1111       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1112     fi
1113   fi
1114
1115   # Check for XGetEventData for GenericEvents
1116   AC_CHECK_FUNC(XGetEventData,
1117                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1118
1119   # set up things for XInput
1120   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1121     have_xinput=yes
1122
1123     AC_DEFINE(XINPUT_XFREE, 1,
1124               [Define to 1 if XFree XInput should be used])
1125
1126     X_PACKAGES="$X_PACKAGES xi"
1127
1128     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1129                     have_xinput2=yes
1130                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1131                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1132                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1133
1134   else
1135     AC_DEFINE(XINPUT_NONE, 1,
1136               [Define to 1 if no XInput should be used])
1137   fi
1138
1139   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1140   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1141
1142   if test "x$enable_xinput" = "xyes" ; then
1143     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1144       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1145     fi
1146   fi
1147
1148   # Check for the RANDR extension
1149   if test x"$enable_xrandr" != xno; then
1150     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1151       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1152
1153       X_PACKAGES="$X_PACKAGES xrandr"
1154       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1155     elif test x"$enable_xrandr" = xyes; then
1156       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1157     fi
1158   fi
1159
1160   # Checks for Xcursor library
1161
1162   if $PKG_CONFIG --exists xcursor ; then
1163     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1164
1165     X_PACKAGES="$X_PACKAGES xcursor"
1166   fi
1167
1168   # Checks for XFixes extension
1169
1170   if test x"$enable_xfixes" != xno; then
1171     if $PKG_CONFIG --exists xfixes ; then
1172       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1173
1174       X_PACKAGES="$X_PACKAGES xfixes"
1175       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1176       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1177     elif test x"$enable_xfixes" = xyes; then
1178       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1179     fi
1180   fi
1181
1182   # Checks for Xcomposite extension
1183
1184   if test x"$enable_xcomposite" != xno; then
1185     if $PKG_CONFIG --exists xcomposite ; then
1186       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1187
1188       X_PACKAGES="$X_PACKAGES xcomposite"
1189       X_EXTENSIONS="$X_EXTENSIONS Composite"
1190       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1191     elif test x"$enable_xcomposite" = xyes; then
1192       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1193     fi
1194   fi
1195
1196   # Checks for Xdamage extension
1197
1198   if test x"$enable_xdamage" != xno; then
1199     if $PKG_CONFIG --exists xdamage ; then
1200       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1201
1202       X_PACKAGES="$X_PACKAGES xdamage"
1203       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1204       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1205     elif test x"$enable_xdamage" = xyes; then
1206       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1207     fi
1208   fi
1209
1210   if $have_base_x_pc ; then
1211     GDK_EXTRA_LIBS="$x_extra_libs"
1212   else
1213     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1214   fi
1215
1216   CPPFLAGS="$gtk_save_cppflags"
1217   LIBS="$gtk_save_libs"
1218
1219   AM_CONDITIONAL(USE_X11, true)
1220
1221   # strip leading space
1222   X_EXTENSIONS=${X_EXTENSIONS#* }
1223
1224 else
1225   XPACKAGES=
1226
1227   AM_CONDITIONAL(XINPUT_XFREE, false)
1228   AM_CONDITIONAL(XINPUT_2, false)
1229   AM_CONDITIONAL(USE_X11, false)
1230   AM_CONDITIONAL(HAVE_X11R6, false)
1231 fi
1232
1233 # Check for Pango flags
1234
1235 AC_MSG_CHECKING(Pango flags)
1236 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1237         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1238         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1239
1240         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1241 else
1242         AC_MSG_ERROR([
1243 *** Pango not found. Pango built with Cairo support is required
1244 *** to build GTK+. See http://www.pango.org for Pango information.
1245 ])
1246 fi
1247
1248 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1249
1250 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1251         :
1252 else
1253         gtk_save_LIBS="$LIBS"
1254         LIBS="$PANGO_LIBS $LIBS"
1255         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1256 *** Can't link to Pango. Pango is required to build
1257 *** GTK+. For more information see http://www.pango.org]))
1258         LIBS="$gtk_save_LIBS"
1259 fi
1260
1261 CFLAGS="$saved_cflags"
1262 LDFLAGS="$saved_ldflags"
1263
1264 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1265
1266 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES` $MATH_LIB"
1267 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1268 #
1269 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1270 # into the pkg-config files
1271 #
1272 if test $enable_explicit_deps != yes ; then
1273   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1274   GDK_EXTRA_LIBS=
1275 fi
1276
1277 AC_SUBST(GDK_PACKAGES)
1278 AC_SUBST(GDK_EXTRA_LIBS)
1279 AC_SUBST(GDK_EXTRA_CFLAGS)
1280 AC_SUBST(GDK_DEP_LIBS)
1281 AC_SUBST(GDK_DEP_CFLAGS)
1282
1283
1284 ########################################
1285 # Check for Accessibility Toolkit flags
1286 ########################################
1287
1288 ATK_PACKAGES=atk
1289 AC_MSG_CHECKING(ATK flags)
1290 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1291         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1292         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1293
1294         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1295 else
1296         AC_MSG_ERROR([
1297 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1298 *** to build GTK+.
1299 ])
1300 fi
1301
1302 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1303         :
1304 else
1305         gtk_save_LIBS="$LIBS"
1306         LIBS="$ATK_LIBS $LIBS"
1307         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1308                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1309                 *** to build GTK+]))
1310         LIBS="$gtk_save_LIBS"
1311 fi
1312
1313 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1314 if test "x$enable_x11_backend" = xyes; then
1315   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1316 fi
1317 GTK_EXTRA_LIBS=
1318 if test x"$os_openbsd" = xyes; then
1319   GTK_EXTRA_LIBS="$GTK_EXTRA_LIBS -lkvm"
1320 fi
1321
1322 GTK_EXTRA_CFLAGS=
1323 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS $MATH_LIB"
1324 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1325
1326 if test x"$os_win32" = xyes; then
1327   GTK_EXTRA_CFLAGS="$msnative_struct"
1328 fi
1329
1330 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1331 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1332 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1333 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1334
1335 AC_SUBST(GTK_PACKAGES)
1336 AC_SUBST(GTK_EXTRA_LIBS)
1337 AC_SUBST(GTK_EXTRA_CFLAGS)
1338 AC_SUBST(GTK_DEP_LIBS)
1339 AC_SUBST(GTK_DEP_CFLAGS)
1340
1341 AC_SUBST(GLIB_PREFIX)
1342 AC_SUBST(ATK_PREFIX)
1343 AC_SUBST(PANGO_PREFIX)
1344 AC_SUBST(CAIRO_PREFIX)
1345
1346 AC_SUBST(GTK_DEBUG_FLAGS)
1347 AC_SUBST(GTK_XIM_FLAGS)
1348
1349 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1350 AC_SUBST(GDK_PIXBUF_LIBS)
1351
1352 ########################
1353 # Checks needed for gail
1354 ########################
1355
1356 old_LIBS="$LIBS"
1357 dnl Checks for inet libraries:
1358 AC_SEARCH_LIBS(gethostent, nsl)
1359 AC_SEARCH_LIBS(setsockopt, socket)
1360 AC_SEARCH_LIBS(connect, inet)
1361
1362 dnl check for the sockaddr_un.sun_len member
1363 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1364                 [struct_sockaddr_un_sun_len=true],
1365                 [struct_sockaddr_un_suin_len=false],
1366                 [#include <sys/types.h>
1367                  #include <sys/un.h>]
1368                 )
1369 case $struct_sockaddr_un_sun_len in
1370         true)
1371                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1372                                    [Have the sockaddr_un.sun_len member])
1373                 ;;
1374         *)
1375                 ;;
1376 esac
1377
1378 GAIL_INET_LIBS="$LIBS"
1379 AC_SUBST([GAIL_INET_LIBS])
1380
1381 LIBS="$old_LIBS"
1382
1383 ################################################################
1384 # Printing system checks
1385 ################################################################
1386
1387 PRINT_BACKENDS="file lpr"
1388
1389 AC_ARG_ENABLE(cups,
1390               [AS_HELP_STRING([--disable-cups],
1391                               [disable cups print backend])],,
1392               [enable_cups=auto])
1393
1394 if test "x$enable_cups" = "xno"; then
1395   AM_CONDITIONAL(HAVE_CUPS, false)
1396 else
1397   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1398   if test "x$CUPS_CONFIG" = "xno"; then
1399     if test "x$enable_cups" = "xauto"; then
1400       AM_CONDITIONAL(HAVE_CUPS, false)
1401     else
1402       AC_MSG_ERROR([
1403 *** cups not found.
1404 ])
1405     fi
1406   else
1407     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1408     CUPS_LIBS=`$CUPS_CONFIG --libs`
1409
1410     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1411     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1412     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1413
1414     if test $CUPS_API_MAJOR -gt 1 -o \
1415             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1416       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1417                 [Define to 1 if CUPS 1.2 API is available])
1418     fi
1419
1420     AC_SUBST(CUPS_API_MAJOR)
1421     AC_SUBST(CUPS_API_MINOR)
1422     AC_SUBST(CUPS_CFLAGS)
1423     AC_SUBST(CUPS_LIBS)
1424
1425     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1426
1427     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1428     AM_CONDITIONAL(HAVE_CUPS, true)
1429
1430     gtk_save_cflags="$CFLAGS"
1431     CFLAGS="$CUPS_CFLAGS"
1432     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1433                                        [[http_t http; char *s = http.authstring;]])],
1434                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1435                                  [Define if cups http_t authstring field is accessible])],
1436                       [])
1437     CFLAGS="$gtk_save_cflags"
1438
1439     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1440
1441     gtk_save_libs="$LIBS"
1442     LIBS="$CUPS_LIBS"
1443     AC_CHECK_FUNCS(httpGetAuthString)
1444     LIBS="$gtk_save_libs"
1445   fi
1446 fi
1447
1448 # Checks to see if we should compile with PAPI backend for GTK+
1449 #
1450
1451 AC_ARG_ENABLE(papi,
1452               [AS_HELP_STRING([--disable-papi],
1453                               [disable papi print backend])],,
1454               [enable_papi=auto])
1455
1456 if test "x$enable_papi" = "xno"; then
1457   AM_CONDITIONAL(HAVE_PAPI, false)
1458 else
1459   AC_MSG_CHECKING(libpapi)
1460   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1461   if test $have_papi = yes; then
1462     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1463     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1464   fi
1465   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1466   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1467     AC_MSG_ERROR([
1468 *** papi not found.
1469 ])
1470   fi
1471 fi
1472
1473 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1474
1475 gtk_save_cppflags="$CPPFLAGS"
1476 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1477
1478 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1479 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1480 *** backend enabled.]))
1481
1482 if test "$os_win32" != "yes"; then
1483   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1484 *** Can't find cairo-ps.h. You must build Cairo with the
1485 *** postscript backend enabled.]))
1486
1487   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1488 *** Cannot find cairo-svg.h. You must build Cairo with the
1489 *** svg backend enabled.]))
1490 fi
1491
1492 CPPFLAGS="$gtk_save_cppflags"
1493
1494
1495 AC_ARG_ENABLE(test-print-backend,
1496               [AS_HELP_STRING([--enable-test-print-backend],
1497                               [build test print backend])],,
1498               [enable_test_print_backend=no])
1499 if test "x$enable_test_print_backend" != "xno" ; then
1500   PRINT_BACKENDS="$PRINT_BACKENDS test"
1501 fi
1502 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1503
1504
1505 ################################################################
1506 # Strip -export-dynamic from the link lines of various libraries
1507 ################################################################
1508
1509 #
1510 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1511 #  but this flag is only meaningful for executables. For libraries
1512 #  the effect is undefined; what it causes on Linux is that the
1513 #  export list from -export-symbols-regex is ignored and everything
1514 #  is exported
1515 #
1516 # We are using gmodule-no-export now, but I'm leaving the stripping
1517 # code in place for now, since pango and atk still require gmodule.
1518 export SED
1519 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1520 if test -n "$export_dynamic"; then
1521   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1522   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1523 fi
1524
1525 #############
1526 # GSettings #
1527 #############
1528
1529 GLIB_GSETTINGS
1530
1531 ##################################################
1532 # GObject introspection
1533 ##################################################
1534
1535 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1536
1537 ##################################################
1538 # Packagekit module
1539 #################################################
1540
1541 AC_ARG_ENABLE(packagekit,
1542               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1543                               [build packagekit open-with module [default=auto]])],
1544               [enable_packagekit="$enableval"],
1545               [enable_packagekit=auto])
1546 if test "$enable_packagekit" = "auto"; then
1547   if test "$os_win32" = "yes"; then
1548     enable_packagekit=no
1549   else
1550     enable_packagekit=yes
1551   fi
1552 fi
1553
1554 AC_MSG_CHECKING([Whether to use PackageKit])
1555 build_packagekit=no
1556 if test "x$enable_packagekit" != "xno"; then
1557   if test "$os_win32" != "yes"; then
1558     build_packagekit=yes
1559     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1560   else
1561     AC_MSG_ERROR([packagekit support is not available on win32])
1562   fi
1563 fi
1564 AC_MSG_RESULT([$build_packagekit])
1565
1566 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1567
1568 ##################################################
1569 # colord module
1570 #################################################
1571
1572 AC_ARG_ENABLE(colord,
1573               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1574                               [build colord support code [default=auto]])],
1575               [enable_colord="$enableval"],
1576               [enable_colord=auto])
1577 if test "$enable_colord" = "auto"; then
1578   if test "$os_win32" = "yes"; then
1579     enable_colord=no
1580   else
1581     enable_colord=yes
1582   fi
1583 fi
1584
1585 AC_MSG_CHECKING([Whether to use colord])
1586 have_colord=no
1587 if test "x$enable_colord" != "xno"; then
1588         if test "$os_win32" != "yes"; then
1589                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1590                                   have_colord=yes, have_colord=no)
1591                 if test "enable_colord" = "yes"; then
1592                         if test "have_colord" = "no"; then
1593                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1594                         fi
1595                 fi
1596         else
1597                 AC_MSG_ERROR([colord support is not available on win32])
1598         fi
1599 fi
1600 AC_MSG_RESULT([$have_colord])
1601
1602 if test "have_colord" = "yes"; then
1603         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1604 fi
1605 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1606
1607 ##################################################
1608 # Checks for gtk-doc and docbook-tools
1609 ##################################################
1610
1611 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1612
1613 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1614 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1615
1616 AC_ARG_ENABLE(man,
1617               [AS_HELP_STRING([--enable-man],
1618                               [regenerate man pages from Docbook [default=no]])],
1619               [enable_man=yes],
1620               [enable_man=no])
1621
1622 if test "${enable_man}" != no; then
1623   dnl
1624   dnl Check for xsltproc
1625   dnl
1626   AC_PATH_PROG([XSLTPROC], [xsltproc])
1627   if test -z "$XSLTPROC"; then
1628     enable_man=no
1629   fi
1630
1631   dnl check for DocBook DTD and stylesheets in the local catalog.
1632   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1633      [DocBook XML DTD V4.1.2],,enable_man=no)
1634   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1635      [DocBook XSL Stylesheets],,enable_man=no)
1636 fi
1637
1638 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1639
1640
1641 ##################################################
1642 # Output commands
1643 ##################################################
1644
1645 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1646         outfile=gdkconfig.h-tmp
1647         cat > $outfile <<\_______EOF
1648 /* gdkconfig.h
1649  *
1650  * This is a generated file.  Please modify `configure.ac'
1651  */
1652
1653 #ifndef __GDKCONFIG_H__
1654 #define __GDKCONFIG_H__
1655
1656 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1657 #error "Only <gdk/gdk.h> can be included directly."
1658 #endif
1659
1660 #include <glib.h>
1661
1662 G_BEGIN_DECLS
1663
1664 _______EOF
1665
1666         cat >>$outfile <<_______EOF
1667 $gdk_windowing
1668 _______EOF
1669
1670         cat >>$outfile <<_______EOF
1671
1672 G_END_DECLS
1673
1674 #endif  /* __GDKCONFIG_H__ */
1675 _______EOF
1676
1677
1678         if cmp -s $outfile gdk/gdkconfig.h; then
1679           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1680           rm -f $outfile
1681         else
1682           mv $outfile gdk/gdkconfig.h
1683         fi
1684 ],[
1685 gdk_windowing='$GDK_WINDOWING'
1686 ])
1687
1688 dnl
1689 dnl Check for -Bsymbolic-functions linker flag used to avoid
1690 dnl intra-library PLT jumps, if available.
1691 dnl
1692 AC_ARG_ENABLE(Bsymbolic,
1693               [AS_HELP_STRING([--disable-Bsymbolic],
1694                               [avoid linking with -Bsymbolic])],,
1695               [SAVED_LDFLAGS="${LDFLAGS}"
1696                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1697                LDFLAGS=-Wl,-Bsymbolic-functions
1698                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1699                                                [[int main (void) { return 0; }]])],
1700                               [AC_MSG_RESULT(yes)
1701                                enable_Bsymbolic=yes],
1702                               [AC_MSG_RESULT(no)
1703                                enable_Bsymbolic=no])
1704                LDFLAGS="${SAVED_LDFLAGS}"])
1705
1706 if test "x${enable_Bsymbolic}" = "xyes" ; then
1707   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1708 fi
1709 AC_SUBST(GTK_LINK_FLAGS)
1710
1711 AC_CONFIG_FILES([
1712 config.h.win32
1713 gtk-zip.sh
1714 Makefile
1715 gdk-3.0.pc
1716 gtk+-3.0.pc
1717 gtk+-unix-print-3.0.pc
1718 gail-3.0.pc
1719 gtk+-3.0-uninstalled.pc
1720 gail-3.0-uninstalled.pc
1721 m4macros/Makefile
1722 po/Makefile.in
1723 po-properties/Makefile.in
1724 demos/Makefile
1725 demos/gtk-demo/Makefile
1726 demos/gtk-demo/geninclude.pl
1727 demos/pixbuf-demo/Makefile
1728 examples/Makefile
1729 tests/Makefile
1730 tests/a11y/Makefile
1731 tests/css/Makefile
1732 tests/css/parser/Makefile
1733 tests/reftests/Makefile
1734 docs/Makefile
1735 docs/reference/Makefile
1736 docs/reference/gdk/Makefile
1737 docs/reference/gdk/version.xml
1738 docs/reference/gtk/Makefile
1739 docs/reference/gtk/version.xml
1740 docs/reference/libgail-util/Makefile
1741 docs/reference/libgail-util/version.xml
1742 docs/tools/Makefile
1743 build/Makefile
1744 build/win32/Makefile
1745 build/win32/vs9/Makefile
1746 build/win32/vs10/Makefile
1747 gdk/Makefile
1748 gdk/broadway/Makefile
1749 gdk/x11/Makefile
1750 gdk/win32/Makefile
1751 gdk/win32/rc/Makefile
1752 gdk/win32/rc/gdk.rc
1753 gdk/quartz/Makefile
1754 gdk/wayland/Makefile
1755 gdk/tests/Makefile
1756 gtk/Makefile
1757 gtk/makefile.msc
1758 gtk/gtkversion.h
1759 gtk/gtk-win32.rc
1760 gtk/a11y/Makefile
1761 gtk/tests/Makefile
1762 libgail-util/Makefile
1763 modules/Makefile
1764 modules/engines/Makefile
1765 modules/engines/pixbuf/Makefile
1766 modules/engines/ms-windows/Makefile
1767 modules/engines/ms-windows/Theme/Makefile
1768 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1769 modules/input/Makefile
1770 modules/printbackends/Makefile
1771 modules/printbackends/cups/Makefile
1772 modules/printbackends/lpr/Makefile
1773 modules/printbackends/file/Makefile
1774 modules/printbackends/papi/Makefile
1775 modules/printbackends/test/Makefile
1776 perf/Makefile
1777 ])
1778
1779 AC_OUTPUT
1780
1781 # beautify the immodule list a bit
1782 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1783 if test -z "${included_immodules}"; then included_immodules="none"; fi
1784
1785 echo ""
1786 echo "        GTK+ $GTK_VERSION"
1787 echo "        ==========="
1788 echo ""
1789 echo "        GDK backends:         $GDK_BACKENDS"
1790 if test "x$enable_x11_backend" = "xyes"; then
1791 echo "        X11 extensions:       $X_EXTENSIONS"
1792 fi
1793 echo "        Print backends:       $PRINT_BACKENDS"
1794 echo "        Dynamic modules:      $build_dynamic_modules"
1795 echo "        Included immodules:   $included_immodules"
1796 echo "        PackageKit support:   $build_packagekit"
1797 echo "        colord support:       $have_colord"
1798 echo "        Introspection:        $found_introspection"
1799 echo "        Debugging:            $enable_debug"
1800 echo "        Documentation:        $enable_gtk_doc"