Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [1])
  13 m4_define([gtk_micro_version], [9])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.29.4])
  43 m4_define([pango_required_version], [1.24.0])
  44 m4_define([atk_required_version], [1.30])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.22.0])
  47 m4_define([introspection_required_version], [0.10.1])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_INSTALL
 129 AC_PROG_MAKE_SET
 130
 131
 132 GETTEXT_PACKAGE=gtk30
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 135                    [The prefix for our gettext translation domains.])
 136
 137 AC_CANONICAL_HOST
 138
 139 MATH_LIB=-lm
 140 AC_MSG_CHECKING([for native Win32])
 141 LIB_EXE_MACHINE_FLAG=X86
 142 EXE_MANIFEST_ARCHITECTURE=X86
 143 case "$host" in
 144   *-*-mingw*)
 145     os_win32=yes
 146     gio_can_sniff=no
 147     MATH_LIB=
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       EXE_MANIFEST_ARCHITECTURE=AMD64
 152       ;;
 153     esac
 154     ;;
 155   *)
 156     os_win32=no
 157     ;;
 158 esac
 159 AC_MSG_RESULT([$os_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 163
 164 case $host in
 165   *-*-linux*)
 166     os_linux=yes
 167     ;;
 168 esac
 169
 170 dnl
 171 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 172 dnl We use this for an automated test for C++ header correctness.
 173 dnl
 174 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 175 AC_LANG_PUSH([C++])
 176
 177 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 178                                    [[class a { int b; } c;]])],
 179                   [],[CXX=])
 180 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 181
 182 gtk_save_cxxflags="$CXXFLAGS"
 183 CXXFLAGS="$CXXFLAGS -x objective-c++"
 184 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 185                                    [[]])],
 186                   [OBJC=yes],[OBJC=no])
 187 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 188 CXXFLAGS="$gtk_save_cxxflags"
 189 AC_LANG_POP([C++])
 190
 191 if test "$os_win32" = "yes"; then
 192   if test x$enable_static = xyes -o x$enable_static = x; then
 193     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 194     enable_static=no
 195   fi
 196   if test x$enable_shared = xno; then
 197     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 198   fi
 199   enable_shared=yes
 200 fi
 201
 202 dnl Initialize libtool
 203 LT_PREREQ([2.2.6])
 204 LT_INIT([disable-static win32-dll])
 205 # Create libtool early, because it's used in configure
 206 LT_OUTPUT
 207
 208 # Make sure we use 64-bit versions of various file stuff.
 209 AC_SYS_LARGEFILE
 210
 211 AM_PROG_AS
 212 AC_PATH_PROG(NM, nm, nm)
 213
 214 AC_MSG_CHECKING([for some Win32 platform])
 215 case "$host" in
 216   *-*-mingw*|*-*-cygwin*)
 217     platform_win32=yes
 218     ;;
 219   *)
 220     platform_win32=no
 221     ;;
 222 esac
 223 AC_MSG_RESULT([$platform_win32])
 224 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 225
 226 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 227 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 228 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 229
 230 if test "$os_win32" = "yes"; then
 231   AC_CHECK_TOOL(WINDRES, windres, no)
 232   if test "$WINDRES" = no; then
 233     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 234   fi
 235   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 236 fi
 237 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 238
 239 m4_define([debug_default],
 240           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 241
 242 dnl declare --enable-* args and collect ac_help strings
 243 AC_ARG_ENABLE(debug,
 244               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 245                               [turn on debugging @<:@default=debug_default@:>@])],,
 246               [enable_debug=debug_default])
 247
 248 AC_ARG_ENABLE(rebuilds,
 249               [AS_HELP_STRING([--disable-rebuilds],
 250                               [disable all source autogeneration rules])],,
 251               [enable_rebuilds=yes])
 252
 253 AC_ARG_ENABLE(gtk2-dependency,
 254               [AS_HELP_STRING([--enable-gtk2-dependency],
 255                               [Do not build gtk-update-icon-cache and other shared tools])],,
 256               [enable_gtk2_dependency=no])
 257
 258 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 259
 260 AC_ARG_ENABLE(xkb,
 261               [AS_HELP_STRING([--enable-xkb],
 262                               [support XKB extension [default=maybe]])],,
 263               [enable_xkb="maybe"])
 264 AC_ARG_ENABLE(xinerama,
 265               [AS_HELP_STRING([--enable-xinerama],
 266                               [support Xinerama extension if available [default=maybe]])],,
 267               [enable_xinerama="maybe"])
 268 AC_ARG_ENABLE(xinput,
 269               [AS_HELP_STRING([--enable-xinput],
 270                               [support XInput extension if available [default=yes]])],,
 271               [enable_xinput="maybe"])
 272 AC_ARG_ENABLE(xrandr,
 273               [AS_HELP_STRING([--enable-xrandr],
 274                               [support XRandR extension if available [default=maybe]])],,
 275               [enable_xrandr="maybe"])
 276 AC_ARG_ENABLE(xfixes,
 277               [AS_HELP_STRING([--enable-xfixes],
 278                               [support XFixes extension if available [default=maybe]])],,
 279               [enable_xfixes="maybe"])
 280 AC_ARG_ENABLE(xcomposite,
 281               [AS_HELP_STRING([--enable-xcomposite],
 282                               [support X Composite extension if available [default=maybe]])],,
 283               [enable_xcomposite="maybe"])
 284 AC_ARG_ENABLE(xdamage,
 285               [AS_HELP_STRING([--enable-xdamage],
 286                               [support X Damage extension if available [default=maybe]])],,
 287               [enable_xdamage="maybe"])
 288
 289 AC_ARG_ENABLE(x11-backend,
 290               [AS_HELP_STRING([--enable-x11-backend],
 291                               [enable the X11 gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(win32-backend,
 294               [AS_HELP_STRING([--enable-win32-backend],
 295                               [enable the Win32 gdk backend])],
 296                               [backend_set=yes])
 297 AC_ARG_ENABLE(quartz-backend,
 298               [AS_HELP_STRING([--enable-quartz-backend],
 299                               [enable the quartz gdk backend])],
 300                               [backend_set=yes])
 301 AC_ARG_ENABLE(broadway-backend,
 302               [AS_HELP_STRING([--enable-broadway-backend],
 303                               [enable the broadway (HTML5) gdk backend])],
 304                               [backend_set=yes])
 305 AC_ARG_ENABLE(wayland-backend,
 306               [AS_HELP_STRING([--enable-wayland-backend],
 307                               [enable the wayland gdk backend])],
 308                               [backend_set=yes])
 309
 310 if test -z "$backend_set"; then
 311   if test "$platform_win32" = yes; then
 312     enable_win32_backend=yes
 313   else
 314     enable_x11_backend=yes
 315   fi
 316 fi
 317
 318 cairo_backends=
 319 backend_immodules=
 320 GDK_BACKENDS=
 321 GDK_EXTRA_LIBS=
 322 GDK_EXTRA_CFLAGS=
 323 GDK_WINDOWING=
 324 GIO_PACKAGE=gio-2.0
 325 PANGO_PACKAGES="pango pangocairo"
 326
 327 if test "x$enable_x11_backend" = xyes; then
 328   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 329   # backend names are identical.
 330   cairo_backends="$cairo_backends cairo-xlib"
 331   GDK_BACKENDS="$GDK_BACKENDS x11"
 332   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 333   # gdkapplaunchcontext-x11.c
 334   GIO_PACKAGE=gio-unix-2.0
 335   backend_immodules="$backend_immodules,xim"
 336   GDK_WINDOWING="$GDK_WINDOWING
 337 #define GDK_WINDOWING_X11"
 338 fi
 339
 340 if test "x$enable_win32_backend" = xyes; then
 341   cairo_backends="$cairo_backends cairo-win32"
 342   GDK_BACKENDS="$GDK_BACKENDS win32"
 343   backend_immodules="$backend_immodules,ime"
 344   GDK_WINDOWING="$GDK_WINDOWING
 345 #define GDK_WINDOWING_WIN32"
 346   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 347   AM_CONDITIONAL(USE_WIN32, true)
 348   PANGO_PACKAGES="pangowin32 pangocairo"
 349 else
 350   AM_CONDITIONAL(USE_WIN32, false)
 351 fi
 352
 353 if test "x$enable_quartz_backend" = xyes; then
 354   cairo_backends="$cairo_backends cairo-quartz"
 355   GDK_BACKENDS="$GDK_BACKENDS quartz"
 356   GDK_WINDOWING="$GDK_WINDOWING
 357 #define GDK_WINDOWING_QUARTZ"
 358   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 359   AM_CONDITIONAL(USE_QUARTZ, true)
 360 else
 361   AM_CONDITIONAL(USE_QUARTZ, false)
 362 fi
 363
 364
 365 if test "x$enable_broadway_backend" == xyes; then
 366   GDK_BACKENDS="$GDK_BACKENDS broadway"
 367   cairo_backends="$cairo_backends cairo"
 368   GDK_WINDOWING="$GDK_WINDOWING
 369 #define GDK_WINDOWING_BROADWAY"
 370   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 371   AM_CONDITIONAL(USE_BROADWAY, true)
 372 else
 373   AM_CONDITIONAL(USE_BROADWAY, false)
 374 fi
 375
 376 if test "x$enable_wayland_backend" == "xyes"; then
 377   # Wayland uses cairo-gl
 378   cairo_backends="$cairo_backends cairo-gl"
 379   GDK_BACKENDS="$GDK_BACKENDS wayland"
 380   GIO_PACKAGE=gio-unix-2.0
 381   GDK_WINDOWING="$GDK_WINDOWING
 382 #define GDK_WINDOWING_WAYLAND"
 383   WAYLAND_PACKAGES="wayland-client xkbcommon wayland-egl"
 384   AM_CONDITIONAL(USE_WAYLAND, true)
 385 else
 386   AM_CONDITIONAL(USE_WAYLAND, false)
 387 fi
 388
 389 # strip leading space
 390 GDK_BACKENDS=${GDK_BACKENDS#* }
 391
 392 AC_SUBST(GDK_BACKENDS)
 393
 394 if test -z "$GDK_BACKENDS"; then
 395   AC_MSG_ERROR([No GDK backends selected.])
 396 fi
 397
 398 if test "x$enable_debug" = "xyes"; then
 399   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 400   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 401 else
 402   if test "x$enable_debug" = "xno"; then
 403     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 404   else
 405     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 406   fi
 407 fi
 408
 409
 410 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 411                    [Define if debugging is enabled])
 412
 413
 414 # Build time sanity check...
 415 AM_SANITY_CHECK
 416
 417 changequote(,)dnl
 418 if test "x$GCC" = "xyes"; then
 419   case " $CFLAGS " in
 420   *[\ \ ]-Wall[\ \      ]*) ;;
 421   *) CFLAGS="$CFLAGS -Wall" ;;
 422   esac
 423
 424   if test "x$enable_ansi" = "xyes"; then
 425     case " $CFLAGS " in
 426     *[\ \       ]-ansi[\ \      ]*) ;;
 427     *) CFLAGS="$CFLAGS -ansi" ;;
 428     esac
 429
 430     case " $CFLAGS " in
 431     *[\ \       ]-pedantic[\ \  ]*) ;;
 432     *) CFLAGS="$CFLAGS -pedantic" ;;
 433     esac
 434   fi
 435 fi
 436 changequote([,])dnl
 437
 438 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 439
 440 # Ensure MSVC-compatible struct packing convention is used when
 441 # compiling for Win32 with gcc.
 442 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 443 # gcc2 uses "-fnative-struct".
 444 if test x"$os_win32" = xyes; then
 445   if test x"$GCC" = xyes; then
 446     msnative_struct=''
 447     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 448     if test -z "$ac_cv_prog_CC"; then
 449       our_gcc="$CC"
 450     else
 451       our_gcc="$ac_cv_prog_CC"
 452     fi
 453     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 454       2.)
 455         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 456           msnative_struct='-fnative-struct'
 457         fi
 458         ;;
 459       *)
 460         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 461           msnative_struct='-mms-bitfields'
 462         fi
 463         ;;
 464     esac
 465     if test x"$msnative_struct" = x ; then
 466       AC_MSG_RESULT([no way])
 467       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 468     else
 469       CFLAGS="$CFLAGS $msnative_struct"
 470       AC_MSG_RESULT([${msnative_struct}])
 471     fi
 472   fi
 473 fi
 474
 475 ## Initial sanity check, done here so that users get told they
 476 ## have the wrong dependencies as early in the process as possible.
 477 ## Later on we actually use the cflags/libs from separate pkg-config
 478 ## calls. Oh, also the later pkg-config calls don't include
 479 ## the version requirements since those make the module lists
 480 ## annoying to construct
 481 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 482   [glib-2.0 >= glib_required_version dnl
 483    atk >= atk_required_version dnl
 484    pango >= pango_required_version dnl
 485    cairo >= cairo_required_version dnl
 486    cairo-gobject >= cairo_required_version dnl
 487    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 488
 489 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 490
 491 if test "$os_win32" != yes; then
 492     # libtool option to control which symbols are exported
 493     # right now, symbols starting with _ are not exported
 494     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 495 else
 496     # We currently use .def files on Windows (for gdk and gtk)
 497     LIBTOOL_EXPORT_OPTIONS=
 498 fi
 499 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 500
 501 dnl ******************************************************
 502 dnl * See whether to include shared library dependencies *
 503 dnl ******************************************************
 504
 505 AC_ARG_ENABLE(explicit-deps,
 506               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 507                               [use explicit dependencies in .pc files [default=auto]])],,
 508               [enable_explicit_deps=auto])
 509
 510 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 511 case $enable_explicit_deps in
 512   auto)
 513     export SED
 514     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 515     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 516       enable_explicit_deps=yes
 517     else
 518       enable_explicit_deps=no
 519     fi
 520   ;;
 521   yes|no)
 522   ;;
 523   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 524   ;;
 525 esac
 526 AC_MSG_RESULT($enable_explicit_deps)
 527
 528 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 529
 530 # define a MAINT-like variable REBUILD which is set if Perl
 531 # and awk are found, so autogenerated sources can be rebuilt
 532
 533 AC_PATH_PROGS(PERL, perl5 perl)
 534
 535 # We would like indent, but don't require it.
 536 AC_CHECK_PROG(INDENT, indent, indent)
 537
 538 REBUILD=\#
 539 if test "x$enable_rebuilds" = "xyes" && \
 540      test -n "$PERL" && \
 541      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 542   REBUILD=
 543 fi
 544 AC_SUBST(REBUILD)
 545
 546 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 547 AC_CHECK_FUNCS(localtime_r)
 548
 549 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 550 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 551 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 552                                 [[char c;
 553                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 554                [gtk_ok=yes], [gtk_ok=no])
 555 AC_MSG_RESULT($gtk_ok)
 556 if test "$gtk_ok" = "yes"; then
 557   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 558             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 559 fi
 560
 561 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 562 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 563 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 564                                 [[char c;
 565                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 566                [gtk_ok=yes], [gtk_ok=no])
 567 AC_MSG_RESULT($gtk_ok)
 568 if test "$gtk_ok" = "yes"; then
 569   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 570             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 571 fi
 572
 573 # _NL_PAPER_HEIGHT is an enum and not a define
 574 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 575 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 576                                 [[char c;
 577                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 578                [gtk_ok=yes], [gtk_ok=no])
 579 AC_MSG_RESULT($gtk_ok)
 580 if test "$gtk_ok" = "yes"; then
 581   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 582             [Define if _NL_PAPER_HEIGHT is available])
 583 fi
 584
 585 # _NL_PAPER_WIDTH is an enum and not a define
 586 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 587 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 588                                 [[char c;
 589                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 590                [gtk_ok=yes], [gtk_ok=no])
 591 AC_MSG_RESULT($gtk_ok)
 592 if test "$gtk_ok" = "yes"; then
 593   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 594             [Define if _NL_PAPER_WIDTH is available])
 595 fi
 596
 597 # i18n stuff
 598 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 599 AM_GLIB_GNU_GETTEXT
 600 LIBS="$LIBS $INTLLIBS"
 601 AC_CONFIG_COMMANDS([po-properties],
 602                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 603                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 604                      esac]],
 605                    [[]])
 606
 607 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 608 dnl po-properties/POTFILES during configure; see GNOME #573515.
 609 dnl
 610 dnl Generate list of files to be processed by xgettext which will
 611 dnl be included in po-properties/Makefile.
 612 test -d po-properties || mkdir po-properties
 613 if test "x$srcdir" != "x."; then
 614   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 615     popropsrcprefix="$srcdir/"
 616   else
 617     popropsrcprefix="../$srcdir/"
 618   fi
 619 else
 620   popropsrcprefix="../"
 621 fi
 622 rm -f po-properties/POTFILES
 623 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 624 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 625 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 626
 627 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 628
 629 dnl The DU4 header files don't provide library prototypes unless
 630 dnl -std1 is given to the native cc.
 631 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 632
 633 gtk_save_LIBS=$LIBS
 634 LIBS="$LIBS -lm"
 635 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 636                                 int main (void) { return (log(1) != log(1.)); }]])],
 637               [AC_MSG_RESULT(none needed)],
 638               [gtk_save_CFLAGS="$CFLAGS"
 639                CFLAGS="$CFLAGS -std1"
 640                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 641                                                int main (void) { return (log(1) != log(1.)); }]])],
 642                              [AC_MSG_RESULT(-std1)],
 643                              [AC_MSG_RESULT()
 644                               CFLAGS="$gtk_save_CFLAGS"
 645                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 646                              [true])],
 647               [AC_MSG_RESULT(none needed)])
 648
 649 LIBS=$gtk_save_LIBS
 650
 651 AC_MSG_CHECKING(for the BeOS)
 652 case $host in
 653   *-*-beos*)
 654     AC_MSG_RESULT(yes)
 655     MATH_LIB=
 656   ;;
 657   *)
 658     AC_MSG_RESULT(no)
 659   ;;
 660 esac
 661
 662 AC_SUBST(MATH_LIB)
 663 #
 664 # see bug 162979
 665 #
 666 AC_MSG_CHECKING(for HP-UX)
 667 case $host_os in
 668   hpux9* | hpux10* | hpux11*)
 669     AC_MSG_RESULT(yes)
 670     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 671   ;;
 672   *)
 673     AC_MSG_RESULT(no)
 674   ;;
 675 esac
 676
 677 #
 678 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 679 #
 680
 681 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 682
 683 AM_PATH_GLIB_2_0(glib_required_version, :,
 684   AC_MSG_ERROR([
 685 *** GLIB glib_required_version or better is required. The latest version of
 686 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 687   gobject gmodule-no-export gthread)
 688
 689 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 690 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 691 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 692 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 693   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 694 fi
 695
 696 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 697
 698
 699 dnl
 700 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 701 dnl
 702 gtk_save_LIBS=$LIBS
 703 LIBS="$LIBS $GLIB_LIBS"
 704 AC_CHECK_FUNCS(bind_textdomain_codeset)
 705 LIBS=$gtk_save_LIBS
 706
 707 AC_CHECK_HEADERS(pwd.h,
 708                  AC_DEFINE(HAVE_PWD_H, 1,
 709                            [Define to 1 if pwd.h is available]))
 710 AC_CHECK_HEADERS(sys/time.h,
 711                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 712                            [Define to 1 if time.h is available]))
 713 AC_CHECK_HEADERS(unistd.h,
 714                  AC_DEFINE(HAVE_UNISTD_H, 1,
 715                            [Define to 1 if unistd.h is available]))
 716 AC_CHECK_HEADERS(ftw.h,
 717                  AC_DEFINE(HAVE_FTW_H, 1,
 718                            [Define to 1 if ftw.h is available]))
 719
 720 AC_MSG_CHECKING([for GNU ftw extensions])
 721 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 722                                      #define _GNU_SOURCE
 723                                      #include <ftw.h>]],
 724                                    [[int flags = FTW_ACTIONRETVAL;]])],
 725                   [gtk_ok=yes],[gtk_ok=no])
 726 if test $gtk_ok = yes; then
 727     AC_MSG_RESULT([yes])
 728     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 729 else
 730     AC_MSG_RESULT([no])
 731 fi
 732
 733 saved_cflags="$CFLAGS"
 734 saved_ldflags="$LDFLAGS"
 735
 736
 737 # Checks for library functions.
 738 AC_FUNC_MMAP
 739
 740 AC_CHECK_FUNCS(mallinfo)
 741 AC_CHECK_FUNCS(getresuid)
 742 AC_TYPE_UID_T
 743
 744 # Check for uxtheme.h (for MS-Windows Engine)
 745 AC_MSG_CHECKING(for uxtheme.h)
 746 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <uxtheme.h>]])],
 747                   [gtk_uxtheme_h=yes], [gtk_uxtheme_h=no])
 748 if test $gtk_uxtheme_h = yes; then
 749    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 750 fi
 751 AC_MSG_RESULT($gtk_uxtheme_h)
 752
 753 # Checks for gdkspawn
 754 AC_CHECK_HEADERS(crt_externs.h)
 755 AC_CHECK_FUNCS(_NSGetEnviron)
 756
 757 AC_MSG_CHECKING(whether to build dynamic modules)
 758
 759 AC_ARG_ENABLE(modules,
 760               [AS_HELP_STRING([--disable-modules],
 761                               [disable dynamic module loading])])
 762
 763 dynworks=false
 764 build_dynamic_modules=no
 765 deps=
 766 if test x$enable_modules = xno; then
 767     AC_MSG_RESULT(no)
 768 else
 769     AC_MSG_RESULT(yes)
 770     AC_MSG_CHECKING(whether dynamic modules work)
 771     ## for loop is to strip newline
 772     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 773     for I in $tmp; do
 774         dynworks=$I
 775     done
 776
 777     dnl Now we check to see if our libtool supports shared lib deps
 778     dnl (in a rather ugly way even)
 779     if $dynworks; then
 780         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 781         module_deplibs_check=`$module_libtool_config | \
 782             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 783             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 784         if test "x$module_deplibs_check" = "xnone" || \
 785            test "x$module_deplibs_check" = "xunknown" || \
 786            test "x$module_deplibs_check" = "x"; then
 787             dynworks=false
 788         fi
 789     fi
 790
 791     if $dynworks; then
 792         build_dynamic_modules=yes
 793         AC_DEFINE(USE_GMODULE, 1,
 794                   [Define to 1 if gmodule works and should be used])
 795         AC_MSG_RESULT(yes)
 796     else
 797         build_dynamic_modules=no
 798         AC_MSG_RESULT(no)
 799     fi
 800 fi
 801
 802 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 803
 804 #
 805 # Allow building some or all immodules included
 806 #
 807 AC_MSG_CHECKING(immodules to build)
 808
 809 AC_ARG_WITH(included_immodules,
 810             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 811                             [build the specified input methods into gtk])])
 812
 813 if $dynworks; then
 814    :
 815 else
 816    ## if the option was specified, leave it; otherwise disable included immodules
 817    if test x$with_included_immodules = xno; then
 818            with_included_immodules=yes
 819    fi
 820 fi
 821
 822 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 823
 824 included_immodules=""
 825 # If the switch specified without listing any specific ones, include all
 826 if test "x$with_included_immodules" = xyes ; then
 827   included_immodules="$all_immodules"
 828 else
 829   included_immodules="$with_included_immodules"
 830 fi
 831
 832 AC_MSG_RESULT($included_immodules)
 833 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 834
 835 INCLUDED_IMMODULE_OBJ=
 836 INCLUDED_IMMODULE_DEFINE=
 837
 838 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 839 for immodule in $included_immodules; do
 840  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 841  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 842    :
 843  else
 844    AC_MSG_ERROR([the specified input method $immodule does not exist])
 845  fi
 846
 847  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 848  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 849  eval INCLUDE_$immodule_underscores=yes
 850 done
 851 IFS="$gtk_save_ifs"
 852 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 853 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 854
 855 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 856 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 857 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 858 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 859 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 860 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 861 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 862 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 863 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 864 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 865 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 866 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 867
 868 # Checks to see whether we should include mediaLib
 869 # support.
 870 #
 871 AC_CHECK_HEADER(sys/systeminfo.h,
 872                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 873                           [Define to 1 if sys/systeminfo.h is available]))
 874 AC_CHECK_HEADER(sys/sysinfo.h,
 875                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 876                           [Define to 1 if sys/sysinfo.h is available]))
 877
 878 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 879
 880 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 881
 882 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 883   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 884   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 885     REBUILD_PNGS=#
 886   fi
 887 fi
 888
 889 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 890
 891 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 892
 893 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 894    test "x$REBUILD_PNGS" = "x#" ; then
 895      AC_MSG_ERROR([
 896 *** gtkbuiltincache.h is not in the tree, and cannot be built
 897 *** because you don't have libpng, or (when cross-compiling) you
 898 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 899 fi
 900
 901 ########################################
 902 # Windowing system checks
 903 ########################################
 904
 905 # GTK+ uses some X calls, so needs to link against X directly
 906 GTK_DEP_PACKAGES_FOR_X=
 907 GTK_DEP_LIBS_FOR_X=
 908 X_EXTENSIONS=
 909
 910 if test "x$enable_x11_backend" = xyes; then
 911   X_PACKAGES=fontconfig
 912
 913   #
 914   # We use fontconfig very peripherally when decoding the default
 915   # settings.
 916   #
 917   if $PKG_CONFIG --exists fontconfig; then : ; else
 918     AC_MSG_ERROR([
 919 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 920   fi
 921
 922   #
 923   # Check for basic X packages; we use pkg-config if available
 924   #
 925   if $PKG_CONFIG --exists x11 xext; then
 926     have_base_x_pc=true
 927     X_PACKAGES="$X_PACKAGES x11 xext"
 928     x_libs="`$PKG_CONFIG --libs x11 xext`"
 929     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 930
 931     # Strip out any .la files that pkg-config might give us (this happens
 932     # with -uninstalled.pc files)
 933     x_libs_for_checks=
 934     for I in $x_libs ; do
 935       case $I in
 936         *.la) ;;
 937         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 938       esac
 939     done
 940
 941     GTK_PACKAGES_FOR_X="x11"
 942   else
 943     have_base_x_pc=false
 944     AC_PATH_XTRA
 945     if test x$no_x = xyes ; then
 946       AC_MSG_ERROR([X development libraries not found])
 947     fi
 948
 949     x_cflags="$X_CFLAGS"
 950     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 951
 952     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 953   fi
 954
 955   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 956   x_extra_libs=
 957
 958   gtk_save_cppflags="$CPPFLAGS"
 959   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 960
 961   gtk_save_LIBS=$LIBS
 962   LIBS="$x_libs_for_checks $LIBS"
 963
 964   # Sanity check for the X11 and Xext libraries. While everything we need from
 965   # Xext is optional, the chances a system has *none* of these things is so
 966   # small that we just unconditionally require it.
 967   AC_CHECK_FUNC(XOpenDisplay, :,
 968                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 969   AC_CHECK_FUNC(XextFindDisplay, :,
 970                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 971
 972   # Check for xReply
 973
 974   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 975   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 976                                      [[xReply *rep;]])],
 977                     [AC_MSG_RESULT([no])],
 978                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 979                                                           #include <X11/Xlibint.h>]],
 980                                                         [[xReply *rep;]])],
 981                                        [AC_MSG_RESULT([yes])
 982                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 983                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 984                                        [AC_MSG_RESULT([unknown])
 985                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 986
 987   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 988
 989   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 990
 991   # Generic X11R6 check needed for XIM support; we could
 992   # probably use this to replace the above, but we'll
 993   # leave the separate checks for XConvertCase and XInternAtoms
 994   # for clarity
 995
 996   have_x11r6=false
 997   AC_CHECK_FUNC(XAddConnectionWatch,
 998       have_x11r6=true)
 999
1000   if $have_x11r6; then
1001     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1002   fi
1003   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1004
1005   # Check for XKB support.
1006
1007   if test "x$enable_xkb" = "xyes"; then
1008         AC_CHECK_FUNC(XkbQueryExtension,
1009                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1010                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1011                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1012   elif test "x$enable_xkb" = "xmaybe"; then
1013         AC_CHECK_FUNC(XkbQueryExtension,
1014                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1015                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1016   else
1017         AC_MSG_WARN(XKB support explicitly disabled)
1018   fi
1019
1020   # Check for shaped window extension
1021
1022   AC_CHECK_FUNC(XShapeCombineMask, :,
1023      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1024
1025   # X SYNC check
1026   gtk_save_CFLAGS="$CFLAGS"
1027   CFLAGS="$CFLAGS $x_cflags"
1028
1029   AC_CHECK_FUNC(XSyncQueryExtension,
1030       [AC_CHECK_HEADER(X11/extensions/sync.h,
1031           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1032           :, [#include <X11/Xlib.h>])])
1033
1034   CFLAGS="$gtk_save_CFLAGS"
1035
1036   if test "x$enable_xinerama" != "xno"; then
1037     # Check for Xinerama extension (Solaris impl or Xfree impl)
1038     have_xfree_xinerama=false
1039     have_solaris_xinerama=false
1040
1041     gtk_save_cppflags="$CPPFLAGS"
1042     CPPFLAGS="$CPPFLAGS $x_cflags"
1043
1044     # Check for XFree
1045     AC_MSG_CHECKING(for Xinerama packages)
1046
1047     if $PKG_CONFIG --exists xinerama ; then
1048        AC_MSG_RESULT(yes)
1049        have_xfree_xinerama=true
1050        X_PACKAGES="$X_PACKAGES xinerama"
1051     else
1052        AC_MSG_RESULT(no)
1053        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1054            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1055            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1056            have_xfree_xinerama=true], :,
1057            [#include <X11/Xlib.h>])])
1058     fi
1059
1060     if $have_xfree_xinerama ; then
1061       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1062       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1063                 [Define to 1 if XFree Xinerama is available])
1064       AC_DEFINE(HAVE_XINERAMA, 1,
1065                 [Define to 1 is Xinerama is available])
1066     else
1067       case "$host" in
1068         *-*-solaris*)
1069             # Check for solaris
1070             AC_MSG_CHECKING(for Xinerama support on Solaris)
1071
1072             have_solaris_xinerama=false
1073             AC_CHECK_FUNC(XineramaGetInfo,
1074                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1075                     [have_solaris_xinerama=true], :,
1076                     [#include <X11/Xlib.h>])])
1077
1078             if $have_solaris_xinerama ; then
1079               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1080               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1081                         [Define to 1 if solaris xinerama is available])
1082               AC_DEFINE(HAVE_XINERAMA, 1,
1083                         [Define to 1 if xinerama is available])
1084               AC_MSG_RESULT(yes)
1085             else
1086               AC_MSG_RESULT(no)
1087             fi
1088             ;;
1089         *)
1090             ;;
1091       esac
1092     fi
1093   fi
1094   if test "x$enable_xinerama" = "xyes" ; then
1095     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1096       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1097     fi
1098   fi
1099
1100   # Check for XGetEventData for GenericEvents
1101   AC_CHECK_FUNC(XGetEventData,
1102                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1103
1104   # set up things for XInput
1105   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1106     have_xinput=yes
1107
1108     AC_DEFINE(XINPUT_XFREE, 1,
1109               [Define to 1 if XFree XInput should be used])
1110
1111     X_PACKAGES="$X_PACKAGES xi"
1112
1113     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1114                     have_xinput2=yes
1115                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1116                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1117                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1118
1119   else
1120     AC_DEFINE(XINPUT_NONE, 1,
1121               [Define to 1 if no XInput should be used])
1122   fi
1123
1124   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1125   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1126
1127   if test "x$enable_xinput" = "xyes" ; then
1128     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1129       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1130     fi
1131   fi
1132
1133   # Check for the RANDR extension
1134   if test x"$enable_xrandr" != xno; then
1135     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1136       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1137
1138       X_PACKAGES="$X_PACKAGES xrandr"
1139       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1140     elif test x"$enable_xrandr" = xyes; then
1141       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1142     fi
1143   fi
1144
1145   # Checks for Xcursor library
1146
1147   if $PKG_CONFIG --exists xcursor ; then
1148     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1149
1150     X_PACKAGES="$X_PACKAGES xcursor"
1151   fi
1152
1153   # Checks for XFixes extension
1154
1155   if test x"$enable_xfixes" != xno; then
1156     if $PKG_CONFIG --exists xfixes ; then
1157       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1158
1159       X_PACKAGES="$X_PACKAGES xfixes"
1160       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1161       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1162     elif test x"$enable_xfixes" = xyes; then
1163       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1164     fi
1165   fi
1166
1167   # Checks for Xcomposite extension
1168
1169   if test x"$enable_xcomposite" != xno; then
1170     if $PKG_CONFIG --exists xcomposite ; then
1171       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1172
1173       X_PACKAGES="$X_PACKAGES xcomposite"
1174       X_EXTENSIONS="$X_EXTENSIONS Composite"
1175       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1176     elif test x"$enable_xcomposite" = xyes; then
1177       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1178     fi
1179   fi
1180
1181   # Checks for Xdamage extension
1182
1183   if test x"$enable_xdamage" != xno; then
1184     if $PKG_CONFIG --exists xdamage ; then
1185       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1186
1187       X_PACKAGES="$X_PACKAGES xdamage"
1188       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1189       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1190     elif test x"$enable_xdamage" = xyes; then
1191       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1192     fi
1193   fi
1194
1195   if $have_base_x_pc ; then
1196     GDK_EXTRA_LIBS="$x_extra_libs"
1197   else
1198     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1199   fi
1200
1201   CPPFLAGS="$gtk_save_cppflags"
1202   LIBS="$gtk_save_libs"
1203
1204   AM_CONDITIONAL(USE_X11, true)
1205
1206   # strip leading space
1207   X_EXTENSIONS=${X_EXTENSIONS#* }
1208
1209 else
1210   XPACKAGES=
1211
1212   AM_CONDITIONAL(XINPUT_XFREE, false)
1213   AM_CONDITIONAL(XINPUT_2, false)
1214   AM_CONDITIONAL(USE_X11, false)
1215   AM_CONDITIONAL(HAVE_X11R6, false)
1216 fi
1217
1218 # Check for Pango flags
1219
1220 AC_MSG_CHECKING(Pango flags)
1221 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1222         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1223         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1224
1225         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1226 else
1227         AC_MSG_ERROR([
1228 *** Pango not found. Pango built with Cairo support is required
1229 *** to build GTK+. See http://www.pango.org for Pango information.
1230 ])
1231 fi
1232
1233 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1234
1235 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1236         :
1237 else
1238         gtk_save_LIBS="$LIBS"
1239         LIBS="$PANGO_LIBS $LIBS"
1240         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1241 *** Can't link to Pango. Pango is required to build
1242 *** GTK+. For more information see http://www.pango.org]))
1243         LIBS="$gtk_save_LIBS"
1244 fi
1245
1246 CFLAGS="$saved_cflags"
1247 LDFLAGS="$saved_ldflags"
1248
1249 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1250
1251 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1252 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1253 #
1254 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1255 # into the pkg-config files
1256 #
1257 if test $enable_explicit_deps != yes ; then
1258   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1259   GDK_EXTRA_LIBS=
1260 fi
1261
1262 AC_SUBST(GDK_PACKAGES)
1263 AC_SUBST(GDK_EXTRA_LIBS)
1264 AC_SUBST(GDK_EXTRA_CFLAGS)
1265 AC_SUBST(GDK_DEP_LIBS)
1266 AC_SUBST(GDK_DEP_CFLAGS)
1267
1268
1269 ########################################
1270 # Check for Accessibility Toolkit flags
1271 ########################################
1272
1273 ATK_PACKAGES=atk
1274 AC_MSG_CHECKING(ATK flags)
1275 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1276         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1277         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1278
1279         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1280 else
1281         AC_MSG_ERROR([
1282 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1283 *** to build GTK+.
1284 ])
1285 fi
1286
1287 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1288         :
1289 else
1290         gtk_save_LIBS="$LIBS"
1291         LIBS="$ATK_LIBS $LIBS"
1292         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1293                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1294                 *** to build GTK+]))
1295         LIBS="$gtk_save_LIBS"
1296 fi
1297
1298 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1299 if test "x$enable_x11_backend" = xyes; then
1300   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1301 fi
1302 GTK_EXTRA_LIBS=
1303 GTK_EXTRA_CFLAGS=
1304 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1305 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1306
1307 if test x"$os_win32" = xyes; then
1308   GTK_EXTRA_CFLAGS="$msnative_struct"
1309 fi
1310
1311 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1312 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1313 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1314 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1315
1316 AC_SUBST(GTK_PACKAGES)
1317 AC_SUBST(GTK_EXTRA_LIBS)
1318 AC_SUBST(GTK_EXTRA_CFLAGS)
1319 AC_SUBST(GTK_DEP_LIBS)
1320 AC_SUBST(GTK_DEP_CFLAGS)
1321
1322 AC_SUBST(GLIB_PREFIX)
1323 AC_SUBST(ATK_PREFIX)
1324 AC_SUBST(PANGO_PREFIX)
1325 AC_SUBST(CAIRO_PREFIX)
1326
1327 AC_SUBST(GTK_DEBUG_FLAGS)
1328 AC_SUBST(GTK_XIM_FLAGS)
1329
1330 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1331 AC_SUBST(GDK_PIXBUF_LIBS)
1332
1333 ########################
1334 # Checks needed for gail
1335 ########################
1336
1337 old_LIBS="$LIBS"
1338 dnl Checks for inet libraries:
1339 AC_SEARCH_LIBS(gethostent, nsl)
1340 AC_SEARCH_LIBS(setsockopt, socket)
1341 AC_SEARCH_LIBS(connect, inet)
1342
1343 dnl check for the sockaddr_un.sun_len member
1344 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1345                 [struct_sockaddr_un_sun_len=true],
1346                 [struct_sockaddr_un_suin_len=false],
1347                 [#include <sys/types.h>
1348                  #include <sys/un.h>]
1349                 )
1350 case $struct_sockaddr_un_sun_len in
1351         true)
1352                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1353                                    [Have the sockaddr_un.sun_len member])
1354                 ;;
1355         *)
1356                 ;;
1357 esac
1358
1359 GAIL_INET_LIBS="$LIBS"
1360 AC_SUBST([GAIL_INET_LIBS])
1361
1362 LIBS="$old_LIBS"
1363
1364 ################################################################
1365 # Printing system checks
1366 ################################################################
1367
1368 PRINT_BACKENDS="file lpr"
1369
1370 AC_ARG_ENABLE(cups,
1371               [AS_HELP_STRING([--disable-cups],
1372                               [disable cups print backend])],,
1373               [enable_cups=auto])
1374
1375 if test "x$enable_cups" = "xno"; then
1376   AM_CONDITIONAL(HAVE_CUPS, false)
1377 else
1378   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1379   if test "x$CUPS_CONFIG" = "xno"; then
1380     if test "x$enable_cups" = "xauto"; then
1381       AM_CONDITIONAL(HAVE_CUPS, false)
1382     else
1383       AC_MSG_ERROR([
1384 *** cups not found.
1385 ])
1386     fi
1387   else
1388     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1389     CUPS_LIBS=`$CUPS_CONFIG --libs`
1390
1391     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1392     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1393     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1394
1395     if test $CUPS_API_MAJOR -gt 1 -o \
1396             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1397       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1398                 [Define to 1 if CUPS 1.2 API is available])
1399     fi
1400
1401     AC_SUBST(CUPS_API_MAJOR)
1402     AC_SUBST(CUPS_API_MINOR)
1403     AC_SUBST(CUPS_CFLAGS)
1404     AC_SUBST(CUPS_LIBS)
1405
1406     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1407
1408     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1409     AM_CONDITIONAL(HAVE_CUPS, true)
1410
1411     gtk_save_cflags="$CFLAGS"
1412     CFLAGS="$CUPS_CFLAGS"
1413     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1414                                        [[http_t http; char *s = http.authstring;]])],
1415                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1416                                  [Define if cups http_t authstring field is accessible])],
1417                       [])
1418     CFLAGS="$gtk_save_cflags"
1419
1420     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1421
1422     gtk_save_libs="$LIBS"
1423     LIBS="$CUPS_LIBS"
1424     AC_CHECK_FUNCS(httpGetAuthString)
1425     LIBS="$gtk_save_libs"
1426   fi
1427 fi
1428
1429 # Checks to see if we should compile with PAPI backend for GTK+
1430 #
1431
1432 AC_ARG_ENABLE(papi,
1433               [AS_HELP_STRING([--disable-papi],
1434                               [disable papi print backend])],,
1435               [enable_papi=auto])
1436
1437 if test "x$enable_papi" = "xno"; then
1438   AM_CONDITIONAL(HAVE_PAPI, false)
1439 else
1440   AC_MSG_CHECKING(libpapi)
1441   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1442   if test $have_papi = yes; then
1443     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1444     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1445   fi
1446   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1447   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1448     AC_MSG_ERROR([
1449 *** papi not found.
1450 ])
1451   fi
1452 fi
1453
1454 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1455
1456 gtk_save_cppflags="$CPPFLAGS"
1457 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1458
1459 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1460 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1461 *** backend enabled.]))
1462
1463 if test "$os_win32" != "yes"; then
1464   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1465 *** Can't find cairo-ps.h. You must build Cairo with the
1466 *** postscript backend enabled.]))
1467
1468   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1469 *** Cannot find cairo-svg.h. You must build Cairo with the
1470 *** svg backend enabled.]))
1471 fi
1472
1473 CPPFLAGS="$gtk_save_cppflags"
1474
1475
1476 AC_ARG_ENABLE(test-print-backend,
1477               [AS_HELP_STRING([--enable-test-print-backend],
1478                               [build test print backend])],,
1479               [enable_test_print_backend=no])
1480 if test "x$enable_test_print_backend" != "xno" ; then
1481   PRINT_BACKENDS="$PRINT_BACKENDS test"
1482 fi
1483 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1484
1485
1486 ################################################################
1487 # Strip -export-dynamic from the link lines of various libraries
1488 ################################################################
1489
1490 #
1491 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1492 #  but this flag is only meaningful for executables. For libraries
1493 #  the effect is undefined; what it causes on Linux is that the
1494 #  export list from -export-symbols-regex is ignored and everything
1495 #  is exported
1496 #
1497 # We are using gmodule-no-export now, but I'm leaving the stripping
1498 # code in place for now, since pango and atk still require gmodule.
1499 export SED
1500 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1501 if test -n "$export_dynamic"; then
1502   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1503   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1504 fi
1505
1506 #############
1507 # GSettings #
1508 #############
1509
1510 GLIB_GSETTINGS
1511
1512 ##################################################
1513 # GObject introspection
1514 ##################################################
1515
1516 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1517
1518 ##################################################
1519 # Packagekit module
1520 #################################################
1521
1522 AC_ARG_ENABLE(packagekit,
1523               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1524                               [build packagekit open-with module [default=auto]])],
1525               [enable_packagekit="$enableval"],
1526               [enable_packagekit=auto])
1527 if test "$enable_packagekit" = "auto"; then
1528   if test "$os_win32" = "yes"; then
1529     enable_packagekit=no
1530   else
1531     enable_packagekit=yes
1532   fi
1533 fi
1534
1535 AC_MSG_CHECKING([Whether to use PackageKit])
1536 build_packagekit=no
1537 if test "x$enable_packagekit" != "xno"; then
1538   if test "$os_win32" != "yes"; then
1539     build_packagekit=yes
1540     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1541   else
1542     AC_MSG_ERROR([packagekit support is not available on win32])
1543   fi
1544 fi
1545 AC_MSG_RESULT([$build_packagekit])
1546
1547 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1548
1549 ##################################################
1550 # colord module
1551 #################################################
1552
1553 AC_ARG_ENABLE(colord,
1554               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1555                               [build colord support code [default=auto]])],
1556               [enable_colord="$enableval"],
1557               [enable_colord=auto])
1558 if test "$enable_colord" = "auto"; then
1559   if test "$os_win32" = "yes"; then
1560     enable_colord=no
1561   else
1562     enable_colord=yes
1563   fi
1564 fi
1565
1566 AC_MSG_CHECKING([Whether to use colord])
1567 have_colord=no
1568 if test "x$enable_colord" != "xno"; then
1569         if test "$os_win32" != "yes"; then
1570                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1571                                   have_colord=yes, have_colord=no)
1572                 if test "enable_colord" = "yes"; then
1573                         if test "have_colord" = "no"; then
1574                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1575                         fi
1576                 fi
1577         else
1578                 AC_MSG_ERROR([colord support is not available on win32])
1579         fi
1580 fi
1581 AC_MSG_RESULT([$have_colord])
1582
1583 if test "have_colord" = "yes"; then
1584         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1585 fi
1586 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1587
1588 ##################################################
1589 # Checks for gtk-doc and docbook-tools
1590 ##################################################
1591
1592 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1593
1594 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1595 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1596
1597 AC_ARG_ENABLE(man,
1598               [AS_HELP_STRING([--enable-man],
1599                               [regenerate man pages from Docbook [default=no]])],
1600               [enable_man=yes],
1601               [enable_man=no])
1602
1603 if test "${enable_man}" != no; then
1604   dnl
1605   dnl Check for xsltproc
1606   dnl
1607   AC_PATH_PROG([XSLTPROC], [xsltproc])
1608   if test -z "$XSLTPROC"; then
1609     enable_man=no
1610   fi
1611
1612   dnl check for DocBook DTD and stylesheets in the local catalog.
1613   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1614      [DocBook XML DTD V4.1.2],,enable_man=no)
1615   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1616      [DocBook XSL Stylesheets],,enable_man=no)
1617 fi
1618
1619 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1620
1621
1622 ##################################################
1623 # Output commands
1624 ##################################################
1625
1626 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1627         outfile=gdkconfig.h-tmp
1628         cat > $outfile <<\_______EOF
1629 /* gdkconfig.h
1630  *
1631  * This is a generated file.  Please modify `configure.ac'
1632  */
1633
1634 #ifndef __GDKCONFIG_H__
1635 #define __GDKCONFIG_H__
1636
1637 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1638 #error "Only <gdk/gdk.h> can be included directly."
1639 #endif
1640
1641 #include <glib.h>
1642
1643 G_BEGIN_DECLS
1644
1645 _______EOF
1646
1647         cat >>$outfile <<_______EOF
1648 $gdk_windowing
1649 _______EOF
1650
1651         cat >>$outfile <<_______EOF
1652
1653 G_END_DECLS
1654
1655 #endif  /* __GDKCONFIG_H__ */
1656 _______EOF
1657
1658
1659         if cmp -s $outfile gdk/gdkconfig.h; then
1660           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1661           rm -f $outfile
1662         else
1663           mv $outfile gdk/gdkconfig.h
1664         fi
1665 ],[
1666 gdk_windowing='$GDK_WINDOWING'
1667 ])
1668
1669 dnl
1670 dnl Check for -Bsymbolic-functions linker flag used to avoid
1671 dnl intra-library PLT jumps, if available.
1672 dnl
1673 AC_ARG_ENABLE(Bsymbolic,
1674               [AS_HELP_STRING([--disable-Bsymbolic],
1675                               [avoid linking with -Bsymbolic])],,
1676               [SAVED_LDFLAGS="${LDFLAGS}"
1677                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1678                LDFLAGS=-Wl,-Bsymbolic-functions
1679                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1680                                                [[int main (void) { return 0; }]])],
1681                               [AC_MSG_RESULT(yes)
1682                                enable_Bsymbolic=yes],
1683                               [AC_MSG_RESULT(no)
1684                                enable_Bsymbolic=no])
1685                LDFLAGS="${SAVED_LDFLAGS}"])
1686
1687 if test "x${enable_Bsymbolic}" = "xyes" ; then
1688   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1689 fi
1690 AC_SUBST(GTK_LINK_FLAGS)
1691
1692 AC_CONFIG_FILES([
1693 config.h.win32
1694 gtk-zip.sh
1695 Makefile
1696 gdk-3.0.pc
1697 gtk+-3.0.pc
1698 gtk+-unix-print-3.0.pc
1699 gail-3.0.pc
1700 gtk+-3.0-uninstalled.pc
1701 gail-3.0-uninstalled.pc
1702 m4macros/Makefile
1703 po/Makefile.in
1704 po-properties/Makefile.in
1705 demos/Makefile
1706 demos/gtk-demo/Makefile
1707 demos/gtk-demo/geninclude.pl
1708 demos/pixbuf-demo/Makefile
1709 examples/Makefile
1710 tests/Makefile
1711 tests/css/Makefile
1712 tests/css/parser/Makefile
1713 tests/reftests/Makefile
1714 docs/Makefile
1715 docs/reference/Makefile
1716 docs/reference/gdk/Makefile
1717 docs/reference/gdk/version.xml
1718 docs/reference/gtk/Makefile
1719 docs/reference/gtk/version.xml
1720 docs/reference/libgail-util/Makefile
1721 docs/reference/libgail-util/version.xml
1722 docs/tools/Makefile
1723 build/Makefile
1724 build/win32/Makefile
1725 build/win32/vs9/Makefile
1726 build/win32/vs10/Makefile
1727 gdk/Makefile
1728 gdk/broadway/Makefile
1729 gdk/x11/Makefile
1730 gdk/win32/Makefile
1731 gdk/win32/rc/Makefile
1732 gdk/win32/rc/gdk.rc
1733 gdk/quartz/Makefile
1734 gdk/wayland/Makefile
1735 gdk/tests/Makefile
1736 gtk/Makefile
1737 gtk/makefile.msc
1738 gtk/gtkversion.h
1739 gtk/gtk-win32.rc
1740 gtk/a11y/Makefile
1741 gtk/a11y/tests/Makefile
1742 gtk/tests/Makefile
1743 libgail-util/Makefile
1744 modules/Makefile
1745 modules/engines/Makefile
1746 modules/engines/pixbuf/Makefile
1747 modules/engines/ms-windows/Makefile
1748 modules/engines/ms-windows/Theme/Makefile
1749 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1750 modules/input/Makefile
1751 modules/printbackends/Makefile
1752 modules/printbackends/cups/Makefile
1753 modules/printbackends/lpr/Makefile
1754 modules/printbackends/file/Makefile
1755 modules/printbackends/papi/Makefile
1756 modules/printbackends/test/Makefile
1757 perf/Makefile
1758 ])
1759
1760 AC_OUTPUT
1761
1762 # beautify the immodule list a bit
1763 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1764 if test -z "${included_immodules}"; then included_immodules="none"; fi
1765
1766 echo ""
1767 echo "        GTK+ $GTK_VERSION"
1768 echo "        ==========="
1769 echo ""
1770 echo "        GDK backends:         $GDK_BACKENDS"
1771 if test "x$enable_x11_backend" = "xyes"; then
1772 echo "        X11 extensions:       $X_EXTENSIONS"
1773 fi
1774 echo "        Print backends:       $PRINT_BACKENDS"
1775 echo "        Dynamic modules:      $build_dynamic_modules"
1776 echo "        Included immodules:   $included_immodules"
1777 echo "        PackageKit support:   $build_packagekit"
1778 echo "        colord support:       $have_colord"
1779 echo "        Introspection:        $found_introspection"
1780 echo "        Debugging:            $enable_debug"
1781 echo "        Documentation:        $enable_gtk_doc"