Pileus Git - ~andy/fetchmail/blob - trio/configure.in

   1 dnl
   2 dnl Configuration for trio
   3 dnl
   4
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([triodef.h])
   7 AC_PREREQ(2.55) dnl autoconf 2.55 was released in 2002
   8
   9 AC_PROG_CC
  10 ifdef([AC_PROG_CC_STDC], [AC_PROG_CC_STDC])
  11 AC_LANG([C])
  12
  13 AC_PROG_INSTALL
  14 AC_PROG_RANLIB
  15
  16 dnl
  17 dnl Alpha floating-point compiler option.
  18 dnl
  19
  20 AC_MSG_CHECKING(for IEEE compilation options)
  21 AC_CACHE_VAL(ac_cv_ieee_option, [
  22   AC_COMPILE_IFELSE(AC_LANG_PROGRAM(,[[[
  23     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
  24     # error "Option needed"
  25     typedef int option_needed[-1];
  26     #endif
  27     ]]]),
  28     ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
  29     AC_COMPILE_IFELSE(AC_LANG_PROGRAM(,[[[
  30       #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__) && !defined(__GNUC__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
  31       # error "Option needed"
  32       typedef int option_needed[-1];
  33       #endif
  34       ]]]),
  35       ac_cv_ieee_option="-ieee",
  36       AC_COMPILE_IFELSE(AC_LANG_PROGRAM(,[[[
  37         #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
  38         # error "Option needed"
  39         typedef int option_needed[-1];
  40         #endif
  41         ]]]),
  42         ac_cv_ieee_option="-mieee",
  43         ac_cv_ieee_option="none"
  44       )
  45     )
  46   )
  47 ])
  48 AC_MSG_RESULT($ac_cv_ieee_option)
  49 if test $ac_cv_ieee_option != none; then
  50   CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
  51 fi
  52
  53 AC_CONFIG_FILES([Makefile])
  54 AC_OUTPUT