Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [2])
  12 m4_define([gtk_minor_version], [91])
  13 m4_define([gtk_micro_version], [7])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.27.5])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.29.2])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.21.0])
  46 GLIB_REQUIRED_VERSION=glib_required_version
  47 PANGO_REQUIRED_VERSION=pango_required_version
  48 ATK_REQUIRED_VERSION=atk_required_version
  49 CAIRO_REQUIRED_VERSION=cairo_required_version
  50 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  51 AC_SUBST(GLIB_REQUIRED_VERSION)
  52 AC_SUBST(PANGO_REQUIRED_VERSION)
  53 AC_SUBST(ATK_REQUIRED_VERSION)
  54 AC_SUBST(CAIRO_REQUIRED_VERSION)
  55 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  56
  57
  58 # Save this value here, since automake will set cflags later
  59 cflags_set=${CFLAGS+set}
  60
  61 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  62 AM_MAINTAINER_MODE([enable])
  63
  64 # Support silent build rules, requires at least automake-1.11. Disable
  65 # by either passing --disable-silent-rules to configure or passing V=1
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 #
  70 # For each of the libraries we build, we define the following
  71 # substituted variables:
  72 #
  73 # foo_PACKAGES:     pkg-config packages this library requires
  74 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  75 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  76 # foo_DEP_LIBS:     All libraries this module requires
  77 # foo_DEP_CFLAGS:   All cflags this module requires
  78
  79
  80 GTK_MAJOR_VERSION=gtk_major_version
  81 GTK_MINOR_VERSION=gtk_minor_version
  82 GTK_MICRO_VERSION=gtk_micro_version
  83 GTK_INTERFACE_AGE=gtk_interface_age
  84 GTK_BINARY_AGE=gtk_binary_age
  85 GTK_VERSION=gtk_version
  86 GTK_API_VERSION=gtk_api_version
  87 GTK_BINARY_VERSION=gtk_binary_version
  88 AC_SUBST(GTK_MAJOR_VERSION)
  89 AC_SUBST(GTK_MINOR_VERSION)
  90 AC_SUBST(GTK_MICRO_VERSION)
  91 AC_SUBST(GTK_INTERFACE_AGE)
  92 AC_SUBST(GTK_BINARY_AGE)
  93 AC_SUBST(GTK_API_VERSION)
  94 AC_SUBST(GTK_VERSION)
  95 AC_SUBST(GTK_BINARY_VERSION)
  96
  97 # libtool versioning
  98 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  99 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 100 #LT_REVISION=$GTK_INTERFACE_AGE
 101 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 102 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 103
 104 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 105 m4_define([lt_revision], [gtk_interface_age])
 106 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 107 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 108 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 109 AC_SUBST(LT_VERSION_INFO)
 110 AC_SUBST(LT_CURRENT_MINUS_AGE)
 111
 112 m4_define([gail_lt_current],[0])
 113 m4_define([gail_lt_revision],[0])
 114 m4_define([gail_lt_age],[0])
 115 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 116 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 117 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 118 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 119
 120 # Checks for programs.
 121 AC_PROG_CC
 122 AC_PROG_CC_C_O
 123 AC_PROG_CC_STDC
 124 AC_PROG_INSTALL
 125 AC_PROG_MAKE_SET
 126
 127
 128 GETTEXT_PACKAGE=gtk30
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 131                    [The prefix for our gettext translation domains.])
 132
 133 AC_CANONICAL_HOST
 134
 135 MATH_LIB=-lm
 136 AC_MSG_CHECKING([for native Win32])
 137 LIB_EXE_MACHINE_FLAG=X86
 138 EXE_MANIFEST_ARCHITECTURE=X86
 139 case "$host" in
 140   *-*-mingw*)
 141     os_win32=yes
 142     gio_can_sniff=no
 143     MATH_LIB=
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       EXE_MANIFEST_ARCHITECTURE=AMD64
 148       ;;
 149     esac
 150     ;;
 151   *)
 152     os_win32=no
 153     ;;
 154 esac
 155 AC_MSG_RESULT([$os_win32])
 156
 157 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 158 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 159
 160 case $host in
 161   *-*-linux*)
 162     os_linux=yes
 163     ;;
 164 esac
 165
 166 dnl
 167 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 168 dnl We use this for an automated test for C++ header correctness.
 169 dnl
 170 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 171 AC_LANG_PUSH([C++])
 172
 173 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 174 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 175
 176 gtk_save_cxxflags="$CXXFLAGS"
 177 CXXFLAGS="$CXXFLAGS -x objective-c++"
 178 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 179 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 180 CXXFLAGS="$gtk_save_cxxflags"
 181 AC_LANG_POP([C++])
 182
 183 if test "$os_win32" = "yes"; then
 184   if test x$enable_static = xyes -o x$enable_static = x; then
 185     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 186     enable_static=no
 187   fi
 188   if test x$enable_shared = xno; then
 189     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 190   fi
 191   enable_shared=yes
 192 fi
 193
 194 dnl Initialize libtool
 195 LT_PREREQ([2.2.6])
 196 LT_INIT([disable-static win32-dll])
 197 # Create libtool early, because it's used in configure
 198 LT_OUTPUT
 199
 200 # Make sure we use 64-bit versions of various file stuff.
 201 AC_SYS_LARGEFILE
 202
 203 AM_PROG_AS
 204 AC_PATH_PROG(NM, nm, nm)
 205
 206 AC_MSG_CHECKING([for some Win32 platform])
 207 case "$host" in
 208   *-*-mingw*|*-*-cygwin*)
 209     platform_win32=yes
 210     ;;
 211   *)
 212     platform_win32=no
 213     ;;
 214 esac
 215 AC_MSG_RESULT([$platform_win32])
 216 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 217
 218 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 219 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 220 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 221
 222 if test "$os_win32" = "yes"; then
 223   AC_CHECK_TOOL(WINDRES, windres, no)
 224   if test "$WINDRES" = no; then
 225     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 226   fi
 227   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 228 fi
 229 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 230
 231 m4_define([debug_default],
 232           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 233
 234 dnl declare --enable-* args and collect ac_help strings
 235 AC_ARG_ENABLE(debug,
 236               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 237                              [turn on debugging @<:@default=debug_default@:>@]),,
 238               enable_debug=debug_default)
 239 AC_ARG_ENABLE(xkb,
 240               [AC_HELP_STRING([--enable-xkb],
 241                               [support XKB [default=maybe]])],,
 242               [enable_xkb="maybe"])
 243 AC_ARG_ENABLE(xinerama,
 244               [AC_HELP_STRING([--enable-xinerama],
 245                               [support xinerama extension if available [default=yes]])],,
 246               [enable_xinerama="yes"])
 247 AC_ARG_ENABLE(rebuilds,
 248               [AC_HELP_STRING([--disable-rebuilds],
 249                               [disable all source autogeneration rules])],,
 250               [enable_rebuilds=yes])
 251
 252 AC_ARG_WITH(xinput,
 253             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 254
 255 if test "$platform_win32" = yes; then
 256   gdktarget=win32
 257 else
 258   gdktarget=x11
 259 fi
 260
 261 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/win32/quartz]] select non-default GDK target],
 262         gdktarget=$with_gdktarget)
 263
 264 AC_SUBST(gdktarget)
 265 case $gdktarget in
 266   x11|win32|quartz) ;;
 267   *) AC_MSG_ERROR([Invalid target for GDK: use x11, quartz or win32.]);;
 268 esac
 269
 270 if test "x$enable_debug" = "xyes"; then
 271   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 272   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 273 else
 274   if test "x$enable_debug" = "xno"; then
 275     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 276   else
 277     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 278   fi
 279 fi
 280
 281
 282 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 283                    [Define if debugging is enabled])
 284
 285
 286 # Build time sanity check...
 287 AM_SANITY_CHECK
 288
 289 changequote(,)dnl
 290 if test "x$GCC" = "xyes"; then
 291   case " $CFLAGS " in
 292   *[\ \ ]-Wall[\ \      ]*) ;;
 293   *) CFLAGS="$CFLAGS -Wall" ;;
 294   esac
 295
 296   if test "x$enable_ansi" = "xyes"; then
 297     case " $CFLAGS " in
 298     *[\ \       ]-ansi[\ \      ]*) ;;
 299     *) CFLAGS="$CFLAGS -ansi" ;;
 300     esac
 301
 302     case " $CFLAGS " in
 303     *[\ \       ]-pedantic[\ \  ]*) ;;
 304     *) CFLAGS="$CFLAGS -pedantic" ;;
 305     esac
 306   fi
 307 fi
 308 changequote([,])dnl
 309
 310 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 311
 312 # Ensure MSVC-compatible struct packing convention is used when
 313 # compiling for Win32 with gcc.
 314 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 315 # gcc2 uses "-fnative-struct".
 316 if test x"$os_win32" = xyes; then
 317   if test x"$GCC" = xyes; then
 318     msnative_struct=''
 319     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 320     if test -z "$ac_cv_prog_CC"; then
 321       our_gcc="$CC"
 322     else
 323       our_gcc="$ac_cv_prog_CC"
 324     fi
 325     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 326       2.)
 327         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 328           msnative_struct='-fnative-struct'
 329         fi
 330         ;;
 331       *)
 332         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 333           msnative_struct='-mms-bitfields'
 334         fi
 335         ;;
 336     esac
 337     if test x"$msnative_struct" = x ; then
 338       AC_MSG_RESULT([no way])
 339       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 340     else
 341       CFLAGS="$CFLAGS $msnative_struct"
 342       AC_MSG_RESULT([${msnative_struct}])
 343     fi
 344   fi
 345 fi
 346
 347 ## Initial sanity check, done here so that users get told they
 348 ## have the wrong dependencies as early in the process as possible.
 349 ## Later on we actually use the cflags/libs from separate pkg-config
 350 ## calls. Oh, also the later pkg-config calls don't include
 351 ## the version requirements since those make the module lists
 352 ## annoying to construct
 353 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 354   [glib-2.0 >= glib_required_version dnl
 355    atk >= atk_required_version dnl
 356    pango >= pango_required_version dnl
 357    cairo >= cairo_required_version dnl
 358    cairo-gobject >= cairo_required_version dnl
 359    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 360
 361 ## In addition to checking that cairo is present, we also need to
 362 ## check that the correct cairo backend is there. E.g. if the GDK
 363 ## target is win32 we need the cairo-win32 backend and so on.
 364 cairo_backend=$gdktarget
 365
 366 # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 367 # backend names are identical.
 368 if test "x$cairo_backend" = "xx11"; then
 369    cairo_backend=xlib
 370 fi
 371 PKG_CHECK_MODULES(CAIRO_BACKEND,
 372   [cairo-$cairo_backend >= cairo_required_version])
 373
 374 if test "$os_win32" != yes; then
 375     # libtool option to control which symbols are exported
 376     # right now, symbols starting with _ are not exported
 377     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 378 else
 379     # We currently use .def files on Windows (for gdk and gtk)
 380     LIBTOOL_EXPORT_OPTIONS=
 381 fi
 382 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 383
 384 dnl ******************************************************
 385 dnl * See whether to include shared library dependencies *
 386 dnl ******************************************************
 387
 388 AC_ARG_ENABLE(explicit-deps,
 389               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 390                               [use explicit dependencies in .pc files [default=auto]])],,
 391               [enable_explicit_deps=auto])
 392
 393 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 394 case $enable_explicit_deps in
 395   auto)
 396     export SED
 397     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 398     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 399       enable_explicit_deps=yes
 400     else
 401       enable_explicit_deps=no
 402     fi
 403   ;;
 404   yes|no)
 405   ;;
 406   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 407   ;;
 408 esac
 409 AC_MSG_RESULT($enable_explicit_deps)
 410
 411 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 412
 413 # define a MAINT-like variable REBUILD which is set if Perl
 414 # and awk are found, so autogenerated sources can be rebuilt
 415
 416 AC_PATH_PROGS(PERL, perl5 perl)
 417
 418 # We would like indent, but don't require it.
 419 AC_CHECK_PROG(INDENT, indent, indent)
 420
 421 REBUILD=\#
 422 if test "x$enable_rebuilds" = "xyes" && \
 423      test -n "$PERL" && \
 424      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 425   REBUILD=
 426 fi
 427 AC_SUBST(REBUILD)
 428
 429 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 430 AC_CHECK_FUNCS(localtime_r)
 431
 432 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 433 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 434 AC_TRY_LINK([#include <langinfo.h>], [
 435 char c;
 436 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 437 ], gtk_ok=yes, gtk_ok=no)
 438 AC_MSG_RESULT($gtk_ok)
 439 if test "$gtk_ok" = "yes"; then
 440   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 441             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 442 fi
 443
 444 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 445 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 446 AC_TRY_LINK([#include <langinfo.h>], [
 447 char c;
 448 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 449 ], gtk_ok=yes, gtk_ok=no)
 450 AC_MSG_RESULT($gtk_ok)
 451 if test "$gtk_ok" = "yes"; then
 452   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 453             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 454 fi
 455
 456 # _NL_PAPER_HEIGHT is an enum and not a define
 457 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 458 AC_TRY_LINK([#include <langinfo.h>], [
 459 char c;
 460 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 461 ], gtk_ok=yes, gtk_ok=no)
 462 AC_MSG_RESULT($gtk_ok)
 463 if test "$gtk_ok" = "yes"; then
 464   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 465             [Define if _NL_PAPER_HEIGHT is available])
 466 fi
 467
 468 # _NL_PAPER_WIDTH is an enum and not a define
 469 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 470 AC_TRY_LINK([#include <langinfo.h>], [
 471 char c;
 472 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 473 ], gtk_ok=yes, gtk_ok=no)
 474 AC_MSG_RESULT($gtk_ok)
 475 if test "$gtk_ok" = "yes"; then
 476   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 477             [Define if _NL_PAPER_WIDTH is available])
 478 fi
 479
 480 # i18n stuff
 481 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 482 AM_GLIB_GNU_GETTEXT
 483 LIBS="$LIBS $INTLLIBS"
 484 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 485         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 486       esac])
 487
 488 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 489 dnl po-properties/POTFILES during configure; see GNOME #573515.
 490 dnl
 491 dnl Generate list of files to be processed by xgettext which will
 492 dnl be included in po-properties/Makefile.
 493 test -d po-properties || mkdir po-properties
 494 if test "x$srcdir" != "x."; then
 495   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 496     popropsrcprefix="$srcdir/"
 497   else
 498     popropsrcprefix="../$srcdir/"
 499   fi
 500 else
 501   popropsrcprefix="../"
 502 fi
 503 rm -f po-properties/POTFILES
 504 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 505 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 506 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 507
 508 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 509
 510 dnl The DU4 header files don't provide library prototypes unless
 511 dnl -std1 is given to the native cc.
 512 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 513
 514 gtk_save_LIBS=$LIBS
 515 LIBS="$LIBS -lm"
 516 AC_TRY_RUN([#include <math.h>
 517              int main (void) { return (log(1) != log(1.)); }],
 518      AC_MSG_RESULT(none needed),
 519      gtk_save_CFLAGS="$CFLAGS"
 520      CFLAGS="$CFLAGS -std1"
 521      AC_TRY_RUN([#include <math.h>
 522                  int main (void) { return (log(1) != log(1.)); }],
 523          AC_MSG_RESULT(-std1),
 524          AC_MSG_RESULT()
 525          CFLAGS="$gtk_save_CFLAGS"
 526          AC_MSG_WARN(
 527                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 528          true
 529      ),
 530      AC_MSG_RESULT(none needed)
 531 )
 532 LIBS=$gtk_save_LIBS
 533
 534 AC_MSG_CHECKING(for the BeOS)
 535 case $host in
 536   *-*-beos*)
 537     AC_MSG_RESULT(yes)
 538     MATH_LIB=
 539   ;;
 540   *)
 541     AC_MSG_RESULT(no)
 542   ;;
 543 esac
 544
 545 AC_SUBST(MATH_LIB)
 546 #
 547 # see bug 162979
 548 #
 549 AC_MSG_CHECKING(for HP-UX)
 550 case $host_os in
 551   hpux9* | hpux10* | hpux11*)
 552     AC_MSG_RESULT(yes)
 553     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 554   ;;
 555   *)
 556     AC_MSG_RESULT(no)
 557   ;;
 558 esac
 559
 560 dnl NeXTStep cc seems to need this
 561 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 562 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 563   AC_MSG_RESULT(none needed),
 564   gtk_save_CFLAGS="$CFLAGS"
 565   CFLAGS="$CFLAGS -posix"
 566   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 567     AC_MSG_RESULT(-posix),
 568     AC_MSG_RESULT()
 569     CFLAGS="$gtk_save_CFLAGS"
 570     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 571
 572 #
 573 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 574 #
 575
 576 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 577
 578 AM_PATH_GLIB_2_0(glib_required_version, :,
 579   AC_MSG_ERROR([
 580 *** GLIB glib_required_version or better is required. The latest version of
 581 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 582   gobject gmodule-no-export gthread)
 583
 584 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 585 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 586 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 587 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 588   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 589 fi
 590
 591 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 592
 593
 594 dnl
 595 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 596 dnl
 597 gtk_save_LIBS=$LIBS
 598 LIBS="$LIBS $GLIB_LIBS"
 599 AC_CHECK_FUNCS(bind_textdomain_codeset)
 600 LIBS=$gtk_save_LIBS
 601
 602 AC_CHECK_HEADERS(pwd.h,
 603                  AC_DEFINE(HAVE_PWD_H, 1,
 604                            [Define to 1 if pwd.h is available]))
 605 AC_CHECK_HEADERS(sys/time.h,
 606                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 607                            [Define to 1 if time.h is available]))
 608 AC_CHECK_HEADERS(unistd.h,
 609                  AC_DEFINE(HAVE_UNISTD_H, 1,
 610                            [Define to 1 if unistd.h is available]))
 611 AC_CHECK_HEADERS(ftw.h,
 612                  AC_DEFINE(HAVE_FTW_H, 1,
 613                            [Define to 1 if ftw.h is available]))
 614
 615 AC_MSG_CHECKING([for GNU ftw extensions])
 616 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 617 #define _GNU_SOURCE
 618 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 619 if test $gtk_ok = yes; then
 620     AC_MSG_RESULT([yes])
 621     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 622 else
 623     AC_MSG_RESULT([no])
 624 fi
 625
 626 saved_cflags="$CFLAGS"
 627 saved_ldflags="$LDFLAGS"
 628
 629
 630 # Checks for header files.
 631 AC_HEADER_STDC
 632
 633 # Checks for typedefs, structures, and compiler characteristics.
 634 AC_C_CONST
 635
 636 # Checks for library functions.
 637 AC_TYPE_SIGNAL
 638 AC_FUNC_MMAP
 639
 640 AC_CHECK_FUNCS(mallinfo)
 641 AC_CHECK_FUNCS(getresuid)
 642 AC_TYPE_UID_T
 643
 644 # Check if <sys/select.h> needs to be included for fd_set
 645 AC_MSG_CHECKING([for fd_set])
 646 AC_TRY_COMPILE([#include <sys/types.h>],
 647         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 648 if test $gtk_ok = yes; then
 649     AC_MSG_RESULT([yes, found in sys/types.h])
 650 else
 651     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 652     if test $gtk_ok = yes; then
 653         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 654                   [Define to 1 if sys/select.h is available])
 655         AC_MSG_RESULT([yes, found in sys/select.h])
 656     else
 657         AC_DEFINE(NO_FD_SET, 1,
 658                   [Define to 1 if fd_set is not available])
 659         AC_MSG_RESULT(no)
 660     fi
 661 fi
 662
 663 # Check for uxtheme.h (for MS-Windows Engine)
 664 AC_MSG_CHECKING(for uxtheme.h)
 665 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 666 if test $gtk_uxtheme_h = yes; then
 667    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 668 fi
 669 AC_MSG_RESULT($gtk_uxtheme_h)
 670
 671 # Checks for gdkspawn
 672 AC_CHECK_HEADERS(crt_externs.h)
 673 AC_CHECK_FUNCS(_NSGetEnviron)
 674
 675 AC_MSG_CHECKING(whether to build dynamic modules)
 676
 677 AC_ARG_ENABLE(modules,
 678               [AC_HELP_STRING([--disable-modules],
 679                               [disable dynamic module loading])])
 680
 681 dynworks=false
 682 deps=
 683 if test x$enable_modules = xno; then
 684     AC_MSG_RESULT(no)
 685 else
 686     AC_MSG_RESULT(yes)
 687     AC_MSG_CHECKING(whether dynamic modules work)
 688     ## for loop is to strip newline
 689     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 690     for I in $tmp; do
 691         dynworks=$I
 692     done
 693
 694     dnl Now we check to see if our libtool supports shared lib deps
 695     dnl (in a rather ugly way even)
 696     if $dynworks; then
 697         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 698         module_deplibs_check=`$module_libtool_config | \
 699             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 700             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 701         if test "x$module_deplibs_check" = "xnone" || \
 702            test "x$module_deplibs_check" = "xunknown" || \
 703            test "x$module_deplibs_check" = "x"; then
 704             dynworks=false
 705         fi
 706     fi
 707
 708     if $dynworks; then
 709         AC_DEFINE(USE_GMODULE, 1,
 710                   [Define to 1 if gmodule works and should be used])
 711         AC_MSG_RESULT(yes)
 712     else
 713         AC_MSG_RESULT(no)
 714     fi
 715 fi
 716
 717 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 718
 719 #
 720 # Allow building some or all immodules included
 721 #
 722 AC_MSG_CHECKING(immodules to build)
 723
 724 dnl due to an autoconf bug, commas in the first arg to
 725 dnl AC_HELP_STRING cause problems.
 726 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 727 dnl                [build the specified input method modules into gtk])
 728 AC_ARG_WITH(included_immodules,
 729 [  --with-included-immodules=MODULE1,MODULE2,...
 730                           build the specified input methods into gtk])
 731
 732 if $dynworks; then
 733    :
 734 else
 735    ## if the option was specified, leave it; otherwise disable included immodules
 736    if test x$with_included_immodules = xno; then
 737            with_included_immodules=yes
 738    fi
 739 fi
 740
 741 all_immodules="am-et,cedilla,cyrillic-translit"
 742 if test "$gdktarget" = "win32"; then
 743    all_immodules="${all_immodules},ime"
 744 fi
 745 all_immodules="${all_immodules},inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr"
 746 if test "$gdktarget" = "x11"; then
 747    all_immodules="${all_immodules},xim"
 748 fi
 749
 750 included_immodules=""
 751 # If the switch specified without listing any specific ones, include all
 752 if test "x$with_included_immodules" = xyes ; then
 753   included_immodules="$all_immodules"
 754 else
 755   included_immodules="$with_included_immodules"
 756 fi
 757
 758 AC_MSG_RESULT($included_immodules)
 759 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 760
 761 INCLUDED_IMMODULE_OBJ=
 762 INCLUDED_IMMODULE_DEFINE=
 763
 764 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 765 for immodule in $included_immodules; do
 766  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 767  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 768    :
 769  else
 770    AC_MSG_ERROR([the specified input method $immodule does not exist])
 771  fi
 772
 773  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 774  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 775  eval INCLUDE_$immodule_underscores=yes
 776 done
 777 IFS="$gtk_save_ifs"
 778 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 779 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 780
 781 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 782 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 783 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 784 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 785 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 786 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 787 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 788 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 789 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 790 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 791 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 792 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 793
 794 AC_HEADER_SYS_WAIT
 795
 796 AC_TYPE_SIGNAL
 797
 798 # Checks to see whether we should include mediaLib
 799 # support.
 800 #
 801 AC_CHECK_HEADER(sys/systeminfo.h,
 802                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 803                           [Define to 1 if sys/systeminfo.h is available]))
 804 AC_CHECK_HEADER(sys/sysinfo.h,
 805                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 806                           [Define to 1 if sys/sysinfo.h is available]))
 807
 808 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 809
 810 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 811
 812 if test $cross_compiling = yes; then
 813   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 814   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 815     REBUILD_PNGS=#
 816   fi
 817 fi
 818
 819 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 820
 821 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 822    test "x$REBUILD_PNGS" = "x#" ; then
 823      AC_MSG_ERROR([
 824 *** gtkbuiltincache.h is not in the tree, and cannot be built
 825 *** because you don't have libpng, or (when cross-compiling) you
 826 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 827 fi
 828
 829 ########################################
 830 # Windowing system checks
 831 ########################################
 832
 833 GDK_EXTRA_LIBS=
 834 GDK_EXTRA_CFLAGS=
 835
 836 # GTK+ uses some X calls, so needs to link against X directly
 837 GTK_DEP_PACKAGES_FOR_X=
 838 GTK_DEP_LIBS_FOR_X=
 839
 840 if test "x$gdktarget" = "xx11"; then
 841   X_PACKAGES=fontconfig
 842
 843   #
 844   # We use fontconfig very peripherally when decoding the default
 845   # settings.
 846   #
 847   if $PKG_CONFIG --exists fontconfig; then : ; else
 848     AC_MSG_ERROR([
 849 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 850   fi
 851
 852   #
 853   # Check for basic X packages; we use pkg-config if available
 854   #
 855   if $PKG_CONFIG --exists x11 xext; then
 856     have_base_x_pc=true
 857     X_PACKAGES="$X_PACKAGES x11 xext"
 858     x_libs="`$PKG_CONFIG --libs x11 xext`"
 859     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 860
 861     # Strip out any .la files that pkg-config might give us (this happens
 862     # with -uninstalled.pc files)
 863     x_libs_for_checks=
 864     for I in $x_libs ; do
 865       case $I in
 866         *.la) ;;
 867         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 868       esac
 869     done
 870
 871     GTK_PACKAGES_FOR_X="x11"
 872   else
 873     have_base_x_pc=false
 874     AC_PATH_XTRA
 875     if test x$no_x = xyes ; then
 876       AC_MSG_ERROR([X development libraries not found])
 877     fi
 878
 879     x_cflags="$X_CFLAGS"
 880     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 881
 882     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 883   fi
 884
 885   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 886   x_extra_libs=
 887
 888   gtk_save_cppflags="$CPPFLAGS"
 889   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 890
 891   gtk_save_LIBS=$LIBS
 892   LIBS="$x_libs_for_checks $LIBS"
 893
 894   # Sanity check for the X11 and Xext libraries. While everything we need from
 895   # Xext is optional, the chances a system has *none* of these things is so
 896   # small that we just unconditionally require it.
 897   AC_CHECK_FUNC(XOpenDisplay, :,
 898                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 899   AC_CHECK_FUNC(XextFindDisplay, :,
 900                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 901
 902   # Check for xReply
 903
 904   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 905   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 906       [xReply *rep;],
 907       [AC_MSG_RESULT([no])],
 908       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 909 #include <X11/Xlibint.h>],
 910            [xReply *rep;],
 911            [AC_MSG_RESULT([yes])
 912             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
 913                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
 914            [AC_MSG_RESULT([unknown])
 915             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 916
 917   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 918
 919   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 920
 921   # Generic X11R6 check needed for XIM support; we could
 922   # probably use this to replace the above, but we'll
 923   # leave the separate checks for XConvertCase and XInternAtoms
 924   # for clarity
 925
 926   have_x11r6=false
 927   AC_CHECK_FUNC(XAddConnectionWatch,
 928       have_x11r6=true)
 929
 930   if $have_x11r6; then
 931     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
 932   fi
 933   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
 934
 935   # Check for XKB support.
 936
 937   if test "x$enable_xkb" = "xyes"; then
 938         AC_MSG_WARN(XKB support explicitly enabled)
 939         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
 940   elif test "x$enable_xkb" = "xmaybe"; then
 941         AC_CHECK_FUNC(XkbQueryExtension,
 942                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
 943   else
 944         AC_MSG_WARN(XKB support explicitly disabled)
 945   fi
 946
 947   # Check for shaped window extension
 948
 949   AC_CHECK_FUNC(XShapeCombineMask, :,
 950      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
 951
 952   # X SYNC check
 953   gtk_save_CFLAGS="$CFLAGS"
 954   CFLAGS="$CFLAGS $x_cflags"
 955
 956   AC_CHECK_FUNC(XSyncQueryExtension,
 957       [AC_CHECK_HEADER(X11/extensions/sync.h,
 958           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
 959           :, [#include <X11/Xlib.h>])])
 960
 961   CFLAGS="$gtk_save_CFLAGS"
 962
 963   if test "x$enable_xinerama" = "xyes"; then
 964     # Check for Xinerama extension (Solaris impl or Xfree impl)
 965     gtk_save_cppflags="$CPPFLAGS"
 966     CPPFLAGS="$CPPFLAGS $x_cflags"
 967
 968     # Check for XFree
 969     AC_MSG_CHECKING(for Xinerama support on XFree86)
 970
 971     have_xfree_xinerama=false
 972     if $PKG_CONFIG --exists xinerama ; then
 973        have_xfree_xinerama=true
 974        X_PACKAGES="$X_PACKAGES xinerama"
 975     else
 976        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
 977            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
 978            [GTK_ADD_LIB(x_extra_libs,Xinerama)
 979            have_xfree_xinerama=true], :,
 980            [#include <X11/Xlib.h>])])
 981     fi
 982
 983     if $have_xfree_xinerama ; then
 984       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
 985                 [Define to 1 if XFree Xinerama is available])
 986       AC_DEFINE(HAVE_XINERAMA, 1,
 987                 [Define to 1 is Xinerama is available])
 988       AC_MSG_RESULT(yes)
 989     else
 990       AC_MSG_RESULT(no)
 991
 992       case "$host" in
 993         *-*-solaris*)
 994             # Check for solaris
 995             AC_MSG_CHECKING(for Xinerama support on Solaris)
 996
 997             have_solaris_xinerama=false
 998             AC_CHECK_FUNC(XineramaGetInfo,
 999                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1000                     [have_solaris_xinerama=true], :,
1001                     [#include <X11/Xlib.h>])])
1002
1003             if $have_solaris_xinerama ; then
1004               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1005                         [Define to 1 if solaris xinerama is available])
1006               AC_DEFINE(HAVE_XINERAMA, 1,
1007                         [Define to 1 if xinerama is available])
1008               AC_MSG_RESULT(yes)
1009             else
1010               AC_MSG_RESULT(no)
1011             fi
1012             ;;
1013         *)
1014             ;;
1015       esac
1016     fi
1017   fi
1018
1019   # set up things for XInput
1020   if test "x$with_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1021     have_xinput=yes
1022
1023     AC_DEFINE(XINPUT_XFREE, 1,
1024               [Define to 1 if XFree XInput should be used])
1025
1026     X_PACKAGES="$X_PACKAGES xi"
1027
1028     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1029                     have_xinput2=yes; AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1030   else
1031     AC_DEFINE(XINPUT_NONE, 1,
1032               [Define to 1 if no XInput should be used])
1033   fi
1034
1035   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1036   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1037
1038   # Check for the RANDR extension
1039   if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1040      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1041
1042      X_PACKAGES="$X_PACKAGES xrandr"
1043   fi
1044
1045   # Checks for Xcursor library
1046
1047   if $PKG_CONFIG --exists xcursor ; then
1048     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1049
1050     X_PACKAGES="$X_PACKAGES xcursor"
1051   fi
1052
1053   # Checks for XFixes extension
1054
1055   if $PKG_CONFIG --exists xfixes ; then
1056     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1057
1058     X_PACKAGES="$X_PACKAGES xfixes"
1059     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1060   fi
1061
1062   # Checks for Xcomposite extension
1063
1064   if $PKG_CONFIG --exists xcomposite ; then
1065     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1066
1067     X_PACKAGES="$X_PACKAGES xcomposite"
1068     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1069   fi
1070
1071   # Checks for Xdamage extension
1072
1073   if $PKG_CONFIG --exists xdamage ; then
1074     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1075
1076     X_PACKAGES="$X_PACKAGES xdamage"
1077     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1078   fi
1079
1080   if $have_base_x_pc ; then
1081     GDK_EXTRA_LIBS="$x_extra_libs"
1082   else
1083     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1084   fi
1085
1086   CPPFLAGS="$gtk_save_cppflags"
1087   LIBS="$gtk_save_libs"
1088
1089   AM_CONDITIONAL(USE_X11, true)
1090 else
1091   XPACKAGES=
1092
1093   AM_CONDITIONAL(XINPUT_XFREE, false)
1094   AM_CONDITIONAL(XINPUT_2, false)
1095   AM_CONDITIONAL(USE_X11, false)
1096   AM_CONDITIONAL(HAVE_X11R6, false)
1097 fi
1098
1099 if test "x$gdktarget" = "xwin32"; then
1100   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1101   AM_CONDITIONAL(USE_WIN32, true)
1102 else
1103   AM_CONDITIONAL(USE_WIN32, false)
1104 fi
1105
1106 if test "x$gdktarget" = "xquartz"; then
1107   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1108   AM_CONDITIONAL(USE_QUARTZ, true)
1109 else
1110   AM_CONDITIONAL(USE_QUARTZ, false)
1111 fi
1112
1113 # Check for Pango flags
1114
1115 if test "x$gdktarget" = "xwin32"; then
1116         PANGO_PACKAGES="pangowin32 pangocairo"
1117 else
1118         PANGO_PACKAGES="pango pangocairo"
1119 fi
1120
1121 AC_MSG_CHECKING(Pango flags)
1122 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1123         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1124         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1125
1126         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1127 else
1128         AC_MSG_ERROR([
1129 *** Pango not found. Pango built with Cairo support is required
1130 *** to build GTK+. See http://www.pango.org for Pango information.
1131 ])
1132 fi
1133
1134 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1135
1136 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1137         :
1138 else
1139         gtk_save_LIBS="$LIBS"
1140         LIBS="$PANGO_LIBS $LIBS"
1141         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1142 *** Can't link to Pango. Pango is required to build
1143 *** GTK+. For more information see http://www.pango.org]))
1144         LIBS="$gtk_save_LIBS"
1145 fi
1146
1147 CFLAGS="$saved_cflags"
1148 LDFLAGS="$saved_ldflags"
1149
1150 # Pull in gio-unix for GDesktopAppInfo usage, see at least gdkapplaunchcontext-x11.c
1151 if test "x$gdktarget" = "xx11"; then
1152   GDK_PACKAGES="$PANGO_PACKAGES gio-unix-2.0 $X_PACKAGES gdk-pixbuf-2.0 cairo-$cairo_backend cairo-gobject"
1153 else
1154   GDK_PACKAGES="$PANGO_PACKAGES gio-2.0 gdk-pixbuf-2.0 cairo-$cairo_backend cairo-gobject"
1155 fi
1156
1157 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1158 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1159 #
1160 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1161 # into the pkg-config files
1162 #
1163 if test $enable_explicit_deps != yes ; then
1164   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0"
1165   GDK_EXTRA_LIBS=
1166 fi
1167
1168 AC_SUBST(GDK_PACKAGES)
1169 AC_SUBST(GDK_EXTRA_LIBS)
1170 AC_SUBST(GDK_EXTRA_CFLAGS)
1171 AC_SUBST(GDK_DEP_LIBS)
1172 AC_SUBST(GDK_DEP_CFLAGS)
1173
1174
1175 ########################################
1176 # Check for Accessibility Toolkit flags
1177 ########################################
1178
1179 ATK_PACKAGES=atk
1180 AC_MSG_CHECKING(ATK flags)
1181 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1182         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1183         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1184
1185         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1186 else
1187         AC_MSG_ERROR([
1188 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1189 *** to build GTK+.
1190 ])
1191 fi
1192
1193 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1194         :
1195 else
1196         gtk_save_LIBS="$LIBS"
1197         LIBS="$ATK_LIBS $LIBS"
1198         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1199                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1200                 *** to build GTK+]))
1201         LIBS="$gtk_save_LIBS"
1202 fi
1203
1204 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1205 if test "x$gdktarget" = "xx11"; then
1206   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1207 fi
1208 GTK_EXTRA_LIBS=
1209 GTK_EXTRA_CFLAGS=
1210 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1211 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1212
1213 if test x"$os_win32" = xyes; then
1214   GTK_EXTRA_CFLAGS="$msnative_struct"
1215 fi
1216
1217 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1218 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1219 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1220 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1221
1222 AC_SUBST(GTK_PACKAGES)
1223 AC_SUBST(GTK_EXTRA_LIBS)
1224 AC_SUBST(GTK_EXTRA_CFLAGS)
1225 AC_SUBST(GTK_DEP_LIBS)
1226 AC_SUBST(GTK_DEP_CFLAGS)
1227
1228 AC_SUBST(GLIB_PREFIX)
1229 AC_SUBST(ATK_PREFIX)
1230 AC_SUBST(PANGO_PREFIX)
1231 AC_SUBST(CAIRO_PREFIX)
1232
1233 AC_SUBST(GTK_DEBUG_FLAGS)
1234 AC_SUBST(GTK_XIM_FLAGS)
1235
1236 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1237 AC_SUBST(GDK_PIXBUF_LIBS)
1238
1239 ########################
1240 # Checks needed for gail
1241 ########################
1242
1243 old_LIBS="$LIBS"
1244 dnl Checks for inet libraries:
1245 AC_SEARCH_LIBS(gethostent, nsl)
1246 AC_SEARCH_LIBS(setsockopt, socket)
1247 AC_SEARCH_LIBS(connect, inet)
1248
1249 dnl check for the sockaddr_un.sun_len member
1250 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1251                 [struct_sockaddr_un_sun_len=true],
1252                 [struct_sockaddr_un_suin_len=false],
1253                 [#include <sys/types.h>
1254                  #include <sys/un.h>]
1255                 )
1256 case $struct_sockaddr_un_sun_len in
1257         true)
1258                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1259                                    [Have the sockaddr_un.sun_len member])
1260                 ;;
1261         *)
1262                 ;;
1263 esac
1264
1265 GAIL_INET_LIBS="$LIBS"
1266 AC_SUBST([GAIL_INET_LIBS])
1267
1268 LIBS="$old_LIBS"
1269
1270 ################################################################
1271 # Printing system checks
1272 ################################################################
1273
1274 AC_ARG_ENABLE(cups,
1275               [AC_HELP_STRING([--disable-cups]
1276                               [disable cups print backend])],,
1277               [enable_cups=auto])
1278
1279 if test "x$enable_cups" = "xno"; then
1280   AM_CONDITIONAL(HAVE_CUPS, false)
1281 else
1282   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1283   if test "x$CUPS_CONFIG" = "xno"; then
1284     if test "x$enable_cups" = "xauto"; then
1285       AM_CONDITIONAL(HAVE_CUPS, false)
1286     else
1287       AC_MSG_ERROR([
1288 *** cups not found.
1289 ])
1290     fi
1291   else
1292     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1293     CUPS_LIBS=`$CUPS_CONFIG --libs`
1294
1295     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1296     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1297     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1298
1299     if test $CUPS_API_MAJOR -gt 1 -o \
1300             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1301       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1302                 [Define to 1 if CUPS 1.2 API is available])
1303     fi
1304
1305     AC_SUBST(CUPS_API_MAJOR)
1306     AC_SUBST(CUPS_API_MINOR)
1307     AC_SUBST(CUPS_CFLAGS)
1308     AC_SUBST(CUPS_LIBS)
1309
1310     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1311
1312     AM_CONDITIONAL(HAVE_CUPS, true)
1313
1314     gtk_save_cflags="$CFLAGS"
1315     CFLAGS="$CUPS_CFLAGS"
1316     AC_TRY_COMPILE([#include <cups/http.h>],
1317                    [http_t http; char *s = http.authstring;],
1318                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1319                               [Define if cups http_t authstring field is accessible])],)
1320     CFLAGS="$gtk_save_cflags"
1321
1322     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1323
1324     gtk_save_libs="$LIBS"
1325     LIBS="$CUPS_LIBS"
1326     AC_CHECK_FUNCS(httpGetAuthString)
1327     LIBS="$gtk_save_libs"
1328   fi
1329 fi
1330
1331 # Checks to see if we should compile with PAPI backend for GTK+
1332 #
1333
1334 AC_ARG_ENABLE(papi,
1335               [AC_HELP_STRING([--disable-papi]
1336                               [disable papi print backend])],,
1337              [enable_papi=auto])
1338
1339 if test "x$enable_papi" = "xno"; then
1340   AM_CONDITIONAL(HAVE_PAPI, false)
1341 else
1342   AC_MSG_CHECKING(libpapi)
1343   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1344   if test $have_papi = yes; then
1345     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1346   fi
1347   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1348   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1349     AC_MSG_ERROR([
1350 *** papi not found.
1351 ])
1352   fi
1353 fi
1354
1355 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1356
1357 gtk_save_cppflags="$CPPFLAGS"
1358 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1359
1360 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1361 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1362 *** backend enabled.]))
1363
1364 if test "$os_win32" != "yes"; then
1365   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1366 *** Can't find cairo-ps.h. You must build Cairo with the
1367 *** postscript backend enabled.]))
1368
1369   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1370 *** Can't find cairo-svg.h. You must build Cairo with the
1371 *** svg backend enabled.]))
1372 fi
1373
1374 CPPFLAGS="$gtk_save_cppflags"
1375
1376
1377 AC_ARG_ENABLE(test-print-backend,
1378               [AC_HELP_STRING([--enable-test-print-backend],
1379                               [build test print backend])],,
1380               [enable_test_print_backend=no])
1381 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1382
1383
1384 ################################################################
1385 # Strip -export-dynamic from the link lines of various libraries
1386 ################################################################
1387
1388 #
1389 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1390 #  but this flag is only meaningful for executables. For libraries
1391 #  the effect is undefined; what it causes on Linux is that the
1392 #  export list from -export-symbols-regex is ignored and everything
1393 #  is exported
1394 #
1395 # We are using gmodule-no-export now, but I'm leaving the stripping
1396 # code in place for now, since pango and atk still require gmodule.
1397 export SED
1398 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1399 if test -n "$export_dynamic"; then
1400   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1401   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1402 fi
1403
1404 #############
1405 # GSettings #
1406 #############
1407
1408 GLIB_GSETTINGS
1409
1410 ##################################################
1411 # GObject introspection
1412 ##################################################
1413
1414 GOBJECT_INTROSPECTION_CHECK([0.9.3])
1415
1416 ##################################################
1417 # Packagekit module
1418 #################################################
1419
1420 AC_ARG_ENABLE(packagekit,
1421               AC_HELP_STRING([--disable-packagekit],
1422                              [build packagekit open with module]))
1423
1424 ENABLE_PACKAGEKIT=
1425 if test "os_win32" != "yes"; then
1426         if test "x$enable_packagekit" != "xno"; then
1427                 ENABLE_PACKAGEKIT=1
1428                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1429         fi
1430 fi
1431
1432 AC_SUBST(ENABLE_PACKAGEKIT)
1433 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$ENABLE_PACKAGEKIT" = "x1")
1434
1435 ##################################################
1436 # Checks for gtk-doc and docbook-tools
1437 ##################################################
1438
1439 GTK_DOC_CHECK([1.11])
1440
1441 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1442 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1443
1444 AC_ARG_ENABLE(man,
1445               [AC_HELP_STRING([--enable-man],
1446                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1447               enable_man=no)
1448
1449 if test "${enable_man}" != no; then
1450   dnl
1451   dnl Check for xsltproc
1452   dnl
1453   AC_PATH_PROG([XSLTPROC], [xsltproc])
1454   if test -z "$XSLTPROC"; then
1455     enable_man=no
1456   fi
1457
1458   dnl check for DocBook DTD and stylesheets in the local catalog.
1459   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1460      [DocBook XML DTD V4.1.2],,enable_man=no)
1461   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1462      [DocBook XSL Stylesheets],,enable_man=no)
1463 fi
1464
1465 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1466
1467
1468 ##################################################
1469 # Output commands
1470 ##################################################
1471
1472 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1473         outfile=gdkconfig.h-tmp
1474         cat > $outfile <<\_______EOF
1475 /* gdkconfig.h
1476  *
1477  * This is a generated file.  Please modify `configure.ac'
1478  */
1479
1480 #ifndef __GDKCONFIG_H__
1481 #define __GDKCONFIG_H__
1482
1483 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1484 #error "Only <gdk/gdk.h> can be included directly."
1485 #endif
1486
1487 #include <glib.h>
1488
1489 G_BEGIN_DECLS
1490
1491 #ifndef GSEAL
1492 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
1493 #  ifdef GSEAL_ENABLE
1494 #    define GSEAL(ident)      _g_sealed__ ## ident
1495 #  else
1496 #    define GSEAL(ident)      ident
1497 #  endif
1498 #endif /* !GSEAL */
1499
1500 _______EOF
1501
1502         cat >>$outfile <<_______EOF
1503 $gdk_windowing
1504 _______EOF
1505
1506         cat >>$outfile <<_______EOF
1507
1508 G_END_DECLS
1509
1510 #endif  /* __GDKCONFIG_H__ */
1511 _______EOF
1512
1513
1514         if cmp -s $outfile gdk/gdkconfig.h; then
1515           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1516           rm -f $outfile
1517         else
1518           mv $outfile gdk/gdkconfig.h
1519         fi
1520 ],[
1521 gdk_windowing=''
1522 if expr "$gdktarget" : ".*x11.*" > /dev/null ; then
1523   gdk_windowing+='
1524 #define GDK_WINDOWING_X11'
1525 fi
1526 if expr "$gdktarget" : ".*win32.*" > /dev/null ; then
1527   gdk_windowing+='
1528 #define GDK_NATIVE_WINDOW_POINTER
1529 #define GDK_WINDOWING_WIN32'
1530 fi
1531 if expr "$gdktarget" : ".*quartz.*" > /dev/null ; then
1532   gdk_windowing='
1533 #define GDK_WINDOWING_QUARTZ'
1534 fi
1535 ])
1536
1537 dnl
1538 dnl Check for -Bsymbolic-functions linker flag used to avoid
1539 dnl intra-library PLT jumps, if available.
1540 dnl
1541 AC_ARG_ENABLE(Bsymbolic,
1542               [AC_HELP_STRING([--disable-Bsymbolic],
1543                               [avoid linking with -Bsymbolic])],,
1544               [SAVED_LDFLAGS="${LDFLAGS}"
1545                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1546                LDFLAGS=-Wl,-Bsymbolic-functions
1547                AC_TRY_LINK([], [int main (void) { return 0; }],
1548                            AC_MSG_RESULT(yes)
1549                            enable_Bsymbolic=yes,
1550                            AC_MSG_RESULT(no)
1551                            enable_Bsymbolic=no)
1552                LDFLAGS="${SAVED_LDFLAGS}"])
1553
1554 if test "x${enable_Bsymbolic}" == "xyes"; then
1555   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1556 fi
1557 AC_SUBST(GTK_LINK_FLAGS)
1558
1559 AC_CONFIG_FILES([
1560 config.h.win32
1561 gtk-zip.sh
1562 Makefile
1563 gdk-3.0.pc
1564 gtk+-3.0.pc
1565 gtk+-unix-print-3.0.pc
1566 gail-3.0.pc
1567 gtk+-3.0-uninstalled.pc
1568 gail-3.0-uninstalled.pc
1569 m4macros/Makefile
1570 po/Makefile.in
1571 po-properties/Makefile.in
1572 demos/Makefile
1573 demos/gtk-demo/Makefile
1574 demos/gtk-demo/geninclude.pl
1575 examples/Makefile
1576 tests/Makefile
1577 docs/Makefile
1578 docs/reference/Makefile
1579 docs/reference/gdk/Makefile
1580 docs/reference/gdk/version.xml
1581 docs/reference/gtk/Makefile
1582 docs/reference/gtk/version.xml
1583 docs/reference/libgail-util/Makefile
1584 docs/tools/Makefile
1585 build/Makefile
1586 build/win32/Makefile
1587 build/win32/vs9/Makefile
1588 gdk/Makefile
1589 gdk/x11/Makefile
1590 gdk/win32/Makefile
1591 gdk/win32/rc/Makefile
1592 gdk/win32/rc/gdk.rc
1593 gdk/quartz/Makefile
1594 gdk/tests/Makefile
1595 gtk/Makefile
1596 gtk/makefile.msc
1597 gtk/gtkversion.h
1598 gtk/gtk-win32.rc
1599 gtk/theme-bits/Makefile
1600 gtk/tests/Makefile
1601 modules/Makefile
1602 modules/other/Makefile
1603 modules/other/gail/Makefile
1604 modules/other/gail/libgail-util/Makefile
1605 modules/other/gail/tests/Makefile
1606 modules/engines/Makefile
1607 modules/engines/pixbuf/Makefile
1608 modules/engines/ms-windows/Makefile
1609 modules/engines/ms-windows/Theme/Makefile
1610 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1611 modules/input/Makefile
1612 modules/printbackends/Makefile
1613 modules/printbackends/cups/Makefile
1614 modules/printbackends/lpr/Makefile
1615 modules/printbackends/file/Makefile
1616 modules/printbackends/papi/Makefile
1617 modules/printbackends/test/Makefile
1618 perf/Makefile
1619 ])
1620
1621 AC_OUTPUT
1622
1623 echo "configuration:
1624         target:             $gdktarget"