Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ([2.62])
   4
   5 # Making releases:
   6 #   GTK_MICRO_VERSION += 1;
   7 #   GTK_INTERFACE_AGE += 1;
   8 #   GTK_BINARY_AGE += 1;
   9 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  10 # if backwards compatibility has been broken,
  11 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  12
  13 m4_define([gtk_major_version], [2])
  14 m4_define([gtk_minor_version], [90])
  15 m4_define([gtk_micro_version], [4])
  16 m4_define([gtk_interface_age], [0])
  17 m4_define([gtk_binary_age],
  18           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  19 m4_define([gtk_version],
  20           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  21 # This is the X.Y used in -lgtk-FOO-X.Y
  22 m4_define([gtk_api_version], [3.0])
  23
  24 # Define a string for the earliest version that this release has
  25 # backwards binary compatibility with for all interfaces a module
  26 # might. Unless we add module-only API with lower stability
  27 # guarantees, this should be unchanged until we break binary compat
  28 # for GTK+.
  29 #
  30 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  31 m4_define([gtk_binary_version], [3.0.0])
  32
  33 # required versions of other packages
  34 m4_define([glib_required_version], [2.25.9])
  35 m4_define([pango_required_version], [1.20])
  36 m4_define([atk_required_version], [1.29.2])
  37 m4_define([cairo_required_version], [1.6])
  38 m4_define([gdk_pixbuf_required_version], [2.21.0])
  39
  40
  41 AC_INIT([gtk+], [gtk_version],
  42         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  43         [gtk+])
  44
  45 AC_CONFIG_HEADER([config.h])
  46 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 # Save this value here, since automake will set cflags later
  50 cflags_set=${CFLAGS+set}
  51
  52 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  53 AM_MAINTAINER_MODE([enable])
  54
  55 # Support silent build rules, requires at least automake-1.11. Enable
  56 # by either passing --enable-silent-rules to configure or passing V=0
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([no])])
  59
  60 #
  61 # For each of the libraries we build, we define the following
  62 # substituted variables:
  63 #
  64 # foo_PACKAGES:     pkg-config packages this library requires
  65 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  66 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  67 # foo_DEP_LIBS:     All libraries this module requires
  68 # foo_DEP_CFLAGS:   All cflags this module requires
  69
  70
  71 GTK_MAJOR_VERSION=gtk_major_version
  72 GTK_MINOR_VERSION=gtk_minor_version
  73 GTK_MICRO_VERSION=gtk_micro_version
  74 GTK_INTERFACE_AGE=gtk_interface_age
  75 GTK_BINARY_AGE=gtk_binary_age
  76 GTK_VERSION=gtk_version
  77 GTK_API_VERSION=gtk_api_version
  78 GTK_BINARY_VERSION=gtk_binary_version
  79 AC_SUBST(GTK_MAJOR_VERSION)
  80 AC_SUBST(GTK_MINOR_VERSION)
  81 AC_SUBST(GTK_MICRO_VERSION)
  82 AC_SUBST(GTK_INTERFACE_AGE)
  83 AC_SUBST(GTK_BINARY_AGE)
  84 AC_SUBST(GTK_API_VERSION)
  85 AC_SUBST(GTK_VERSION)
  86 AC_SUBST(GTK_BINARY_VERSION)
  87
  88 # libtool versioning
  89 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  90 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  91 #LT_REVISION=$GTK_INTERFACE_AGE
  92 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  93 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  94
  95 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
  96 m4_define([lt_revision], [gtk_interface_age])
  97 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
  98 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  99 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 100 AC_SUBST(LT_VERSION_INFO)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 m4_define([gail_lt_current],[0])
 104 m4_define([gail_lt_revision],[0])
 105 m4_define([gail_lt_age],[0])
 106 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 107 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 108 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 109 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 110
 111 # Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CC_C_O
 114 AC_PROG_CC_STDC
 115 AC_PROG_INSTALL
 116 AC_PROG_MAKE_SET
 117
 118
 119 GETTEXT_PACKAGE=gtk30
 120 AC_SUBST(GETTEXT_PACKAGE)
 121 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 122                    [The prefix for our gettext translation domains.])
 123
 124 AC_CANONICAL_HOST
 125
 126 MATH_LIB=-lm
 127 AC_MSG_CHECKING([for native Win32])
 128 LIB_EXE_MACHINE_FLAG=X86
 129 EXE_MANIFEST_ARCHITECTURE=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     os_win32=yes
 133     gio_can_sniff=no
 134     MATH_LIB=
 135     case "$host" in
 136     x86_64-*-*)
 137       LIB_EXE_MACHINE_FLAG=X64
 138       EXE_MANIFEST_ARCHITECTURE=AMD64
 139       ;;
 140     esac
 141     ;;
 142   *)
 143     os_win32=no
 144     ;;
 145 esac
 146 AC_MSG_RESULT([$os_win32])
 147
 148 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 149 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 150
 151 case $host in
 152   *-*-linux*)
 153     os_linux=yes
 154     ;;
 155 esac
 156
 157 dnl
 158 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 159 dnl We use this for an automated test for C++ header correctness.
 160 dnl
 161 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 162 AC_LANG_PUSH([C++])
 163
 164 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 165 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 166
 167 gtk_save_cxxflags="$CXXFLAGS"
 168 CXXFLAGS="$CXXFLAGS -x objective-c++"
 169 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 170 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 171 CXXFLAGS="$gtk_save_cxxflags"
 172 AC_LANG_POP([C++])
 173
 174 if test "$os_win32" = "yes"; then
 175   if test x$enable_static = xyes -o x$enable_static = x; then
 176     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 177     enable_static=no
 178   fi
 179   if test x$enable_shared = xno; then
 180     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 181   fi
 182   enable_shared=yes
 183 fi
 184
 185 dnl Initialize libtool
 186 LT_PREREQ([2.2.6])
 187 LT_INIT([disable-static win32-dll])
 188 # Create libtool early, because it's used in configure
 189 LT_OUTPUT
 190
 191 # Make sure we use 64-bit versions of various file stuff.
 192 AC_SYS_LARGEFILE
 193
 194 AM_PROG_AS
 195 AC_PATH_PROG(NM, nm, nm)
 196
 197 AC_MSG_CHECKING([for some Win32 platform])
 198 case "$host" in
 199   *-*-mingw*|*-*-cygwin*)
 200     platform_win32=yes
 201     ;;
 202   *)
 203     platform_win32=no
 204     ;;
 205 esac
 206 AC_MSG_RESULT([$platform_win32])
 207 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 208
 209 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 210 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 211 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 212
 213 if test "$os_win32" = "yes"; then
 214   AC_CHECK_TOOL(WINDRES, windres, no)
 215   if test "$WINDRES" = no; then
 216     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 217   fi
 218   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 219 fi
 220 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 221
 222 m4_define([debug_default],
 223           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 224
 225 dnl declare --enable-* args and collect ac_help strings
 226 AC_ARG_ENABLE(debug,
 227               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 228                              [turn on debugging @<:@default=debug_default@:>@]),,
 229               enable_debug=debug_default)
 230 AC_ARG_ENABLE(shm,
 231               [AC_HELP_STRING([--enable-shm],
 232                               [support shared memory if available [default=yes]])],,
 233               [enable_shm="yes"])
 234 AC_ARG_ENABLE(xkb,
 235               [AC_HELP_STRING([--enable-xkb],
 236                               [support XKB [default=maybe]])],,
 237               [enable_xkb="maybe"])
 238 AC_ARG_ENABLE(xinerama,
 239               [AC_HELP_STRING([--enable-xinerama],
 240                               [support xinerama extension if available [default=yes]])],,
 241               [enable_xinerama="yes"])
 242 AC_ARG_ENABLE(rebuilds,
 243               [AC_HELP_STRING([--disable-rebuilds],
 244                               [disable all source autogeneration rules])],,
 245               [enable_rebuilds=yes])
 246 AC_ARG_ENABLE(visibility,
 247               [AC_HELP_STRING([--disable-visibility],
 248                               [do not use ELF visibility attributes])],,
 249               [enable_visibility=yes])
 250
 251 AC_ARG_WITH(xinput,
 252             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 253
 254 if test "$platform_win32" = yes; then
 255   gdktarget=win32
 256 else
 257   gdktarget=x11
 258 fi
 259
 260 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/win32/quartz/directfb]] select non-default GDK target],
 261         gdktarget=$with_gdktarget)
 262
 263 AC_SUBST(gdktarget)
 264 case $gdktarget in
 265   x11|win32|quartz|directfb) ;;
 266   *) AC_MSG_ERROR([Invalid target for GDK: use x11, quartz, directfb or win32.]);;
 267 esac
 268
 269 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 270 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 271
 272 AC_SUBST(gdktargetlib)
 273 AC_SUBST(gtktargetlib)
 274
 275 if test "x$enable_debug" = "xyes"; then
 276   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 277   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 278 else
 279   if test "x$enable_debug" = "xno"; then
 280     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 281   else
 282     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 283   fi
 284 fi
 285
 286
 287 if test "x$enable_visibility" = "xno"; then
 288   GTK_DEBUG_FLAGS="$GTK_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 289 fi
 290
 291
 292 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 293                    [Define if debugging is enabled])
 294
 295
 296 # Build time sanity check...
 297 AM_SANITY_CHECK
 298
 299 changequote(,)dnl
 300 if test "x$GCC" = "xyes"; then
 301   case " $CFLAGS " in
 302   *[\ \ ]-Wall[\ \      ]*) ;;
 303   *) CFLAGS="$CFLAGS -Wall" ;;
 304   esac
 305
 306   if test "x$enable_ansi" = "xyes"; then
 307     case " $CFLAGS " in
 308     *[\ \       ]-ansi[\ \      ]*) ;;
 309     *) CFLAGS="$CFLAGS -ansi" ;;
 310     esac
 311
 312     case " $CFLAGS " in
 313     *[\ \       ]-pedantic[\ \  ]*) ;;
 314     *) CFLAGS="$CFLAGS -pedantic" ;;
 315     esac
 316   fi
 317 fi
 318 changequote([,])dnl
 319
 320 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 321
 322 # Ensure MSVC-compatible struct packing convention is used when
 323 # compiling for Win32 with gcc.
 324 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 325 # gcc2 uses "-fnative-struct".
 326 if test x"$os_win32" = xyes; then
 327   if test x"$GCC" = xyes; then
 328     msnative_struct=''
 329     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 330     if test -z "$ac_cv_prog_CC"; then
 331       our_gcc="$CC"
 332     else
 333       our_gcc="$ac_cv_prog_CC"
 334     fi
 335     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 336       2.)
 337         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 338           msnative_struct='-fnative-struct'
 339         fi
 340         ;;
 341       *)
 342         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 343           msnative_struct='-mms-bitfields'
 344         fi
 345         ;;
 346     esac
 347     if test x"$msnative_struct" = x ; then
 348       AC_MSG_RESULT([no way])
 349       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 350     else
 351       CFLAGS="$CFLAGS $msnative_struct"
 352       AC_MSG_RESULT([${msnative_struct}])
 353     fi
 354   fi
 355 fi
 356
 357 ## Initial sanity check, done here so that users get told they
 358 ## have the wrong dependencies as early in the process as possible.
 359 ## Later on we actually use the cflags/libs from separate pkg-config
 360 ## calls. Oh, also the later pkg-config calls don't include
 361 ## the version requirements since those make the module lists
 362 ## annoying to construct
 363 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 364   [glib-2.0 >= glib_required_version dnl
 365    atk >= atk_required_version dnl
 366    pango >= pango_required_version dnl
 367    cairo >= cairo_required_version dnl
 368    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 369
 370 ## In addition to checking that cairo is present, we also need to
 371 ## check that the correct cairo backend is there. E.g. if the GDK
 372 ## target is win32 we need the cairo-win32 backend and so on.
 373 cairo_backend=$gdktarget
 374
 375 # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 376 # backend names are identical.
 377 if test "x$cairo_backend" = "xx11"; then
 378    cairo_backend=xlib
 379 fi
 380 PKG_CHECK_MODULES(CAIRO_BACKEND,
 381   [cairo-$cairo_backend >= cairo_required_version])
 382
 383 if test "$os_win32" != yes; then
 384     # libtool option to control which symbols are exported
 385     # right now, symbols starting with _ are not exported
 386     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 387 else
 388     # We currently use .def files on Windows (for gdk and gtk)
 389     LIBTOOL_EXPORT_OPTIONS=
 390 fi
 391 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 392
 393 dnl ******************************************************
 394 dnl * See whether to include shared library dependencies *
 395 dnl ******************************************************
 396
 397 AC_ARG_ENABLE(explicit-deps,
 398               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 399                               [use explicit dependencies in .pc files [default=auto]])],,
 400               [enable_explicit_deps=auto])
 401
 402 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 403 case $enable_explicit_deps in
 404   auto)
 405     export SED
 406     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 407     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 408       enable_explicit_deps=yes
 409     else
 410       enable_explicit_deps=no
 411     fi
 412   ;;
 413   yes|no)
 414   ;;
 415   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 416   ;;
 417 esac
 418 AC_MSG_RESULT($enable_explicit_deps)
 419
 420 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 421
 422 # define a MAINT-like variable REBUILD which is set if Perl
 423 # and awk are found, so autogenerated sources can be rebuilt
 424
 425 AC_PATH_PROGS(PERL, perl5 perl)
 426
 427 # We would like indent, but don't require it.
 428 AC_CHECK_PROG(INDENT, indent, indent)
 429
 430 REBUILD=\#
 431 if test "x$enable_rebuilds" = "xyes" && \
 432      test -n "$PERL" && \
 433      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 434   REBUILD=
 435 fi
 436 AC_SUBST(REBUILD)
 437
 438 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 439 AC_CHECK_FUNCS(localtime_r)
 440
 441 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 442 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 443 AC_TRY_LINK([#include <langinfo.h>], [
 444 char c;
 445 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 446 ], gtk_ok=yes, gtk_ok=no)
 447 AC_MSG_RESULT($gtk_ok)
 448 if test "$gtk_ok" = "yes"; then
 449   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 450             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 451 fi
 452
 453 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 454 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 455 AC_TRY_LINK([#include <langinfo.h>], [
 456 char c;
 457 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 458 ], gtk_ok=yes, gtk_ok=no)
 459 AC_MSG_RESULT($gtk_ok)
 460 if test "$gtk_ok" = "yes"; then
 461   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 462             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 463 fi
 464
 465 # _NL_PAPER_HEIGHT is an enum and not a define
 466 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 467 AC_TRY_LINK([#include <langinfo.h>], [
 468 char c;
 469 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 470 ], gtk_ok=yes, gtk_ok=no)
 471 AC_MSG_RESULT($gtk_ok)
 472 if test "$gtk_ok" = "yes"; then
 473   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 474             [Define if _NL_PAPER_HEIGHT is available])
 475 fi
 476
 477 # _NL_PAPER_WIDTH is an enum and not a define
 478 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 479 AC_TRY_LINK([#include <langinfo.h>], [
 480 char c;
 481 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 482 ], gtk_ok=yes, gtk_ok=no)
 483 AC_MSG_RESULT($gtk_ok)
 484 if test "$gtk_ok" = "yes"; then
 485   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 486             [Define if _NL_PAPER_WIDTH is available])
 487 fi
 488
 489 # sigsetjmp is a macro on some platforms, so AC_CHECK_FUNCS is not reliable
 490 AC_MSG_CHECKING(for sigsetjmp)
 491 AC_TRY_LINK([#include <setjmp.h>], [
 492 sigjmp_buf env;
 493 sigsetjmp(env, 0);
 494 ], gtk_ok=yes, gtk_ok=no)
 495 AC_MSG_RESULT($gtk_ok)
 496 if test "$gtk_ok" = "yes"; then
 497   AC_DEFINE(HAVE_SIGSETJMP, 1,
 498             [Define to 1 if sigsetjmp is available])
 499 fi
 500
 501 # i18n stuff
 502 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 503 AM_GLIB_GNU_GETTEXT
 504 LIBS="$LIBS $INTLLIBS"
 505 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 506         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 507       esac])
 508
 509 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 510 dnl po-properties/POTFILES during configure; see GNOME #573515.
 511 dnl
 512 dnl Generate list of files to be processed by xgettext which will
 513 dnl be included in po-properties/Makefile.
 514 test -d po-properties || mkdir po-properties
 515 if test "x$srcdir" != "x."; then
 516   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 517     popropsrcprefix="$srcdir/"
 518   else
 519     popropsrcprefix="../$srcdir/"
 520   fi
 521 else
 522   popropsrcprefix="../"
 523 fi
 524 rm -f po-properties/POTFILES
 525 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 526 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 527 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 528
 529 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 530
 531 dnl The DU4 header files don't provide library prototypes unless
 532 dnl -std1 is given to the native cc.
 533 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 534
 535 gtk_save_LIBS=$LIBS
 536 LIBS="$LIBS -lm"
 537 AC_TRY_RUN([#include <math.h>
 538              int main (void) { return (log(1) != log(1.)); }],
 539      AC_MSG_RESULT(none needed),
 540      gtk_save_CFLAGS="$CFLAGS"
 541      CFLAGS="$CFLAGS -std1"
 542      AC_TRY_RUN([#include <math.h>
 543                  int main (void) { return (log(1) != log(1.)); }],
 544          AC_MSG_RESULT(-std1),
 545          AC_MSG_RESULT()
 546          CFLAGS="$gtk_save_CFLAGS"
 547          AC_MSG_WARN(
 548                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 549          true
 550      ),
 551      AC_MSG_RESULT(none needed)
 552 )
 553 LIBS=$gtk_save_LIBS
 554
 555 AC_MSG_CHECKING(for the BeOS)
 556 case $host in
 557   *-*-beos*)
 558     AC_MSG_RESULT(yes)
 559     MATH_LIB=
 560   ;;
 561   *)
 562     AC_MSG_RESULT(no)
 563   ;;
 564 esac
 565
 566 AC_SUBST(MATH_LIB)
 567 #
 568 # see bug 162979
 569 #
 570 AC_MSG_CHECKING(for HP-UX)
 571 case $host_os in
 572   hpux9* | hpux10* | hpux11*)
 573     AC_MSG_RESULT(yes)
 574     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 575   ;;
 576   *)
 577     AC_MSG_RESULT(no)
 578   ;;
 579 esac
 580
 581 dnl NeXTStep cc seems to need this
 582 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 583 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 584   AC_MSG_RESULT(none needed),
 585   gtk_save_CFLAGS="$CFLAGS"
 586   CFLAGS="$CFLAGS -posix"
 587   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 588     AC_MSG_RESULT(-posix),
 589     AC_MSG_RESULT()
 590     CFLAGS="$gtk_save_CFLAGS"
 591     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 592
 593 #
 594 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 595 #
 596
 597 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 598
 599 AM_PATH_GLIB_2_0(glib_required_version, :,
 600   AC_MSG_ERROR([
 601 *** GLIB glib_required_version or better is required. The latest version of
 602 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 603   gobject gmodule-no-export gthread)
 604
 605 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 606 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 607 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 608 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 609   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 610 fi
 611
 612 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 613
 614
 615 dnl
 616 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 617 dnl
 618 gtk_save_LIBS=$LIBS
 619 LIBS="$LIBS $GLIB_LIBS"
 620 AC_CHECK_FUNCS(bind_textdomain_codeset)
 621 LIBS=$gtk_save_LIBS
 622
 623 AC_CHECK_HEADERS(pwd.h,
 624                  AC_DEFINE(HAVE_PWD_H, 1,
 625                            [Define to 1 if pwd.h is available]))
 626 AC_CHECK_HEADERS(sys/time.h,
 627                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 628                            [Define to 1 if time.h is available]))
 629 AC_CHECK_HEADERS(unistd.h,
 630                  AC_DEFINE(HAVE_UNISTD_H, 1,
 631                            [Define to 1 if unistd.h is available]))
 632 AC_CHECK_HEADERS(ftw.h,
 633                  AC_DEFINE(HAVE_FTW_H, 1,
 634                            [Define to 1 if ftw.h is available]))
 635
 636 AC_MSG_CHECKING([for GNU ftw extensions])
 637 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 638 #define _GNU_SOURCE
 639 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 640 if test $gtk_ok = yes; then
 641     AC_MSG_RESULT([yes])
 642     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 643 else
 644     AC_MSG_RESULT([no])
 645 fi
 646
 647 saved_cflags="$CFLAGS"
 648 saved_ldflags="$LDFLAGS"
 649
 650
 651 # Checks for header files.
 652 AC_HEADER_STDC
 653
 654 # Checks for typedefs, structures, and compiler characteristics.
 655 AC_C_CONST
 656
 657 # Checks for library functions.
 658 AC_TYPE_SIGNAL
 659 AC_FUNC_MMAP
 660
 661 AC_CHECK_FUNCS(mallinfo)
 662 AC_CHECK_FUNCS(getresuid)
 663 AC_TYPE_UID_T
 664
 665 # Check if <sys/select.h> needs to be included for fd_set
 666 AC_MSG_CHECKING([for fd_set])
 667 AC_TRY_COMPILE([#include <sys/types.h>],
 668         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 669 if test $gtk_ok = yes; then
 670     AC_MSG_RESULT([yes, found in sys/types.h])
 671 else
 672     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 673     if test $gtk_ok = yes; then
 674         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 675                   [Define to 1 if sys/select.h is available])
 676         AC_MSG_RESULT([yes, found in sys/select.h])
 677     else
 678         AC_DEFINE(NO_FD_SET, 1,
 679                   [Define to 1 if fd_set is not available])
 680         AC_MSG_RESULT(no)
 681     fi
 682 fi
 683
 684 # `widechar' tests for gdki18n.h
 685 AC_MSG_CHECKING(for wchar.h)
 686 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 687 if test $gdk_wchar_h = yes; then
 688    AC_DEFINE(HAVE_WCHAR_H, 1, [Have wchar.h include file])
 689 fi
 690 AC_MSG_RESULT($gdk_wchar_h)
 691
 692 # Check for wctype.h (for iswalnum)
 693 AC_MSG_CHECKING(for wctype.h)
 694 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 695 if test $gdk_wctype_h = yes; then
 696    AC_DEFINE(HAVE_WCTYPE_H, 1, [Have wctype.h include file])
 697 fi
 698 AC_MSG_RESULT($gdk_wctype_h)
 699
 700 # in Solaris 2.5, `iswalnum' is in -lw
 701 GDK_WLIBS=
 702 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 703
 704 oLIBS="$LIBS"
 705 LIBS="$LIBS $GDK_WLIBS"
 706 # The following is necessary for Linux libc-5.4.38
 707 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 708 AC_TRY_LINK([#include <stdlib.h>],[
 709 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 710 #  ifdef HAVE_WCTYPE_H
 711 #    include <wctype.h>
 712 #  else
 713 #    ifdef HAVE_WCHAR_H
 714 #      include <wchar.h>
 715 #    endif
 716 #  endif
 717 #else
 718 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 719 #endif
 720 iswalnum((wchar_t) 0);
 721 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 722 LIBS="$oLIBS"
 723
 724 if test $gdk_working_wctype = no; then
 725    AC_DEFINE(HAVE_BROKEN_WCTYPE, 1, [Is the wctype implementation broken])
 726    GDK_WLIBS=
 727 fi
 728 AC_MSG_RESULT($gdk_working_wctype)
 729 AC_SUBST(GDK_WLIBS)
 730
 731 # Check for uxtheme.h (for MS-Windows Engine)
 732 AC_MSG_CHECKING(for uxtheme.h)
 733 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 734 if test $gtk_uxtheme_h = yes; then
 735    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 736 fi
 737 AC_MSG_RESULT($gtk_uxtheme_h)
 738
 739 # Checks for gdkspawn
 740 AC_CHECK_HEADERS(crt_externs.h)
 741 AC_CHECK_FUNCS(_NSGetEnviron)
 742
 743 AC_ARG_ENABLE(modules,
 744               [AC_HELP_STRING([--disable-modules],
 745                               [disable dynamic module loading])])
 746
 747 dynworks=false
 748 deps=
 749 if test x$enable_modules = xno; then
 750     AC_MSG_RESULT(no)
 751 else
 752     AC_MSG_RESULT(yes)
 753     AC_MSG_CHECKING(whether dynamic modules work)
 754     ## for loop is to strip newline
 755     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 756     for I in $tmp; do
 757         dynworks=$I
 758     done
 759
 760     dnl Now we check to see if our libtool supports shared lib deps
 761     dnl (in a rather ugly way even)
 762     if $dynworks; then
 763         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 764         module_deplibs_check=`$module_libtool_config | \
 765             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 766             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 767         if test "x$module_deplibs_check" = "xnone" || \
 768            test "x$module_deplibs_check" = "xunknown" || \
 769            test "x$module_deplibs_check" = "x"; then
 770             dynworks=false
 771         fi
 772     fi
 773
 774     if $dynworks; then
 775         AC_DEFINE(USE_GMODULE, 1,
 776                   [Define to 1 if gmodule works and should be used])
 777         AC_MSG_RESULT(yes)
 778     else
 779         AC_MSG_RESULT(no)
 780     fi
 781 fi
 782
 783 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 784
 785 #
 786 # Allow building some or all immodules included
 787 #
 788 AC_MSG_CHECKING(immodules to build)
 789
 790 dnl due to an autoconf bug, commas in the first arg to
 791 dnl AC_HELP_STRING cause problems.
 792 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 793 dnl                [build the specified input method modules into gtk])
 794 AC_ARG_WITH(included_immodules,
 795 [  --with-included-immodules=MODULE1,MODULE2,...
 796                           build the specified input methods into gtk])
 797
 798 if $dynworks; then
 799    :
 800 else
 801    ## if the option was specified, leave it; otherwise disable included immodules
 802    if test x$with_included_immodules = xno; then
 803            with_included_immodules=yes
 804    fi
 805 fi
 806
 807 all_immodules="am-et,cedilla,cyrillic-translit"
 808 if test "$gdktarget" = "win32"; then
 809    all_immodules="${all_immodules},ime"
 810 fi
 811 all_immodules="${all_immodules},inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr"
 812 if test "$gdktarget" = "x11"; then
 813    all_immodules="${all_immodules},xim"
 814 fi
 815
 816 included_immodules=""
 817 # If the switch specified without listing any specific ones, include all
 818 if test "x$with_included_immodules" = xyes ; then
 819   included_immodules="$all_immodules"
 820 else
 821   included_immodules="$with_included_immodules"
 822 fi
 823
 824 AC_MSG_RESULT($included_immodules)
 825 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 826
 827 INCLUDED_IMMODULE_OBJ=
 828 INCLUDED_IMMODULE_DEFINE=
 829
 830 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 831 for immodule in $included_immodules; do
 832  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 833  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 834    :
 835  else
 836    AC_MSG_ERROR([the specified input method $immodule does not exist])
 837  fi
 838
 839  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 840  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 841  eval INCLUDE_$immodule_underscores=yes
 842 done
 843 IFS="$gtk_save_ifs"
 844 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 845 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 846
 847 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 848 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 849 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 850 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 851 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 852 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 853 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 854 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 855 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 856 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 857 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 858 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 859
 860 AC_HEADER_SYS_WAIT
 861
 862 AC_TYPE_SIGNAL
 863
 864 # Checks to see whether we should include mediaLib
 865 # support.
 866 #
 867 AC_CHECK_HEADER(sys/systeminfo.h,
 868                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 869                           [Define to 1 if sys/systeminfo.h is available]))
 870 AC_CHECK_HEADER(sys/sysinfo.h,
 871                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 872                           [Define to 1 if sys/sysinfo.h is available]))
 873
 874 AC_MSG_CHECKING(for mediaLib 2.3)
 875 use_mlib25=no
 876 # Check for a mediaLib 2.3 function since that is what the GTK+ mediaLib
 877 # patch requires.
 878 AC_CHECK_LIB(mlib, mlib_ImageSetStruct, use_mlib=yes, use_mlib=no)
 879 if test $use_mlib = yes; then
 880     AC_DEFINE(USE_MEDIALIB, 1,
 881               [Define to 1 if medialib is available and should be used])
 882     MEDIA_LIB=-lmlib
 883
 884     AC_MSG_CHECKING(for mediaLib 2.5)
 885     # Check for a mediaLib 2.5 function since that is what is needed for
 886     # gdk_rgb_convert integration.
 887     AC_CHECK_LIB(mlib, mlib_VideoColorRGBint_to_BGRAint, use_mlib25=yes, use_mlib25=no)
 888     if test $use_mlib25 = yes; then
 889         AC_DEFINE(USE_MEDIALIB25, 1,
 890                   [Define to 1 if medialib 2.5 is available])
 891     fi
 892 fi
 893 AM_CONDITIONAL(USE_MEDIALIB, test $use_mlib = yes)
 894 AM_CONDITIONAL(USE_MEDIALIB25, test $use_mlib25 = yes)
 895
 896 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 897
 898 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 899
 900 if test $cross_compiling = yes; then
 901   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 902   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 903     REBUILD_PNGS=#
 904   fi
 905 fi
 906
 907 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 908
 909 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 910    test "x$REBUILD_PNGS" = "x#" ; then
 911      AC_MSG_ERROR([
 912 *** gtkbuiltincache.h is not in the tree, and cannot be built
 913 *** because you don't have libpng, or (when cross-compiling) you
 914 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 915 fi
 916
 917 ########################################
 918 # Windowing system checks
 919 ########################################
 920
 921 GDK_EXTRA_LIBS="$GDK_WLIBS"
 922 GDK_EXTRA_CFLAGS=
 923
 924 # GTK+ uses some X calls, so needs to link against X directly
 925 GTK_DEP_PACKAGES_FOR_X=
 926 GTK_DEP_LIBS_FOR_X=
 927
 928 if test "x$gdktarget" = "xx11"; then
 929   X_PACKAGES=fontconfig
 930
 931   #
 932   # We use fontconfig very peripherally when decoding the default
 933   # settings.
 934   #
 935   if $PKG_CONFIG --exists fontconfig; then : ; else
 936     AC_MSG_ERROR([
 937 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 938   fi
 939
 940   #
 941   # Check for basic X packages; we use pkg-config if available
 942   #
 943   if $PKG_CONFIG --exists x11 xext xrender; then
 944     have_base_x_pc=true
 945     X_PACKAGES="$X_PACKAGES x11 xext xrender"
 946     x_libs="`$PKG_CONFIG --libs x11 xext xrender`"
 947     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext xrender`"
 948
 949     # Strip out any .la files that pkg-config might give us (this happens
 950     # with -uninstalled.pc files)
 951     x_libs_for_checks=
 952     for I in $x_libs ; do
 953       case $I in
 954         *.la) ;;
 955         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 956       esac
 957     done
 958
 959     GTK_PACKAGES_FOR_X="x11"
 960   else
 961     have_base_x_pc=false
 962     AC_PATH_XTRA
 963     if test x$no_x = xyes ; then
 964       AC_MSG_ERROR([X development libraries not found])
 965     fi
 966
 967     x_cflags="$X_CFLAGS"
 968     x_libs_for_checks="$X_LIBS -lXext -lXrender -lX11 $X_EXTRA_LIBS"
 969
 970     GTK_DEP_LIBS_FOR_X="$X_LIBS -lXrender -lX11 $X_EXTRA_LIBS"
 971   fi
 972
 973   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 974   x_extra_libs=
 975
 976   gtk_save_cppflags="$CPPFLAGS"
 977   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 978
 979   gtk_save_LIBS=$LIBS
 980   LIBS="$x_libs_for_checks $LIBS"
 981
 982   # Sanity check for the X11 and Xext libraries. While everything we need from
 983   # Xext is optional, the chances a system has *none* of these things is so
 984   # small that we just unconditionally require it.
 985   AC_CHECK_FUNC(XOpenDisplay, :,
 986                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 987   AC_CHECK_FUNC(XextFindDisplay, :,
 988                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 989   AC_CHECK_FUNC(XRenderQueryExtension, :,
 990                 AC_MSG_ERROR([*** libXrender not found. Check 'config.log' for more details.]))
 991
 992   # Check for xReply
 993
 994   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 995   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 996       [xReply *rep;],
 997       [AC_MSG_RESULT([no])],
 998       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 999 #include <X11/Xlibint.h>],
1000            [xReply *rep;],
1001            [AC_MSG_RESULT([yes])
1002             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1003                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
1004            [AC_MSG_RESULT([unknown])
1005             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1006
1007   # Check for XConvertCase, XInternAtoms (X11R6 specific)
1008
1009   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1010
1011   # Generic X11R6 check needed for XIM support; we could
1012   # probably use this to replace the above, but we'll
1013   # leave the separate checks for XConvertCase and XInternAtoms
1014   # for clarity
1015
1016   have_x11r6=false
1017   AC_CHECK_FUNC(XAddConnectionWatch,
1018       have_x11r6=true)
1019
1020   if $have_x11r6; then
1021     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1022   fi
1023   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1024
1025   # Check for XKB support.
1026
1027   if test "x$enable_xkb" = "xyes"; then
1028         AC_MSG_WARN(XKB support explicitly enabled)
1029         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
1030   elif test "x$enable_xkb" = "xmaybe"; then
1031         AC_CHECK_FUNC(XkbQueryExtension,
1032                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1033   else
1034         AC_MSG_WARN(XKB support explicitly disabled)
1035   fi
1036
1037   # Check for shaped window extension
1038
1039   AC_CHECK_FUNC(XShapeCombineMask, :,
1040      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1041
1042   # X SYNC check
1043   gtk_save_CFLAGS="$CFLAGS"
1044   CFLAGS="$CFLAGS $x_cflags"
1045
1046   AC_CHECK_FUNC(XSyncQueryExtension,
1047       [AC_CHECK_HEADER(X11/extensions/sync.h,
1048           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1049           :, [#include <X11/Xlib.h>])])
1050
1051   CFLAGS="$gtk_save_CFLAGS"
1052
1053   # Xshm checks
1054
1055   if test "x$enable_shm" = "xyes"; then
1056      # Check for the XShm extension, normally in Xext
1057      AC_CHECK_FUNC(XShmAttach,
1058         :,
1059         # On AIX, it is in XextSam instead
1060         [AC_CHECK_LIB(XextSam, XShmAttach,
1061             [GTK_ADD_LIB(x_extra_libs,XextSam)])])
1062   fi
1063
1064   if test "x$enable_shm" = "xyes"; then
1065     # Check for shared memory
1066     AC_CHECK_HEADER(sys/ipc.h,
1067                     AC_DEFINE(HAVE_IPC_H, 1,
1068                               [Define to 1 if ipc.h is available]),
1069                     no_sys_ipc=yes)
1070     AC_CHECK_HEADER(sys/shm.h,
1071                     AC_DEFINE(HAVE_SHM_H, 1,
1072                               [Define to 1 if shm.h is available]),
1073                     no_sys_shm=yes)
1074
1075     # Check for the X shared memory extension header file
1076     have_xshm=no
1077     AC_MSG_CHECKING(X11/extensions/XShm.h)
1078     if test "x$no_xext_lib" = "xyes"; then
1079       :
1080     else
1081       gtk_save_CFLAGS="$CFLAGS"
1082       CFLAGS="$CFLAGS $x_cflags"
1083       AC_TRY_COMPILE([
1084 #include <stdlib.h>
1085 #include <sys/types.h>
1086 #include <sys/ipc.h>
1087 #include <sys/shm.h>
1088 #include <X11/Xlib.h>
1089 #include <X11/Xutil.h>
1090 #include <X11/extensions/XShm.h>
1091 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
1092       CFLAGS="$gtk_save_CFLAGS"
1093     fi
1094     AC_MSG_RESULT($have_xshm)
1095     if test $have_xshm = yes ; then
1096       AC_DEFINE(HAVE_XSHM_H, 1,
1097                 [Define to 1 if xshm.h is available])
1098     fi
1099   fi
1100
1101   if test "x$enable_xinerama" = "xyes"; then
1102     # Check for Xinerama extension (Solaris impl or Xfree impl)
1103     gtk_save_cppflags="$CPPFLAGS"
1104     CPPFLAGS="$CPPFLAGS $x_cflags"
1105
1106     # Check for XFree
1107     AC_MSG_CHECKING(for Xinerama support on XFree86)
1108
1109     have_xfree_xinerama=false
1110     if $PKG_CONFIG --exists xinerama ; then
1111        have_xfree_xinerama=true
1112        X_PACKAGES="$X_PACKAGES xinerama"
1113     else
1114        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1115            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1116            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1117            have_xfree_xinerama=true], :,
1118            [#include <X11/Xlib.h>])])
1119     fi
1120
1121     if $have_xfree_xinerama ; then
1122       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1123                 [Define to 1 if XFree Xinerama is available])
1124       AC_DEFINE(HAVE_XINERAMA, 1,
1125                 [Define to 1 is Xinerama is available])
1126       AC_MSG_RESULT(yes)
1127     else
1128       AC_MSG_RESULT(no)
1129
1130       case "$host" in
1131         *-*-solaris*)
1132             # Check for solaris
1133             AC_MSG_CHECKING(for Xinerama support on Solaris)
1134
1135             have_solaris_xinerama=false
1136             AC_CHECK_FUNC(XineramaGetInfo,
1137                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1138                     [have_solaris_xinerama=true], :,
1139                     [#include <X11/Xlib.h>])])
1140
1141             if $have_solaris_xinerama ; then
1142               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1143                         [Define to 1 if solaris xinerama is available])
1144               AC_DEFINE(HAVE_XINERAMA, 1,
1145                         [Define to 1 if xinerama is available])
1146               AC_MSG_RESULT(yes)
1147             else
1148               AC_MSG_RESULT(no)
1149             fi
1150             ;;
1151         *)
1152             ;;
1153       esac
1154     fi
1155   fi
1156
1157   # set up things for XInput
1158   if test "x$with_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1159     have_xinput=yes
1160
1161     AC_DEFINE(XINPUT_XFREE, 1,
1162               [Define to 1 if XFree XInput should be used])
1163
1164     X_PACKAGES="$X_PACKAGES xi"
1165
1166     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1167                     have_xinput2=yes; AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1168   else
1169     AC_DEFINE(XINPUT_NONE, 1,
1170               [Define to 1 if no XInput should be used])
1171   fi
1172
1173   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1174   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1175
1176   # Check for the RANDR extension
1177   if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1178      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1179
1180      X_PACKAGES="$X_PACKAGES xrandr"
1181   fi
1182
1183   # Checks for Xcursor library
1184
1185   if $PKG_CONFIG --exists xcursor ; then
1186     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1187
1188     X_PACKAGES="$X_PACKAGES xcursor"
1189   fi
1190
1191   # Checks for XFixes extension
1192
1193   if $PKG_CONFIG --exists xfixes ; then
1194     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1195
1196     X_PACKAGES="$X_PACKAGES xfixes"
1197     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1198   fi
1199
1200   # Checks for Xcomposite extension
1201
1202   if $PKG_CONFIG --exists xcomposite ; then
1203     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1204
1205     X_PACKAGES="$X_PACKAGES xcomposite"
1206     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1207   fi
1208
1209   # Checks for Xdamage extension
1210
1211   if $PKG_CONFIG --exists xdamage ; then
1212     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1213
1214     X_PACKAGES="$X_PACKAGES xdamage"
1215     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1216   fi
1217
1218   if $have_base_x_pc ; then
1219     GDK_EXTRA_LIBS="$x_extra_libs"
1220   else
1221     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1222   fi
1223
1224   CPPFLAGS="$gtk_save_cppflags"
1225   LIBS="$gtk_save_libs"
1226
1227   AM_CONDITIONAL(USE_X11, true)
1228 else
1229   XPACKAGES=
1230
1231   AM_CONDITIONAL(XINPUT_XFREE, false)
1232   AM_CONDITIONAL(XINPUT_2, false)
1233   AM_CONDITIONAL(USE_X11, false)
1234   AM_CONDITIONAL(HAVE_X11R6, false)
1235 fi
1236
1237 if test "x$gdktarget" = "xwin32"; then
1238   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1239   AM_CONDITIONAL(USE_WIN32, true)
1240 else
1241   AM_CONDITIONAL(USE_WIN32, false)
1242 fi
1243
1244 if test "x$gdktarget" = "xquartz"; then
1245   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1246   AM_CONDITIONAL(USE_QUARTZ, true)
1247 else
1248   AM_CONDITIONAL(USE_QUARTZ, false)
1249 fi
1250
1251 if test "x$gdktarget" = "xdirectfb"; then
1252   DIRECTFB_REQUIRED_VERSION=1.0.0
1253   AC_MSG_CHECKING(for DirectFB)
1254
1255   PKG_CHECK_MODULES(DIRECTFB, [directfb >= $DIRECTFB_REQUIRED_VERSION])
1256   AM_CONDITIONAL(USE_DIRECTFB, true)
1257 else
1258   AM_CONDITIONAL(USE_DIRECTFB, false)
1259 fi
1260
1261
1262 # Check for Pango flags
1263
1264 if test "x$gdktarget" = "xwin32"; then
1265         PANGO_PACKAGES="pangowin32 pangocairo"
1266 else
1267         PANGO_PACKAGES="pango pangocairo"
1268 fi
1269
1270 AC_MSG_CHECKING(Pango flags)
1271 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1272         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1273         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1274
1275         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1276 else
1277         AC_MSG_ERROR([
1278 *** Pango not found. Pango built with Cairo support is required
1279 *** to build GTK+. See http://www.pango.org for Pango information.
1280 ])
1281 fi
1282
1283 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1284
1285 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1286         :
1287 else
1288         gtk_save_LIBS="$LIBS"
1289         LIBS="$PANGO_LIBS $LIBS"
1290         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1291 *** Can't link to Pango. Pango is required to build
1292 *** GTK+. For more information see http://www.pango.org]))
1293         LIBS="$gtk_save_LIBS"
1294 fi
1295
1296 CFLAGS="$saved_cflags"
1297 LDFLAGS="$saved_ldflags"
1298
1299 # Pull in gio-unix for GDesktopAppInfo usage, see at least gdkapplaunchcontext-x11.c
1300 if test "x$gdktarget" = "xx11"; then
1301   GDK_PACKAGES="$PANGO_PACKAGES gio-unix-2.0 $X_PACKAGES gdk-pixbuf-2.0 cairo-$cairo_backend"
1302 else
1303   GDK_PACKAGES="$PANGO_PACKAGES $X_PACKAGES gdk-pixbuf-2.0 cairo-$cairo_backend"
1304 fi
1305
1306 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1307 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1308 #
1309 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1310 # into the pkg-config files
1311 #
1312 if test $enable_explicit_deps != yes ; then
1313   GDK_PACKAGES="$PANGO_PACKAGES"
1314   GDK_EXTRA_LIBS=
1315 fi
1316
1317 AC_SUBST(GDK_PACKAGES)
1318 AC_SUBST(GDK_EXTRA_LIBS)
1319 AC_SUBST(GDK_EXTRA_CFLAGS)
1320 AC_SUBST(GDK_DEP_LIBS)
1321 AC_SUBST(GDK_DEP_CFLAGS)
1322
1323
1324 ########################################
1325 # Check for Accessibility Toolkit flags
1326 ########################################
1327
1328 ATK_PACKAGES=atk
1329 AC_MSG_CHECKING(ATK flags)
1330 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1331         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1332         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1333
1334         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1335 else
1336         AC_MSG_ERROR([
1337 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1338 *** to build GTK+.
1339 ])
1340 fi
1341
1342 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1343         :
1344 else
1345         gtk_save_LIBS="$LIBS"
1346         LIBS="$ATK_LIBS $LIBS"
1347         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1348                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1349                 *** to build GTK+]))
1350         LIBS="$gtk_save_LIBS"
1351 fi
1352
1353 GTK_PACKAGES="atk cairo gdk-pixbuf-2.0 gio-2.0"
1354 if test "x$gdktarget" = "xx11"; then
1355   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1356 fi
1357 GTK_EXTRA_LIBS=
1358 GTK_EXTRA_CFLAGS=
1359 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1360 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1361
1362 if test x"$os_win32" = xyes; then
1363   GTK_EXTRA_CFLAGS="$msnative_struct"
1364 fi
1365
1366 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1367 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1368 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1369 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1370
1371 AC_SUBST(GTK_PACKAGES)
1372 AC_SUBST(GTK_EXTRA_LIBS)
1373 AC_SUBST(GTK_EXTRA_CFLAGS)
1374 AC_SUBST(GTK_DEP_LIBS)
1375 AC_SUBST(GTK_DEP_CFLAGS)
1376
1377 AC_SUBST(GLIB_PREFIX)
1378 AC_SUBST(ATK_PREFIX)
1379 AC_SUBST(PANGO_PREFIX)
1380 AC_SUBST(CAIRO_PREFIX)
1381
1382 AC_SUBST(GTK_DEBUG_FLAGS)
1383 AC_SUBST(GTK_XIM_FLAGS)
1384
1385 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1386 AC_SUBST(GDK_PIXBUF_LIBS)
1387
1388 ########################
1389 # Checks needed for gail
1390 ########################
1391
1392 old_LIBS="$LIBS"
1393 dnl Checks for inet libraries:
1394 AC_SEARCH_LIBS(gethostent, nsl)
1395 AC_SEARCH_LIBS(setsockopt, socket)
1396 AC_SEARCH_LIBS(connect, inet)
1397
1398 dnl check for the sockaddr_un.sun_len member
1399 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1400                 [struct_sockaddr_un_sun_len=true],
1401                 [struct_sockaddr_un_suin_len=false],
1402                 [#include <sys/types.h>
1403                  #include <sys/un.h>]
1404                 )
1405 case $struct_sockaddr_un_sun_len in
1406         true)
1407                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1408                                    [Have the sockaddr_un.sun_len member])
1409                 ;;
1410         *)
1411                 ;;
1412 esac
1413
1414 GAIL_INET_LIBS="$LIBS"
1415 AC_SUBST([GAIL_INET_LIBS])
1416
1417 LIBS="$old_LIBS"
1418
1419 ################################################################
1420 # Printing system checks
1421 ################################################################
1422
1423 AC_ARG_ENABLE(cups,
1424               [AC_HELP_STRING([--disable-cups]
1425                               [disable cups print backend])],,
1426               [enable_cups=auto])
1427
1428 if test "x$enable_cups" = "xno"; then
1429   AM_CONDITIONAL(HAVE_CUPS, false)
1430 else
1431   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1432   if test "x$CUPS_CONFIG" = "xno"; then
1433     if test "x$enable_cups" = "xauto"; then
1434       AM_CONDITIONAL(HAVE_CUPS, false)
1435     else
1436       AC_MSG_ERROR([
1437 *** cups not found.
1438 ])
1439     fi
1440   else
1441     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1442     CUPS_LIBS=`$CUPS_CONFIG --libs`
1443
1444     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1445     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1446     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1447
1448     if test $CUPS_API_MAJOR -gt 1 -o \
1449             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1450       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1451                 [Define to 1 if CUPS 1.2 API is available])
1452     fi
1453
1454     AC_SUBST(CUPS_API_MAJOR)
1455     AC_SUBST(CUPS_API_MINOR)
1456     AC_SUBST(CUPS_CFLAGS)
1457     AC_SUBST(CUPS_LIBS)
1458
1459     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1460
1461     AM_CONDITIONAL(HAVE_CUPS, true)
1462
1463     gtk_save_cflags="$CFLAGS"
1464     CFLAGS="$CUPS_CFLAGS"
1465     AC_TRY_COMPILE([#include <cups/http.h>],
1466                    [http_t http; char *s = http.authstring;],
1467                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1468                               [Define if cups http_t authstring field is accessible])],)
1469     CFLAGS="$gtk_save_cflags"
1470
1471     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1472
1473     gtk_save_libs="$LIBS"
1474     LIBS="$CUPS_LIBS"
1475     AC_CHECK_FUNCS(httpGetAuthString)
1476     LIBS="$gtk_save_libs"
1477   fi
1478 fi
1479
1480 # Checks to see if we should compile with PAPI backend for GTK+
1481 #
1482
1483 AC_ARG_ENABLE(papi,
1484               [AC_HELP_STRING([--disable-papi]
1485                               [disable papi print backend])],,
1486              [enable_papi=auto])
1487
1488 if test "x$enable_papi" = "xno"; then
1489   AM_CONDITIONAL(HAVE_PAPI, false)
1490 else
1491   AC_MSG_CHECKING(libpapi)
1492   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1493   if test $have_papi = yes; then
1494     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1495   fi
1496   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1497   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1498     AC_MSG_ERROR([
1499 *** papi not found.
1500 ])
1501   fi
1502 fi
1503
1504 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1505
1506 gtk_save_cppflags="$CPPFLAGS"
1507 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1508
1509 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1510 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1511 *** backend enabled.]))
1512
1513 if test "$os_win32" != "yes"; then
1514   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1515 *** Can't find cairo-ps.h. You must build Cairo with the
1516 *** postscript backend enabled.]))
1517
1518   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1519 *** Can't find cairo-svg.h. You must build Cairo with the
1520 *** svg backend enabled.]))
1521 fi
1522
1523 CPPFLAGS="$gtk_save_cppflags"
1524
1525
1526 AC_ARG_ENABLE(test-print-backend,
1527               [AC_HELP_STRING([--enable-test-print-backend],
1528                               [build test print backend])],,
1529               [enable_test_print_backend=no])
1530 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1531
1532
1533 ################################################################
1534 # Strip -export-dynamic from the link lines of various libraries
1535 ################################################################
1536
1537 #
1538 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1539 #  but this flag is only meaningful for executables. For libraries
1540 #  the effect is undefined; what it causes on Linux is that the
1541 #  export list from -export-symbols-regex is ignored and everything
1542 #  is exported
1543 #
1544 # We are using gmodule-no-export now, but I'm leaving the stripping
1545 # code in place for now, since pango and atk still require gmodule.
1546 export SED
1547 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1548 if test -n "$export_dynamic"; then
1549   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1550   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1551 fi
1552
1553 ##################################################
1554 # GObject introspection
1555 ##################################################
1556
1557 GOBJECT_INTROSPECTION_CHECK([0.6.14])
1558
1559 ##################################################
1560 # Checks for gtk-doc and docbook-tools
1561 ##################################################
1562
1563 GTK_DOC_CHECK([1.11])
1564
1565 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1566 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1567
1568 AC_ARG_ENABLE(man,
1569               [AC_HELP_STRING([--enable-man],
1570                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1571               enable_man=no)
1572
1573 if test "${enable_man}" != no; then
1574   dnl
1575   dnl Check for xsltproc
1576   dnl
1577   AC_PATH_PROG([XSLTPROC], [xsltproc])
1578   if test -z "$XSLTPROC"; then
1579     enable_man=no
1580   fi
1581
1582   dnl check for DocBook DTD and stylesheets in the local catalog.
1583   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1584      [DocBook XML DTD V4.1.2],,enable_man=no)
1585   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1586      [DocBook XSL Stylesheets],,enable_man=no)
1587 fi
1588
1589 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1590
1591
1592 ##################################################
1593 # Output commands
1594 ##################################################
1595
1596 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1597         outfile=gdkconfig.h-tmp
1598         cat > $outfile <<\_______EOF
1599 /* gdkconfig.h
1600  *
1601  * This is a generated file.  Please modify `configure.ac'
1602  */
1603
1604 #ifndef GDKCONFIG_H
1605 #define GDKCONFIG_H
1606
1607 #ifdef __cplusplus
1608 extern "C" {
1609 #endif /* __cplusplus */
1610
1611 #ifndef GSEAL
1612 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
1613 #  ifdef GSEAL_ENABLE
1614 #    define GSEAL(ident)      _g_sealed__ ## ident
1615 #  else
1616 #    define GSEAL(ident)      ident
1617 #  endif
1618 #endif /* !GSEAL */
1619
1620 _______EOF
1621
1622         cat >>$outfile <<_______EOF
1623 $gdk_windowing
1624 $gdk_wc
1625 _______EOF
1626
1627         cat >>$outfile <<_______EOF
1628
1629 #ifdef __cplusplus
1630 }
1631 #endif /* __cplusplus */
1632
1633 #endif /* GDKCONFIG_H */
1634 _______EOF
1635
1636
1637         if cmp -s $outfile gdk/gdkconfig.h; then
1638           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1639           rm -f $outfile
1640         else
1641           mv $outfile gdk/gdkconfig.h
1642         fi
1643 ],[
1644 if test "x$gdktarget" = "xx11" ; then
1645   gdk_windowing='
1646 #define GDK_WINDOWING_X11'
1647 elif test "x$gdktarget" = "xwin32" ; then
1648   gdk_windowing='
1649 #define GDK_NATIVE_WINDOW_POINTER
1650
1651 #define GDK_WINDOWING_WIN32'
1652 elif test "x$gdktarget" = "xquartz" ; then
1653   gdk_windowing='
1654 #define GDK_WINDOWING_QUARTZ'
1655 elif test "x$gdktarget" = "xdirectfb" ; then
1656   gdk_windowing='
1657 #define GDK_WINDOWING_DIRECTFB'
1658 fi
1659
1660 if test x$gdk_wchar_h = xyes; then
1661   gdk_wc='
1662 #define GDK_HAVE_WCHAR_H 1'
1663 fi
1664 if test x$gdk_wctype_h = xyes; then
1665   gdk_wc="\$gdk_wc
1666 #define GDK_HAVE_WCTYPE_H 1"
1667 fi
1668 if test x$gdk_working_wctype = xno; then
1669   gdk_wc="\$gdk_wc
1670 #define GDK_HAVE_BROKEN_WCTYPE 1"
1671 fi
1672
1673
1674 ])
1675
1676 AC_CONFIG_FILES([
1677 config.h.win32
1678 gtk-zip.sh
1679 Makefile
1680 gdk-3.0.pc
1681 gtk+-3.0.pc
1682 gtk+-unix-print-3.0.pc
1683 gail-3.0.pc
1684 gdk-3.0-uninstalled.pc
1685 gtk+-3.0-uninstalled.pc
1686 gail-3.0-uninstalled.pc
1687 m4macros/Makefile
1688 po/Makefile.in
1689 po-properties/Makefile.in
1690 demos/Makefile
1691 demos/gtk-demo/Makefile
1692 demos/gtk-demo/geninclude.pl
1693 tests/Makefile
1694 docs/Makefile
1695 docs/reference/Makefile
1696 docs/reference/gdk/Makefile
1697 docs/reference/gdk/version.xml
1698 docs/reference/gtk/Makefile
1699 docs/reference/gtk/version.xml
1700 docs/reference/libgail-util/Makefile
1701 docs/faq/Makefile
1702 docs/tools/Makefile
1703 docs/tutorial/Makefile
1704 build/Makefile
1705 build/win32/Makefile
1706 build/win32/vs9/Makefile
1707 gdk/Makefile
1708 gdk/x11/Makefile
1709 gdk/win32/Makefile
1710 gdk/win32/rc/Makefile
1711 gdk/win32/rc/gdk.rc
1712 gdk/quartz/Makefile
1713 gdk/directfb/Makefile
1714 gdk/tests/Makefile
1715 gtk/Makefile
1716 gtk/makefile.msc
1717 gtk/gtkversion.h
1718 gtk/gtk-win32.rc
1719 gtk/theme-bits/Makefile
1720 gtk/tests/Makefile
1721 modules/Makefile
1722 modules/other/Makefile
1723 modules/other/gail/Makefile
1724 modules/other/gail/libgail-util/Makefile
1725 modules/other/gail/tests/Makefile
1726 modules/engines/Makefile
1727 modules/engines/pixbuf/Makefile
1728 modules/engines/ms-windows/Makefile
1729 modules/engines/ms-windows/Theme/Makefile
1730 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1731 modules/input/Makefile
1732 modules/printbackends/Makefile
1733 modules/printbackends/cups/Makefile
1734 modules/printbackends/lpr/Makefile
1735 modules/printbackends/file/Makefile
1736 modules/printbackends/papi/Makefile
1737 modules/printbackends/test/Makefile
1738 perf/Makefile
1739 ])
1740
1741 AC_OUTPUT
1742
1743 echo "configuration:
1744         target: $gdktarget"