Pileus Git - ~andy/gtk/blob - acinclude.m4

   1 # autoconf 2.13 / 2.50 compatibility macro
   2
   3 # GLIB_AC_DIVERT_BEFORE_HELP(STUFF)
   4 # ---------------------------------
   5 # Put STUFF early enough so that they are available for $ac_help expansion.
   6 # Handle both classic (<= v2.13) and modern autoconf
   7 AC_DEFUN([GLIB_AC_DIVERT_BEFORE_HELP],
   8 [ifdef([m4_divert_text], [m4_divert_text([NOTICE],[$1])],
   9        [ifdef([AC_DIVERT], [AC_DIVERT([NOTICE],[$1])],
  10               [AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  11 $1
  12 AC_DIVERT_POP()])])])
  13
  14 # Checks the location of the XML Catalog
  15 # Usage:
  16 #   JH_PATH_XML_CATALOG
  17 # Defines XMLCATALOG and XML_CATALOG_FILE substitutions
  18 AC_DEFUN([JH_PATH_XML_CATALOG],
  19 [
  20   # check for the presence of the XML catalog
  21   AC_ARG_WITH([xml-catalog],
  22               AC_HELP_STRING([--with-xml-catalog=CATALOG],
  23                              [path to xml catalog to use]),,
  24               [with_xml_catalog=/etc/xml/catalog])
  25   XML_CATALOG_FILE="$with_xml_catalog"
  26   AC_MSG_CHECKING([for XML catalog ($XML_CATALOG_FILE)])
  27   if test -f "$XML_CATALOG_FILE"; then
  28     AC_MSG_RESULT([found])
  29   else
  30     AC_MSG_RESULT([not found])
  31     AC_MSG_ERROR([XML catalog not found])
  32   fi
  33   AC_SUBST([XML_CATALOG_FILE])
  34
  35   # check for the xmlcatalog program
  36   AC_PATH_PROG(XMLCATALOG, xmlcatalog, no)
  37   if test "x$XMLCATALOG" = xno; then
  38     AC_MSG_ERROR([could not find xmlcatalog program])
  39   fi
  40 ])
  41
  42 # Checks if a particular URI appears in the XML catalog
  43 # Usage:
  44 #   JH_CHECK_XML_CATALOG(URI, [FRIENDLY-NAME], [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
  45 AC_DEFUN([JH_CHECK_XML_CATALOG],
  46 [
  47   AC_REQUIRE([JH_PATH_XML_CATALOG])dnl
  48   AC_MSG_CHECKING([for ifelse([$2],,[$1],[$2]) in XML catalog])
  49   if AC_RUN_LOG([$XMLCATALOG --noout "$XML_CATALOG_FILE" "$1" >&2]); then
  50     AC_MSG_RESULT([found])
  51     ifelse([$3],,,[$3
  52 ])dnl
  53   else
  54     AC_MSG_RESULT([not found])
  55     ifelse([$4],,
  56        [AC_MSG_ERROR([could not find ifelse([$2],,[$1],[$2]) in XML catalog])],
  57        [$4])
  58   fi
  59 ])