Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [7])
  13 m4_define([gtk_micro_version], [13])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AC_CANONICAL_HOST
  33 AC_CANONICAL_TARGET
  34
  35 # Define a string for the earliest version that this release has
  36 # backwards binary compatibility with for all interfaces a module
  37 # might. Unless we add module-only API with lower stability
  38 # guarantees, this should be unchanged until we break binary compat
  39 # for GTK+.
  40 #
  41 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  42 m4_define([gtk_binary_version], [3.0.0])
  43
  44 # required versions of other packages
  45 m4_define([glib_required_version], [2.35.3])
  46 m4_define([pango_required_version], [1.32.4])
  47 m4_define([atk_required_version], [2.7.5])
  48 m4_define([cairo_required_version], [1.10.0])
  49 m4_define([gdk_pixbuf_required_version], [2.27.1])
  50 m4_define([introspection_required_version], [1.32.0])
  51 GLIB_REQUIRED_VERSION=glib_required_version
  52 PANGO_REQUIRED_VERSION=pango_required_version
  53 ATK_REQUIRED_VERSION=atk_required_version
  54 CAIRO_REQUIRED_VERSION=cairo_required_version
  55 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  56 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  57
  58 AC_SUBST(GLIB_REQUIRED_VERSION)
  59 AC_SUBST(PANGO_REQUIRED_VERSION)
  60 AC_SUBST(ATK_REQUIRED_VERSION)
  61 AC_SUBST(CAIRO_REQUIRED_VERSION)
  62 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  63 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  64
  65 # Save this value here, since automake will set cflags later
  66 cflags_set=${CFLAGS+set}
  67
  68 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  69 AM_MAINTAINER_MODE([enable])
  70
  71 # Support silent build rules. Disable
  72 # by either passing --disable-silent-rules to configure or passing V=1
  73 # to make
  74 AM_SILENT_RULES([yes])
  75
  76 #
  77 # For each of the libraries we build, we define the following
  78 # substituted variables:
  79 #
  80 # foo_PACKAGES:     pkg-config packages this library requires
  81 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  82 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  83 # foo_DEP_LIBS:     All libraries this module requires
  84 # foo_DEP_CFLAGS:   All cflags this module requires
  85
  86
  87 GTK_MAJOR_VERSION=gtk_major_version
  88 GTK_MINOR_VERSION=gtk_minor_version
  89 GTK_MICRO_VERSION=gtk_micro_version
  90 GTK_INTERFACE_AGE=gtk_interface_age
  91 GTK_BINARY_AGE=gtk_binary_age
  92 GTK_VERSION=gtk_version
  93 GTK_API_VERSION=gtk_api_version
  94 GTK_BINARY_VERSION=gtk_binary_version
  95 AC_SUBST(GTK_MAJOR_VERSION)
  96 AC_SUBST(GTK_MINOR_VERSION)
  97 AC_SUBST(GTK_MICRO_VERSION)
  98 AC_SUBST(GTK_INTERFACE_AGE)
  99 AC_SUBST(GTK_BINARY_AGE)
 100 AC_SUBST(GTK_API_VERSION)
 101 AC_SUBST(GTK_VERSION)
 102 AC_SUBST(GTK_BINARY_VERSION)
 103
 104 # libtool versioning
 105 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 106 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 107 #LT_REVISION=$GTK_INTERFACE_AGE
 108 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 109 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 110
 111 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 112 m4_define([lt_revision], [gtk_interface_age])
 113 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 114 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 115 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 116 AC_SUBST(LT_VERSION_INFO)
 117 AC_SUBST(LT_CURRENT_MINUS_AGE)
 118
 119 m4_define([gail_lt_current],[0])
 120 m4_define([gail_lt_revision],[0])
 121 m4_define([gail_lt_age],[0])
 122 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 123 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 124 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 125 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 126
 127 # Checks for programs.
 128 AC_PROG_CC
 129 AX_PROG_CC_FOR_BUILD
 130 AC_PROG_CC_C_O
 131 AC_PROG_MKDIR_P
 132 AC_PROG_INSTALL
 133 AC_PROG_MAKE_SET
 134
 135
 136 GETTEXT_PACKAGE=gtk30
 137 AC_SUBST(GETTEXT_PACKAGE)
 138 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 139                    [The prefix for our gettext translation domains.])
 140
 141 MATH_LIB=-lm
 142 AC_MSG_CHECKING([for native Win32])
 143 LIB_EXE_MACHINE_FLAG=X86
 144 EXE_MANIFEST_ARCHITECTURE=X86
 145 DISABLE_ON_W32=''
 146 case "$host" in
 147   *-*-mingw*)
 148     dnl Comment-out certain gtk3.types.in lines
 149     DISABLE_ON_W32='%'
 150     os_win32=yes
 151     gio_can_sniff=no
 152     MATH_LIB=
 153     case "$host" in
 154     x86_64-*-*)
 155       LIB_EXE_MACHINE_FLAG=X64
 156       EXE_MANIFEST_ARCHITECTURE=AMD64
 157       ;;
 158     esac
 159     ;;
 160   *)
 161     os_win32=no
 162     ;;
 163 esac
 164 AC_MSG_RESULT([$os_win32])
 165
 166 AC_SUBST(DISABLE_ON_W32)
 167 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 168 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 169
 170 case $host in
 171   *-*-linux*)
 172     os_linux=yes
 173     ;;
 174 esac
 175
 176 dnl
 177 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 178 dnl We use this for an automated test for C++ header correctness.
 179 dnl
 180 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 181 AC_LANG_PUSH([C++])
 182
 183 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 184                                    [[class a { int b; } c;]])],
 185                   [],[CXX=])
 186 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 187
 188 gtk_save_cxxflags="$CXXFLAGS"
 189 CXXFLAGS="$CXXFLAGS -x objective-c++"
 190 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 191                                    [[]])],
 192                   [OBJC=yes],[OBJC=no])
 193 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 194 CXXFLAGS="$gtk_save_cxxflags"
 195 AC_LANG_POP([C++])
 196
 197 if test "$os_win32" = "yes"; then
 198   if test x$enable_static = xyes -o x$enable_static = x; then
 199     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 200     enable_static=no
 201   fi
 202   if test x$enable_shared = xno; then
 203     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 204   fi
 205   enable_shared=yes
 206 fi
 207
 208 dnl Initialize libtool
 209 LT_PREREQ([2.2.6])
 210 LT_INIT([disable-static win32-dll])
 211 # Create libtool early, because it's used in configure
 212 LT_OUTPUT
 213
 214 # Make sure we use 64-bit versions of various file stuff.
 215 AC_SYS_LARGEFILE
 216
 217 AM_PROG_AS
 218 AC_PATH_PROG(NM, nm, nm)
 219
 220 AC_MSG_CHECKING([for some Win32 platform])
 221 case "$host" in
 222   *-*-mingw*|*-*-cygwin*)
 223     platform_win32=yes
 224     ;;
 225   *)
 226     platform_win32=no
 227     ;;
 228 esac
 229 AC_MSG_RESULT([$platform_win32])
 230 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 231
 232 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 233 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 234 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 235
 236 if test "$os_win32" = "yes"; then
 237   AC_CHECK_TOOL(WINDRES, windres, no)
 238   if test "$WINDRES" = no; then
 239     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 240   fi
 241   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 242 fi
 243 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 244
 245 m4_define([debug_default],
 246           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 247
 248 dnl declare --enable-* args and collect ac_help strings
 249 AC_ARG_ENABLE(debug,
 250               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 251                               [turn on debugging @<:@default=debug_default@:>@])],,
 252               [enable_debug=debug_default])
 253
 254 AC_ARG_ENABLE(rebuilds,
 255               [AS_HELP_STRING([--disable-rebuilds],
 256                               [disable all source autogeneration rules])],,
 257               [enable_rebuilds=yes])
 258
 259 AC_ARG_ENABLE(gtk2-dependency,
 260               [AS_HELP_STRING([--enable-gtk2-dependency],
 261                               [Do not build gtk-update-icon-cache and other shared tools])],,
 262               [enable_gtk2_dependency=no])
 263
 264 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 265
 266 AC_ARG_ENABLE(xkb,
 267               [AS_HELP_STRING([--enable-xkb],
 268                               [support XKB extension [default=maybe]])],,
 269               [enable_xkb="maybe"])
 270 AC_ARG_ENABLE(xinerama,
 271               [AS_HELP_STRING([--enable-xinerama],
 272                               [support Xinerama extension [default=maybe]])],,
 273               [enable_xinerama="maybe"])
 274 AC_ARG_ENABLE(xrandr,
 275               [AS_HELP_STRING([--enable-xrandr],
 276                               [support XRandR extension [default=maybe]])],,
 277               [enable_xrandr="maybe"])
 278 AC_ARG_ENABLE(xfixes,
 279               [AS_HELP_STRING([--enable-xfixes],
 280                               [support XFixes extension [default=maybe]])],,
 281               [enable_xfixes="maybe"])
 282 AC_ARG_ENABLE(xcomposite,
 283               [AS_HELP_STRING([--enable-xcomposite],
 284                               [support X Composite extension [default=maybe]])],,
 285               [enable_xcomposite="maybe"])
 286 AC_ARG_ENABLE(xdamage,
 287               [AS_HELP_STRING([--enable-xdamage],
 288                               [support X Damage extension [default=maybe]])],,
 289               [enable_xdamage="maybe"])
 290
 291 AC_ARG_ENABLE(x11-backend,
 292               [AS_HELP_STRING([--enable-x11-backend],
 293                               [enable the X11 gdk backend])],
 294                               [backend_set=yes])
 295 AC_ARG_ENABLE(win32-backend,
 296               [AS_HELP_STRING([--enable-win32-backend],
 297                               [enable the Win32 gdk backend])],
 298                               [backend_set=yes])
 299 AC_ARG_ENABLE(quartz-backend,
 300               [AS_HELP_STRING([--enable-quartz-backend],
 301                               [enable the quartz gdk backend])],
 302                               [backend_set=yes])
 303 AC_ARG_ENABLE(broadway-backend,
 304               [AS_HELP_STRING([--enable-broadway-backend],
 305                               [enable the broadway (HTML5) gdk backend])],
 306                               [backend_set=yes])
 307 AC_ARG_ENABLE(wayland-backend,
 308               [AS_HELP_STRING([--enable-wayland-backend],
 309                               [enable the wayland gdk backend])],
 310                               [backend_set=yes])
 311
 312 if test -z "$backend_set"; then
 313   if test "$platform_win32" = yes; then
 314     enable_win32_backend=yes
 315   else
 316     enable_x11_backend=yes
 317   fi
 318 fi
 319
 320 AC_ARG_ENABLE(quartz-relocation,
 321               [AS_HELP_STRING([--enable-quartz-relocation],
 322                               [enable bundle-based relocation functions])],
 323                               [quartz_relocation=yes])
 324
 325 cairo_backends=
 326 backend_immodules=
 327 have_gio_unix=no
 328 GDK_BACKENDS=
 329 GDK_EXTRA_LIBS=
 330 GDK_EXTRA_CFLAGS=
 331 GDK_WINDOWING=
 332 PANGO_PACKAGES="pango pangocairo"
 333
 334 if test "$enable_x11_backend" = "yes"; then
 335   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 336   # backend names are identical.
 337   cairo_backends="$cairo_backends cairo-xlib"
 338   GDK_BACKENDS="$GDK_BACKENDS x11"
 339   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 340   # gdkapplaunchcontext-x11.c
 341   have_gio_unix=yes
 342   backend_immodules="$backend_immodules,xim"
 343   GDK_WINDOWING="$GDK_WINDOWING
 344 #define GDK_WINDOWING_X11"
 345 fi
 346
 347 if test "$enable_win32_backend" = "yes"; then
 348   cairo_backends="$cairo_backends cairo-win32"
 349   GDK_BACKENDS="$GDK_BACKENDS win32"
 350   backend_immodules="$backend_immodules,ime"
 351   GDK_WINDOWING="$GDK_WINDOWING
 352 #define GDK_WINDOWING_WIN32"
 353   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 354   AM_CONDITIONAL(USE_WIN32, true)
 355   PANGO_PACKAGES="pangowin32 pangocairo"
 356 else
 357   AM_CONDITIONAL(USE_WIN32, false)
 358 fi
 359
 360 DISABLE_ON_QUARTZ=''
 361 if test "x$enable_quartz_backend" = xyes; then
 362   cairo_backends="$cairo_backends cairo-quartz"
 363   GDK_BACKENDS="$GDK_BACKENDS quartz"
 364   GDK_WINDOWING="$GDK_WINDOWING
 365 #define GDK_WINDOWING_QUARTZ"
 366   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 367   DISABLE_ON_QUARTZ='%'
 368   AM_CONDITIONAL(USE_QUARTZ, true)
 369   if test "x$quartz_relocation" = xyes; then
 370     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 371   fi
 372   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 373   # gdkapplaunchcontext-x11.c
 374   have_gio_unix=yes
 375
 376 else
 377   AM_CONDITIONAL(USE_QUARTZ, false)
 378 fi
 379 AC_SUBST(DISABLE_ON_QUARTZ)
 380
 381 if test "x$enable_broadway_backend" = xyes; then
 382   GDK_BACKENDS="$GDK_BACKENDS broadway"
 383   cairo_backends="$cairo_backends cairo"
 384   have_gio_unix=yes
 385   GDK_WINDOWING="$GDK_WINDOWING
 386 #define GDK_WINDOWING_BROADWAY"
 387   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 388   AM_CONDITIONAL(USE_BROADWAY, true)
 389 else
 390   AM_CONDITIONAL(USE_BROADWAY, false)
 391 fi
 392
 393 DISABLE_ON_WAYLAND=''
 394 if test "x$enable_wayland_backend" = "xyes"; then
 395   # For the cairo image backend
 396   cairo_backends="$cairo_backends cairo"
 397   GDK_BACKENDS="$GDK_BACKENDS wayland"
 398   have_gio_unix=yes
 399   GDK_WINDOWING="$GDK_WINDOWING
 400 #define GDK_WINDOWING_WAYLAND"
 401   DISABLE_ON_WAYLAND='%'
 402   WAYLAND_PACKAGES="wayland-client >= 1.0.0 xkbcommon >= 0.2.0 wayland-cursor"
 403   AM_CONDITIONAL(USE_WAYLAND, true)
 404 else
 405   AM_CONDITIONAL(USE_WAYLAND, false)
 406 fi
 407 AC_SUBST(DISABLE_ON_WAYLAND)
 408
 409 # strip leading space
 410 GDK_BACKENDS=${GDK_BACKENDS#* }
 411
 412 AC_SUBST(GDK_BACKENDS)
 413
 414 if test -z "$GDK_BACKENDS"; then
 415   AC_MSG_ERROR([No GDK backends selected.])
 416 fi
 417
 418 if test "x$enable_debug" = "xyes"; then
 419   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 420   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 421 else
 422   if test "x$enable_debug" = "xno"; then
 423     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 424   else
 425     GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"
 426   fi
 427 fi
 428
 429
 430 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 431                    [Define if debugging is enabled])
 432
 433
 434 # Build time sanity check...
 435 AM_SANITY_CHECK
 436
 437 changequote(,)dnl
 438 if test "x$GCC" = "xyes"; then
 439   case " $CFLAGS " in
 440   *[\ \ ]-Wall[\ \      ]*) ;;
 441   *) CFLAGS="$CFLAGS -Wall" ;;
 442   esac
 443
 444   if test "x$enable_ansi" = "xyes"; then
 445     case " $CFLAGS " in
 446     *[\ \       ]-ansi[\ \      ]*) ;;
 447     *) CFLAGS="$CFLAGS -ansi" ;;
 448     esac
 449
 450     case " $CFLAGS " in
 451     *[\ \       ]-pedantic[\ \  ]*) ;;
 452     *) CFLAGS="$CFLAGS -pedantic" ;;
 453     esac
 454   fi
 455 fi
 456 changequote([,])dnl
 457
 458 # Ensure MSVC-compatible struct packing convention is used when
 459 # compiling for Win32 with gcc.
 460 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 461 # gcc2 uses "-fnative-struct".
 462 if test x"$os_win32" = xyes; then
 463   if test x"$GCC" = xyes; then
 464     msnative_struct=''
 465     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 466     if test -z "$ac_cv_prog_CC"; then
 467       our_gcc="$CC"
 468     else
 469       our_gcc="$ac_cv_prog_CC"
 470     fi
 471     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 472       2.)
 473         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 474           msnative_struct='-fnative-struct'
 475         fi
 476         ;;
 477       *)
 478         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 479           msnative_struct='-mms-bitfields'
 480         fi
 481         ;;
 482     esac
 483     if test x"$msnative_struct" = x ; then
 484       AC_MSG_RESULT([no way])
 485       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 486     else
 487       CFLAGS="$CFLAGS $msnative_struct"
 488       AC_MSG_RESULT([${msnative_struct}])
 489     fi
 490   fi
 491 fi
 492
 493 ## Initial sanity check, done here so that users get told they
 494 ## have the wrong dependencies as early in the process as possible.
 495 ## Later on we actually use the cflags/libs from separate pkg-config
 496 ## calls. Oh, also the later pkg-config calls don't include
 497 ## the version requirements since those make the module lists
 498 ## annoying to construct
 499 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 500   [glib-2.0 >= glib_required_version dnl
 501    atk >= atk_required_version dnl
 502    pango >= pango_required_version dnl
 503    cairo >= cairo_required_version dnl
 504    cairo-gobject >= cairo_required_version dnl
 505    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 506
 507 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 508
 509 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0])
 510
 511 if test "$os_win32" != yes; then
 512     # libtool option to control which symbols are exported
 513     # right now, symbols starting with _ are not exported
 514     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 515 else
 516     # We currently use .def files on Windows (for gdk and gtk)
 517     LIBTOOL_EXPORT_OPTIONS=
 518 fi
 519 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 520
 521 dnl ******************************************************
 522 dnl * See whether to include shared library dependencies *
 523 dnl ******************************************************
 524
 525 AC_ARG_ENABLE(explicit-deps,
 526               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 527                               [use explicit dependencies in .pc files [default=auto]])],,
 528               [enable_explicit_deps=auto])
 529
 530 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 531 case $enable_explicit_deps in
 532   auto)
 533     export SED
 534     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 535     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 536       enable_explicit_deps=yes
 537     else
 538       enable_explicit_deps=no
 539     fi
 540   ;;
 541   yes|no)
 542   ;;
 543   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 544   ;;
 545 esac
 546 AC_MSG_RESULT($enable_explicit_deps)
 547
 548 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 549
 550 # define a MAINT-like variable REBUILD which is set if Perl
 551 # and awk are found, so autogenerated sources can be rebuilt
 552
 553 AC_PATH_PROGS(PERL, perl5 perl)
 554
 555 # We would like indent, but don't require it.
 556 AC_CHECK_PROG(INDENT, indent, indent)
 557
 558 REBUILD=\#
 559 if test "x$enable_rebuilds" = "xyes" && \
 560      test -n "$PERL" && \
 561      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 562   REBUILD=
 563 fi
 564 AC_SUBST(REBUILD)
 565
 566 AC_CHECK_FUNCS(lstat mkstemp)
 567 AC_CHECK_FUNCS(localtime_r)
 568
 569 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 570 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 571 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 572                                 [[char c;
 573                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 574                [gtk_ok=yes], [gtk_ok=no])
 575 AC_MSG_RESULT($gtk_ok)
 576 if test "$gtk_ok" = "yes"; then
 577   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 578             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 579 fi
 580
 581 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 582 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 583 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 584                                 [[char c;
 585                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 586                [gtk_ok=yes], [gtk_ok=no])
 587 AC_MSG_RESULT($gtk_ok)
 588 if test "$gtk_ok" = "yes"; then
 589   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 590             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 591 fi
 592
 593 # _NL_PAPER_HEIGHT is an enum and not a define
 594 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 595 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 596                                 [[char c;
 597                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 598                [gtk_ok=yes], [gtk_ok=no])
 599 AC_MSG_RESULT($gtk_ok)
 600 if test "$gtk_ok" = "yes"; then
 601   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 602             [Define if _NL_PAPER_HEIGHT is available])
 603 fi
 604
 605 # _NL_PAPER_WIDTH is an enum and not a define
 606 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 607 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 608                                 [[char c;
 609                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 610                [gtk_ok=yes], [gtk_ok=no])
 611 AC_MSG_RESULT($gtk_ok)
 612 if test "$gtk_ok" = "yes"; then
 613   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 614             [Define if _NL_PAPER_WIDTH is available])
 615 fi
 616
 617 # i18n stuff
 618 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 619 AM_GLIB_GNU_GETTEXT
 620 LIBS="$LIBS $INTLLIBS"
 621 AC_CONFIG_COMMANDS([po-properties],
 622                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 623                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 624                      esac]],
 625                    [[]])
 626
 627 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 628 dnl po-properties/POTFILES during configure; see GNOME #573515.
 629 dnl
 630 dnl Generate list of files to be processed by xgettext which will
 631 dnl be included in po-properties/Makefile.
 632 test -d po-properties || mkdir po-properties
 633 if test "x$srcdir" != "x."; then
 634   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 635     popropsrcprefix="$srcdir/"
 636   else
 637     popropsrcprefix="../$srcdir/"
 638   fi
 639 else
 640   popropsrcprefix="../"
 641 fi
 642 rm -f po-properties/POTFILES
 643 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 644 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 645 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 646
 647 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 648
 649 dnl The DU4 header files don't provide library prototypes unless
 650 dnl -std1 is given to the native cc.
 651 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 652
 653 gtk_save_LIBS=$LIBS
 654 LIBS="$LIBS -lm"
 655 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 656                                 int main (void) { return (log(1) != log(1.)); }]])],
 657               [AC_MSG_RESULT(none needed)],
 658               [gtk_save_CFLAGS="$CFLAGS"
 659                CFLAGS="$CFLAGS -std1"
 660                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 661                                                int main (void) { return (log(1) != log(1.)); }]])],
 662                              [AC_MSG_RESULT(-std1)],
 663                              [AC_MSG_RESULT()
 664                               CFLAGS="$gtk_save_CFLAGS"
 665                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 666                              [true])],
 667               [AC_MSG_RESULT(none needed)])
 668
 669 LIBS=$gtk_save_LIBS
 670
 671 AC_MSG_CHECKING(for the BeOS)
 672 case $host in
 673   *-*-beos*)
 674     AC_MSG_RESULT(yes)
 675     MATH_LIB=
 676   ;;
 677   *)
 678     AC_MSG_RESULT(no)
 679   ;;
 680 esac
 681
 682 AC_SUBST(MATH_LIB)
 683 #
 684 # see bug 162979
 685 #
 686 AC_MSG_CHECKING(for HP-UX)
 687 case $host_os in
 688   hpux9* | hpux10* | hpux11*)
 689     AC_MSG_RESULT(yes)
 690     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 691   ;;
 692   *)
 693     AC_MSG_RESULT(no)
 694   ;;
 695 esac
 696
 697 #
 698 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 699 #
 700
 701 AM_PATH_GLIB_2_0(glib_required_version, :,
 702   AC_MSG_ERROR([
 703 *** GLIB glib_required_version or better is required. The latest version of
 704 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 705   gobject gmodule-no-export)
 706
 707 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 708 dnl
 709 gtk_save_LIBS=$LIBS
 710 LIBS="$LIBS $GLIB_LIBS"
 711 AC_CHECK_FUNCS(bind_textdomain_codeset)
 712 LIBS=$gtk_save_LIBS
 713
 714 AC_CHECK_HEADERS(pwd.h,
 715                  AC_DEFINE(HAVE_PWD_H, 1,
 716                            [Define to 1 if pwd.h is available]))
 717 AC_CHECK_HEADERS(sys/time.h,
 718                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 719                            [Define to 1 if time.h is available]))
 720 AC_CHECK_HEADERS(unistd.h,
 721                  AC_DEFINE(HAVE_UNISTD_H, 1,
 722                            [Define to 1 if unistd.h is available]))
 723 AC_CHECK_HEADERS(ftw.h,
 724                  AC_DEFINE(HAVE_FTW_H, 1,
 725                            [Define to 1 if ftw.h is available]))
 726
 727 AC_MSG_CHECKING([for GNU ftw extensions])
 728 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 729                                      #define _GNU_SOURCE
 730                                      #include <ftw.h>]],
 731                                    [[int flags = FTW_ACTIONRETVAL;]])],
 732                   [gtk_ok=yes],[gtk_ok=no])
 733 if test $gtk_ok = yes; then
 734     AC_MSG_RESULT([yes])
 735     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 736 else
 737     AC_MSG_RESULT([no])
 738 fi
 739
 740 #
 741 # Disable deprecation checks for all libraries we depend on on stable branches.
 742 # This is so newer versions of those libraries don't cause more warnings with
 743 # a stable GTK version.
 744 # We don't ever want to turn off deprecation warnings for master however, because
 745 # that's where we get rid of deprecated API we use.
 746 #
 747 if test m4_eval(gtk_minor_version % 2) = 0 ; then
 748   AC_DEFINE_UNQUOTED(GLIB_DISABLE_DEPRECATION_WARNINGS, 1,
 749                      [Disable deprecation warnings from glib])
 750 fi
 751
 752 dnl
 753 saved_cflags="$CFLAGS"
 754 saved_ldflags="$LDFLAGS"
 755
 756
 757 # Checks for library functions.
 758 AC_FUNC_MMAP
 759
 760 AC_CHECK_FUNCS(mallinfo)
 761 AC_CHECK_FUNCS(getresuid)
 762 AC_TYPE_UID_T
 763
 764 # Check for round(), rint(), isnan(), isinf() and nearbyint()
 765 AC_CHECK_LIB(m,round,,)
 766 AC_CHECK_FUNCS(round rint nearbyint)
 767 AC_CHECK_DECLS([isnan, isinf], [], [], [[#include <math.h>]])
 768
 769 # Checks for gdkspawn
 770 AC_CHECK_HEADERS(crt_externs.h)
 771 AC_CHECK_FUNCS(_NSGetEnviron)
 772
 773 AC_MSG_CHECKING(whether to build dynamic modules)
 774
 775 AC_ARG_ENABLE(modules,
 776               [AS_HELP_STRING([--disable-modules],
 777                               [disable dynamic module loading])])
 778
 779 dynworks=false
 780 build_dynamic_modules=no
 781 deps=
 782 if test x$enable_modules = xno; then
 783     AC_MSG_RESULT(no)
 784 else
 785     AC_MSG_RESULT(yes)
 786     AC_MSG_CHECKING(whether dynamic modules work)
 787     ## for loop is to strip newline
 788     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 789     for I in $tmp; do
 790         dynworks=$I
 791     done
 792
 793     dnl Now we check to see if our libtool supports shared lib deps
 794     dnl (in a rather ugly way even)
 795     if $dynworks; then
 796         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 797         module_deplibs_check=`$module_libtool_config | \
 798             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 799             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 800         if test "x$module_deplibs_check" = "xnone" || \
 801            test "x$module_deplibs_check" = "xunknown" || \
 802            test "x$module_deplibs_check" = "x"; then
 803             dynworks=false
 804         fi
 805     fi
 806
 807     if $dynworks; then
 808         build_dynamic_modules=yes
 809         AC_DEFINE(USE_GMODULE, 1,
 810                   [Define to 1 if gmodule works and should be used])
 811         AC_MSG_RESULT(yes)
 812     else
 813         build_dynamic_modules=no
 814         AC_MSG_RESULT(no)
 815     fi
 816 fi
 817
 818 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 819
 820 #
 821 # Allow building some or all immodules included
 822 #
 823 AC_MSG_CHECKING(immodules to build)
 824
 825 AC_ARG_WITH(included_immodules,
 826             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 827                             [build the specified input methods into gtk])])
 828
 829 if $dynworks; then
 830    :
 831 else
 832    ## if the option was specified, leave it; otherwise disable included immodules
 833    if test x$with_included_immodules = xno; then
 834            with_included_immodules=yes
 835    fi
 836 fi
 837
 838 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 839
 840 included_immodules=""
 841 # If the switch specified without listing any specific ones, include all
 842 if test "x$with_included_immodules" = xyes ; then
 843   included_immodules="$all_immodules"
 844 else
 845   included_immodules="$with_included_immodules"
 846 fi
 847
 848 AC_MSG_RESULT($included_immodules)
 849 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 850
 851 INCLUDED_IMMODULE_OBJ=
 852 INCLUDED_IMMODULE_DEFINE=
 853
 854 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 855 for immodule in $included_immodules; do
 856  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 857  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 858    :
 859  else
 860    AC_MSG_ERROR([the specified input method $immodule does not exist])
 861  fi
 862
 863  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 864  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 865  eval INCLUDE_$immodule_underscores=yes
 866 done
 867 IFS="$gtk_save_ifs"
 868 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 869 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 870
 871 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 872 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 873 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 874 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 875 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 876 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 877 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 878 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 879 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 880 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 881 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 882 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 883
 884 # Checks to see whether we should include mediaLib
 885 # support.
 886 #
 887 AC_CHECK_HEADER(sys/systeminfo.h,
 888                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 889                           [Define to 1 if sys/systeminfo.h is available]))
 890 AC_CHECK_HEADER(sys/sysinfo.h,
 891                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 892                           [Define to 1 if sys/sysinfo.h is available]))
 893
 894 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 895
 896 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 897
 898 AS_IF([test "x$enable_gtk2_dependency" = xyes],
 899       [AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 900        if test x$GTK_UPDATE_ICON_CACHE = xno; then
 901          REBUILD_PNGS=#
 902        fi],
 903
 904       [test "x$cross_compiling" = xyes],
 905       [# If no GTK+2 dependency and cross compiling, we need to find a host gdk-pixbuf.
 906        # pkg.m4 blocks all variable starting with PKG, so allow this one
 907        m4_pattern_allow([PKG_CONFIG_FOR_BUILD])
 908
 909        AS_IF([test x$PKG_CONFIG_FOR_BUILD = x],
 910              [AC_MSG_ERROR([You must define PKG_CONFIG_FOR_BUILD when cross compiling])])
 911
 912        AC_MSG_CHECKING([for native gdk-pixbuf])
 913        AS_IF([AC_RUN_LOG([$PKG_CONFIG_FOR_BUILD --exists --print-errors gdk-pixbuf-2.0])],
 914              [AC_MSG_RESULT([yes])],
 915              [AC_MSG_ERROR([native gdk-pixbuf not found])])
 916
 917        NATIVE_GDKPIXBUF_CFLAGS=`$PKG_CONFIG_FOR_BUILD --cflags gdk-pixbuf-2.0`
 918        NATIVE_GDKPIXBUF_LIBS=`$PKG_CONFIG_FOR_BUILD --libs gdk-pixbuf-2.0`
 919        AC_SUBST(NATIVE_GDKPIXBUF_CFLAGS)
 920        AC_SUBST(NATIVE_GDKPIXBUF_LIBS)]
 921 )
 922
 923 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$enable_gtk2_dependency" = xyes])
 924
 925 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 926
 927 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 928    test "x$REBUILD_PNGS" = "x#" ; then
 929      AC_MSG_ERROR([
 930 *** gtkbuiltincache.h is not in the tree, and cannot be built
 931 *** because you don't have libpng, or (when cross-compiling) you
 932 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 933 fi
 934
 935 ########################################
 936 # Windowing system checks
 937 ########################################
 938
 939 # GTK+ uses some X calls, so needs to link against X directly
 940 GTK_DEP_PACKAGES_FOR_X=
 941 GTK_DEP_LIBS_FOR_X=
 942 X_EXTENSIONS=
 943
 944 if test "x$enable_x11_backend" = xyes; then
 945   X_PACKAGES=fontconfig
 946
 947   #
 948   # We use fontconfig very peripherally when decoding the default
 949   # settings.
 950   #
 951   if $PKG_CONFIG --exists fontconfig; then : ; else
 952     AC_MSG_ERROR([
 953 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 954   fi
 955
 956   #
 957   # Check for basic X packages; we use pkg-config if available
 958   #
 959   if $PKG_CONFIG --exists x11 xext; then
 960     have_base_x_pc=true
 961     X_PACKAGES="$X_PACKAGES x11 xext"
 962     x_libs="`$PKG_CONFIG --libs x11 xext`"
 963     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 964
 965     # Strip out any .la files that pkg-config might give us (this happens
 966     # with -uninstalled.pc files)
 967     x_libs_for_checks=
 968     for I in $x_libs ; do
 969       case $I in
 970         *.la) ;;
 971         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 972       esac
 973     done
 974
 975     GTK_PACKAGES_FOR_X="x11"
 976   else
 977     have_base_x_pc=false
 978     AC_PATH_XTRA
 979     if test x$no_x = xyes ; then
 980       AC_MSG_ERROR([X development libraries not found])
 981     fi
 982
 983     x_cflags="$X_CFLAGS"
 984     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 985
 986     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 987   fi
 988
 989   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 990   x_extra_libs=
 991
 992   gtk_save_cppflags="$CPPFLAGS"
 993   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 994
 995   gtk_save_LIBS=$LIBS
 996   LIBS="$x_libs_for_checks $LIBS"
 997
 998   # Sanity check for the X11 and Xext libraries. While everything we need from
 999   # Xext is optional, the chances a system has *none* of these things is so
1000   # small that we just unconditionally require it.
1001   AC_CHECK_FUNC(XOpenDisplay, :,
1002                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
1003   AC_CHECK_FUNC(XextFindDisplay, :,
1004                 AC_MSG_ERROR([*** libX11 and libXext not found. Check 'config.log' for more details.]))
1005
1006   # Check for xReply
1007
1008   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
1009   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
1010                                      [[xReply *rep = NULL;
1011                                        rep = rep;]])],
1012                     [AC_MSG_RESULT([no])],
1013                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
1014                                                           #include <X11/Xlibint.h>]],
1015                                                         [[xReply *rep = NULL;
1016                                                           rep = rep;]])],
1017                                        [AC_MSG_RESULT([yes])
1018                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
1019                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
1020                                        [AC_MSG_RESULT([unknown])
1021                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1022
1023   # Check for XKB support.
1024
1025   if test "x$enable_xkb" = "xyes"; then
1026         AC_CHECK_FUNC(XkbQueryExtension,
1027                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1028                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1029                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1030   elif test "x$enable_xkb" = "xmaybe"; then
1031         AC_CHECK_FUNC(XkbQueryExtension,
1032                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1033                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1034   else
1035         AC_MSG_WARN(XKB support explicitly disabled)
1036   fi
1037
1038   # Check for shaped window extension
1039
1040   AC_CHECK_FUNC(XShapeCombineMask, :,
1041      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1042
1043   # X SYNC check
1044   gtk_save_CFLAGS="$CFLAGS"
1045   CFLAGS="$CFLAGS $x_cflags"
1046
1047   AC_CHECK_FUNC(XSyncQueryExtension,
1048       [AC_CHECK_HEADER(X11/extensions/sync.h,
1049           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1050           :, [#include <X11/Xlib.h>])])
1051
1052   CFLAGS="$gtk_save_CFLAGS"
1053
1054   if test "x$enable_xinerama" != "xno"; then
1055     # Check for Xinerama extension (Solaris impl or Xfree impl)
1056     have_xfree_xinerama=false
1057     have_solaris_xinerama=false
1058
1059     gtk_save_cppflags="$CPPFLAGS"
1060     CPPFLAGS="$CPPFLAGS $x_cflags"
1061
1062     # Check for XFree
1063     AC_MSG_CHECKING(for Xinerama packages)
1064
1065     if $PKG_CONFIG --exists xinerama ; then
1066        AC_MSG_RESULT(yes)
1067        have_xfree_xinerama=true
1068        X_PACKAGES="$X_PACKAGES xinerama"
1069     else
1070        AC_MSG_RESULT(no)
1071        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1072            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1073            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1074            have_xfree_xinerama=true], :,
1075            [#include <X11/Xlib.h>])])
1076     fi
1077
1078     if $have_xfree_xinerama ; then
1079       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1080       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1081                 [Define to 1 if XFree Xinerama is available])
1082       AC_DEFINE(HAVE_XINERAMA, 1,
1083                 [Define to 1 is Xinerama is available])
1084     else
1085       case "$host" in
1086         *-*-solaris*)
1087             # Check for solaris
1088             AC_MSG_CHECKING(for Xinerama support on Solaris)
1089
1090             have_solaris_xinerama=false
1091             AC_CHECK_FUNC(XineramaGetInfo,
1092                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1093                     [have_solaris_xinerama=true], :,
1094                     [#include <X11/Xlib.h>])])
1095
1096             if $have_solaris_xinerama ; then
1097               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1098               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1099                         [Define to 1 if solaris xinerama is available])
1100               AC_DEFINE(HAVE_XINERAMA, 1,
1101                         [Define to 1 if xinerama is available])
1102               AC_MSG_RESULT(yes)
1103             else
1104               AC_MSG_RESULT(no)
1105             fi
1106             ;;
1107         *)
1108             ;;
1109       esac
1110     fi
1111   fi
1112   if test "x$enable_xinerama" = "xyes" ; then
1113     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1114       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1115     fi
1116   fi
1117
1118   # Check for XGetEventData for GenericEvents
1119   AC_CHECK_FUNC(XGetEventData,
1120                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1121
1122   # set up things for XInput
1123   if $PKG_CONFIG --exists "xi" ; then
1124
1125     X_PACKAGES="$X_PACKAGES xi"
1126     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xi"
1127
1128     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1129                     have_xinput2=yes
1130                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1131
1132     gtk_save_LIBS="$LIBS"
1133     LIBS="$LIBS -lXi"
1134
1135     # Note that we also check that the XIScrollClassInfo struct is defined,
1136     # because at least Ubuntu Oneiric seems to have XIAllowTouchEvents(), but not the XIScrollClassInfo struct.
1137     AC_CHECK_FUNC([XIAllowTouchEvents],
1138       [AC_CHECK_MEMBER([XIScrollClassInfo.number],
1139                        have_xinput2_2=yes
1140                        AC_DEFINE(XINPUT_2_2, 1, [Define to 1 if XInput 2.2 is available]),
1141                        have_xinput2_2=no,
1142                        [[#include <X11/extensions/XInput2.h>]])])
1143     LIBS="$gtk_save_LIBS"
1144
1145     if test "x$have_xinput2_2" = "xyes"; then
1146       X_EXTENSIONS="$X_EXTENSIONS XI2.2"
1147     else
1148       X_EXTENSIONS="$X_EXTENSIONS XI2"
1149     fi
1150   fi
1151
1152   AS_IF([test "x$have_xinput2" != "xyes"],
1153         [AC_MSG_ERROR([*** XInput2 extension not found. Check 'config.log' for more details.])])
1154
1155   # Check for the RANDR extension
1156   if test x"$enable_xrandr" != xno; then
1157     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1158       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1159
1160       X_PACKAGES="$X_PACKAGES xrandr"
1161       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1162     elif test x"$enable_xrandr" = xyes; then
1163       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1164     fi
1165   fi
1166
1167   # Checks for Xcursor library
1168
1169   if $PKG_CONFIG --exists xcursor ; then
1170     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1171
1172     X_PACKAGES="$X_PACKAGES xcursor"
1173   fi
1174
1175   # Checks for XFixes extension
1176
1177   if test x"$enable_xfixes" != xno; then
1178     if $PKG_CONFIG --exists xfixes ; then
1179       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1180
1181       X_PACKAGES="$X_PACKAGES xfixes"
1182       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1183       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1184     elif test x"$enable_xfixes" = xyes; then
1185       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1186     fi
1187   fi
1188
1189   # Checks for Xcomposite extension
1190
1191   if test x"$enable_xcomposite" != xno; then
1192     if $PKG_CONFIG --exists xcomposite ; then
1193       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1194
1195       X_PACKAGES="$X_PACKAGES xcomposite"
1196       X_EXTENSIONS="$X_EXTENSIONS Composite"
1197       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1198     elif test x"$enable_xcomposite" = xyes; then
1199       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1200     fi
1201   fi
1202
1203   # Checks for Xdamage extension
1204
1205   if test x"$enable_xdamage" != xno; then
1206     if $PKG_CONFIG --exists xdamage ; then
1207       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1208
1209       X_PACKAGES="$X_PACKAGES xdamage"
1210       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1211       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1212     elif test x"$enable_xdamage" = xyes; then
1213       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1214     fi
1215   fi
1216
1217   if $have_base_x_pc ; then
1218     GDK_EXTRA_LIBS="$x_extra_libs"
1219   else
1220     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1221   fi
1222
1223   CPPFLAGS="$gtk_save_cppflags"
1224   LIBS="$gtk_save_libs"
1225
1226   AM_CONDITIONAL(USE_X11, true)
1227
1228   # strip leading space
1229   X_EXTENSIONS=${X_EXTENSIONS#* }
1230
1231 else
1232   XPACKAGES=
1233
1234   AM_CONDITIONAL(USE_X11, false)
1235 fi
1236
1237 # Check for gio-unix
1238 if test "$have_gio_unix" = "yes"; then
1239   GDK_GIO_PACKAGE=gio-unix-2.0
1240   AC_DEFINE([HAVE_GIO_UNIX], [1],
1241             [Define if gio-unix is available])
1242 else
1243   GDK_GIO_PACKAGE=gio-2.0
1244 fi
1245 AM_CONDITIONAL(HAVE_GIO_UNIX, test "$have_gio_unix" = "yes")
1246
1247 # Check for Pango flags
1248
1249 AC_MSG_CHECKING(Pango flags)
1250 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1251         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1252         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1253
1254         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1255 else
1256         AC_MSG_ERROR([
1257 *** Pango not found. Pango built with Cairo support is required
1258 *** to build GTK+. See http://www.pango.org for Pango information.
1259 ])
1260 fi
1261
1262 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1263
1264 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1265         :
1266 else
1267         gtk_save_LIBS="$LIBS"
1268         LIBS="$PANGO_LIBS $LIBS"
1269         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1270 *** Can't link to Pango. Pango is required to build
1271 *** GTK+. For more information see http://www.pango.org]))
1272         LIBS="$gtk_save_LIBS"
1273 fi
1274
1275 CFLAGS="$saved_cflags"
1276 LDFLAGS="$saved_ldflags"
1277
1278 GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo cairo-gobject"
1279 GDK_PRIVATE_PACKAGES="$GDK_GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES $cairo_backends"
1280 if test "x$enable_x11_backend" = xyes; then
1281   GDK_PRIVATE_PACKAGES="$GDK_PRIVATE_PACKAGES pangoft2"
1282 fi
1283
1284 PKG_CHECK_MODULES(GDK_DEP, $GDK_PACKAGES $GDK_PRIVATE_PACKAGES)
1285 GDK_DEP_LIBS="$GDK_EXTRA_LIBS $GDK_DEP_LIBS $MATH_LIB"
1286 GDK_DEP_CFLAGS="$GDK_DEP_CFLAGS $GDK_EXTRA_CFLAGS"
1287 #
1288 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1289 # into the pkg-config files
1290 #
1291 if test $enable_explicit_deps != yes ; then
1292   GDK_EXTRA_LIBS=
1293 fi
1294
1295 AC_SUBST(GDK_PACKAGES)
1296 AC_SUBST(GDK_PRIVATE_PACKAGES)
1297 AC_SUBST(GDK_EXTRA_LIBS)
1298 AC_SUBST(GDK_EXTRA_CFLAGS)
1299 AC_SUBST(GDK_DEP_LIBS)
1300 AC_SUBST(GDK_DEP_CFLAGS)
1301
1302
1303 ########################################
1304 # Check for Accessibility Toolkit flags
1305 ########################################
1306
1307 if test x$enable_x11_backend = xyes; then
1308    ATK_PACKAGES="atk atk-bridge-2.0"
1309 else
1310    ATK_PACKAGES="atk"
1311 fi
1312
1313 PKG_CHECK_MODULES(ATK, $ATK_PACKAGES)
1314
1315 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1316 GTK_PRIVATE_PACKAGES="$ATK_PACKAGES"
1317 if test "x$enable_x11_backend" = xyes; then
1318   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES pangoft2"
1319 fi
1320 if test "$have_gio_unix" = "yes"; then
1321   GTK_PRIVATE_PACKAGES="$GTK_PRIVATE_PACKAGES gio-unix-2.0"
1322 fi
1323 GTK_EXTRA_LIBS=
1324
1325 GTK_EXTRA_CFLAGS=
1326 PKG_CHECK_MODULES(GTK_DEP, $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES $GTK_PRIVATE_PACKAGES)
1327 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X $GTK_DEP_LIBS $GTK_EXTRA_LIBS $MATH_LIB"
1328 GTK_DEP_CFLAGS="$GTK_DEP_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1329
1330 if test x"$os_win32" = xyes; then
1331   GTK_EXTRA_CFLAGS="$msnative_struct"
1332 fi
1333
1334 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1335 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1336 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1337 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1338
1339 AC_SUBST(GTK_PACKAGES)
1340 AC_SUBST(GTK_PRIVATE_PACKAGES)
1341 AC_SUBST(GTK_EXTRA_LIBS)
1342 AC_SUBST(GTK_EXTRA_CFLAGS)
1343 AC_SUBST(GTK_DEP_LIBS)
1344 AC_SUBST(GTK_DEP_CFLAGS)
1345
1346 AC_SUBST(GLIB_PREFIX)
1347 AC_SUBST(ATK_PREFIX)
1348 AC_SUBST(PANGO_PREFIX)
1349 AC_SUBST(CAIRO_PREFIX)
1350
1351 AC_SUBST(GTK_DEBUG_FLAGS)
1352 AC_SUBST(GTK_XIM_FLAGS)
1353
1354 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1355 AC_SUBST(GDK_PIXBUF_LIBS)
1356
1357 ########################
1358 # Checks needed for gail
1359 ########################
1360
1361 old_LIBS="$LIBS"
1362 dnl Checks for inet libraries:
1363 AC_SEARCH_LIBS(gethostent, nsl)
1364 AC_SEARCH_LIBS(setsockopt, socket)
1365 AC_SEARCH_LIBS(connect, inet)
1366
1367 dnl check for the sockaddr_un.sun_len member
1368 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1369                 [struct_sockaddr_un_sun_len=true],
1370                 [struct_sockaddr_un_suin_len=false],
1371                 [#include <sys/types.h>
1372                  #include <sys/un.h>]
1373                 )
1374 case $struct_sockaddr_un_sun_len in
1375         true)
1376                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1377                                    [Have the sockaddr_un.sun_len member])
1378                 ;;
1379         *)
1380                 ;;
1381 esac
1382
1383 GAIL_INET_LIBS="$LIBS"
1384 AC_SUBST([GAIL_INET_LIBS])
1385
1386 LIBS="$old_LIBS"
1387
1388 ################################################################
1389 # Printing system checks
1390 ################################################################
1391
1392 PRINT_BACKENDS="file lpr"
1393
1394 AC_ARG_ENABLE(cups,
1395               [AS_HELP_STRING([--disable-cups],
1396                               [disable cups print backend])],,
1397               [enable_cups=auto])
1398
1399 if test "x$enable_cups" = "xno"; then
1400   AM_CONDITIONAL(HAVE_CUPS, false)
1401 else
1402   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1403   if test "x$CUPS_CONFIG" = "xno"; then
1404     if test "x$enable_cups" = "xauto"; then
1405       AM_CONDITIONAL(HAVE_CUPS, false)
1406     else
1407       AC_MSG_ERROR([
1408 *** cups not found.
1409 ])
1410     fi
1411   else
1412     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1413     CUPS_LIBS=`$CUPS_CONFIG --libs`
1414
1415     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1416     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1417     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1418
1419     if test $CUPS_API_MAJOR -gt 1 -o \
1420             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -lt 2; then
1421       AC_MSG_ERROR([CUPS >= 1.2 not found])
1422     fi
1423     if test $CUPS_API_MAJOR -gt 1 -o \
1424             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 6; then
1425       AC_DEFINE(HAVE_CUPS_API_1_6, 1,
1426                 [Define to 1 if CUPS 1.6 API is available])
1427       have_cups_api_1_6=yes
1428     fi
1429
1430     AC_SUBST(CUPS_API_MAJOR)
1431     AC_SUBST(CUPS_API_MINOR)
1432     AC_SUBST(CUPS_CFLAGS)
1433     AC_SUBST(CUPS_LIBS)
1434
1435     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1436
1437     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1438     AM_CONDITIONAL(HAVE_CUPS, true)
1439
1440     gtk_save_cflags="$CFLAGS"
1441     CFLAGS="$CUPS_CFLAGS"
1442     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1443                                        [[http_t http; char *s = http.authstring;]])],
1444                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1445                                  [Define if cups http_t authstring field is accessible])],
1446                       [])
1447     CFLAGS="$gtk_save_cflags"
1448
1449     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1450
1451     gtk_save_libs="$LIBS"
1452     LIBS="$CUPS_LIBS"
1453     AC_CHECK_FUNCS(httpGetAuthString)
1454     LIBS="$gtk_save_libs"
1455   fi
1456 fi
1457
1458 # Checks to see if we should compile with PAPI backend for GTK+
1459 #
1460
1461 AC_ARG_ENABLE(papi,
1462               [AS_HELP_STRING([--disable-papi],
1463                               [disable papi print backend])],,
1464               [enable_papi=auto])
1465
1466 if test "x$enable_papi" = "xno"; then
1467   AM_CONDITIONAL(HAVE_PAPI, false)
1468 else
1469   AC_MSG_CHECKING(libpapi)
1470   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1471   if test $have_papi = yes; then
1472     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1473     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1474   fi
1475   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1476   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1477     AC_MSG_ERROR([
1478 *** papi not found.
1479 ])
1480   fi
1481 fi
1482
1483 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1484
1485 gtk_save_cppflags="$CPPFLAGS"
1486 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1487
1488 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1489 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1490 *** backend enabled.]))
1491
1492 if test "$os_win32" != "yes"; then
1493   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1494 *** Can't find cairo-ps.h. You must build Cairo with the
1495 *** postscript backend enabled.]))
1496
1497   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1498 *** Cannot find cairo-svg.h. You must build Cairo with the
1499 *** svg backend enabled.]))
1500 fi
1501
1502 CPPFLAGS="$gtk_save_cppflags"
1503
1504
1505 AC_ARG_ENABLE(test-print-backend,
1506               [AS_HELP_STRING([--enable-test-print-backend],
1507                               [build test print backend])],,
1508               [enable_test_print_backend=no])
1509 if test "x$enable_test_print_backend" != "xno" ; then
1510   PRINT_BACKENDS="$PRINT_BACKENDS test"
1511 fi
1512 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1513
1514 if test "$os_win32" = "yes"; then
1515   AC_CHECK_TYPES([IPrintDialogCallback],[],[],[[#include <windows.h>]])
1516 fi
1517
1518 ################################################################
1519 # Strip -export-dynamic from the link lines of various libraries
1520 ################################################################
1521
1522 #
1523 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1524 #  but this flag is only meaningful for executables. For libraries
1525 #  the effect is undefined; what it causes on Linux is that the
1526 #  export list from -export-symbols-regex is ignored and everything
1527 #  is exported
1528 #
1529 # We are using gmodule-no-export now, but I'm leaving the stripping
1530 # code in place for now, since pango and atk still require gmodule.
1531 export SED
1532 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1533 if test -n "$export_dynamic"; then
1534   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1535   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1536 fi
1537
1538 #############
1539 # GSettings #
1540 #############
1541
1542 GLIB_GSETTINGS
1543
1544 ##################################################
1545 # GObject introspection
1546 ##################################################
1547
1548 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1549
1550 ##################################################
1551 # Packagekit module
1552 #################################################
1553
1554 AC_ARG_ENABLE(packagekit,
1555               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1556                               [build PackageKit open-with module [default=auto]])],
1557               [enable_packagekit="$enableval"],
1558               [enable_packagekit=auto])
1559 if test "$enable_packagekit" = "auto"; then
1560   if test "$os_win32" = "yes"; then
1561     enable_packagekit=no
1562   else
1563     enable_packagekit=yes
1564   fi
1565 fi
1566
1567 AC_MSG_CHECKING([whether to use PackageKit])
1568 build_packagekit=no
1569 if test "x$enable_packagekit" != "xno"; then
1570   if test "$os_win32" != "yes"; then
1571     build_packagekit=yes
1572     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1573   else
1574     AC_MSG_ERROR([packagekit support is not available on win32])
1575   fi
1576 fi
1577 AC_MSG_RESULT([$build_packagekit])
1578
1579 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1580
1581 ##################################################
1582 # colord module
1583 #################################################
1584
1585 AC_ARG_ENABLE(colord,
1586               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1587                               [build colord support code [default=auto]])],
1588               [enable_colord="$enableval"],
1589               [enable_colord=auto])
1590
1591 AC_MSG_CHECKING([whether to use colord])
1592 if test "$enable_colord" = "auto"; then
1593   if test "$os_win32" = "yes"; then
1594     enable_colord=no
1595   fi
1596 fi
1597 if test "$enable_colord" != "no"; then
1598   AC_MSG_RESULT([yes])
1599 else
1600   AC_MSG_RESULT([no])
1601 fi
1602
1603 have_colord=no
1604 if test "$enable_colord" != "no"; then
1605         if test "$os_win32" != "yes"; then
1606                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1607                                   have_colord=yes, have_colord=no)
1608                 if test "$enable_colord" = "yes"; then
1609                         if test "$have_colord" = "no"; then
1610                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1611                         fi
1612                 fi
1613         else
1614                 AC_MSG_ERROR([colord support is not available on win32])
1615         fi
1616 fi
1617
1618 if test "$have_colord" = "yes"; then
1619         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1620 fi
1621 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1622
1623 ##################################################
1624 # Checks for gtk-doc and docbook-tools
1625 ##################################################
1626
1627 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1628
1629 AC_ARG_ENABLE(man,
1630               [AS_HELP_STRING([--enable-man],
1631                               [generate man pages [default=auto]])],,
1632               enable_man=maybe)
1633
1634 if test "$enable_man" != no; then
1635   AC_PATH_PROG([XSLTPROC], [xsltproc])
1636   if test -z "$XSLTPROC"; then
1637     if test "$enable_man" = yes ; then
1638       AC_MSG_ERROR([xsltproc is required for --enable-man])
1639     fi
1640     enable_man=no
1641   fi
1642 fi
1643
1644 if test "$enable_man" != no; then
1645   dnl check for DocBook DTD in the local catalog
1646   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1647      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
1648   if test "$have_docbook_dtd" != yes; then
1649     if test "$enable_man" = yes ; then
1650       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
1651     fi
1652     enable_man=no
1653   fi
1654 fi
1655
1656 if test "$enable_man" != no; then
1657   dnl check for DocBook XSL stylesheets in the local catalog
1658   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1659      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
1660   if test "$have_docbook_dtd" != yes; then
1661     if test "$enable_man" = yes ; then
1662       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
1663     fi
1664     enable_man=no
1665   fi
1666 fi
1667
1668 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
1669
1670 AC_MSG_CHECKING([whether to generate man pages])
1671 if test "$enable_man" != no; then
1672   AC_MSG_RESULT([yes])
1673 else
1674   AC_MSG_RESULT([no])
1675 fi
1676
1677 ##################################################
1678 # Output commands
1679 ##################################################
1680
1681 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1682         outfile=gdkconfig.h-tmp
1683         cat > $outfile <<\_______EOF
1684 /* gdkconfig.h
1685  *
1686  * This is a generated file.  Please modify `configure.ac'
1687  */
1688
1689 #ifndef __GDKCONFIG_H__
1690 #define __GDKCONFIG_H__
1691
1692 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1693 #error "Only <gdk/gdk.h> can be included directly."
1694 #endif
1695
1696 #include <glib.h>
1697
1698 G_BEGIN_DECLS
1699
1700 _______EOF
1701
1702         cat >>$outfile <<_______EOF
1703 $gdk_windowing
1704 _______EOF
1705
1706         cat >>$outfile <<_______EOF
1707
1708 G_END_DECLS
1709
1710 #endif  /* __GDKCONFIG_H__ */
1711 _______EOF
1712
1713
1714         if cmp -s $outfile gdk/gdkconfig.h; then
1715           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1716           rm -f $outfile
1717         else
1718           mv $outfile gdk/gdkconfig.h
1719         fi
1720 ],[
1721 gdk_windowing='$GDK_WINDOWING'
1722 ])
1723
1724 dnl
1725 dnl Check for -Bsymbolic-functions linker flag used to avoid
1726 dnl intra-library PLT jumps, if available.
1727 dnl
1728 AC_ARG_ENABLE(Bsymbolic,
1729               [AS_HELP_STRING([--disable-Bsymbolic],
1730                               [avoid linking with -Bsymbolic])],,
1731               [SAVED_LDFLAGS="${LDFLAGS}"
1732                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1733                LDFLAGS=-Wl,-Bsymbolic-functions
1734                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1735                                                [[int main (void) { return 0; }]])],
1736                               [AC_MSG_RESULT(yes)
1737                                enable_Bsymbolic=yes],
1738                               [AC_MSG_RESULT(no)
1739                                enable_Bsymbolic=no])
1740                LDFLAGS="${SAVED_LDFLAGS}"])
1741
1742 if test "x${enable_Bsymbolic}" = "xyes" ; then
1743   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1744 fi
1745 AC_SUBST(GTK_LINK_FLAGS)
1746
1747 AC_CONFIG_FILES([
1748 config.h.win32
1749 gtk-zip.sh
1750 Makefile
1751 gdk-3.0.pc
1752 gtk+-3.0.pc
1753 gtk+-unix-print-3.0.pc
1754 gail-3.0.pc
1755 m4macros/Makefile
1756 po/Makefile.in
1757 po-properties/Makefile.in
1758 demos/Makefile
1759 demos/gtk-demo/Makefile
1760 demos/gtk-demo/geninclude.pl
1761 demos/pixbuf-demo/Makefile
1762 demos/widget-factory/Makefile
1763 examples/Makefile
1764 tests/Makefile
1765 tests/a11y/Makefile
1766 tests/css/Makefile
1767 tests/css/parser/Makefile
1768 tests/reftests/Makefile
1769 tests/visuals/Makefile
1770 docs/Makefile
1771 docs/reference/Makefile
1772 docs/reference/gdk/Makefile
1773 docs/reference/gdk/version.xml
1774 docs/reference/gtk/Makefile
1775 docs/reference/gtk/gtk3.types
1776 docs/reference/gtk/version.xml
1777 docs/reference/libgail-util/Makefile
1778 docs/reference/libgail-util/version.xml
1779 docs/tools/Makefile
1780 build/Makefile
1781 build/win32/Makefile
1782 build/win32/vs9/Makefile
1783 build/win32/vs10/Makefile
1784 gdk/Makefile
1785 gdk/broadway/Makefile
1786 gdk/x11/Makefile
1787 gdk/win32/Makefile
1788 gdk/win32/rc/Makefile
1789 gdk/win32/rc/gdk.rc
1790 gdk/quartz/Makefile
1791 gdk/wayland/Makefile
1792 gdk/tests/Makefile
1793 gdk/gdkversionmacros.h
1794 gtk/Makefile
1795 gtk/makefile.msc
1796 gtk/gtkversion.h
1797 gtk/gtk-win32.rc
1798 gtk/a11y/Makefile
1799 gtk/native/Makefile
1800 gtk/tests/Makefile
1801 libgail-util/Makefile
1802 modules/Makefile
1803 modules/engines/Makefile
1804 modules/engines/pixbuf/Makefile
1805 modules/input/Makefile
1806 modules/printbackends/Makefile
1807 modules/printbackends/cups/Makefile
1808 modules/printbackends/lpr/Makefile
1809 modules/printbackends/file/Makefile
1810 modules/printbackends/papi/Makefile
1811 modules/printbackends/test/Makefile
1812 perf/Makefile
1813 ])
1814
1815 AC_OUTPUT
1816
1817 # beautify the immodule list a bit
1818 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1819 if test -z "${included_immodules}"; then included_immodules="none"; fi
1820
1821 echo ""
1822 echo "        GTK+ $GTK_VERSION"
1823 echo "        ==========="
1824 echo ""
1825 echo "        GDK backends:         $GDK_BACKENDS"
1826 if test "$enable_x11_backend" = "yes"; then
1827 echo "        X11 extensions:       $X_EXTENSIONS"
1828 fi
1829 echo "        Print backends:       $PRINT_BACKENDS"
1830 echo "        Dynamic modules:      $build_dynamic_modules"
1831 echo "        Included immodules:   $included_immodules"
1832 echo "        PackageKit support:   $build_packagekit"
1833 echo "        colord support:       $have_colord"
1834 echo "        Introspection:        $found_introspection"
1835 echo "        Debugging:            $enable_debug"
1836 echo "        Documentation:        $enable_gtk_doc"