Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [0])
  13 m4_define([gtk_micro_version], [1])
  14 m4_define([gtk_interface_age], [1])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.28.0])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.30])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.22.0])
  46 m4_define([introspection_required_version], [0.10.1])
  47 GLIB_REQUIRED_VERSION=glib_required_version
  48 PANGO_REQUIRED_VERSION=pango_required_version
  49 ATK_REQUIRED_VERSION=atk_required_version
  50 CAIRO_REQUIRED_VERSION=cairo_required_version
  51 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  52 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  53
  54 AC_SUBST(GLIB_REQUIRED_VERSION)
  55 AC_SUBST(PANGO_REQUIRED_VERSION)
  56 AC_SUBST(ATK_REQUIRED_VERSION)
  57 AC_SUBST(CAIRO_REQUIRED_VERSION)
  58 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  59 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  60
  61 # Save this value here, since automake will set cflags later
  62 cflags_set=${CFLAGS+set}
  63
  64 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  65 AM_MAINTAINER_MODE([enable])
  66
  67 # Support silent build rules, requires at least automake-1.11. Disable
  68 # by either passing --disable-silent-rules to configure or passing V=1
  69 # to make
  70 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  71
  72 #
  73 # For each of the libraries we build, we define the following
  74 # substituted variables:
  75 #
  76 # foo_PACKAGES:     pkg-config packages this library requires
  77 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  78 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  79 # foo_DEP_LIBS:     All libraries this module requires
  80 # foo_DEP_CFLAGS:   All cflags this module requires
  81
  82
  83 GTK_MAJOR_VERSION=gtk_major_version
  84 GTK_MINOR_VERSION=gtk_minor_version
  85 GTK_MICRO_VERSION=gtk_micro_version
  86 GTK_INTERFACE_AGE=gtk_interface_age
  87 GTK_BINARY_AGE=gtk_binary_age
  88 GTK_VERSION=gtk_version
  89 GTK_API_VERSION=gtk_api_version
  90 GTK_BINARY_VERSION=gtk_binary_version
  91 AC_SUBST(GTK_MAJOR_VERSION)
  92 AC_SUBST(GTK_MINOR_VERSION)
  93 AC_SUBST(GTK_MICRO_VERSION)
  94 AC_SUBST(GTK_INTERFACE_AGE)
  95 AC_SUBST(GTK_BINARY_AGE)
  96 AC_SUBST(GTK_API_VERSION)
  97 AC_SUBST(GTK_VERSION)
  98 AC_SUBST(GTK_BINARY_VERSION)
  99
 100 # libtool versioning
 101 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 102 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 103 #LT_REVISION=$GTK_INTERFACE_AGE
 104 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 105 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 106
 107 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 108 m4_define([lt_revision], [gtk_interface_age])
 109 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 110 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 111 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 112 AC_SUBST(LT_VERSION_INFO)
 113 AC_SUBST(LT_CURRENT_MINUS_AGE)
 114
 115 m4_define([gail_lt_current],[0])
 116 m4_define([gail_lt_revision],[0])
 117 m4_define([gail_lt_age],[0])
 118 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 119 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 120 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 121 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 122
 123 # Checks for programs.
 124 AC_PROG_CC
 125 AC_PROG_CC_C_O
 126 AC_PROG_CC_STDC
 127 AC_PROG_INSTALL
 128 AC_PROG_MAKE_SET
 129
 130
 131 GETTEXT_PACKAGE=gtk30
 132 AC_SUBST(GETTEXT_PACKAGE)
 133 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 134                    [The prefix for our gettext translation domains.])
 135
 136 AC_CANONICAL_HOST
 137
 138 MATH_LIB=-lm
 139 AC_MSG_CHECKING([for native Win32])
 140 LIB_EXE_MACHINE_FLAG=X86
 141 EXE_MANIFEST_ARCHITECTURE=X86
 142 case "$host" in
 143   *-*-mingw*)
 144     os_win32=yes
 145     gio_can_sniff=no
 146     MATH_LIB=
 147     case "$host" in
 148     x86_64-*-*)
 149       LIB_EXE_MACHINE_FLAG=X64
 150       EXE_MANIFEST_ARCHITECTURE=AMD64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     os_win32=no
 156     ;;
 157 esac
 158 AC_MSG_RESULT([$os_win32])
 159
 160 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 161 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 162
 163 case $host in
 164   *-*-linux*)
 165     os_linux=yes
 166     ;;
 167 esac
 168
 169 dnl
 170 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 171 dnl We use this for an automated test for C++ header correctness.
 172 dnl
 173 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 174 AC_LANG_PUSH([C++])
 175
 176 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 177                                    [[class a { int b; } c;]])],
 178                   [],[CXX=])
 179 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 180
 181 gtk_save_cxxflags="$CXXFLAGS"
 182 CXXFLAGS="$CXXFLAGS -x objective-c++"
 183 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 184                                    [[]])],
 185                   [OBJC=yes],[OBJC=no])
 186 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 187 CXXFLAGS="$gtk_save_cxxflags"
 188 AC_LANG_POP([C++])
 189
 190 if test "$os_win32" = "yes"; then
 191   if test x$enable_static = xyes -o x$enable_static = x; then
 192     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 193     enable_static=no
 194   fi
 195   if test x$enable_shared = xno; then
 196     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 197   fi
 198   enable_shared=yes
 199 fi
 200
 201 dnl Initialize libtool
 202 LT_PREREQ([2.2.6])
 203 LT_INIT([disable-static win32-dll])
 204 # Create libtool early, because it's used in configure
 205 LT_OUTPUT
 206
 207 # Make sure we use 64-bit versions of various file stuff.
 208 AC_SYS_LARGEFILE
 209
 210 AM_PROG_AS
 211 AC_PATH_PROG(NM, nm, nm)
 212
 213 AC_MSG_CHECKING([for some Win32 platform])
 214 case "$host" in
 215   *-*-mingw*|*-*-cygwin*)
 216     platform_win32=yes
 217     ;;
 218   *)
 219     platform_win32=no
 220     ;;
 221 esac
 222 AC_MSG_RESULT([$platform_win32])
 223 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 224
 225 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 226 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 227 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 228
 229 if test "$os_win32" = "yes"; then
 230   AC_CHECK_TOOL(WINDRES, windres, no)
 231   if test "$WINDRES" = no; then
 232     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 233   fi
 234   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 235 fi
 236 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 237
 238 m4_define([debug_default],
 239           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 240
 241 dnl declare --enable-* args and collect ac_help strings
 242 AC_ARG_ENABLE(debug,
 243               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 244                               [turn on debugging @<:@default=debug_default@:>@])],,
 245               [enable_debug=debug_default])
 246
 247 AC_ARG_ENABLE(rebuilds,
 248               [AS_HELP_STRING([--disable-rebuilds],
 249                               [disable all source autogeneration rules])],,
 250               [enable_rebuilds=yes])
 251
 252 AC_ARG_ENABLE(gtk2-dependency,
 253               [AS_HELP_STRING([--enable-gtk2-dependency],
 254                               [Do not build gtk-update-icon-cache and other shared tools])],,
 255               [enable_gtk2_dependency=no])
 256
 257 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 258
 259 AC_ARG_ENABLE(xkb,
 260               [AS_HELP_STRING([--enable-xkb],
 261                               [support XKB extension [default=maybe]])],,
 262               [enable_xkb="maybe"])
 263 AC_ARG_ENABLE(xinerama,
 264               [AS_HELP_STRING([--enable-xinerama],
 265                               [support Xinerama extension if available [default=maybe]])],,
 266               [enable_xinerama="maybe"])
 267 AC_ARG_ENABLE(xinput,
 268               [AS_HELP_STRING([--enable-xinput],
 269                               [support XInput extension if available [default=yes]])],,
 270               [enable_xinput="maybe"])
 271 AC_ARG_ENABLE(xrandr,
 272               [AS_HELP_STRING([--enable-xrandr],
 273                               [support XRandR extension if available [default=maybe]])],,
 274               [enable_xrandr="maybe"])
 275 AC_ARG_ENABLE(xfixes,
 276               [AS_HELP_STRING([--enable-xfixes],
 277                               [support XFixes extension if available [default=maybe]])],,
 278               [enable_xfixes="maybe"])
 279 AC_ARG_ENABLE(xcomposite,
 280               [AS_HELP_STRING([--enable-xcomposite],
 281                               [support X Composite extension if available [default=maybe]])],,
 282               [enable_xcomposite="maybe"])
 283 AC_ARG_ENABLE(xdamage,
 284               [AS_HELP_STRING([--enable-xdamage],
 285                               [support X Damage extension if available [default=maybe]])],,
 286               [enable_xdamage="maybe"])
 287
 288 AC_ARG_ENABLE(x11-backend,
 289               [AS_HELP_STRING([--enable-x11-backend],
 290                               [enable the X11 gdk backend])],
 291                               [backend_set=yes])
 292 AC_ARG_ENABLE(win32-backend,
 293               [AS_HELP_STRING([--enable-win32-backend],
 294                               [enable the Win32 gdk backend])],
 295                               [backend_set=yes])
 296 AC_ARG_ENABLE(quartz-backend,
 297               [AS_HELP_STRING([--enable-quartz-backend],
 298                               [enable the quartz gdk backend])],
 299                               [backend_set=yes])
 300 AC_ARG_ENABLE(broadway-backend,
 301               [AC_HELP_STRING([--enable-broadway-backend],
 302                               [enable the broadway (HTML5) gdk backend])],
 303                               [backend_set=yes])
 304
 305 if test -z "$backend_set"; then
 306   if test "$platform_win32" = yes; then
 307     enable_win32_backend=yes
 308   else
 309     enable_x11_backend=yes
 310   fi
 311 fi
 312
 313 cairo_backends=
 314 backend_immodules=
 315 GDK_BACKENDS=
 316 GDK_EXTRA_LIBS=
 317 GDK_EXTRA_CFLAGS=
 318 GDK_WINDOWING=
 319 GIO_PACKAGE=gio-2.0
 320 PANGO_PACKAGES="pango pangocairo"
 321
 322 if test "x$enable_x11_backend" == xyes; then
 323   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 324   # backend names are identical.
 325   cairo_backends="$cairo_backends cairo-xlib"
 326   GDK_BACKENDS="$GDK_BACKENDS x11"
 327   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 328   # gdkapplaunchcontext-x11.c
 329   GIO_PACKAGE=gio-unix-2.0
 330   backend_immodules="$backend_immodules,xim"
 331   GDK_WINDOWING="$GDK_WINDOWING
 332 #define GDK_WINDOWING_X11"
 333 fi
 334
 335 if test "x$enable_win32_backend" == xyes; then
 336   cairo_backends="$cairo_backends cairo-win32"
 337   GDK_BACKENDS="$GDK_BACKENDS win32"
 338   backend_immodules="$backend_immodules,ime"
 339   GDK_WINDOWING="$GDK_WINDOWING
 340 #define GDK_WINDOWING_WIN32"
 341   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 342   AM_CONDITIONAL(USE_WIN32, true)
 343   PANGO_PACKAGES="pangowin32 pangocairo"
 344 else
 345   AM_CONDITIONAL(USE_WIN32, false)
 346 fi
 347
 348 if test "x$enable_quartz_backend" == xyes; then
 349   cairo_backends="$cairo_backends cairo-quartz"
 350   GDK_BACKENDS="$GDK_BACKENDS quartz"
 351   GDK_WINDOWING="$GDK_WINDOWING
 352 #define GDK_WINDOWING_QUARTZ"
 353   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 354   AM_CONDITIONAL(USE_QUARTZ, true)
 355 else
 356   AM_CONDITIONAL(USE_QUARTZ, false)
 357 fi
 358
 359 if test "x$enable_broadway_backend" == xyes; then
 360   GDK_BACKENDS="$GDK_BACKENDS broadway"
 361   cairo_backends="$cairo_backends cairo"
 362   GDK_WINDOWING="$GDK_WINDOWING
 363 #define GDK_WINDOWING_BROADWAY"
 364   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 365   AM_CONDITIONAL(USE_BROADWAY, true)
 366 else
 367   AM_CONDITIONAL(USE_BROADWAY, false)
 368 fi
 369
 370 # strip leading space
 371 GDK_BACKENDS=${GDK_BACKENDS/# }
 372
 373 AC_SUBST(GDK_BACKENDS)
 374
 375 if test -z "$GDK_BACKENDS"; then
 376   AC_MSG_ERROR([No GDK backends selected.])
 377 fi
 378
 379 if test "x$enable_debug" = "xyes"; then
 380   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 381   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 382 else
 383   if test "x$enable_debug" = "xno"; then
 384     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 385   else
 386     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 387   fi
 388 fi
 389
 390
 391 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 392                    [Define if debugging is enabled])
 393
 394
 395 # Build time sanity check...
 396 AM_SANITY_CHECK
 397
 398 changequote(,)dnl
 399 if test "x$GCC" = "xyes"; then
 400   case " $CFLAGS " in
 401   *[\ \ ]-Wall[\ \      ]*) ;;
 402   *) CFLAGS="$CFLAGS -Wall" ;;
 403   esac
 404
 405   if test "x$enable_ansi" = "xyes"; then
 406     case " $CFLAGS " in
 407     *[\ \       ]-ansi[\ \      ]*) ;;
 408     *) CFLAGS="$CFLAGS -ansi" ;;
 409     esac
 410
 411     case " $CFLAGS " in
 412     *[\ \       ]-pedantic[\ \  ]*) ;;
 413     *) CFLAGS="$CFLAGS -pedantic" ;;
 414     esac
 415   fi
 416 fi
 417 changequote([,])dnl
 418
 419 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 420
 421 # Ensure MSVC-compatible struct packing convention is used when
 422 # compiling for Win32 with gcc.
 423 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 424 # gcc2 uses "-fnative-struct".
 425 if test x"$os_win32" = xyes; then
 426   if test x"$GCC" = xyes; then
 427     msnative_struct=''
 428     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 429     if test -z "$ac_cv_prog_CC"; then
 430       our_gcc="$CC"
 431     else
 432       our_gcc="$ac_cv_prog_CC"
 433     fi
 434     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 435       2.)
 436         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 437           msnative_struct='-fnative-struct'
 438         fi
 439         ;;
 440       *)
 441         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 442           msnative_struct='-mms-bitfields'
 443         fi
 444         ;;
 445     esac
 446     if test x"$msnative_struct" = x ; then
 447       AC_MSG_RESULT([no way])
 448       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 449     else
 450       CFLAGS="$CFLAGS $msnative_struct"
 451       AC_MSG_RESULT([${msnative_struct}])
 452     fi
 453   fi
 454 fi
 455
 456 ## Initial sanity check, done here so that users get told they
 457 ## have the wrong dependencies as early in the process as possible.
 458 ## Later on we actually use the cflags/libs from separate pkg-config
 459 ## calls. Oh, also the later pkg-config calls don't include
 460 ## the version requirements since those make the module lists
 461 ## annoying to construct
 462 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 463   [glib-2.0 >= glib_required_version dnl
 464    atk >= atk_required_version dnl
 465    pango >= pango_required_version dnl
 466    cairo >= cairo_required_version dnl
 467    cairo-gobject >= cairo_required_version dnl
 468    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 469
 470 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 471
 472 if test "$os_win32" != yes; then
 473     # libtool option to control which symbols are exported
 474     # right now, symbols starting with _ are not exported
 475     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 476 else
 477     # We currently use .def files on Windows (for gdk and gtk)
 478     LIBTOOL_EXPORT_OPTIONS=
 479 fi
 480 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 481
 482 dnl ******************************************************
 483 dnl * See whether to include shared library dependencies *
 484 dnl ******************************************************
 485
 486 AC_ARG_ENABLE(explicit-deps,
 487               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 488                               [use explicit dependencies in .pc files [default=auto]])],,
 489               [enable_explicit_deps=auto])
 490
 491 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 492 case $enable_explicit_deps in
 493   auto)
 494     export SED
 495     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 496     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 497       enable_explicit_deps=yes
 498     else
 499       enable_explicit_deps=no
 500     fi
 501   ;;
 502   yes|no)
 503   ;;
 504   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 505   ;;
 506 esac
 507 AC_MSG_RESULT($enable_explicit_deps)
 508
 509 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 510
 511 # define a MAINT-like variable REBUILD which is set if Perl
 512 # and awk are found, so autogenerated sources can be rebuilt
 513
 514 AC_PATH_PROGS(PERL, perl5 perl)
 515
 516 # We would like indent, but don't require it.
 517 AC_CHECK_PROG(INDENT, indent, indent)
 518
 519 REBUILD=\#
 520 if test "x$enable_rebuilds" = "xyes" && \
 521      test -n "$PERL" && \
 522      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 523   REBUILD=
 524 fi
 525 AC_SUBST(REBUILD)
 526
 527 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 528 AC_CHECK_FUNCS(localtime_r)
 529
 530 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 531 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 532 AC_TRY_LINK([#include <langinfo.h>], [
 533 char c;
 534 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 535 ], gtk_ok=yes, gtk_ok=no)
 536 AC_MSG_RESULT($gtk_ok)
 537 if test "$gtk_ok" = "yes"; then
 538   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 539             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 540 fi
 541
 542 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 543 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 544 AC_TRY_LINK([#include <langinfo.h>], [
 545 char c;
 546 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 547 ], gtk_ok=yes, gtk_ok=no)
 548 AC_MSG_RESULT($gtk_ok)
 549 if test "$gtk_ok" = "yes"; then
 550   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 551             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 552 fi
 553
 554 # _NL_PAPER_HEIGHT is an enum and not a define
 555 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 556 AC_TRY_LINK([#include <langinfo.h>], [
 557 char c;
 558 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 559 ], gtk_ok=yes, gtk_ok=no)
 560 AC_MSG_RESULT($gtk_ok)
 561 if test "$gtk_ok" = "yes"; then
 562   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 563             [Define if _NL_PAPER_HEIGHT is available])
 564 fi
 565
 566 # _NL_PAPER_WIDTH is an enum and not a define
 567 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 568 AC_TRY_LINK([#include <langinfo.h>], [
 569 char c;
 570 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 571 ], gtk_ok=yes, gtk_ok=no)
 572 AC_MSG_RESULT($gtk_ok)
 573 if test "$gtk_ok" = "yes"; then
 574   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 575             [Define if _NL_PAPER_WIDTH is available])
 576 fi
 577
 578 # i18n stuff
 579 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 580 AM_GLIB_GNU_GETTEXT
 581 LIBS="$LIBS $INTLLIBS"
 582 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 583         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 584       esac])
 585
 586 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 587 dnl po-properties/POTFILES during configure; see GNOME #573515.
 588 dnl
 589 dnl Generate list of files to be processed by xgettext which will
 590 dnl be included in po-properties/Makefile.
 591 test -d po-properties || mkdir po-properties
 592 if test "x$srcdir" != "x."; then
 593   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 594     popropsrcprefix="$srcdir/"
 595   else
 596     popropsrcprefix="../$srcdir/"
 597   fi
 598 else
 599   popropsrcprefix="../"
 600 fi
 601 rm -f po-properties/POTFILES
 602 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 603 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 604 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 605
 606 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 607
 608 dnl The DU4 header files don't provide library prototypes unless
 609 dnl -std1 is given to the native cc.
 610 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 611
 612 gtk_save_LIBS=$LIBS
 613 LIBS="$LIBS -lm"
 614 AC_TRY_RUN([#include <math.h>
 615              int main (void) { return (log(1) != log(1.)); }],
 616      AC_MSG_RESULT(none needed),
 617      gtk_save_CFLAGS="$CFLAGS"
 618      CFLAGS="$CFLAGS -std1"
 619      AC_TRY_RUN([#include <math.h>
 620                  int main (void) { return (log(1) != log(1.)); }],
 621          AC_MSG_RESULT(-std1),
 622          AC_MSG_RESULT()
 623          CFLAGS="$gtk_save_CFLAGS"
 624          AC_MSG_WARN(
 625                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 626          true
 627      ),
 628      AC_MSG_RESULT(none needed)
 629 )
 630 LIBS=$gtk_save_LIBS
 631
 632 AC_MSG_CHECKING(for the BeOS)
 633 case $host in
 634   *-*-beos*)
 635     AC_MSG_RESULT(yes)
 636     MATH_LIB=
 637   ;;
 638   *)
 639     AC_MSG_RESULT(no)
 640   ;;
 641 esac
 642
 643 AC_SUBST(MATH_LIB)
 644 #
 645 # see bug 162979
 646 #
 647 AC_MSG_CHECKING(for HP-UX)
 648 case $host_os in
 649   hpux9* | hpux10* | hpux11*)
 650     AC_MSG_RESULT(yes)
 651     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 652   ;;
 653   *)
 654     AC_MSG_RESULT(no)
 655   ;;
 656 esac
 657
 658 #
 659 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 660 #
 661
 662 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 663
 664 AM_PATH_GLIB_2_0(glib_required_version, :,
 665   AC_MSG_ERROR([
 666 *** GLIB glib_required_version or better is required. The latest version of
 667 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 668   gobject gmodule-no-export gthread)
 669
 670 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 671 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 672 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 673 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 674   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 675 fi
 676
 677 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 678
 679
 680 dnl
 681 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 682 dnl
 683 gtk_save_LIBS=$LIBS
 684 LIBS="$LIBS $GLIB_LIBS"
 685 AC_CHECK_FUNCS(bind_textdomain_codeset)
 686 LIBS=$gtk_save_LIBS
 687
 688 AC_CHECK_HEADERS(pwd.h,
 689                  AC_DEFINE(HAVE_PWD_H, 1,
 690                            [Define to 1 if pwd.h is available]))
 691 AC_CHECK_HEADERS(sys/time.h,
 692                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 693                            [Define to 1 if time.h is available]))
 694 AC_CHECK_HEADERS(unistd.h,
 695                  AC_DEFINE(HAVE_UNISTD_H, 1,
 696                            [Define to 1 if unistd.h is available]))
 697 AC_CHECK_HEADERS(ftw.h,
 698                  AC_DEFINE(HAVE_FTW_H, 1,
 699                            [Define to 1 if ftw.h is available]))
 700
 701 AC_MSG_CHECKING([for GNU ftw extensions])
 702 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 703                                      #define _GNU_SOURCE
 704                                      #include <ftw.h>]],
 705                                    [[int flags = FTW_ACTIONRETVAL;]])],
 706                   [gtk_ok=yes],[gtk_ok=no])
 707 if test $gtk_ok = yes; then
 708     AC_MSG_RESULT([yes])
 709     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 710 else
 711     AC_MSG_RESULT([no])
 712 fi
 713
 714 saved_cflags="$CFLAGS"
 715 saved_ldflags="$LDFLAGS"
 716
 717
 718 # Checks for library functions.
 719 AC_FUNC_MMAP
 720
 721 AC_CHECK_FUNCS(mallinfo)
 722 AC_CHECK_FUNCS(getresuid)
 723 AC_TYPE_UID_T
 724
 725 # Check if <sys/select.h> needs to be included for fd_set
 726 AC_MSG_CHECKING([for fd_set])
 727 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 728                                    [[fd_set readMask, writeMask;]])],
 729                   [gtk_ok=yes],[gtk_ok=no])
 730 if test $gtk_ok = yes; then
 731     AC_MSG_RESULT([yes, found in sys/types.h])
 732 else
 733     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 734     if test $gtk_ok = yes; then
 735         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 736                   [Define to 1 if sys/select.h is available])
 737         AC_MSG_RESULT([yes, found in sys/select.h])
 738     else
 739         AC_DEFINE(NO_FD_SET, 1,
 740                   [Define to 1 if fd_set is not available])
 741         AC_MSG_RESULT(no)
 742     fi
 743 fi
 744
 745 # Check for uxtheme.h (for MS-Windows Engine)
 746 AC_MSG_CHECKING(for uxtheme.h)
 747 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 748 if test $gtk_uxtheme_h = yes; then
 749    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 750 fi
 751 AC_MSG_RESULT($gtk_uxtheme_h)
 752
 753 # Checks for gdkspawn
 754 AC_CHECK_HEADERS(crt_externs.h)
 755 AC_CHECK_FUNCS(_NSGetEnviron)
 756
 757 AC_MSG_CHECKING(whether to build dynamic modules)
 758
 759 AC_ARG_ENABLE(modules,
 760               [AS_HELP_STRING([--disable-modules],
 761                               [disable dynamic module loading])])
 762
 763 dynworks=false
 764 build_dynamic_modules=no
 765 deps=
 766 if test x$enable_modules = xno; then
 767     AC_MSG_RESULT(no)
 768 else
 769     AC_MSG_RESULT(yes)
 770     AC_MSG_CHECKING(whether dynamic modules work)
 771     ## for loop is to strip newline
 772     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 773     for I in $tmp; do
 774         dynworks=$I
 775     done
 776
 777     dnl Now we check to see if our libtool supports shared lib deps
 778     dnl (in a rather ugly way even)
 779     if $dynworks; then
 780         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 781         module_deplibs_check=`$module_libtool_config | \
 782             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 783             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 784         if test "x$module_deplibs_check" = "xnone" || \
 785            test "x$module_deplibs_check" = "xunknown" || \
 786            test "x$module_deplibs_check" = "x"; then
 787             dynworks=false
 788         fi
 789     fi
 790
 791     if $dynworks; then
 792         build_dynamic_modules=yes
 793         AC_DEFINE(USE_GMODULE, 1,
 794                   [Define to 1 if gmodule works and should be used])
 795         AC_MSG_RESULT(yes)
 796     else
 797         build_dynamic_modules=no
 798         AC_MSG_RESULT(no)
 799     fi
 800 fi
 801
 802 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 803
 804 #
 805 # Allow building some or all immodules included
 806 #
 807 AC_MSG_CHECKING(immodules to build)
 808
 809 AC_ARG_WITH(included_immodules,
 810             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 811                             [build the specified input methods into gtk])])
 812
 813 if $dynworks; then
 814    :
 815 else
 816    ## if the option was specified, leave it; otherwise disable included immodules
 817    if test x$with_included_immodules = xno; then
 818            with_included_immodules=yes
 819    fi
 820 fi
 821
 822 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 823
 824 included_immodules=""
 825 # If the switch specified without listing any specific ones, include all
 826 if test "x$with_included_immodules" = xyes ; then
 827   included_immodules="$all_immodules"
 828 else
 829   included_immodules="$with_included_immodules"
 830 fi
 831
 832 AC_MSG_RESULT($included_immodules)
 833 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 834
 835 INCLUDED_IMMODULE_OBJ=
 836 INCLUDED_IMMODULE_DEFINE=
 837
 838 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 839 for immodule in $included_immodules; do
 840  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 841  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 842    :
 843  else
 844    AC_MSG_ERROR([the specified input method $immodule does not exist])
 845  fi
 846
 847  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 848  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 849  eval INCLUDE_$immodule_underscores=yes
 850 done
 851 IFS="$gtk_save_ifs"
 852 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 853 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 854
 855 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 856 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 857 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 858 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 859 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 860 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 861 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 862 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 863 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 864 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 865 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 866 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 867
 868 # Checks to see whether we should include mediaLib
 869 # support.
 870 #
 871 AC_CHECK_HEADER(sys/systeminfo.h,
 872                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 873                           [Define to 1 if sys/systeminfo.h is available]))
 874 AC_CHECK_HEADER(sys/sysinfo.h,
 875                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 876                           [Define to 1 if sys/sysinfo.h is available]))
 877
 878 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 879
 880 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 881
 882 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 883   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 884   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 885     REBUILD_PNGS=#
 886   fi
 887 fi
 888
 889 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 890
 891 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 892
 893 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 894    test "x$REBUILD_PNGS" = "x#" ; then
 895      AC_MSG_ERROR([
 896 *** gtkbuiltincache.h is not in the tree, and cannot be built
 897 *** because you don't have libpng, or (when cross-compiling) you
 898 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 899 fi
 900
 901 ########################################
 902 # Windowing system checks
 903 ########################################
 904
 905 # GTK+ uses some X calls, so needs to link against X directly
 906 GTK_DEP_PACKAGES_FOR_X=
 907 GTK_DEP_LIBS_FOR_X=
 908 X_EXTENSIONS=
 909
 910 if test "x$enable_x11_backend" == xyes; then
 911   X_PACKAGES=fontconfig
 912
 913   #
 914   # We use fontconfig very peripherally when decoding the default
 915   # settings.
 916   #
 917   if $PKG_CONFIG --exists fontconfig; then : ; else
 918     AC_MSG_ERROR([
 919 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 920   fi
 921
 922   #
 923   # Check for basic X packages; we use pkg-config if available
 924   #
 925   if $PKG_CONFIG --exists x11 xext; then
 926     have_base_x_pc=true
 927     X_PACKAGES="$X_PACKAGES x11 xext"
 928     x_libs="`$PKG_CONFIG --libs x11 xext`"
 929     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 930
 931     # Strip out any .la files that pkg-config might give us (this happens
 932     # with -uninstalled.pc files)
 933     x_libs_for_checks=
 934     for I in $x_libs ; do
 935       case $I in
 936         *.la) ;;
 937         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 938       esac
 939     done
 940
 941     GTK_PACKAGES_FOR_X="x11"
 942   else
 943     have_base_x_pc=false
 944     AC_PATH_XTRA
 945     if test x$no_x = xyes ; then
 946       AC_MSG_ERROR([X development libraries not found])
 947     fi
 948
 949     x_cflags="$X_CFLAGS"
 950     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 951
 952     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 953   fi
 954
 955   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 956   x_extra_libs=
 957
 958   gtk_save_cppflags="$CPPFLAGS"
 959   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 960
 961   gtk_save_LIBS=$LIBS
 962   LIBS="$x_libs_for_checks $LIBS"
 963
 964   # Sanity check for the X11 and Xext libraries. While everything we need from
 965   # Xext is optional, the chances a system has *none* of these things is so
 966   # small that we just unconditionally require it.
 967   AC_CHECK_FUNC(XOpenDisplay, :,
 968                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 969   AC_CHECK_FUNC(XextFindDisplay, :,
 970                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 971
 972   # Check for xReply
 973
 974   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 975   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 976                                      [[xReply *rep;]])],
 977                     [AC_MSG_RESULT([no])],
 978                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 979                                                           #include <X11/Xlibint.h>]],
 980                                                         [[xReply *rep;]])],
 981                                        [AC_MSG_RESULT([yes])
 982                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 983                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 984                                        [AC_MSG_RESULT([unknown])
 985                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 986
 987   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 988
 989   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 990
 991   # Generic X11R6 check needed for XIM support; we could
 992   # probably use this to replace the above, but we'll
 993   # leave the separate checks for XConvertCase and XInternAtoms
 994   # for clarity
 995
 996   have_x11r6=false
 997   AC_CHECK_FUNC(XAddConnectionWatch,
 998       have_x11r6=true)
 999
1000   if $have_x11r6; then
1001     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1002   fi
1003   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1004
1005   # Check for XKB support.
1006
1007   if test "x$enable_xkb" = "xyes"; then
1008         AC_CHECK_FUNC(XkbQueryExtension,
1009                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1010                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1011                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1012   elif test "x$enable_xkb" = "xmaybe"; then
1013         AC_CHECK_FUNC(XkbQueryExtension,
1014                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1015                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1016   else
1017         AC_MSG_WARN(XKB support explicitly disabled)
1018   fi
1019
1020   # Check for shaped window extension
1021
1022   AC_CHECK_FUNC(XShapeCombineMask, :,
1023      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1024
1025   # X SYNC check
1026   gtk_save_CFLAGS="$CFLAGS"
1027   CFLAGS="$CFLAGS $x_cflags"
1028
1029   AC_CHECK_FUNC(XSyncQueryExtension,
1030       [AC_CHECK_HEADER(X11/extensions/sync.h,
1031           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1032           :, [#include <X11/Xlib.h>])])
1033
1034   CFLAGS="$gtk_save_CFLAGS"
1035
1036   if test "x$enable_xinerama" != "xno"; then
1037     # Check for Xinerama extension (Solaris impl or Xfree impl)
1038     have_xfree_xinerama=false
1039     have_solaris_xinerama=false
1040
1041     gtk_save_cppflags="$CPPFLAGS"
1042     CPPFLAGS="$CPPFLAGS $x_cflags"
1043
1044     # Check for XFree
1045     AC_MSG_CHECKING(for Xinerama packages)
1046
1047     if $PKG_CONFIG --exists xinerama ; then
1048        AC_MSG_RESULT(yes)
1049        have_xfree_xinerama=true
1050        X_PACKAGES="$X_PACKAGES xinerama"
1051     else
1052        AC_MSG_RESULT(no)
1053        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1054            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1055            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1056            have_xfree_xinerama=true], :,
1057            [#include <X11/Xlib.h>])])
1058     fi
1059
1060     if $have_xfree_xinerama ; then
1061       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1062       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1063                 [Define to 1 if XFree Xinerama is available])
1064       AC_DEFINE(HAVE_XINERAMA, 1,
1065                 [Define to 1 is Xinerama is available])
1066     else
1067       case "$host" in
1068         *-*-solaris*)
1069             # Check for solaris
1070             AC_MSG_CHECKING(for Xinerama support on Solaris)
1071
1072             have_solaris_xinerama=false
1073             AC_CHECK_FUNC(XineramaGetInfo,
1074                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1075                     [have_solaris_xinerama=true], :,
1076                     [#include <X11/Xlib.h>])])
1077
1078             if $have_solaris_xinerama ; then
1079               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1080               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1081                         [Define to 1 if solaris xinerama is available])
1082               AC_DEFINE(HAVE_XINERAMA, 1,
1083                         [Define to 1 if xinerama is available])
1084               AC_MSG_RESULT(yes)
1085             else
1086               AC_MSG_RESULT(no)
1087             fi
1088             ;;
1089         *)
1090             ;;
1091       esac
1092     fi
1093   fi
1094   if test "x$enable_xinerama" = "xyes" ; then
1095     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1096       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1097     fi
1098   fi
1099
1100   # set up things for XInput
1101   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1102     have_xinput=yes
1103
1104     AC_DEFINE(XINPUT_XFREE, 1,
1105               [Define to 1 if XFree XInput should be used])
1106
1107     X_PACKAGES="$X_PACKAGES xi"
1108
1109     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1110                     have_xinput2=yes
1111                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1112                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1113                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1114
1115   else
1116     AC_DEFINE(XINPUT_NONE, 1,
1117               [Define to 1 if no XInput should be used])
1118   fi
1119
1120   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1121   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1122
1123   if test "x$enable_xinput" = "xyes" ; then
1124     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1125       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1126     fi
1127   fi
1128
1129   # Check for the RANDR extension
1130   if test x"$enable_xrandr" != xno; then
1131     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1132       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1133
1134       X_PACKAGES="$X_PACKAGES xrandr"
1135       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1136     elif test x"$enable_xrandr" = xyes; then
1137       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1138     fi
1139   fi
1140
1141   # Checks for Xcursor library
1142
1143   if $PKG_CONFIG --exists xcursor ; then
1144     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1145
1146     X_PACKAGES="$X_PACKAGES xcursor"
1147   fi
1148
1149   # Checks for XFixes extension
1150
1151   if test x"$enable_xfixes" != xno; then
1152     if $PKG_CONFIG --exists xfixes ; then
1153       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1154
1155       X_PACKAGES="$X_PACKAGES xfixes"
1156       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1157       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1158     elif test x"$enable_xfixes" = xyes; then
1159       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1160     fi
1161   fi
1162
1163   # Checks for Xcomposite extension
1164
1165   if test x"$enable_xcomposite" != xno; then
1166     if $PKG_CONFIG --exists xcomposite ; then
1167       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1168
1169       X_PACKAGES="$X_PACKAGES xcomposite"
1170       X_EXTENSIONS="$X_EXTENSIONS Composite"
1171       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1172     elif test x"$enable_xcomposite" = xyes; then
1173       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1174     fi
1175   fi
1176
1177   # Checks for Xdamage extension
1178
1179   if test x"$enable_xdamage" != xno; then
1180     if $PKG_CONFIG --exists xdamage ; then
1181       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1182
1183       X_PACKAGES="$X_PACKAGES xdamage"
1184       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1185       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1186     elif test x"$enable_xdamage" = xyes; then
1187       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1188     fi
1189   fi
1190
1191   if $have_base_x_pc ; then
1192     GDK_EXTRA_LIBS="$x_extra_libs"
1193   else
1194     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1195   fi
1196
1197   CPPFLAGS="$gtk_save_cppflags"
1198   LIBS="$gtk_save_libs"
1199
1200   AM_CONDITIONAL(USE_X11, true)
1201
1202   # strip leading space
1203   X_EXTENSIONS=${X_EXTENSIONS/# }
1204
1205 else
1206   XPACKAGES=
1207
1208   AM_CONDITIONAL(XINPUT_XFREE, false)
1209   AM_CONDITIONAL(XINPUT_2, false)
1210   AM_CONDITIONAL(USE_X11, false)
1211   AM_CONDITIONAL(HAVE_X11R6, false)
1212 fi
1213
1214 # Check for Pango flags
1215
1216 AC_MSG_CHECKING(Pango flags)
1217 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1218         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1219         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1220
1221         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1222 else
1223         AC_MSG_ERROR([
1224 *** Pango not found. Pango built with Cairo support is required
1225 *** to build GTK+. See http://www.pango.org for Pango information.
1226 ])
1227 fi
1228
1229 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1230
1231 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1232         :
1233 else
1234         gtk_save_LIBS="$LIBS"
1235         LIBS="$PANGO_LIBS $LIBS"
1236         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1237 *** Can't link to Pango. Pango is required to build
1238 *** GTK+. For more information see http://www.pango.org]))
1239         LIBS="$gtk_save_LIBS"
1240 fi
1241
1242 CFLAGS="$saved_cflags"
1243 LDFLAGS="$saved_ldflags"
1244
1245 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1246
1247 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1248 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1249 #
1250 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1251 # into the pkg-config files
1252 #
1253 if test $enable_explicit_deps != yes ; then
1254   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1255   GDK_EXTRA_LIBS=
1256 fi
1257
1258 AC_SUBST(GDK_PACKAGES)
1259 AC_SUBST(GDK_EXTRA_LIBS)
1260 AC_SUBST(GDK_EXTRA_CFLAGS)
1261 AC_SUBST(GDK_DEP_LIBS)
1262 AC_SUBST(GDK_DEP_CFLAGS)
1263
1264
1265 ########################################
1266 # Check for Accessibility Toolkit flags
1267 ########################################
1268
1269 ATK_PACKAGES=atk
1270 AC_MSG_CHECKING(ATK flags)
1271 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1272         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1273         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1274
1275         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1276 else
1277         AC_MSG_ERROR([
1278 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1279 *** to build GTK+.
1280 ])
1281 fi
1282
1283 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1284         :
1285 else
1286         gtk_save_LIBS="$LIBS"
1287         LIBS="$ATK_LIBS $LIBS"
1288         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1289                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1290                 *** to build GTK+]))
1291         LIBS="$gtk_save_LIBS"
1292 fi
1293
1294 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1295 if test "x$enable_x11_backend" == xyes; then
1296   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1297 fi
1298 GTK_EXTRA_LIBS=
1299 GTK_EXTRA_CFLAGS=
1300 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1301 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1302
1303 if test x"$os_win32" = xyes; then
1304   GTK_EXTRA_CFLAGS="$msnative_struct"
1305 fi
1306
1307 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1308 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1309 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1310 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1311
1312 AC_SUBST(GTK_PACKAGES)
1313 AC_SUBST(GTK_EXTRA_LIBS)
1314 AC_SUBST(GTK_EXTRA_CFLAGS)
1315 AC_SUBST(GTK_DEP_LIBS)
1316 AC_SUBST(GTK_DEP_CFLAGS)
1317
1318 AC_SUBST(GLIB_PREFIX)
1319 AC_SUBST(ATK_PREFIX)
1320 AC_SUBST(PANGO_PREFIX)
1321 AC_SUBST(CAIRO_PREFIX)
1322
1323 AC_SUBST(GTK_DEBUG_FLAGS)
1324 AC_SUBST(GTK_XIM_FLAGS)
1325
1326 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1327 AC_SUBST(GDK_PIXBUF_LIBS)
1328
1329 ########################
1330 # Checks needed for gail
1331 ########################
1332
1333 old_LIBS="$LIBS"
1334 dnl Checks for inet libraries:
1335 AC_SEARCH_LIBS(gethostent, nsl)
1336 AC_SEARCH_LIBS(setsockopt, socket)
1337 AC_SEARCH_LIBS(connect, inet)
1338
1339 dnl check for the sockaddr_un.sun_len member
1340 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1341                 [struct_sockaddr_un_sun_len=true],
1342                 [struct_sockaddr_un_suin_len=false],
1343                 [#include <sys/types.h>
1344                  #include <sys/un.h>]
1345                 )
1346 case $struct_sockaddr_un_sun_len in
1347         true)
1348                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1349                                    [Have the sockaddr_un.sun_len member])
1350                 ;;
1351         *)
1352                 ;;
1353 esac
1354
1355 GAIL_INET_LIBS="$LIBS"
1356 AC_SUBST([GAIL_INET_LIBS])
1357
1358 LIBS="$old_LIBS"
1359
1360 ################################################################
1361 # Printing system checks
1362 ################################################################
1363
1364 PRINT_BACKENDS="file lpr"
1365
1366 AC_ARG_ENABLE(cups,
1367               [AS_HELP_STRING([--disable-cups],
1368                               [disable cups print backend])],,
1369               [enable_cups=auto])
1370
1371 if test "x$enable_cups" = "xno"; then
1372   AM_CONDITIONAL(HAVE_CUPS, false)
1373 else
1374   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1375   if test "x$CUPS_CONFIG" = "xno"; then
1376     if test "x$enable_cups" = "xauto"; then
1377       AM_CONDITIONAL(HAVE_CUPS, false)
1378     else
1379       AC_MSG_ERROR([
1380 *** cups not found.
1381 ])
1382     fi
1383   else
1384     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1385     CUPS_LIBS=`$CUPS_CONFIG --libs`
1386
1387     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1388     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1389     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1390
1391     if test $CUPS_API_MAJOR -gt 1 -o \
1392             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1393       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1394                 [Define to 1 if CUPS 1.2 API is available])
1395     fi
1396
1397     AC_SUBST(CUPS_API_MAJOR)
1398     AC_SUBST(CUPS_API_MINOR)
1399     AC_SUBST(CUPS_CFLAGS)
1400     AC_SUBST(CUPS_LIBS)
1401
1402     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1403
1404     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1405     AM_CONDITIONAL(HAVE_CUPS, true)
1406
1407     gtk_save_cflags="$CFLAGS"
1408     CFLAGS="$CUPS_CFLAGS"
1409     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1410                                        [[http_t http; char *s = http.authstring;]])],
1411                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1412                                  [Define if cups http_t authstring field is accessible])],
1413                       [])
1414     CFLAGS="$gtk_save_cflags"
1415
1416     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1417
1418     gtk_save_libs="$LIBS"
1419     LIBS="$CUPS_LIBS"
1420     AC_CHECK_FUNCS(httpGetAuthString)
1421     LIBS="$gtk_save_libs"
1422   fi
1423 fi
1424
1425 # Checks to see if we should compile with PAPI backend for GTK+
1426 #
1427
1428 AC_ARG_ENABLE(papi,
1429               [AS_HELP_STRING([--disable-papi],
1430                               [disable papi print backend])],,
1431               [enable_papi=auto])
1432
1433 if test "x$enable_papi" = "xno"; then
1434   AM_CONDITIONAL(HAVE_PAPI, false)
1435 else
1436   AC_MSG_CHECKING(libpapi)
1437   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1438   if test $have_papi = yes; then
1439     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1440     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1441   fi
1442   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1443   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1444     AC_MSG_ERROR([
1445 *** papi not found.
1446 ])
1447   fi
1448 fi
1449
1450 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1451
1452 gtk_save_cppflags="$CPPFLAGS"
1453 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1454
1455 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1456 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1457 *** backend enabled.]))
1458
1459 if test "$os_win32" != "yes"; then
1460   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1461 *** Can't find cairo-ps.h. You must build Cairo with the
1462 *** postscript backend enabled.]))
1463
1464   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1465 *** Cannot find cairo-svg.h. You must build Cairo with the
1466 *** svg backend enabled.]))
1467 fi
1468
1469 CPPFLAGS="$gtk_save_cppflags"
1470
1471
1472 AC_ARG_ENABLE(test-print-backend,
1473               [AS_HELP_STRING([--enable-test-print-backend],
1474                               [build test print backend])],,
1475               [enable_test_print_backend=no])
1476 if test "x$enable_test_print_backend" != "xno" ; then
1477   PRINT_BACKENDS="$PRINT_BACKENDS test"
1478 fi
1479 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1480
1481
1482 ################################################################
1483 # Strip -export-dynamic from the link lines of various libraries
1484 ################################################################
1485
1486 #
1487 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1488 #  but this flag is only meaningful for executables. For libraries
1489 #  the effect is undefined; what it causes on Linux is that the
1490 #  export list from -export-symbols-regex is ignored and everything
1491 #  is exported
1492 #
1493 # We are using gmodule-no-export now, but I'm leaving the stripping
1494 # code in place for now, since pango and atk still require gmodule.
1495 export SED
1496 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1497 if test -n "$export_dynamic"; then
1498   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1499   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1500 fi
1501
1502 #############
1503 # GSettings #
1504 #############
1505
1506 GLIB_GSETTINGS
1507
1508 ##################################################
1509 # GObject introspection
1510 ##################################################
1511
1512 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1513
1514 ##################################################
1515 # Packagekit module
1516 #################################################
1517
1518 AC_ARG_ENABLE(packagekit,
1519               [AS_HELP_STRING([--disable-packagekit],
1520                               [build packagekit open-with module])])
1521
1522 build_packagekit=no
1523 if test "os_win32" != "yes"; then
1524         if test "x$enable_packagekit" != "xno"; then
1525                 build_packagekit=yes
1526                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1527         fi
1528 fi
1529
1530 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1531
1532 ##################################################
1533 # Checks for gtk-doc and docbook-tools
1534 ##################################################
1535
1536 GTK_DOC_CHECK([1.11])
1537
1538 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1539 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1540
1541 AC_ARG_ENABLE(man,
1542               [AS_HELP_STRING([--enable-man],
1543                               [regenerate man pages from Docbook [default=no]])],
1544               [enable_man=yes],
1545               [enable_man=no])
1546
1547 if test "${enable_man}" != no; then
1548   dnl
1549   dnl Check for xsltproc
1550   dnl
1551   AC_PATH_PROG([XSLTPROC], [xsltproc])
1552   if test -z "$XSLTPROC"; then
1553     enable_man=no
1554   fi
1555
1556   dnl check for DocBook DTD and stylesheets in the local catalog.
1557   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1558      [DocBook XML DTD V4.1.2],,enable_man=no)
1559   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1560      [DocBook XSL Stylesheets],,enable_man=no)
1561 fi
1562
1563 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1564
1565
1566 ##################################################
1567 # Output commands
1568 ##################################################
1569
1570 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1571         outfile=gdkconfig.h-tmp
1572         cat > $outfile <<\_______EOF
1573 /* gdkconfig.h
1574  *
1575  * This is a generated file.  Please modify `configure.ac'
1576  */
1577
1578 #ifndef __GDKCONFIG_H__
1579 #define __GDKCONFIG_H__
1580
1581 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1582 #error "Only <gdk/gdk.h> can be included directly."
1583 #endif
1584
1585 #include <glib.h>
1586
1587 G_BEGIN_DECLS
1588
1589 _______EOF
1590
1591         cat >>$outfile <<_______EOF
1592 $gdk_windowing
1593 _______EOF
1594
1595         cat >>$outfile <<_______EOF
1596
1597 G_END_DECLS
1598
1599 #endif  /* __GDKCONFIG_H__ */
1600 _______EOF
1601
1602
1603         if cmp -s $outfile gdk/gdkconfig.h; then
1604           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1605           rm -f $outfile
1606         else
1607           mv $outfile gdk/gdkconfig.h
1608         fi
1609 ],[
1610 gdk_windowing='$GDK_WINDOWING'
1611 ])
1612
1613 dnl
1614 dnl Check for -Bsymbolic-functions linker flag used to avoid
1615 dnl intra-library PLT jumps, if available.
1616 dnl
1617 AC_ARG_ENABLE(Bsymbolic,
1618               [AS_HELP_STRING([--disable-Bsymbolic],
1619                               [avoid linking with -Bsymbolic])],,
1620               [SAVED_LDFLAGS="${LDFLAGS}"
1621                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1622                LDFLAGS=-Wl,-Bsymbolic-functions
1623                AC_TRY_LINK([], [int main (void) { return 0; }],
1624                            AC_MSG_RESULT(yes)
1625                            enable_Bsymbolic=yes,
1626                            AC_MSG_RESULT(no)
1627                            enable_Bsymbolic=no)
1628                LDFLAGS="${SAVED_LDFLAGS}"])
1629
1630 if test "x${enable_Bsymbolic}" = "xyes" ; then
1631   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1632 fi
1633 AC_SUBST(GTK_LINK_FLAGS)
1634
1635 AC_CONFIG_FILES([
1636 config.h.win32
1637 gtk-zip.sh
1638 Makefile
1639 gdk-3.0.pc
1640 gtk+-3.0.pc
1641 gtk+-unix-print-3.0.pc
1642 gail-3.0.pc
1643 gtk+-3.0-uninstalled.pc
1644 gail-3.0-uninstalled.pc
1645 m4macros/Makefile
1646 po/Makefile.in
1647 po-properties/Makefile.in
1648 demos/Makefile
1649 demos/gtk-demo/Makefile
1650 demos/gtk-demo/geninclude.pl
1651 examples/Makefile
1652 tests/Makefile
1653 docs/Makefile
1654 docs/reference/Makefile
1655 docs/reference/gdk/Makefile
1656 docs/reference/gdk/version.xml
1657 docs/reference/gtk/Makefile
1658 docs/reference/gtk/version.xml
1659 docs/reference/libgail-util/Makefile
1660 docs/reference/libgail-util/version.xml
1661 docs/tools/Makefile
1662 build/Makefile
1663 build/win32/Makefile
1664 build/win32/vs9/Makefile
1665 gdk/Makefile
1666 gdk/broadway/Makefile
1667 gdk/x11/Makefile
1668 gdk/win32/Makefile
1669 gdk/win32/rc/Makefile
1670 gdk/win32/rc/gdk.rc
1671 gdk/quartz/Makefile
1672 gdk/tests/Makefile
1673 gtk/Makefile
1674 gtk/makefile.msc
1675 gtk/gtkversion.h
1676 gtk/gtk-win32.rc
1677 gtk/tests/Makefile
1678 modules/Makefile
1679 modules/other/Makefile
1680 modules/other/gail/Makefile
1681 modules/other/gail/libgail-util/Makefile
1682 modules/other/gail/tests/Makefile
1683 modules/engines/Makefile
1684 modules/engines/pixbuf/Makefile
1685 modules/engines/ms-windows/Makefile
1686 modules/engines/ms-windows/Theme/Makefile
1687 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1688 modules/input/Makefile
1689 modules/printbackends/Makefile
1690 modules/printbackends/cups/Makefile
1691 modules/printbackends/lpr/Makefile
1692 modules/printbackends/file/Makefile
1693 modules/printbackends/papi/Makefile
1694 modules/printbackends/test/Makefile
1695 perf/Makefile
1696 ])
1697
1698 AC_OUTPUT
1699
1700 # beautify the immodule list a bit
1701 included_immodules=${included_immodules//,/ }
1702 included_immodules=${included_immodules:-none}
1703
1704 echo ""
1705 echo "        GTK+ $GTK_VERSION"
1706 echo "        ==========="
1707 echo ""
1708 echo "        GDK backends:         $GDK_BACKENDS"
1709 if test "x$enable_x11_backend" = "xyes"; then
1710 echo "        X11 extensions:       $X_EXTENSIONS"
1711 fi
1712 echo "        Print backends:       $PRINT_BACKENDS"
1713 echo "        Dynamic modules:      $build_dynamic_modules"
1714 echo "        Included immodules:   $included_immodules"
1715 echo "        PackageKit support:   $build_packagekit"
1716 echo "        Introspection:        $found_introspection"
1717 echo "        Debugging:            $enable_debug"
1718 echo "        Documentation:        $enable_gtk_doc"