Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [2])
  12 m4_define([gtk_minor_version], [91])
  13 m4_define([gtk_micro_version], [6])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.64])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.27.3])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.29.2])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.21.0])
  46 GLIB_REQUIRED_VERSION=glib_required_version
  47 PANGO_REQUIRED_VERSION=pango_required_version
  48 ATK_REQUIRED_VERSION=atk_required_version
  49 CAIRO_REQUIRED_VERSION=cairo_required_version
  50 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  51 AC_SUBST(GLIB_REQUIRED_VERSION)
  52 AC_SUBST(PANGO_REQUIRED_VERSION)
  53 AC_SUBST(ATK_REQUIRED_VERSION)
  54 AC_SUBST(CAIRO_REQUIRED_VERSION)
  55 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  56
  57
  58 # Save this value here, since automake will set cflags later
  59 cflags_set=${CFLAGS+set}
  60
  61 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  62 AM_MAINTAINER_MODE([enable])
  63
  64 # Support silent build rules, requires at least automake-1.11. Disable
  65 # by either passing --disable-silent-rules to configure or passing V=1
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 #
  70 # For each of the libraries we build, we define the following
  71 # substituted variables:
  72 #
  73 # foo_PACKAGES:     pkg-config packages this library requires
  74 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  75 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  76 # foo_DEP_LIBS:     All libraries this module requires
  77 # foo_DEP_CFLAGS:   All cflags this module requires
  78
  79
  80 GTK_MAJOR_VERSION=gtk_major_version
  81 GTK_MINOR_VERSION=gtk_minor_version
  82 GTK_MICRO_VERSION=gtk_micro_version
  83 GTK_INTERFACE_AGE=gtk_interface_age
  84 GTK_BINARY_AGE=gtk_binary_age
  85 GTK_VERSION=gtk_version
  86 GTK_API_VERSION=gtk_api_version
  87 GTK_BINARY_VERSION=gtk_binary_version
  88 AC_SUBST(GTK_MAJOR_VERSION)
  89 AC_SUBST(GTK_MINOR_VERSION)
  90 AC_SUBST(GTK_MICRO_VERSION)
  91 AC_SUBST(GTK_INTERFACE_AGE)
  92 AC_SUBST(GTK_BINARY_AGE)
  93 AC_SUBST(GTK_API_VERSION)
  94 AC_SUBST(GTK_VERSION)
  95 AC_SUBST(GTK_BINARY_VERSION)
  96
  97 # libtool versioning
  98 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  99 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 100 #LT_REVISION=$GTK_INTERFACE_AGE
 101 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 102 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 103
 104 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 105 m4_define([lt_revision], [gtk_interface_age])
 106 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 107 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 108 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 109 AC_SUBST(LT_VERSION_INFO)
 110 AC_SUBST(LT_CURRENT_MINUS_AGE)
 111
 112 m4_define([gail_lt_current],[0])
 113 m4_define([gail_lt_revision],[0])
 114 m4_define([gail_lt_age],[0])
 115 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 116 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 117 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 118 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 119
 120 # Checks for programs.
 121 AC_PROG_CC
 122 AC_PROG_CC_C_O
 123 AC_PROG_CC_STDC
 124 AC_PROG_INSTALL
 125 AC_PROG_MAKE_SET
 126
 127
 128 GETTEXT_PACKAGE=gtk30
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 131                    [The prefix for our gettext translation domains.])
 132
 133 AC_CANONICAL_HOST
 134
 135 MATH_LIB=-lm
 136 AC_MSG_CHECKING([for native Win32])
 137 LIB_EXE_MACHINE_FLAG=X86
 138 EXE_MANIFEST_ARCHITECTURE=X86
 139 case "$host" in
 140   *-*-mingw*)
 141     os_win32=yes
 142     gio_can_sniff=no
 143     MATH_LIB=
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       EXE_MANIFEST_ARCHITECTURE=AMD64
 148       ;;
 149     esac
 150     ;;
 151   *)
 152     os_win32=no
 153     ;;
 154 esac
 155 AC_MSG_RESULT([$os_win32])
 156
 157 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 158 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 159
 160 case $host in
 161   *-*-linux*)
 162     os_linux=yes
 163     ;;
 164 esac
 165
 166 dnl
 167 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 168 dnl We use this for an automated test for C++ header correctness.
 169 dnl
 170 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 171 AC_LANG_PUSH([C++])
 172
 173 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 174 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 175
 176 gtk_save_cxxflags="$CXXFLAGS"
 177 CXXFLAGS="$CXXFLAGS -x objective-c++"
 178 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 179 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 180 CXXFLAGS="$gtk_save_cxxflags"
 181 AC_LANG_POP([C++])
 182
 183 if test "$os_win32" = "yes"; then
 184   if test x$enable_static = xyes -o x$enable_static = x; then
 185     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 186     enable_static=no
 187   fi
 188   if test x$enable_shared = xno; then
 189     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 190   fi
 191   enable_shared=yes
 192 fi
 193
 194 dnl Initialize libtool
 195 LT_PREREQ([2.2.6])
 196 LT_INIT([disable-static win32-dll])
 197 # Create libtool early, because it's used in configure
 198 LT_OUTPUT
 199
 200 # Make sure we use 64-bit versions of various file stuff.
 201 AC_SYS_LARGEFILE
 202
 203 AM_PROG_AS
 204 AC_PATH_PROG(NM, nm, nm)
 205
 206 AC_MSG_CHECKING([for some Win32 platform])
 207 case "$host" in
 208   *-*-mingw*|*-*-cygwin*)
 209     platform_win32=yes
 210     ;;
 211   *)
 212     platform_win32=no
 213     ;;
 214 esac
 215 AC_MSG_RESULT([$platform_win32])
 216 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 217
 218 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 219 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 220 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 221
 222 if test "$os_win32" = "yes"; then
 223   AC_CHECK_TOOL(WINDRES, windres, no)
 224   if test "$WINDRES" = no; then
 225     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 226   fi
 227   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 228 fi
 229 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 230
 231 m4_define([debug_default],
 232           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 233
 234 dnl declare --enable-* args and collect ac_help strings
 235 AC_ARG_ENABLE(debug,
 236               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 237                              [turn on debugging @<:@default=debug_default@:>@]),,
 238               enable_debug=debug_default)
 239 AC_ARG_ENABLE(xkb,
 240               [AC_HELP_STRING([--enable-xkb],
 241                               [support XKB [default=maybe]])],,
 242               [enable_xkb="maybe"])
 243 AC_ARG_ENABLE(xinerama,
 244               [AC_HELP_STRING([--enable-xinerama],
 245                               [support xinerama extension if available [default=yes]])],,
 246               [enable_xinerama="yes"])
 247 AC_ARG_ENABLE(rebuilds,
 248               [AC_HELP_STRING([--disable-rebuilds],
 249                               [disable all source autogeneration rules])],,
 250               [enable_rebuilds=yes])
 251
 252 AC_ARG_WITH(xinput,
 253             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 254
 255 if test "$platform_win32" = yes; then
 256   gdktarget=win32
 257 else
 258   gdktarget=x11
 259 fi
 260
 261 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/win32/quartz/broadway]] select non-default GDK target],
 262         gdktarget=$with_gdktarget)
 263
 264 AC_SUBST(gdktarget)
 265 case $gdktarget in
 266   x11|win32|quartz|broadway) ;;
 267   *) AC_MSG_ERROR([Invalid target for GDK: use x11, broadway, quartz or win32.]);;
 268 esac
 269
 270 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 271 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 272
 273 AC_SUBST(gdktargetlib)
 274 AC_SUBST(gtktargetlib)
 275
 276 if test "x$enable_debug" = "xyes"; then
 277   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 278   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 279 else
 280   if test "x$enable_debug" = "xno"; then
 281     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 282   else
 283     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 284   fi
 285 fi
 286
 287
 288 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 289                    [Define if debugging is enabled])
 290
 291
 292 # Build time sanity check...
 293 AM_SANITY_CHECK
 294
 295 changequote(,)dnl
 296 if test "x$GCC" = "xyes"; then
 297   case " $CFLAGS " in
 298   *[\ \ ]-Wall[\ \      ]*) ;;
 299   *) CFLAGS="$CFLAGS -Wall" ;;
 300   esac
 301
 302   if test "x$enable_ansi" = "xyes"; then
 303     case " $CFLAGS " in
 304     *[\ \       ]-ansi[\ \      ]*) ;;
 305     *) CFLAGS="$CFLAGS -ansi" ;;
 306     esac
 307
 308     case " $CFLAGS " in
 309     *[\ \       ]-pedantic[\ \  ]*) ;;
 310     *) CFLAGS="$CFLAGS -pedantic" ;;
 311     esac
 312   fi
 313 fi
 314 changequote([,])dnl
 315
 316 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 317
 318 # Ensure MSVC-compatible struct packing convention is used when
 319 # compiling for Win32 with gcc.
 320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 321 # gcc2 uses "-fnative-struct".
 322 if test x"$os_win32" = xyes; then
 323   if test x"$GCC" = xyes; then
 324     msnative_struct=''
 325     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 326     if test -z "$ac_cv_prog_CC"; then
 327       our_gcc="$CC"
 328     else
 329       our_gcc="$ac_cv_prog_CC"
 330     fi
 331     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 332       2.)
 333         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 334           msnative_struct='-fnative-struct'
 335         fi
 336         ;;
 337       *)
 338         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 339           msnative_struct='-mms-bitfields'
 340         fi
 341         ;;
 342     esac
 343     if test x"$msnative_struct" = x ; then
 344       AC_MSG_RESULT([no way])
 345       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 346     else
 347       CFLAGS="$CFLAGS $msnative_struct"
 348       AC_MSG_RESULT([${msnative_struct}])
 349     fi
 350   fi
 351 fi
 352
 353 ## Initial sanity check, done here so that users get told they
 354 ## have the wrong dependencies as early in the process as possible.
 355 ## Later on we actually use the cflags/libs from separate pkg-config
 356 ## calls. Oh, also the later pkg-config calls don't include
 357 ## the version requirements since those make the module lists
 358 ## annoying to construct
 359 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 360   [glib-2.0 >= glib_required_version dnl
 361    atk >= atk_required_version dnl
 362    pango >= pango_required_version dnl
 363    cairo >= cairo_required_version dnl
 364    cairo-gobject >= cairo_required_version dnl
 365    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 366
 367 ## In addition to checking that cairo is present, we also need to
 368 ## check that the correct cairo backend is there. E.g. if the GDK
 369 ## target is win32 we need the cairo-win32 backend and so on.
 370 cairo_backend=cairo-$gdktarget
 371
 372 # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 373 # backend names are identical.
 374 if test "x$cairo_backend" = "xcairo-x11"; then
 375    cairo_backend=cairo-xlib
 376 fi
 377 if test "x$cairo_backend" = "xcairo-broadway"; then
 378    cairo_backend=cairo
 379 fi
 380 PKG_CHECK_MODULES(CAIRO_BACKEND,
 381   [$cairo_backend >= cairo_required_version])
 382
 383 if test "$os_win32" != yes; then
 384     # libtool option to control which symbols are exported
 385     # right now, symbols starting with _ are not exported
 386     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 387 else
 388     # We currently use .def files on Windows (for gdk and gtk)
 389     LIBTOOL_EXPORT_OPTIONS=
 390 fi
 391 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 392
 393 dnl ******************************************************
 394 dnl * See whether to include shared library dependencies *
 395 dnl ******************************************************
 396
 397 AC_ARG_ENABLE(explicit-deps,
 398               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 399                               [use explicit dependencies in .pc files [default=auto]])],,
 400               [enable_explicit_deps=auto])
 401
 402 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 403 case $enable_explicit_deps in
 404   auto)
 405     export SED
 406     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 407     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 408       enable_explicit_deps=yes
 409     else
 410       enable_explicit_deps=no
 411     fi
 412   ;;
 413   yes|no)
 414   ;;
 415   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 416   ;;
 417 esac
 418 AC_MSG_RESULT($enable_explicit_deps)
 419
 420 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 421
 422 # define a MAINT-like variable REBUILD which is set if Perl
 423 # and awk are found, so autogenerated sources can be rebuilt
 424
 425 AC_PATH_PROGS(PERL, perl5 perl)
 426
 427 # We would like indent, but don't require it.
 428 AC_CHECK_PROG(INDENT, indent, indent)
 429
 430 REBUILD=\#
 431 if test "x$enable_rebuilds" = "xyes" && \
 432      test -n "$PERL" && \
 433      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 434   REBUILD=
 435 fi
 436 AC_SUBST(REBUILD)
 437
 438 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 439 AC_CHECK_FUNCS(localtime_r)
 440
 441 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 442 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 443 AC_TRY_LINK([#include <langinfo.h>], [
 444 char c;
 445 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 446 ], gtk_ok=yes, gtk_ok=no)
 447 AC_MSG_RESULT($gtk_ok)
 448 if test "$gtk_ok" = "yes"; then
 449   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 450             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 451 fi
 452
 453 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 454 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 455 AC_TRY_LINK([#include <langinfo.h>], [
 456 char c;
 457 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 458 ], gtk_ok=yes, gtk_ok=no)
 459 AC_MSG_RESULT($gtk_ok)
 460 if test "$gtk_ok" = "yes"; then
 461   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 462             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 463 fi
 464
 465 # _NL_PAPER_HEIGHT is an enum and not a define
 466 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 467 AC_TRY_LINK([#include <langinfo.h>], [
 468 char c;
 469 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 470 ], gtk_ok=yes, gtk_ok=no)
 471 AC_MSG_RESULT($gtk_ok)
 472 if test "$gtk_ok" = "yes"; then
 473   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 474             [Define if _NL_PAPER_HEIGHT is available])
 475 fi
 476
 477 # _NL_PAPER_WIDTH is an enum and not a define
 478 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 479 AC_TRY_LINK([#include <langinfo.h>], [
 480 char c;
 481 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 482 ], gtk_ok=yes, gtk_ok=no)
 483 AC_MSG_RESULT($gtk_ok)
 484 if test "$gtk_ok" = "yes"; then
 485   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 486             [Define if _NL_PAPER_WIDTH is available])
 487 fi
 488
 489 # i18n stuff
 490 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 491 AM_GLIB_GNU_GETTEXT
 492 LIBS="$LIBS $INTLLIBS"
 493 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 494         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 495       esac])
 496
 497 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 498 dnl po-properties/POTFILES during configure; see GNOME #573515.
 499 dnl
 500 dnl Generate list of files to be processed by xgettext which will
 501 dnl be included in po-properties/Makefile.
 502 test -d po-properties || mkdir po-properties
 503 if test "x$srcdir" != "x."; then
 504   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 505     popropsrcprefix="$srcdir/"
 506   else
 507     popropsrcprefix="../$srcdir/"
 508   fi
 509 else
 510   popropsrcprefix="../"
 511 fi
 512 rm -f po-properties/POTFILES
 513 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 514 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 515 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 516
 517 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 518
 519 dnl The DU4 header files don't provide library prototypes unless
 520 dnl -std1 is given to the native cc.
 521 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 522
 523 gtk_save_LIBS=$LIBS
 524 LIBS="$LIBS -lm"
 525 AC_TRY_RUN([#include <math.h>
 526              int main (void) { return (log(1) != log(1.)); }],
 527      AC_MSG_RESULT(none needed),
 528      gtk_save_CFLAGS="$CFLAGS"
 529      CFLAGS="$CFLAGS -std1"
 530      AC_TRY_RUN([#include <math.h>
 531                  int main (void) { return (log(1) != log(1.)); }],
 532          AC_MSG_RESULT(-std1),
 533          AC_MSG_RESULT()
 534          CFLAGS="$gtk_save_CFLAGS"
 535          AC_MSG_WARN(
 536                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 537          true
 538      ),
 539      AC_MSG_RESULT(none needed)
 540 )
 541 LIBS=$gtk_save_LIBS
 542
 543 AC_MSG_CHECKING(for the BeOS)
 544 case $host in
 545   *-*-beos*)
 546     AC_MSG_RESULT(yes)
 547     MATH_LIB=
 548   ;;
 549   *)
 550     AC_MSG_RESULT(no)
 551   ;;
 552 esac
 553
 554 AC_SUBST(MATH_LIB)
 555 #
 556 # see bug 162979
 557 #
 558 AC_MSG_CHECKING(for HP-UX)
 559 case $host_os in
 560   hpux9* | hpux10* | hpux11*)
 561     AC_MSG_RESULT(yes)
 562     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 563   ;;
 564   *)
 565     AC_MSG_RESULT(no)
 566   ;;
 567 esac
 568
 569 dnl NeXTStep cc seems to need this
 570 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 571 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 572   AC_MSG_RESULT(none needed),
 573   gtk_save_CFLAGS="$CFLAGS"
 574   CFLAGS="$CFLAGS -posix"
 575   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 576     AC_MSG_RESULT(-posix),
 577     AC_MSG_RESULT()
 578     CFLAGS="$gtk_save_CFLAGS"
 579     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 580
 581 #
 582 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 583 #
 584
 585 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 586
 587 AM_PATH_GLIB_2_0(glib_required_version, :,
 588   AC_MSG_ERROR([
 589 *** GLIB glib_required_version or better is required. The latest version of
 590 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 591   gobject gmodule-no-export gthread)
 592
 593 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 594 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 595 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 596 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 597   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 598 fi
 599
 600 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 601
 602
 603 dnl
 604 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 605 dnl
 606 gtk_save_LIBS=$LIBS
 607 LIBS="$LIBS $GLIB_LIBS"
 608 AC_CHECK_FUNCS(bind_textdomain_codeset)
 609 LIBS=$gtk_save_LIBS
 610
 611 AC_CHECK_HEADERS(pwd.h,
 612                  AC_DEFINE(HAVE_PWD_H, 1,
 613                            [Define to 1 if pwd.h is available]))
 614 AC_CHECK_HEADERS(sys/time.h,
 615                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 616                            [Define to 1 if time.h is available]))
 617 AC_CHECK_HEADERS(unistd.h,
 618                  AC_DEFINE(HAVE_UNISTD_H, 1,
 619                            [Define to 1 if unistd.h is available]))
 620 AC_CHECK_HEADERS(ftw.h,
 621                  AC_DEFINE(HAVE_FTW_H, 1,
 622                            [Define to 1 if ftw.h is available]))
 623
 624 AC_MSG_CHECKING([for GNU ftw extensions])
 625 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 626 #define _GNU_SOURCE
 627 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 628 if test $gtk_ok = yes; then
 629     AC_MSG_RESULT([yes])
 630     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 631 else
 632     AC_MSG_RESULT([no])
 633 fi
 634
 635 saved_cflags="$CFLAGS"
 636 saved_ldflags="$LDFLAGS"
 637
 638
 639 # Checks for header files.
 640 AC_HEADER_STDC
 641
 642 # Checks for typedefs, structures, and compiler characteristics.
 643 AC_C_CONST
 644
 645 # Checks for library functions.
 646 AC_TYPE_SIGNAL
 647 AC_FUNC_MMAP
 648
 649 AC_CHECK_FUNCS(mallinfo)
 650 AC_CHECK_FUNCS(getresuid)
 651 AC_TYPE_UID_T
 652
 653 # Check if <sys/select.h> needs to be included for fd_set
 654 AC_MSG_CHECKING([for fd_set])
 655 AC_TRY_COMPILE([#include <sys/types.h>],
 656         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 657 if test $gtk_ok = yes; then
 658     AC_MSG_RESULT([yes, found in sys/types.h])
 659 else
 660     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 661     if test $gtk_ok = yes; then
 662         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 663                   [Define to 1 if sys/select.h is available])
 664         AC_MSG_RESULT([yes, found in sys/select.h])
 665     else
 666         AC_DEFINE(NO_FD_SET, 1,
 667                   [Define to 1 if fd_set is not available])
 668         AC_MSG_RESULT(no)
 669     fi
 670 fi
 671
 672 # `widechar' tests for gdki18n.h
 673 AC_MSG_CHECKING(for wchar.h)
 674 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 675 if test $gdk_wchar_h = yes; then
 676    AC_DEFINE(HAVE_WCHAR_H, 1, [Have wchar.h include file])
 677 fi
 678 AC_MSG_RESULT($gdk_wchar_h)
 679
 680 # Check for wctype.h (for iswalnum)
 681 AC_MSG_CHECKING(for wctype.h)
 682 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 683 if test $gdk_wctype_h = yes; then
 684    AC_DEFINE(HAVE_WCTYPE_H, 1, [Have wctype.h include file])
 685 fi
 686 AC_MSG_RESULT($gdk_wctype_h)
 687
 688 # in Solaris 2.5, `iswalnum' is in -lw
 689 GDK_WLIBS=
 690 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 691
 692 oLIBS="$LIBS"
 693 LIBS="$LIBS $GDK_WLIBS"
 694 # The following is necessary for Linux libc-5.4.38
 695 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 696 AC_TRY_LINK([#include <stdlib.h>],[
 697 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 698 #  ifdef HAVE_WCTYPE_H
 699 #    include <wctype.h>
 700 #  else
 701 #    ifdef HAVE_WCHAR_H
 702 #      include <wchar.h>
 703 #    endif
 704 #  endif
 705 #else
 706 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 707 #endif
 708 iswalnum((wchar_t) 0);
 709 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 710 LIBS="$oLIBS"
 711
 712 if test $gdk_working_wctype = no; then
 713    AC_DEFINE(HAVE_BROKEN_WCTYPE, 1, [Is the wctype implementation broken])
 714    GDK_WLIBS=
 715 fi
 716 AC_MSG_RESULT($gdk_working_wctype)
 717 AC_SUBST(GDK_WLIBS)
 718
 719 # Check for uxtheme.h (for MS-Windows Engine)
 720 AC_MSG_CHECKING(for uxtheme.h)
 721 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 722 if test $gtk_uxtheme_h = yes; then
 723    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 724 fi
 725 AC_MSG_RESULT($gtk_uxtheme_h)
 726
 727 # Checks for gdkspawn
 728 AC_CHECK_HEADERS(crt_externs.h)
 729 AC_CHECK_FUNCS(_NSGetEnviron)
 730
 731 AC_MSG_CHECKING(whether to build dynamic modules)
 732
 733 AC_ARG_ENABLE(modules,
 734               [AC_HELP_STRING([--disable-modules],
 735                               [disable dynamic module loading])])
 736
 737 dynworks=false
 738 deps=
 739 if test x$enable_modules = xno; then
 740     AC_MSG_RESULT(no)
 741 else
 742     AC_MSG_RESULT(yes)
 743     AC_MSG_CHECKING(whether dynamic modules work)
 744     ## for loop is to strip newline
 745     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 746     for I in $tmp; do
 747         dynworks=$I
 748     done
 749
 750     dnl Now we check to see if our libtool supports shared lib deps
 751     dnl (in a rather ugly way even)
 752     if $dynworks; then
 753         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 754         module_deplibs_check=`$module_libtool_config | \
 755             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 756             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 757         if test "x$module_deplibs_check" = "xnone" || \
 758            test "x$module_deplibs_check" = "xunknown" || \
 759            test "x$module_deplibs_check" = "x"; then
 760             dynworks=false
 761         fi
 762     fi
 763
 764     if $dynworks; then
 765         AC_DEFINE(USE_GMODULE, 1,
 766                   [Define to 1 if gmodule works and should be used])
 767         AC_MSG_RESULT(yes)
 768     else
 769         AC_MSG_RESULT(no)
 770     fi
 771 fi
 772
 773 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 774
 775 #
 776 # Allow building some or all immodules included
 777 #
 778 AC_MSG_CHECKING(immodules to build)
 779
 780 dnl due to an autoconf bug, commas in the first arg to
 781 dnl AC_HELP_STRING cause problems.
 782 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 783 dnl                [build the specified input method modules into gtk])
 784 AC_ARG_WITH(included_immodules,
 785 [  --with-included-immodules=MODULE1,MODULE2,...
 786                           build the specified input methods into gtk])
 787
 788 if $dynworks; then
 789    :
 790 else
 791    ## if the option was specified, leave it; otherwise disable included immodules
 792    if test x$with_included_immodules = xno; then
 793            with_included_immodules=yes
 794    fi
 795 fi
 796
 797 all_immodules="am-et,cedilla,cyrillic-translit"
 798 if test "$gdktarget" = "win32"; then
 799    all_immodules="${all_immodules},ime"
 800 fi
 801 all_immodules="${all_immodules},inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr"
 802 if test "$gdktarget" = "x11"; then
 803    all_immodules="${all_immodules},xim"
 804 fi
 805
 806 included_immodules=""
 807 # If the switch specified without listing any specific ones, include all
 808 if test "x$with_included_immodules" = xyes ; then
 809   included_immodules="$all_immodules"
 810 else
 811   included_immodules="$with_included_immodules"
 812 fi
 813
 814 AC_MSG_RESULT($included_immodules)
 815 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 816
 817 INCLUDED_IMMODULE_OBJ=
 818 INCLUDED_IMMODULE_DEFINE=
 819
 820 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 821 for immodule in $included_immodules; do
 822  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 823  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 824    :
 825  else
 826    AC_MSG_ERROR([the specified input method $immodule does not exist])
 827  fi
 828
 829  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 830  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 831  eval INCLUDE_$immodule_underscores=yes
 832 done
 833 IFS="$gtk_save_ifs"
 834 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 835 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 836
 837 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 838 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 839 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 840 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 841 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 842 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 843 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 844 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 845 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 846 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 847 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 848 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 849
 850 AC_HEADER_SYS_WAIT
 851
 852 AC_TYPE_SIGNAL
 853
 854 # Checks to see whether we should include mediaLib
 855 # support.
 856 #
 857 AC_CHECK_HEADER(sys/systeminfo.h,
 858                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 859                           [Define to 1 if sys/systeminfo.h is available]))
 860 AC_CHECK_HEADER(sys/sysinfo.h,
 861                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 862                           [Define to 1 if sys/sysinfo.h is available]))
 863
 864 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 865
 866 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 867
 868 if test $cross_compiling = yes; then
 869   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 870   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 871     REBUILD_PNGS=#
 872   fi
 873 fi
 874
 875 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 876
 877 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 878    test "x$REBUILD_PNGS" = "x#" ; then
 879      AC_MSG_ERROR([
 880 *** gtkbuiltincache.h is not in the tree, and cannot be built
 881 *** because you don't have libpng, or (when cross-compiling) you
 882 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 883 fi
 884
 885 ########################################
 886 # Windowing system checks
 887 ########################################
 888
 889 GDK_EXTRA_LIBS="$GDK_WLIBS"
 890 GDK_EXTRA_CFLAGS=
 891
 892 # GTK+ uses some X calls, so needs to link against X directly
 893 GTK_DEP_PACKAGES_FOR_X=
 894 GTK_DEP_LIBS_FOR_X=
 895
 896 if test "x$gdktarget" = "xx11"; then
 897   X_PACKAGES=fontconfig
 898
 899   #
 900   # We use fontconfig very peripherally when decoding the default
 901   # settings.
 902   #
 903   if $PKG_CONFIG --exists fontconfig; then : ; else
 904     AC_MSG_ERROR([
 905 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 906   fi
 907
 908   #
 909   # Check for basic X packages; we use pkg-config if available
 910   #
 911   if $PKG_CONFIG --exists x11 xext; then
 912     have_base_x_pc=true
 913     X_PACKAGES="$X_PACKAGES x11 xext"
 914     x_libs="`$PKG_CONFIG --libs x11 xext`"
 915     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 916
 917     # Strip out any .la files that pkg-config might give us (this happens
 918     # with -uninstalled.pc files)
 919     x_libs_for_checks=
 920     for I in $x_libs ; do
 921       case $I in
 922         *.la) ;;
 923         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 924       esac
 925     done
 926
 927     GTK_PACKAGES_FOR_X="x11"
 928   else
 929     have_base_x_pc=false
 930     AC_PATH_XTRA
 931     if test x$no_x = xyes ; then
 932       AC_MSG_ERROR([X development libraries not found])
 933     fi
 934
 935     x_cflags="$X_CFLAGS"
 936     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 937
 938     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 939   fi
 940
 941   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 942   x_extra_libs=
 943
 944   gtk_save_cppflags="$CPPFLAGS"
 945   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 946
 947   gtk_save_LIBS=$LIBS
 948   LIBS="$x_libs_for_checks $LIBS"
 949
 950   # Sanity check for the X11 and Xext libraries. While everything we need from
 951   # Xext is optional, the chances a system has *none* of these things is so
 952   # small that we just unconditionally require it.
 953   AC_CHECK_FUNC(XOpenDisplay, :,
 954                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 955   AC_CHECK_FUNC(XextFindDisplay, :,
 956                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 957
 958   # Check for xReply
 959
 960   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 961   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 962       [xReply *rep;],
 963       [AC_MSG_RESULT([no])],
 964       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 965 #include <X11/Xlibint.h>],
 966            [xReply *rep;],
 967            [AC_MSG_RESULT([yes])
 968             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
 969                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
 970            [AC_MSG_RESULT([unknown])
 971             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 972
 973   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 974
 975   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 976
 977   # Generic X11R6 check needed for XIM support; we could
 978   # probably use this to replace the above, but we'll
 979   # leave the separate checks for XConvertCase and XInternAtoms
 980   # for clarity
 981
 982   have_x11r6=false
 983   AC_CHECK_FUNC(XAddConnectionWatch,
 984       have_x11r6=true)
 985
 986   if $have_x11r6; then
 987     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
 988   fi
 989   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
 990
 991   # Check for XKB support.
 992
 993   if test "x$enable_xkb" = "xyes"; then
 994         AC_MSG_WARN(XKB support explicitly enabled)
 995         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
 996   elif test "x$enable_xkb" = "xmaybe"; then
 997         AC_CHECK_FUNC(XkbQueryExtension,
 998                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
 999   else
1000         AC_MSG_WARN(XKB support explicitly disabled)
1001   fi
1002
1003   # Check for shaped window extension
1004
1005   AC_CHECK_FUNC(XShapeCombineMask, :,
1006      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1007
1008   # X SYNC check
1009   gtk_save_CFLAGS="$CFLAGS"
1010   CFLAGS="$CFLAGS $x_cflags"
1011
1012   AC_CHECK_FUNC(XSyncQueryExtension,
1013       [AC_CHECK_HEADER(X11/extensions/sync.h,
1014           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1015           :, [#include <X11/Xlib.h>])])
1016
1017   CFLAGS="$gtk_save_CFLAGS"
1018
1019   if test "x$enable_xinerama" = "xyes"; then
1020     # Check for Xinerama extension (Solaris impl or Xfree impl)
1021     gtk_save_cppflags="$CPPFLAGS"
1022     CPPFLAGS="$CPPFLAGS $x_cflags"
1023
1024     # Check for XFree
1025     AC_MSG_CHECKING(for Xinerama support on XFree86)
1026
1027     have_xfree_xinerama=false
1028     if $PKG_CONFIG --exists xinerama ; then
1029        have_xfree_xinerama=true
1030        X_PACKAGES="$X_PACKAGES xinerama"
1031     else
1032        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1033            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1034            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1035            have_xfree_xinerama=true], :,
1036            [#include <X11/Xlib.h>])])
1037     fi
1038
1039     if $have_xfree_xinerama ; then
1040       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1041                 [Define to 1 if XFree Xinerama is available])
1042       AC_DEFINE(HAVE_XINERAMA, 1,
1043                 [Define to 1 is Xinerama is available])
1044       AC_MSG_RESULT(yes)
1045     else
1046       AC_MSG_RESULT(no)
1047
1048       case "$host" in
1049         *-*-solaris*)
1050             # Check for solaris
1051             AC_MSG_CHECKING(for Xinerama support on Solaris)
1052
1053             have_solaris_xinerama=false
1054             AC_CHECK_FUNC(XineramaGetInfo,
1055                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1056                     [have_solaris_xinerama=true], :,
1057                     [#include <X11/Xlib.h>])])
1058
1059             if $have_solaris_xinerama ; then
1060               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1061                         [Define to 1 if solaris xinerama is available])
1062               AC_DEFINE(HAVE_XINERAMA, 1,
1063                         [Define to 1 if xinerama is available])
1064               AC_MSG_RESULT(yes)
1065             else
1066               AC_MSG_RESULT(no)
1067             fi
1068             ;;
1069         *)
1070             ;;
1071       esac
1072     fi
1073   fi
1074
1075   # set up things for XInput
1076   if test "x$with_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1077     have_xinput=yes
1078
1079     AC_DEFINE(XINPUT_XFREE, 1,
1080               [Define to 1 if XFree XInput should be used])
1081
1082     X_PACKAGES="$X_PACKAGES xi"
1083
1084     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1085                     have_xinput2=yes; AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1086   else
1087     AC_DEFINE(XINPUT_NONE, 1,
1088               [Define to 1 if no XInput should be used])
1089   fi
1090
1091   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1092   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1093
1094   # Check for the RANDR extension
1095   if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1096      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1097
1098      X_PACKAGES="$X_PACKAGES xrandr"
1099   fi
1100
1101   # Checks for Xcursor library
1102
1103   if $PKG_CONFIG --exists xcursor ; then
1104     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1105
1106     X_PACKAGES="$X_PACKAGES xcursor"
1107   fi
1108
1109   # Checks for XFixes extension
1110
1111   if $PKG_CONFIG --exists xfixes ; then
1112     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1113
1114     X_PACKAGES="$X_PACKAGES xfixes"
1115     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1116   fi
1117
1118   # Checks for Xcomposite extension
1119
1120   if $PKG_CONFIG --exists xcomposite ; then
1121     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1122
1123     X_PACKAGES="$X_PACKAGES xcomposite"
1124     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1125   fi
1126
1127   # Checks for Xdamage extension
1128
1129   if $PKG_CONFIG --exists xdamage ; then
1130     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1131
1132     X_PACKAGES="$X_PACKAGES xdamage"
1133     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1134   fi
1135
1136   if $have_base_x_pc ; then
1137     GDK_EXTRA_LIBS="$x_extra_libs"
1138   else
1139     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1140   fi
1141
1142   CPPFLAGS="$gtk_save_cppflags"
1143   LIBS="$gtk_save_libs"
1144
1145   AM_CONDITIONAL(USE_X11, true)
1146 else
1147   XPACKAGES=
1148
1149   AM_CONDITIONAL(XINPUT_XFREE, false)
1150   AM_CONDITIONAL(XINPUT_2, false)
1151   AM_CONDITIONAL(USE_X11, false)
1152   AM_CONDITIONAL(HAVE_X11R6, false)
1153 fi
1154
1155 if test "x$gdktarget" = "xwin32"; then
1156   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1157   AM_CONDITIONAL(USE_WIN32, true)
1158 else
1159   AM_CONDITIONAL(USE_WIN32, false)
1160 fi
1161
1162 if test "x$gdktarget" = "xquartz"; then
1163   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1164   AM_CONDITIONAL(USE_QUARTZ, true)
1165 else
1166   AM_CONDITIONAL(USE_QUARTZ, false)
1167 fi
1168
1169 if test "x$gdktarget" = "xbroadway" ; then
1170   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
1171 fi
1172
1173 # Check for Pango flags
1174
1175 if test "x$gdktarget" = "xwin32"; then
1176         PANGO_PACKAGES="pangowin32 pangocairo"
1177 else
1178         PANGO_PACKAGES="pango pangocairo"
1179 fi
1180
1181 AC_MSG_CHECKING(Pango flags)
1182 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1183         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1184         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1185
1186         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1187 else
1188         AC_MSG_ERROR([
1189 *** Pango not found. Pango built with Cairo support is required
1190 *** to build GTK+. See http://www.pango.org for Pango information.
1191 ])
1192 fi
1193
1194 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1195
1196 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1197         :
1198 else
1199         gtk_save_LIBS="$LIBS"
1200         LIBS="$PANGO_LIBS $LIBS"
1201         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1202 *** Can't link to Pango. Pango is required to build
1203 *** GTK+. For more information see http://www.pango.org]))
1204         LIBS="$gtk_save_LIBS"
1205 fi
1206
1207 CFLAGS="$saved_cflags"
1208 LDFLAGS="$saved_ldflags"
1209
1210 # Pull in gio-unix for GDesktopAppInfo usage, see at least gdkapplaunchcontext-x11.c
1211 if test "x$gdktarget" = "xx11" || test "x$gdktarget" = "xbroadway" ; then
1212   GDK_PACKAGES="$PANGO_PACKAGES gio-unix-2.0 $X_PACKAGES gdk-pixbuf-2.0 $cairo_backend cairo-gobject"
1213 else
1214   GDK_PACKAGES="$PANGO_PACKAGES gio-2.0 gdk-pixbuf-2.0 $cairo_backend cairo-gobject"
1215 fi
1216
1217 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1218 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1219 #
1220 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1221 # into the pkg-config files
1222 #
1223 if test $enable_explicit_deps != yes ; then
1224   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0"
1225   GDK_EXTRA_LIBS=
1226 fi
1227
1228 AC_SUBST(GDK_PACKAGES)
1229 AC_SUBST(GDK_EXTRA_LIBS)
1230 AC_SUBST(GDK_EXTRA_CFLAGS)
1231 AC_SUBST(GDK_DEP_LIBS)
1232 AC_SUBST(GDK_DEP_CFLAGS)
1233
1234
1235 ########################################
1236 # Check for Accessibility Toolkit flags
1237 ########################################
1238
1239 ATK_PACKAGES=atk
1240 AC_MSG_CHECKING(ATK flags)
1241 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1242         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1243         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1244
1245         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1246 else
1247         AC_MSG_ERROR([
1248 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1249 *** to build GTK+.
1250 ])
1251 fi
1252
1253 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1254         :
1255 else
1256         gtk_save_LIBS="$LIBS"
1257         LIBS="$ATK_LIBS $LIBS"
1258         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1259                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1260                 *** to build GTK+]))
1261         LIBS="$gtk_save_LIBS"
1262 fi
1263
1264 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1265 if test "x$gdktarget" = "xx11"; then
1266   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1267 fi
1268 GTK_EXTRA_LIBS=
1269 GTK_EXTRA_CFLAGS=
1270 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1271 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1272
1273 if test x"$os_win32" = xyes; then
1274   GTK_EXTRA_CFLAGS="$msnative_struct"
1275 fi
1276
1277 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1278 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1279 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1280 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1281
1282 AC_SUBST(GTK_PACKAGES)
1283 AC_SUBST(GTK_EXTRA_LIBS)
1284 AC_SUBST(GTK_EXTRA_CFLAGS)
1285 AC_SUBST(GTK_DEP_LIBS)
1286 AC_SUBST(GTK_DEP_CFLAGS)
1287
1288 AC_SUBST(GLIB_PREFIX)
1289 AC_SUBST(ATK_PREFIX)
1290 AC_SUBST(PANGO_PREFIX)
1291 AC_SUBST(CAIRO_PREFIX)
1292
1293 AC_SUBST(GTK_DEBUG_FLAGS)
1294 AC_SUBST(GTK_XIM_FLAGS)
1295
1296 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1297 AC_SUBST(GDK_PIXBUF_LIBS)
1298
1299 ########################
1300 # Checks needed for gail
1301 ########################
1302
1303 old_LIBS="$LIBS"
1304 dnl Checks for inet libraries:
1305 AC_SEARCH_LIBS(gethostent, nsl)
1306 AC_SEARCH_LIBS(setsockopt, socket)
1307 AC_SEARCH_LIBS(connect, inet)
1308
1309 dnl check for the sockaddr_un.sun_len member
1310 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1311                 [struct_sockaddr_un_sun_len=true],
1312                 [struct_sockaddr_un_suin_len=false],
1313                 [#include <sys/types.h>
1314                  #include <sys/un.h>]
1315                 )
1316 case $struct_sockaddr_un_sun_len in
1317         true)
1318                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1319                                    [Have the sockaddr_un.sun_len member])
1320                 ;;
1321         *)
1322                 ;;
1323 esac
1324
1325 GAIL_INET_LIBS="$LIBS"
1326 AC_SUBST([GAIL_INET_LIBS])
1327
1328 LIBS="$old_LIBS"
1329
1330 ################################################################
1331 # Printing system checks
1332 ################################################################
1333
1334 AC_ARG_ENABLE(cups,
1335               [AC_HELP_STRING([--disable-cups]
1336                               [disable cups print backend])],,
1337               [enable_cups=auto])
1338
1339 if test "x$enable_cups" = "xno"; then
1340   AM_CONDITIONAL(HAVE_CUPS, false)
1341 else
1342   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1343   if test "x$CUPS_CONFIG" = "xno"; then
1344     if test "x$enable_cups" = "xauto"; then
1345       AM_CONDITIONAL(HAVE_CUPS, false)
1346     else
1347       AC_MSG_ERROR([
1348 *** cups not found.
1349 ])
1350     fi
1351   else
1352     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1353     CUPS_LIBS=`$CUPS_CONFIG --libs`
1354
1355     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1356     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1357     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1358
1359     if test $CUPS_API_MAJOR -gt 1 -o \
1360             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1361       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1362                 [Define to 1 if CUPS 1.2 API is available])
1363     fi
1364
1365     AC_SUBST(CUPS_API_MAJOR)
1366     AC_SUBST(CUPS_API_MINOR)
1367     AC_SUBST(CUPS_CFLAGS)
1368     AC_SUBST(CUPS_LIBS)
1369
1370     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1371
1372     AM_CONDITIONAL(HAVE_CUPS, true)
1373
1374     gtk_save_cflags="$CFLAGS"
1375     CFLAGS="$CUPS_CFLAGS"
1376     AC_TRY_COMPILE([#include <cups/http.h>],
1377                    [http_t http; char *s = http.authstring;],
1378                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1379                               [Define if cups http_t authstring field is accessible])],)
1380     CFLAGS="$gtk_save_cflags"
1381
1382     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1383
1384     gtk_save_libs="$LIBS"
1385     LIBS="$CUPS_LIBS"
1386     AC_CHECK_FUNCS(httpGetAuthString)
1387     LIBS="$gtk_save_libs"
1388   fi
1389 fi
1390
1391 # Checks to see if we should compile with PAPI backend for GTK+
1392 #
1393
1394 AC_ARG_ENABLE(papi,
1395               [AC_HELP_STRING([--disable-papi]
1396                               [disable papi print backend])],,
1397              [enable_papi=auto])
1398
1399 if test "x$enable_papi" = "xno"; then
1400   AM_CONDITIONAL(HAVE_PAPI, false)
1401 else
1402   AC_MSG_CHECKING(libpapi)
1403   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1404   if test $have_papi = yes; then
1405     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1406   fi
1407   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1408   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1409     AC_MSG_ERROR([
1410 *** papi not found.
1411 ])
1412   fi
1413 fi
1414
1415 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1416
1417 gtk_save_cppflags="$CPPFLAGS"
1418 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1419
1420 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1421 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1422 *** backend enabled.]))
1423
1424 if test "$os_win32" != "yes"; then
1425   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1426 *** Can't find cairo-ps.h. You must build Cairo with the
1427 *** postscript backend enabled.]))
1428
1429   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1430 *** Can't find cairo-svg.h. You must build Cairo with the
1431 *** svg backend enabled.]))
1432 fi
1433
1434 CPPFLAGS="$gtk_save_cppflags"
1435
1436
1437 AC_ARG_ENABLE(test-print-backend,
1438               [AC_HELP_STRING([--enable-test-print-backend],
1439                               [build test print backend])],,
1440               [enable_test_print_backend=no])
1441 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1442
1443
1444 ################################################################
1445 # Strip -export-dynamic from the link lines of various libraries
1446 ################################################################
1447
1448 #
1449 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1450 #  but this flag is only meaningful for executables. For libraries
1451 #  the effect is undefined; what it causes on Linux is that the
1452 #  export list from -export-symbols-regex is ignored and everything
1453 #  is exported
1454 #
1455 # We are using gmodule-no-export now, but I'm leaving the stripping
1456 # code in place for now, since pango and atk still require gmodule.
1457 export SED
1458 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1459 if test -n "$export_dynamic"; then
1460   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1461   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1462 fi
1463
1464 #############
1465 # GSettings #
1466 #############
1467
1468 GLIB_GSETTINGS
1469
1470 ##################################################
1471 # GObject introspection
1472 ##################################################
1473
1474 GOBJECT_INTROSPECTION_CHECK([0.9.3])
1475
1476 ##################################################
1477 # Packagekit module
1478 #################################################
1479
1480 AC_ARG_ENABLE(packagekit,
1481               AC_HELP_STRING([--disable-packagekit],
1482                              [build packagekit open with module]))
1483
1484 ENABLE_PACKAGEKIT=
1485 if test "os_win32" != "yes"; then
1486         if test "x$enable_packagekit" != "xno"; then
1487                 ENABLE_PACKAGEKIT=1
1488                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1489         fi
1490 fi
1491
1492 AC_SUBST(ENABLE_PACKAGEKIT)
1493 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$ENABLE_PACKAGEKIT" = "x1")
1494
1495 ##################################################
1496 # Checks for gtk-doc and docbook-tools
1497 ##################################################
1498
1499 GTK_DOC_CHECK([1.11])
1500
1501 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1502 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1503
1504 AC_ARG_ENABLE(man,
1505               [AC_HELP_STRING([--enable-man],
1506                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1507               enable_man=no)
1508
1509 if test "${enable_man}" != no; then
1510   dnl
1511   dnl Check for xsltproc
1512   dnl
1513   AC_PATH_PROG([XSLTPROC], [xsltproc])
1514   if test -z "$XSLTPROC"; then
1515     enable_man=no
1516   fi
1517
1518   dnl check for DocBook DTD and stylesheets in the local catalog.
1519   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1520      [DocBook XML DTD V4.1.2],,enable_man=no)
1521   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1522      [DocBook XSL Stylesheets],,enable_man=no)
1523 fi
1524
1525 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1526
1527
1528 ##################################################
1529 # Output commands
1530 ##################################################
1531
1532 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1533         outfile=gdkconfig.h-tmp
1534         cat > $outfile <<\_______EOF
1535 /* gdkconfig.h
1536  *
1537  * This is a generated file.  Please modify `configure.ac'
1538  */
1539
1540 #ifndef GDKCONFIG_H
1541 #define GDKCONFIG_H
1542
1543 #ifdef __cplusplus
1544 extern "C" {
1545 #endif /* __cplusplus */
1546
1547 #ifndef GSEAL
1548 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
1549 #  ifdef GSEAL_ENABLE
1550 #    define GSEAL(ident)      _g_sealed__ ## ident
1551 #  else
1552 #    define GSEAL(ident)      ident
1553 #  endif
1554 #endif /* !GSEAL */
1555
1556 _______EOF
1557
1558         cat >>$outfile <<_______EOF
1559 $gdk_windowing
1560 $gdk_wc
1561 _______EOF
1562
1563         cat >>$outfile <<_______EOF
1564
1565 #ifdef __cplusplus
1566 }
1567 #endif /* __cplusplus */
1568
1569 #endif /* GDKCONFIG_H */
1570 _______EOF
1571
1572
1573         if cmp -s $outfile gdk/gdkconfig.h; then
1574           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1575           rm -f $outfile
1576         else
1577           mv $outfile gdk/gdkconfig.h
1578         fi
1579 ],[
1580 if test "x$gdktarget" = "xx11" ; then
1581   gdk_windowing='
1582 #define GDK_WINDOWING_X11'
1583 elif test "x$gdktarget" = "xwin32" ; then
1584   gdk_windowing='
1585 #define GDK_NATIVE_WINDOW_POINTER
1586
1587 #define GDK_WINDOWING_WIN32'
1588 elif test "x$gdktarget" = "xquartz" ; then
1589   gdk_windowing='
1590 #define GDK_WINDOWING_QUARTZ'
1591 elif test "x$gdktarget" = "xbroadway" ; then
1592   gdk_windowing='
1593 #define GDK_WINDOWING_BROADWAY'
1594 fi
1595
1596 if test x$gdk_wchar_h = xyes; then
1597   gdk_wc='
1598 #define GDK_HAVE_WCHAR_H 1'
1599 fi
1600 if test x$gdk_wctype_h = xyes; then
1601   gdk_wc="\$gdk_wc
1602 #define GDK_HAVE_WCTYPE_H 1"
1603 fi
1604 if test x$gdk_working_wctype = xno; then
1605   gdk_wc="\$gdk_wc
1606 #define GDK_HAVE_BROKEN_WCTYPE 1"
1607 fi
1608 ])
1609
1610 dnl
1611 dnl Check for -Bsymbolic-functions linker flag used to avoid
1612 dnl intra-library PLT jumps, if available.
1613 dnl
1614 AC_ARG_ENABLE(Bsymbolic,
1615               [AC_HELP_STRING([--disable-Bsymbolic],
1616                               [avoid linking with -Bsymbolic])],,
1617               [SAVED_LDFLAGS="${LDFLAGS}"
1618                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1619                LDFLAGS=-Wl,-Bsymbolic-functions
1620                AC_TRY_LINK([], [int main (void) { return 0; }],
1621                            AC_MSG_RESULT(yes)
1622                            enable_Bsymbolic=yes,
1623                            AC_MSG_RESULT(no)
1624                            enable_Bsymbolic=no)
1625                LDFLAGS="${SAVED_LDFLAGS}"])
1626
1627 if test "x${enable_Bsymbolic}" == "xyes"; then
1628   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1629 fi
1630 AC_SUBST(GTK_LINK_FLAGS)
1631
1632 AC_CONFIG_FILES([
1633 config.h.win32
1634 gtk-zip.sh
1635 Makefile
1636 gdk-3.0.pc
1637 gtk+-3.0.pc
1638 gtk+-unix-print-3.0.pc
1639 gail-3.0.pc
1640 gdk-3.0-uninstalled.pc
1641 gtk+-3.0-uninstalled.pc
1642 gail-3.0-uninstalled.pc
1643 m4macros/Makefile
1644 po/Makefile.in
1645 po-properties/Makefile.in
1646 demos/Makefile
1647 demos/gtk-demo/Makefile
1648 demos/gtk-demo/geninclude.pl
1649 examples/Makefile
1650 tests/Makefile
1651 docs/Makefile
1652 docs/reference/Makefile
1653 docs/reference/gdk/Makefile
1654 docs/reference/gdk/version.xml
1655 docs/reference/gtk/Makefile
1656 docs/reference/gtk/version.xml
1657 docs/reference/libgail-util/Makefile
1658 docs/tools/Makefile
1659 build/Makefile
1660 build/win32/Makefile
1661 build/win32/vs9/Makefile
1662 gdk/Makefile
1663 gdk/broadway/Makefile
1664 gdk/x11/Makefile
1665 gdk/win32/Makefile
1666 gdk/win32/rc/Makefile
1667 gdk/win32/rc/gdk.rc
1668 gdk/quartz/Makefile
1669 gdk/tests/Makefile
1670 gtk/Makefile
1671 gtk/makefile.msc
1672 gtk/gtkversion.h
1673 gtk/gtk-win32.rc
1674 gtk/theme-bits/Makefile
1675 gtk/tests/Makefile
1676 modules/Makefile
1677 modules/other/Makefile
1678 modules/other/gail/Makefile
1679 modules/other/gail/libgail-util/Makefile
1680 modules/other/gail/tests/Makefile
1681 modules/engines/Makefile
1682 modules/engines/pixbuf/Makefile
1683 modules/engines/ms-windows/Makefile
1684 modules/engines/ms-windows/Theme/Makefile
1685 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1686 modules/input/Makefile
1687 modules/printbackends/Makefile
1688 modules/printbackends/cups/Makefile
1689 modules/printbackends/lpr/Makefile
1690 modules/printbackends/file/Makefile
1691 modules/printbackends/papi/Makefile
1692 modules/printbackends/test/Makefile
1693 perf/Makefile
1694 ])
1695
1696 AC_OUTPUT
1697
1698 echo "configuration:
1699         target:             $gdktarget"