Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [0])
  13 m4_define([gtk_micro_version], [1])
  14 m4_define([gtk_interface_age], [1])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.28.0])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.30])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.22.0])
  46 m4_define([introspection_required_version], [0.10.1])
  47 GLIB_REQUIRED_VERSION=glib_required_version
  48 PANGO_REQUIRED_VERSION=pango_required_version
  49 ATK_REQUIRED_VERSION=atk_required_version
  50 CAIRO_REQUIRED_VERSION=cairo_required_version
  51 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  52 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  53
  54 AC_SUBST(GLIB_REQUIRED_VERSION)
  55 AC_SUBST(PANGO_REQUIRED_VERSION)
  56 AC_SUBST(ATK_REQUIRED_VERSION)
  57 AC_SUBST(CAIRO_REQUIRED_VERSION)
  58 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  59 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  60
  61 # Save this value here, since automake will set cflags later
  62 cflags_set=${CFLAGS+set}
  63
  64 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  65 AM_MAINTAINER_MODE([enable])
  66
  67 # Support silent build rules, requires at least automake-1.11. Disable
  68 # by either passing --disable-silent-rules to configure or passing V=1
  69 # to make
  70 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  71
  72 #
  73 # For each of the libraries we build, we define the following
  74 # substituted variables:
  75 #
  76 # foo_PACKAGES:     pkg-config packages this library requires
  77 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  78 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  79 # foo_DEP_LIBS:     All libraries this module requires
  80 # foo_DEP_CFLAGS:   All cflags this module requires
  81
  82
  83 GTK_MAJOR_VERSION=gtk_major_version
  84 GTK_MINOR_VERSION=gtk_minor_version
  85 GTK_MICRO_VERSION=gtk_micro_version
  86 GTK_INTERFACE_AGE=gtk_interface_age
  87 GTK_BINARY_AGE=gtk_binary_age
  88 GTK_VERSION=gtk_version
  89 GTK_API_VERSION=gtk_api_version
  90 GTK_BINARY_VERSION=gtk_binary_version
  91 AC_SUBST(GTK_MAJOR_VERSION)
  92 AC_SUBST(GTK_MINOR_VERSION)
  93 AC_SUBST(GTK_MICRO_VERSION)
  94 AC_SUBST(GTK_INTERFACE_AGE)
  95 AC_SUBST(GTK_BINARY_AGE)
  96 AC_SUBST(GTK_API_VERSION)
  97 AC_SUBST(GTK_VERSION)
  98 AC_SUBST(GTK_BINARY_VERSION)
  99
 100 # libtool versioning
 101 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 102 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 103 #LT_REVISION=$GTK_INTERFACE_AGE
 104 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 105 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 106
 107 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 108 m4_define([lt_revision], [gtk_interface_age])
 109 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 110 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 111 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 112 AC_SUBST(LT_VERSION_INFO)
 113 AC_SUBST(LT_CURRENT_MINUS_AGE)
 114
 115 m4_define([gail_lt_current],[0])
 116 m4_define([gail_lt_revision],[0])
 117 m4_define([gail_lt_age],[0])
 118 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 119 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 120 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 121 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 122
 123 # Checks for programs.
 124 AC_PROG_CC
 125 AC_PROG_CC_C_O
 126 AC_PROG_CC_STDC
 127 AC_PROG_INSTALL
 128 AC_PROG_MAKE_SET
 129
 130
 131 GETTEXT_PACKAGE=gtk30
 132 AC_SUBST(GETTEXT_PACKAGE)
 133 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 134                    [The prefix for our gettext translation domains.])
 135
 136 AC_CANONICAL_HOST
 137
 138 MATH_LIB=-lm
 139 AC_MSG_CHECKING([for native Win32])
 140 LIB_EXE_MACHINE_FLAG=X86
 141 EXE_MANIFEST_ARCHITECTURE=X86
 142 case "$host" in
 143   *-*-mingw*)
 144     os_win32=yes
 145     gio_can_sniff=no
 146     MATH_LIB=
 147     case "$host" in
 148     x86_64-*-*)
 149       LIB_EXE_MACHINE_FLAG=X64
 150       EXE_MANIFEST_ARCHITECTURE=AMD64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     os_win32=no
 156     ;;
 157 esac
 158 AC_MSG_RESULT([$os_win32])
 159
 160 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 161 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 162
 163 case $host in
 164   *-*-linux*)
 165     os_linux=yes
 166     ;;
 167 esac
 168
 169 dnl
 170 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 171 dnl We use this for an automated test for C++ header correctness.
 172 dnl
 173 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 174 AC_LANG_PUSH([C++])
 175
 176 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 177                                    [[class a { int b; } c;]])],
 178                   [],[CXX=])
 179 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 180
 181 gtk_save_cxxflags="$CXXFLAGS"
 182 CXXFLAGS="$CXXFLAGS -x objective-c++"
 183 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 184                                    [[]])],
 185                   [OBJC=yes],[OBJC=no])
 186 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 187 CXXFLAGS="$gtk_save_cxxflags"
 188 AC_LANG_POP([C++])
 189
 190 if test "$os_win32" = "yes"; then
 191   if test x$enable_static = xyes -o x$enable_static = x; then
 192     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 193     enable_static=no
 194   fi
 195   if test x$enable_shared = xno; then
 196     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 197   fi
 198   enable_shared=yes
 199 fi
 200
 201 dnl Initialize libtool
 202 LT_PREREQ([2.2.6])
 203 LT_INIT([disable-static win32-dll])
 204 # Create libtool early, because it's used in configure
 205 LT_OUTPUT
 206
 207 # Make sure we use 64-bit versions of various file stuff.
 208 AC_SYS_LARGEFILE
 209
 210 AM_PROG_AS
 211 AC_PATH_PROG(NM, nm, nm)
 212
 213 AC_MSG_CHECKING([for some Win32 platform])
 214 case "$host" in
 215   *-*-mingw*|*-*-cygwin*)
 216     platform_win32=yes
 217     ;;
 218   *)
 219     platform_win32=no
 220     ;;
 221 esac
 222 AC_MSG_RESULT([$platform_win32])
 223 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 224
 225 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 226 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 227 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 228
 229 if test "$os_win32" = "yes"; then
 230   AC_CHECK_TOOL(WINDRES, windres, no)
 231   if test "$WINDRES" = no; then
 232     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 233   fi
 234   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 235 fi
 236 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 237
 238 m4_define([debug_default],
 239           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 240
 241 dnl declare --enable-* args and collect ac_help strings
 242 AC_ARG_ENABLE(debug,
 243               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 244                               [turn on debugging @<:@default=debug_default@:>@])],,
 245               [enable_debug=debug_default])
 246
 247 AC_ARG_ENABLE(rebuilds,
 248               [AS_HELP_STRING([--disable-rebuilds],
 249                               [disable all source autogeneration rules])],,
 250               [enable_rebuilds=yes])
 251
 252 AC_ARG_ENABLE(gtk2-dependency,
 253               [AS_HELP_STRING([--enable-gtk2-dependency],
 254                               [Do not build gtk-update-icon-cache and other shared tools])],,
 255               [enable_gtk2_dependency=no])
 256
 257 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 258
 259 AC_ARG_ENABLE(xkb,
 260               [AS_HELP_STRING([--enable-xkb],
 261                               [support XKB extension [default=maybe]])],,
 262               [enable_xkb="maybe"])
 263 AC_ARG_ENABLE(xinerama,
 264               [AS_HELP_STRING([--enable-xinerama],
 265                               [support Xinerama extension if available [default=maybe]])],,
 266               [enable_xinerama="maybe"])
 267 AC_ARG_ENABLE(xinput,
 268               [AS_HELP_STRING([--enable-xinput],
 269                               [support XInput extension if available [default=yes]])],,
 270               [enable_xinput="maybe"])
 271 AC_ARG_ENABLE(xrandr,
 272               [AS_HELP_STRING([--enable-xrandr],
 273                               [support XRandR extension if available [default=maybe]])],,
 274               [enable_xrandr="maybe"])
 275 AC_ARG_ENABLE(xfixes,
 276               [AS_HELP_STRING([--enable-xfixes],
 277                               [support XFixes extension if available [default=maybe]])],,
 278               [enable_xfixes="maybe"])
 279 AC_ARG_ENABLE(xcomposite,
 280               [AS_HELP_STRING([--enable-xcomposite],
 281                               [support X Composite extension if available [default=maybe]])],,
 282               [enable_xcomposite="maybe"])
 283 AC_ARG_ENABLE(xdamage,
 284               [AS_HELP_STRING([--enable-xdamage],
 285                               [support X Damage extension if available [default=maybe]])],,
 286               [enable_xdamage="maybe"])
 287
 288 AC_ARG_ENABLE(x11-backend,
 289               [AS_HELP_STRING([--enable-x11-backend],
 290                               [enable the X11 gdk backend])],
 291                               [backend_set=yes])
 292 AC_ARG_ENABLE(win32-backend,
 293               [AS_HELP_STRING([--enable-win32-backend],
 294                               [enable the Win32 gdk backend])],
 295                               [backend_set=yes])
 296 AC_ARG_ENABLE(quartz-backend,
 297               [AS_HELP_STRING([--enable-quartz-backend],
 298                               [enable the quartz gdk backend])],
 299                               [backend_set=yes])
 300
 301 if test -z "$backend_set"; then
 302   if test "$platform_win32" = yes; then
 303     enable_win32_backend=yes
 304   else
 305     enable_x11_backend=yes
 306   fi
 307 fi
 308
 309 cairo_backends=
 310 backend_immodules=
 311 GDK_BACKENDS=
 312 GDK_EXTRA_LIBS=
 313 GDK_EXTRA_CFLAGS=
 314 GDK_WINDOWING=
 315 GIO_PACKAGE=gio-2.0
 316 PANGO_PACKAGES="pango pangocairo"
 317
 318 if test "x$enable_x11_backend" == xyes; then
 319   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 320   # backend names are identical.
 321   cairo_backends="$cairo_backends cairo-xlib"
 322   GDK_BACKENDS="$GDK_BACKENDS x11"
 323   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 324   # gdkapplaunchcontext-x11.c
 325   GIO_PACKAGE=gio-unix-2.0
 326   backend_immodules="$backend_immodules,xim"
 327   GDK_WINDOWING="$GDK_WINDOWING
 328 #define GDK_WINDOWING_X11"
 329 fi
 330
 331 if test "x$enable_win32_backend" == xyes; then
 332   cairo_backends="$cairo_backends cairo-win32"
 333   GDK_BACKENDS="$GDK_BACKENDS win32"
 334   backend_immodules="$backend_immodules,ime"
 335   GDK_WINDOWING="$GDK_WINDOWING
 336 #define GDK_WINDOWING_WIN32"
 337   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 338   AM_CONDITIONAL(USE_WIN32, true)
 339   PANGO_PACKAGES="pangowin32 pangocairo"
 340 else
 341   AM_CONDITIONAL(USE_WIN32, false)
 342 fi
 343
 344 if test "x$enable_quartz_backend" == xyes; then
 345   cairo_backends="$cairo_backends cairo-quartz"
 346   GDK_BACKENDS="$GDK_BACKENDS quartz"
 347   GDK_WINDOWING="$GDK_WINDOWING
 348 #define GDK_WINDOWING_QUARTZ"
 349   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 350   AM_CONDITIONAL(USE_QUARTZ, true)
 351 else
 352   AM_CONDITIONAL(USE_QUARTZ, false)
 353 fi
 354
 355 # strip leading space
 356 GDK_BACKENDS=${GDK_BACKENDS/# }
 357
 358 AC_SUBST(GDK_BACKENDS)
 359
 360 if test -z "$GDK_BACKENDS"; then
 361   AC_MSG_ERROR([No GDK backends selected.])
 362 fi
 363
 364 if test "x$enable_debug" = "xyes"; then
 365   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 366   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 367 else
 368   if test "x$enable_debug" = "xno"; then
 369     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 370   else
 371     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 372   fi
 373 fi
 374
 375
 376 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 377                    [Define if debugging is enabled])
 378
 379
 380 # Build time sanity check...
 381 AM_SANITY_CHECK
 382
 383 changequote(,)dnl
 384 if test "x$GCC" = "xyes"; then
 385   case " $CFLAGS " in
 386   *[\ \ ]-Wall[\ \      ]*) ;;
 387   *) CFLAGS="$CFLAGS -Wall" ;;
 388   esac
 389
 390   if test "x$enable_ansi" = "xyes"; then
 391     case " $CFLAGS " in
 392     *[\ \       ]-ansi[\ \      ]*) ;;
 393     *) CFLAGS="$CFLAGS -ansi" ;;
 394     esac
 395
 396     case " $CFLAGS " in
 397     *[\ \       ]-pedantic[\ \  ]*) ;;
 398     *) CFLAGS="$CFLAGS -pedantic" ;;
 399     esac
 400   fi
 401 fi
 402 changequote([,])dnl
 403
 404 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 405
 406 # Ensure MSVC-compatible struct packing convention is used when
 407 # compiling for Win32 with gcc.
 408 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 409 # gcc2 uses "-fnative-struct".
 410 if test x"$os_win32" = xyes; then
 411   if test x"$GCC" = xyes; then
 412     msnative_struct=''
 413     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 414     if test -z "$ac_cv_prog_CC"; then
 415       our_gcc="$CC"
 416     else
 417       our_gcc="$ac_cv_prog_CC"
 418     fi
 419     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 420       2.)
 421         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 422           msnative_struct='-fnative-struct'
 423         fi
 424         ;;
 425       *)
 426         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 427           msnative_struct='-mms-bitfields'
 428         fi
 429         ;;
 430     esac
 431     if test x"$msnative_struct" = x ; then
 432       AC_MSG_RESULT([no way])
 433       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 434     else
 435       CFLAGS="$CFLAGS $msnative_struct"
 436       AC_MSG_RESULT([${msnative_struct}])
 437     fi
 438   fi
 439 fi
 440
 441 ## Initial sanity check, done here so that users get told they
 442 ## have the wrong dependencies as early in the process as possible.
 443 ## Later on we actually use the cflags/libs from separate pkg-config
 444 ## calls. Oh, also the later pkg-config calls don't include
 445 ## the version requirements since those make the module lists
 446 ## annoying to construct
 447 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 448   [glib-2.0 >= glib_required_version dnl
 449    atk >= atk_required_version dnl
 450    pango >= pango_required_version dnl
 451    cairo >= cairo_required_version dnl
 452    cairo-gobject >= cairo_required_version dnl
 453    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 454
 455 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 456
 457 if test "$os_win32" != yes; then
 458     # libtool option to control which symbols are exported
 459     # right now, symbols starting with _ are not exported
 460     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 461 else
 462     # We currently use .def files on Windows (for gdk and gtk)
 463     LIBTOOL_EXPORT_OPTIONS=
 464 fi
 465 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 466
 467 dnl ******************************************************
 468 dnl * See whether to include shared library dependencies *
 469 dnl ******************************************************
 470
 471 AC_ARG_ENABLE(explicit-deps,
 472               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 473                               [use explicit dependencies in .pc files [default=auto]])],,
 474               [enable_explicit_deps=auto])
 475
 476 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 477 case $enable_explicit_deps in
 478   auto)
 479     export SED
 480     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 481     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 482       enable_explicit_deps=yes
 483     else
 484       enable_explicit_deps=no
 485     fi
 486   ;;
 487   yes|no)
 488   ;;
 489   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 490   ;;
 491 esac
 492 AC_MSG_RESULT($enable_explicit_deps)
 493
 494 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 495
 496 # define a MAINT-like variable REBUILD which is set if Perl
 497 # and awk are found, so autogenerated sources can be rebuilt
 498
 499 AC_PATH_PROGS(PERL, perl5 perl)
 500
 501 # We would like indent, but don't require it.
 502 AC_CHECK_PROG(INDENT, indent, indent)
 503
 504 REBUILD=\#
 505 if test "x$enable_rebuilds" = "xyes" && \
 506      test -n "$PERL" && \
 507      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 508   REBUILD=
 509 fi
 510 AC_SUBST(REBUILD)
 511
 512 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 513 AC_CHECK_FUNCS(localtime_r)
 514
 515 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 516 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 517 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 518                                 [[char c;
 519                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 520                [gtk_ok=yes], [gtk_ok=no])
 521 AC_MSG_RESULT($gtk_ok)
 522 if test "$gtk_ok" = "yes"; then
 523   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 524             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 525 fi
 526
 527 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 528 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 529 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 530                                 [[char c;
 531                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 532                [gtk_ok=yes], [gtk_ok=no])
 533 AC_MSG_RESULT($gtk_ok)
 534 if test "$gtk_ok" = "yes"; then
 535   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 536             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 537 fi
 538
 539 # _NL_PAPER_HEIGHT is an enum and not a define
 540 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 541 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 542                                 [[char c;
 543                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 544                [gtk_ok=yes], [gtk_ok=no])
 545 AC_MSG_RESULT($gtk_ok)
 546 if test "$gtk_ok" = "yes"; then
 547   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 548             [Define if _NL_PAPER_HEIGHT is available])
 549 fi
 550
 551 # _NL_PAPER_WIDTH is an enum and not a define
 552 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 553 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 554                                 [[char c;
 555                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 556                [gtk_ok=yes], [gtk_ok=no])
 557 AC_MSG_RESULT($gtk_ok)
 558 if test "$gtk_ok" = "yes"; then
 559   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 560             [Define if _NL_PAPER_WIDTH is available])
 561 fi
 562
 563 # i18n stuff
 564 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 565 AM_GLIB_GNU_GETTEXT
 566 LIBS="$LIBS $INTLLIBS"
 567 AC_CONFIG_COMMANDS([po-properties],
 568                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 569                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 570                      esac]],
 571                    [[]])
 572
 573 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 574 dnl po-properties/POTFILES during configure; see GNOME #573515.
 575 dnl
 576 dnl Generate list of files to be processed by xgettext which will
 577 dnl be included in po-properties/Makefile.
 578 test -d po-properties || mkdir po-properties
 579 if test "x$srcdir" != "x."; then
 580   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 581     popropsrcprefix="$srcdir/"
 582   else
 583     popropsrcprefix="../$srcdir/"
 584   fi
 585 else
 586   popropsrcprefix="../"
 587 fi
 588 rm -f po-properties/POTFILES
 589 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 590 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 591 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 592
 593 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 594
 595 dnl The DU4 header files don't provide library prototypes unless
 596 dnl -std1 is given to the native cc.
 597 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 598
 599 gtk_save_LIBS=$LIBS
 600 LIBS="$LIBS -lm"
 601 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 602                                 int main (void) { return (log(1) != log(1.)); }]])],
 603               [AC_MSG_RESULT(none needed)],
 604               [gtk_save_CFLAGS="$CFLAGS"
 605                CFLAGS="$CFLAGS -std1"
 606                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 607                                                int main (void) { return (log(1) != log(1.)); }]])],
 608                              [AC_MSG_RESULT(-std1)],
 609                              [AC_MSG_RESULT()
 610                               CFLAGS="$gtk_save_CFLAGS"
 611                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 612                              [true])],
 613               [AC_MSG_RESULT(none needed)])
 614
 615 LIBS=$gtk_save_LIBS
 616
 617 AC_MSG_CHECKING(for the BeOS)
 618 case $host in
 619   *-*-beos*)
 620     AC_MSG_RESULT(yes)
 621     MATH_LIB=
 622   ;;
 623   *)
 624     AC_MSG_RESULT(no)
 625   ;;
 626 esac
 627
 628 AC_SUBST(MATH_LIB)
 629 #
 630 # see bug 162979
 631 #
 632 AC_MSG_CHECKING(for HP-UX)
 633 case $host_os in
 634   hpux9* | hpux10* | hpux11*)
 635     AC_MSG_RESULT(yes)
 636     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 637   ;;
 638   *)
 639     AC_MSG_RESULT(no)
 640   ;;
 641 esac
 642
 643 #
 644 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 645 #
 646
 647 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 648
 649 AM_PATH_GLIB_2_0(glib_required_version, :,
 650   AC_MSG_ERROR([
 651 *** GLIB glib_required_version or better is required. The latest version of
 652 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 653   gobject gmodule-no-export gthread)
 654
 655 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 656 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 657 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 658 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 659   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 660 fi
 661
 662 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 663
 664
 665 dnl
 666 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 667 dnl
 668 gtk_save_LIBS=$LIBS
 669 LIBS="$LIBS $GLIB_LIBS"
 670 AC_CHECK_FUNCS(bind_textdomain_codeset)
 671 LIBS=$gtk_save_LIBS
 672
 673 AC_CHECK_HEADERS(pwd.h,
 674                  AC_DEFINE(HAVE_PWD_H, 1,
 675                            [Define to 1 if pwd.h is available]))
 676 AC_CHECK_HEADERS(sys/time.h,
 677                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 678                            [Define to 1 if time.h is available]))
 679 AC_CHECK_HEADERS(unistd.h,
 680                  AC_DEFINE(HAVE_UNISTD_H, 1,
 681                            [Define to 1 if unistd.h is available]))
 682 AC_CHECK_HEADERS(ftw.h,
 683                  AC_DEFINE(HAVE_FTW_H, 1,
 684                            [Define to 1 if ftw.h is available]))
 685
 686 AC_MSG_CHECKING([for GNU ftw extensions])
 687 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 688                                      #define _GNU_SOURCE
 689                                      #include <ftw.h>]],
 690                                    [[int flags = FTW_ACTIONRETVAL;]])],
 691                   [gtk_ok=yes],[gtk_ok=no])
 692 if test $gtk_ok = yes; then
 693     AC_MSG_RESULT([yes])
 694     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 695 else
 696     AC_MSG_RESULT([no])
 697 fi
 698
 699 saved_cflags="$CFLAGS"
 700 saved_ldflags="$LDFLAGS"
 701
 702
 703 # Checks for library functions.
 704 AC_FUNC_MMAP
 705
 706 AC_CHECK_FUNCS(mallinfo)
 707 AC_CHECK_FUNCS(getresuid)
 708 AC_TYPE_UID_T
 709
 710 # Check for uxtheme.h (for MS-Windows Engine)
 711 AC_MSG_CHECKING(for uxtheme.h)
 712 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <uxtheme.h>]])],
 713                   [gtk_uxtheme_h=yes], [gtk_uxtheme_h=no])
 714 if test $gtk_uxtheme_h = yes; then
 715    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 716 fi
 717 AC_MSG_RESULT($gtk_uxtheme_h)
 718
 719 # Checks for gdkspawn
 720 AC_CHECK_HEADERS(crt_externs.h)
 721 AC_CHECK_FUNCS(_NSGetEnviron)
 722
 723 AC_MSG_CHECKING(whether to build dynamic modules)
 724
 725 AC_ARG_ENABLE(modules,
 726               [AS_HELP_STRING([--disable-modules],
 727                               [disable dynamic module loading])])
 728
 729 dynworks=false
 730 build_dynamic_modules=no
 731 deps=
 732 if test x$enable_modules = xno; then
 733     AC_MSG_RESULT(no)
 734 else
 735     AC_MSG_RESULT(yes)
 736     AC_MSG_CHECKING(whether dynamic modules work)
 737     ## for loop is to strip newline
 738     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 739     for I in $tmp; do
 740         dynworks=$I
 741     done
 742
 743     dnl Now we check to see if our libtool supports shared lib deps
 744     dnl (in a rather ugly way even)
 745     if $dynworks; then
 746         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 747         module_deplibs_check=`$module_libtool_config | \
 748             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 749             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 750         if test "x$module_deplibs_check" = "xnone" || \
 751            test "x$module_deplibs_check" = "xunknown" || \
 752            test "x$module_deplibs_check" = "x"; then
 753             dynworks=false
 754         fi
 755     fi
 756
 757     if $dynworks; then
 758         build_dynamic_modules=yes
 759         AC_DEFINE(USE_GMODULE, 1,
 760                   [Define to 1 if gmodule works and should be used])
 761         AC_MSG_RESULT(yes)
 762     else
 763         build_dynamic_modules=no
 764         AC_MSG_RESULT(no)
 765     fi
 766 fi
 767
 768 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 769
 770 #
 771 # Allow building some or all immodules included
 772 #
 773 AC_MSG_CHECKING(immodules to build)
 774
 775 AC_ARG_WITH(included_immodules,
 776             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 777                             [build the specified input methods into gtk])])
 778
 779 if $dynworks; then
 780    :
 781 else
 782    ## if the option was specified, leave it; otherwise disable included immodules
 783    if test x$with_included_immodules = xno; then
 784            with_included_immodules=yes
 785    fi
 786 fi
 787
 788 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 789
 790 included_immodules=""
 791 # If the switch specified without listing any specific ones, include all
 792 if test "x$with_included_immodules" = xyes ; then
 793   included_immodules="$all_immodules"
 794 else
 795   included_immodules="$with_included_immodules"
 796 fi
 797
 798 AC_MSG_RESULT($included_immodules)
 799 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 800
 801 INCLUDED_IMMODULE_OBJ=
 802 INCLUDED_IMMODULE_DEFINE=
 803
 804 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 805 for immodule in $included_immodules; do
 806  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 807  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 808    :
 809  else
 810    AC_MSG_ERROR([the specified input method $immodule does not exist])
 811  fi
 812
 813  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 814  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 815  eval INCLUDE_$immodule_underscores=yes
 816 done
 817 IFS="$gtk_save_ifs"
 818 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 819 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 820
 821 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 822 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 823 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 824 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 825 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 826 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 827 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 828 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 829 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 830 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 831 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 832 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 833
 834 # Checks to see whether we should include mediaLib
 835 # support.
 836 #
 837 AC_CHECK_HEADER(sys/systeminfo.h,
 838                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 839                           [Define to 1 if sys/systeminfo.h is available]))
 840 AC_CHECK_HEADER(sys/sysinfo.h,
 841                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 842                           [Define to 1 if sys/sysinfo.h is available]))
 843
 844 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 845
 846 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 847
 848 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 849   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 850   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 851     REBUILD_PNGS=#
 852   fi
 853 fi
 854
 855 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 856
 857 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 858
 859 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 860    test "x$REBUILD_PNGS" = "x#" ; then
 861      AC_MSG_ERROR([
 862 *** gtkbuiltincache.h is not in the tree, and cannot be built
 863 *** because you don't have libpng, or (when cross-compiling) you
 864 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 865 fi
 866
 867 ########################################
 868 # Windowing system checks
 869 ########################################
 870
 871 # GTK+ uses some X calls, so needs to link against X directly
 872 GTK_DEP_PACKAGES_FOR_X=
 873 GTK_DEP_LIBS_FOR_X=
 874 X_EXTENSIONS=
 875
 876 if test "x$enable_x11_backend" == xyes; then
 877   X_PACKAGES=fontconfig
 878
 879   #
 880   # We use fontconfig very peripherally when decoding the default
 881   # settings.
 882   #
 883   if $PKG_CONFIG --exists fontconfig; then : ; else
 884     AC_MSG_ERROR([
 885 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 886   fi
 887
 888   #
 889   # Check for basic X packages; we use pkg-config if available
 890   #
 891   if $PKG_CONFIG --exists x11 xext; then
 892     have_base_x_pc=true
 893     X_PACKAGES="$X_PACKAGES x11 xext"
 894     x_libs="`$PKG_CONFIG --libs x11 xext`"
 895     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 896
 897     # Strip out any .la files that pkg-config might give us (this happens
 898     # with -uninstalled.pc files)
 899     x_libs_for_checks=
 900     for I in $x_libs ; do
 901       case $I in
 902         *.la) ;;
 903         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 904       esac
 905     done
 906
 907     GTK_PACKAGES_FOR_X="x11"
 908   else
 909     have_base_x_pc=false
 910     AC_PATH_XTRA
 911     if test x$no_x = xyes ; then
 912       AC_MSG_ERROR([X development libraries not found])
 913     fi
 914
 915     x_cflags="$X_CFLAGS"
 916     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 917
 918     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 919   fi
 920
 921   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 922   x_extra_libs=
 923
 924   gtk_save_cppflags="$CPPFLAGS"
 925   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 926
 927   gtk_save_LIBS=$LIBS
 928   LIBS="$x_libs_for_checks $LIBS"
 929
 930   # Sanity check for the X11 and Xext libraries. While everything we need from
 931   # Xext is optional, the chances a system has *none* of these things is so
 932   # small that we just unconditionally require it.
 933   AC_CHECK_FUNC(XOpenDisplay, :,
 934                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 935   AC_CHECK_FUNC(XextFindDisplay, :,
 936                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 937
 938   # Check for xReply
 939
 940   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 941   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 942                                      [[xReply *rep;]])],
 943                     [AC_MSG_RESULT([no])],
 944                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 945                                                           #include <X11/Xlibint.h>]],
 946                                                         [[xReply *rep;]])],
 947                                        [AC_MSG_RESULT([yes])
 948                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 949                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 950                                        [AC_MSG_RESULT([unknown])
 951                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 952
 953   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 954
 955   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 956
 957   # Generic X11R6 check needed for XIM support; we could
 958   # probably use this to replace the above, but we'll
 959   # leave the separate checks for XConvertCase and XInternAtoms
 960   # for clarity
 961
 962   have_x11r6=false
 963   AC_CHECK_FUNC(XAddConnectionWatch,
 964       have_x11r6=true)
 965
 966   if $have_x11r6; then
 967     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
 968   fi
 969   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
 970
 971   # Check for XKB support.
 972
 973   if test "x$enable_xkb" = "xyes"; then
 974         AC_CHECK_FUNC(XkbQueryExtension,
 975                       X_EXTENSIONS="$X_EXTENSIONS XKB"
 976                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
 977                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
 978   elif test "x$enable_xkb" = "xmaybe"; then
 979         AC_CHECK_FUNC(XkbQueryExtension,
 980                       X_EXTENSIONS="$X_EXTENSIONS XKB"
 981                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
 982   else
 983         AC_MSG_WARN(XKB support explicitly disabled)
 984   fi
 985
 986   # Check for shaped window extension
 987
 988   AC_CHECK_FUNC(XShapeCombineMask, :,
 989      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
 990
 991   # X SYNC check
 992   gtk_save_CFLAGS="$CFLAGS"
 993   CFLAGS="$CFLAGS $x_cflags"
 994
 995   AC_CHECK_FUNC(XSyncQueryExtension,
 996       [AC_CHECK_HEADER(X11/extensions/sync.h,
 997           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
 998           :, [#include <X11/Xlib.h>])])
 999
1000   CFLAGS="$gtk_save_CFLAGS"
1001
1002   if test "x$enable_xinerama" != "xno"; then
1003     # Check for Xinerama extension (Solaris impl or Xfree impl)
1004     have_xfree_xinerama=false
1005     have_solaris_xinerama=false
1006
1007     gtk_save_cppflags="$CPPFLAGS"
1008     CPPFLAGS="$CPPFLAGS $x_cflags"
1009
1010     # Check for XFree
1011     AC_MSG_CHECKING(for Xinerama packages)
1012
1013     if $PKG_CONFIG --exists xinerama ; then
1014        AC_MSG_RESULT(yes)
1015        have_xfree_xinerama=true
1016        X_PACKAGES="$X_PACKAGES xinerama"
1017     else
1018        AC_MSG_RESULT(no)
1019        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1020            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1021            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1022            have_xfree_xinerama=true], :,
1023            [#include <X11/Xlib.h>])])
1024     fi
1025
1026     if $have_xfree_xinerama ; then
1027       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1028       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1029                 [Define to 1 if XFree Xinerama is available])
1030       AC_DEFINE(HAVE_XINERAMA, 1,
1031                 [Define to 1 is Xinerama is available])
1032     else
1033       case "$host" in
1034         *-*-solaris*)
1035             # Check for solaris
1036             AC_MSG_CHECKING(for Xinerama support on Solaris)
1037
1038             have_solaris_xinerama=false
1039             AC_CHECK_FUNC(XineramaGetInfo,
1040                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1041                     [have_solaris_xinerama=true], :,
1042                     [#include <X11/Xlib.h>])])
1043
1044             if $have_solaris_xinerama ; then
1045               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1046               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1047                         [Define to 1 if solaris xinerama is available])
1048               AC_DEFINE(HAVE_XINERAMA, 1,
1049                         [Define to 1 if xinerama is available])
1050               AC_MSG_RESULT(yes)
1051             else
1052               AC_MSG_RESULT(no)
1053             fi
1054             ;;
1055         *)
1056             ;;
1057       esac
1058     fi
1059   fi
1060   if test "x$enable_xinerama" = "xyes" ; then
1061     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1062       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1063     fi
1064   fi
1065
1066   # set up things for XInput
1067   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1068     have_xinput=yes
1069
1070     AC_DEFINE(XINPUT_XFREE, 1,
1071               [Define to 1 if XFree XInput should be used])
1072
1073     X_PACKAGES="$X_PACKAGES xi"
1074
1075     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1076                     have_xinput2=yes
1077                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1078                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1079                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1080
1081   else
1082     AC_DEFINE(XINPUT_NONE, 1,
1083               [Define to 1 if no XInput should be used])
1084   fi
1085
1086   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1087   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1088
1089   if test "x$enable_xinput" = "xyes" ; then
1090     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1091       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1092     fi
1093   fi
1094
1095   # Check for the RANDR extension
1096   if test x"$enable_xrandr" != xno; then
1097     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1098       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1099
1100       X_PACKAGES="$X_PACKAGES xrandr"
1101       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1102     elif test x"$enable_xrandr" = xyes; then
1103       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1104     fi
1105   fi
1106
1107   # Checks for Xcursor library
1108
1109   if $PKG_CONFIG --exists xcursor ; then
1110     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1111
1112     X_PACKAGES="$X_PACKAGES xcursor"
1113   fi
1114
1115   # Checks for XFixes extension
1116
1117   if test x"$enable_xfixes" != xno; then
1118     if $PKG_CONFIG --exists xfixes ; then
1119       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1120
1121       X_PACKAGES="$X_PACKAGES xfixes"
1122       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1123       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1124     elif test x"$enable_xfixes" = xyes; then
1125       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1126     fi
1127   fi
1128
1129   # Checks for Xcomposite extension
1130
1131   if test x"$enable_xcomposite" != xno; then
1132     if $PKG_CONFIG --exists xcomposite ; then
1133       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1134
1135       X_PACKAGES="$X_PACKAGES xcomposite"
1136       X_EXTENSIONS="$X_EXTENSIONS Composite"
1137       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1138     elif test x"$enable_xcomposite" = xyes; then
1139       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1140     fi
1141   fi
1142
1143   # Checks for Xdamage extension
1144
1145   if test x"$enable_xdamage" != xno; then
1146     if $PKG_CONFIG --exists xdamage ; then
1147       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1148
1149       X_PACKAGES="$X_PACKAGES xdamage"
1150       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1151       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1152     elif test x"$enable_xdamage" = xyes; then
1153       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1154     fi
1155   fi
1156
1157   if $have_base_x_pc ; then
1158     GDK_EXTRA_LIBS="$x_extra_libs"
1159   else
1160     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1161   fi
1162
1163   CPPFLAGS="$gtk_save_cppflags"
1164   LIBS="$gtk_save_libs"
1165
1166   AM_CONDITIONAL(USE_X11, true)
1167
1168   # strip leading space
1169   X_EXTENSIONS=${X_EXTENSIONS/# }
1170
1171 else
1172   XPACKAGES=
1173
1174   AM_CONDITIONAL(XINPUT_XFREE, false)
1175   AM_CONDITIONAL(XINPUT_2, false)
1176   AM_CONDITIONAL(USE_X11, false)
1177   AM_CONDITIONAL(HAVE_X11R6, false)
1178 fi
1179
1180 # Check for Pango flags
1181
1182 AC_MSG_CHECKING(Pango flags)
1183 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1184         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1185         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1186
1187         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1188 else
1189         AC_MSG_ERROR([
1190 *** Pango not found. Pango built with Cairo support is required
1191 *** to build GTK+. See http://www.pango.org for Pango information.
1192 ])
1193 fi
1194
1195 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1196
1197 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1198         :
1199 else
1200         gtk_save_LIBS="$LIBS"
1201         LIBS="$PANGO_LIBS $LIBS"
1202         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1203 *** Can't link to Pango. Pango is required to build
1204 *** GTK+. For more information see http://www.pango.org]))
1205         LIBS="$gtk_save_LIBS"
1206 fi
1207
1208 CFLAGS="$saved_cflags"
1209 LDFLAGS="$saved_ldflags"
1210
1211 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1212
1213 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1214 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1215 #
1216 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1217 # into the pkg-config files
1218 #
1219 if test $enable_explicit_deps != yes ; then
1220   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1221   GDK_EXTRA_LIBS=
1222 fi
1223
1224 AC_SUBST(GDK_PACKAGES)
1225 AC_SUBST(GDK_EXTRA_LIBS)
1226 AC_SUBST(GDK_EXTRA_CFLAGS)
1227 AC_SUBST(GDK_DEP_LIBS)
1228 AC_SUBST(GDK_DEP_CFLAGS)
1229
1230
1231 ########################################
1232 # Check for Accessibility Toolkit flags
1233 ########################################
1234
1235 ATK_PACKAGES=atk
1236 AC_MSG_CHECKING(ATK flags)
1237 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1238         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1239         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1240
1241         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1242 else
1243         AC_MSG_ERROR([
1244 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1245 *** to build GTK+.
1246 ])
1247 fi
1248
1249 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1250         :
1251 else
1252         gtk_save_LIBS="$LIBS"
1253         LIBS="$ATK_LIBS $LIBS"
1254         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1255                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1256                 *** to build GTK+]))
1257         LIBS="$gtk_save_LIBS"
1258 fi
1259
1260 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1261 if test "x$enable_x11_backend" == xyes; then
1262   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1263 fi
1264 GTK_EXTRA_LIBS=
1265 GTK_EXTRA_CFLAGS=
1266 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1267 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1268
1269 if test x"$os_win32" = xyes; then
1270   GTK_EXTRA_CFLAGS="$msnative_struct"
1271 fi
1272
1273 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1274 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1275 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1276 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1277
1278 AC_SUBST(GTK_PACKAGES)
1279 AC_SUBST(GTK_EXTRA_LIBS)
1280 AC_SUBST(GTK_EXTRA_CFLAGS)
1281 AC_SUBST(GTK_DEP_LIBS)
1282 AC_SUBST(GTK_DEP_CFLAGS)
1283
1284 AC_SUBST(GLIB_PREFIX)
1285 AC_SUBST(ATK_PREFIX)
1286 AC_SUBST(PANGO_PREFIX)
1287 AC_SUBST(CAIRO_PREFIX)
1288
1289 AC_SUBST(GTK_DEBUG_FLAGS)
1290 AC_SUBST(GTK_XIM_FLAGS)
1291
1292 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1293 AC_SUBST(GDK_PIXBUF_LIBS)
1294
1295 ########################
1296 # Checks needed for gail
1297 ########################
1298
1299 old_LIBS="$LIBS"
1300 dnl Checks for inet libraries:
1301 AC_SEARCH_LIBS(gethostent, nsl)
1302 AC_SEARCH_LIBS(setsockopt, socket)
1303 AC_SEARCH_LIBS(connect, inet)
1304
1305 dnl check for the sockaddr_un.sun_len member
1306 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1307                 [struct_sockaddr_un_sun_len=true],
1308                 [struct_sockaddr_un_suin_len=false],
1309                 [#include <sys/types.h>
1310                  #include <sys/un.h>]
1311                 )
1312 case $struct_sockaddr_un_sun_len in
1313         true)
1314                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1315                                    [Have the sockaddr_un.sun_len member])
1316                 ;;
1317         *)
1318                 ;;
1319 esac
1320
1321 GAIL_INET_LIBS="$LIBS"
1322 AC_SUBST([GAIL_INET_LIBS])
1323
1324 LIBS="$old_LIBS"
1325
1326 ################################################################
1327 # Printing system checks
1328 ################################################################
1329
1330 PRINT_BACKENDS="file lpr"
1331
1332 AC_ARG_ENABLE(cups,
1333               [AS_HELP_STRING([--disable-cups],
1334                               [disable cups print backend])],,
1335               [enable_cups=auto])
1336
1337 if test "x$enable_cups" = "xno"; then
1338   AM_CONDITIONAL(HAVE_CUPS, false)
1339 else
1340   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1341   if test "x$CUPS_CONFIG" = "xno"; then
1342     if test "x$enable_cups" = "xauto"; then
1343       AM_CONDITIONAL(HAVE_CUPS, false)
1344     else
1345       AC_MSG_ERROR([
1346 *** cups not found.
1347 ])
1348     fi
1349   else
1350     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1351     CUPS_LIBS=`$CUPS_CONFIG --libs`
1352
1353     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1354     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1355     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1356
1357     if test $CUPS_API_MAJOR -gt 1 -o \
1358             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1359       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1360                 [Define to 1 if CUPS 1.2 API is available])
1361     fi
1362
1363     AC_SUBST(CUPS_API_MAJOR)
1364     AC_SUBST(CUPS_API_MINOR)
1365     AC_SUBST(CUPS_CFLAGS)
1366     AC_SUBST(CUPS_LIBS)
1367
1368     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1369
1370     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1371     AM_CONDITIONAL(HAVE_CUPS, true)
1372
1373     gtk_save_cflags="$CFLAGS"
1374     CFLAGS="$CUPS_CFLAGS"
1375     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1376                                        [[http_t http; char *s = http.authstring;]])],
1377                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1378                                  [Define if cups http_t authstring field is accessible])],
1379                       [])
1380     CFLAGS="$gtk_save_cflags"
1381
1382     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1383
1384     gtk_save_libs="$LIBS"
1385     LIBS="$CUPS_LIBS"
1386     AC_CHECK_FUNCS(httpGetAuthString)
1387     LIBS="$gtk_save_libs"
1388   fi
1389 fi
1390
1391 # Checks to see if we should compile with PAPI backend for GTK+
1392 #
1393
1394 AC_ARG_ENABLE(papi,
1395               [AS_HELP_STRING([--disable-papi],
1396                               [disable papi print backend])],,
1397               [enable_papi=auto])
1398
1399 if test "x$enable_papi" = "xno"; then
1400   AM_CONDITIONAL(HAVE_PAPI, false)
1401 else
1402   AC_MSG_CHECKING(libpapi)
1403   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1404   if test $have_papi = yes; then
1405     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1406     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1407   fi
1408   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1409   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1410     AC_MSG_ERROR([
1411 *** papi not found.
1412 ])
1413   fi
1414 fi
1415
1416 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1417
1418 gtk_save_cppflags="$CPPFLAGS"
1419 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1420
1421 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1422 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1423 *** backend enabled.]))
1424
1425 if test "$os_win32" != "yes"; then
1426   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1427 *** Can't find cairo-ps.h. You must build Cairo with the
1428 *** postscript backend enabled.]))
1429
1430   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1431 *** Cannot find cairo-svg.h. You must build Cairo with the
1432 *** svg backend enabled.]))
1433 fi
1434
1435 CPPFLAGS="$gtk_save_cppflags"
1436
1437
1438 AC_ARG_ENABLE(test-print-backend,
1439               [AS_HELP_STRING([--enable-test-print-backend],
1440                               [build test print backend])],,
1441               [enable_test_print_backend=no])
1442 if test "x$enable_test_print_backend" != "xno" ; then
1443   PRINT_BACKENDS="$PRINT_BACKENDS test"
1444 fi
1445 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1446
1447
1448 ################################################################
1449 # Strip -export-dynamic from the link lines of various libraries
1450 ################################################################
1451
1452 #
1453 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1454 #  but this flag is only meaningful for executables. For libraries
1455 #  the effect is undefined; what it causes on Linux is that the
1456 #  export list from -export-symbols-regex is ignored and everything
1457 #  is exported
1458 #
1459 # We are using gmodule-no-export now, but I'm leaving the stripping
1460 # code in place for now, since pango and atk still require gmodule.
1461 export SED
1462 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1463 if test -n "$export_dynamic"; then
1464   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1465   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1466 fi
1467
1468 #############
1469 # GSettings #
1470 #############
1471
1472 GLIB_GSETTINGS
1473
1474 ##################################################
1475 # GObject introspection
1476 ##################################################
1477
1478 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1479
1480 ##################################################
1481 # Packagekit module
1482 #################################################
1483
1484 AC_ARG_ENABLE(packagekit,
1485               [AS_HELP_STRING([--disable-packagekit],
1486                               [build packagekit open-with module])])
1487
1488 build_packagekit=no
1489 if test "os_win32" != "yes"; then
1490         if test "x$enable_packagekit" != "xno"; then
1491                 build_packagekit=yes
1492                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1493         fi
1494 fi
1495
1496 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1497
1498 ##################################################
1499 # Checks for gtk-doc and docbook-tools
1500 ##################################################
1501
1502 GTK_DOC_CHECK([1.11])
1503
1504 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1505 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1506
1507 AC_ARG_ENABLE(man,
1508               [AS_HELP_STRING([--enable-man],
1509                               [regenerate man pages from Docbook [default=no]])],
1510               [enable_man=yes],
1511               [enable_man=no])
1512
1513 if test "${enable_man}" != no; then
1514   dnl
1515   dnl Check for xsltproc
1516   dnl
1517   AC_PATH_PROG([XSLTPROC], [xsltproc])
1518   if test -z "$XSLTPROC"; then
1519     enable_man=no
1520   fi
1521
1522   dnl check for DocBook DTD and stylesheets in the local catalog.
1523   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1524      [DocBook XML DTD V4.1.2],,enable_man=no)
1525   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1526      [DocBook XSL Stylesheets],,enable_man=no)
1527 fi
1528
1529 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1530
1531
1532 ##################################################
1533 # Output commands
1534 ##################################################
1535
1536 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1537         outfile=gdkconfig.h-tmp
1538         cat > $outfile <<\_______EOF
1539 /* gdkconfig.h
1540  *
1541  * This is a generated file.  Please modify `configure.ac'
1542  */
1543
1544 #ifndef __GDKCONFIG_H__
1545 #define __GDKCONFIG_H__
1546
1547 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1548 #error "Only <gdk/gdk.h> can be included directly."
1549 #endif
1550
1551 #include <glib.h>
1552
1553 G_BEGIN_DECLS
1554
1555 _______EOF
1556
1557         cat >>$outfile <<_______EOF
1558 $gdk_windowing
1559 _______EOF
1560
1561         cat >>$outfile <<_______EOF
1562
1563 G_END_DECLS
1564
1565 #endif  /* __GDKCONFIG_H__ */
1566 _______EOF
1567
1568
1569         if cmp -s $outfile gdk/gdkconfig.h; then
1570           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1571           rm -f $outfile
1572         else
1573           mv $outfile gdk/gdkconfig.h
1574         fi
1575 ],[
1576 gdk_windowing='$GDK_WINDOWING'
1577 ])
1578
1579 dnl
1580 dnl Check for -Bsymbolic-functions linker flag used to avoid
1581 dnl intra-library PLT jumps, if available.
1582 dnl
1583 AC_ARG_ENABLE(Bsymbolic,
1584               [AS_HELP_STRING([--disable-Bsymbolic],
1585                               [avoid linking with -Bsymbolic])],,
1586               [SAVED_LDFLAGS="${LDFLAGS}"
1587                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1588                LDFLAGS=-Wl,-Bsymbolic-functions
1589                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1590                                                [[int main (void) { return 0; }]])],
1591                               [AC_MSG_RESULT(yes)
1592                                enable_Bsymbolic=yes],
1593                               [AC_MSG_RESULT(no)
1594                                enable_Bsymbolic=no])
1595                LDFLAGS="${SAVED_LDFLAGS}"])
1596
1597 if test "x${enable_Bsymbolic}" = "xyes" ; then
1598   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1599 fi
1600 AC_SUBST(GTK_LINK_FLAGS)
1601
1602 AC_CONFIG_FILES([
1603 config.h.win32
1604 gtk-zip.sh
1605 Makefile
1606 gdk-3.0.pc
1607 gtk+-3.0.pc
1608 gtk+-unix-print-3.0.pc
1609 gail-3.0.pc
1610 gtk+-3.0-uninstalled.pc
1611 gail-3.0-uninstalled.pc
1612 m4macros/Makefile
1613 po/Makefile.in
1614 po-properties/Makefile.in
1615 demos/Makefile
1616 demos/gtk-demo/Makefile
1617 demos/gtk-demo/geninclude.pl
1618 examples/Makefile
1619 tests/Makefile
1620 docs/Makefile
1621 docs/reference/Makefile
1622 docs/reference/gdk/Makefile
1623 docs/reference/gdk/version.xml
1624 docs/reference/gtk/Makefile
1625 docs/reference/gtk/version.xml
1626 docs/reference/libgail-util/Makefile
1627 docs/reference/libgail-util/version.xml
1628 docs/tools/Makefile
1629 build/Makefile
1630 build/win32/Makefile
1631 build/win32/vs9/Makefile
1632 gdk/Makefile
1633 gdk/x11/Makefile
1634 gdk/win32/Makefile
1635 gdk/win32/rc/Makefile
1636 gdk/win32/rc/gdk.rc
1637 gdk/quartz/Makefile
1638 gdk/tests/Makefile
1639 gtk/Makefile
1640 gtk/makefile.msc
1641 gtk/gtkversion.h
1642 gtk/gtk-win32.rc
1643 gtk/tests/Makefile
1644 modules/Makefile
1645 modules/other/Makefile
1646 modules/other/gail/Makefile
1647 modules/other/gail/libgail-util/Makefile
1648 modules/other/gail/tests/Makefile
1649 modules/engines/Makefile
1650 modules/engines/pixbuf/Makefile
1651 modules/engines/ms-windows/Makefile
1652 modules/engines/ms-windows/Theme/Makefile
1653 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1654 modules/input/Makefile
1655 modules/printbackends/Makefile
1656 modules/printbackends/cups/Makefile
1657 modules/printbackends/lpr/Makefile
1658 modules/printbackends/file/Makefile
1659 modules/printbackends/papi/Makefile
1660 modules/printbackends/test/Makefile
1661 perf/Makefile
1662 ])
1663
1664 AC_OUTPUT
1665
1666 # beautify the immodule list a bit
1667 included_immodules=${included_immodules//,/ }
1668 included_immodules=${included_immodules:-none}
1669
1670 echo ""
1671 echo "        GTK+ $GTK_VERSION"
1672 echo "        ==========="
1673 echo ""
1674 echo "        GDK backends:         $GDK_BACKENDS"
1675 if test "x$enable_x11_backend" = "xyes"; then
1676 echo "        X11 extensions:       $X_EXTENSIONS"
1677 fi
1678 echo "        Print backends:       $PRINT_BACKENDS"
1679 echo "        Dynamic modules:      $build_dynamic_modules"
1680 echo "        Included immodules:   $included_immodules"
1681 echo "        PackageKit support:   $build_packagekit"
1682 echo "        Introspection:        $found_introspection"
1683 echo "        Debugging:            $enable_debug"
1684 echo "        Documentation:        $enable_gtk_doc"