Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21 %}
  22
  23 /* this doesn't work with Linux lex, see the INSTALL file */
  24 %o 7000
  25 %a 4000
  26 %p 3000
  27 %option nounput noyywrap
  28
  29 %s NAME AUTH
  30
  31 %%
  32
  33 \"[^\"]*\"      {
  34                         yytext[yyleng-1] = '\0';
  35                         escapes(yytext+1, yytext);
  36                         yyleng = strlen(yytext);
  37                         yylval.sval = yytext;
  38                         SETSTATE(0);
  39                         return STRING;
  40                 }
  41 \'[^\']*\'      {
  42                         yytext[yyleng-1] = '\0';
  43                         escapes(yytext+1, yytext);
  44                         yyleng = strlen(yytext);
  45                         yylval.sval = yytext;
  46                         SETSTATE(0);
  47                         return STRING;
  48                 }
  49
  50 "*"             { BEGIN(0); return WILDCARD; }
  51
  52 <NAME>[^=;:, \t\r\n]+   {
  53                         static char *in;
  54                         static size_t ins;
  55
  56                         if ((size_t)yyleng + 1 > ins) {
  57                             ins = yyleng + 1;
  58                             in = (char *)xrealloc(in, ins);
  59                         }
  60                         memcpy(in, yytext, yyleng);
  61                         in[yyleng] = '\0';
  62                         escapes(in, in);
  63                         yyleng = strlen(in);
  64                         yylval.sval = in;
  65                         SETSTATE(0);
  66                         return STRING;
  67                 }
  68
  69 set             { return SET; }
  70 logfile         { return LOGFILE; }
  71 idfile          { return IDFILE; }
  72 pidfile         { return PIDFILE; }
  73 daemon          { return DAEMON; }
  74 syslog          { return SYSLOG; }
  75 invisible       { return INVISIBLE; }
  76 showdots        { return SHOWDOTS; }
  77 postmaster      { return POSTMASTER; }
  78 bouncemail      { return BOUNCEMAIL; }
  79 spambounce      { return SPAMBOUNCE; }
  80 warnings        { return WARNINGS; }
  81 tracepolls      { return TRACEPOLLS; }
  82
  83 defaults        { return DEFAULTS; }
  84 server          { return POLL; }
  85 poll            { return POLL; }
  86 skip            { return SKIP; }
  87 via             { return VIA; }
  88 aka             { return AKA; }
  89 local(domains)  { return LOCALDOMAINS; }
  90 proto(col)?     { return PROTOCOL; }
  91 service         { return SERVICE; }
  92 port            { return PORT; }
  93 interval        { return INTERVAL; }
  94 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  95 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  96 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  97 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
  98 kerberos(_v)?4  { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
  99 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
 100 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
 101 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
 102 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
 103 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
 104 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
 105 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
 106 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
 107 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
 108 timeout         { return TIMEOUT;}
 109 envelope        { return ENVELOPE; }
 110 qvirtual        { return QVIRTUAL; }
 111 principal       { return PRINCIPAL; }
 112 esmtpname       { return ESMTPNAME; }
 113 esmtppassword   { return ESMTPPASSWORD; }
 114
 115
 116 user(name)?     {SETSTATE(NAME); return USERNAME; }
 117 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 118 folder(s)?      { return FOLDER; }
 119 smtp(host)?     { return SMTPHOST; }
 120 fetchdomains    { return FETCHDOMAINS; }
 121 smtpaddress     { return SMTPADDRESS; }
 122 smtpname        { return SMTPNAME; }
 123 antispam        { return SPAMRESPONSE; }
 124 mda             { return MDA; }
 125 bsmtp           { return BSMTP; }
 126 lmtp            { return LMTP; }
 127 pre(connect)?   { return PRECONNECT; }
 128 post(connect)?  { return POSTCONNECT; }
 129 interface       { return INTERFACE; }
 130 monitor         { return MONITOR; }
 131 plugin          { return PLUGIN; }
 132 plugout         { return PLUGOUT; }
 133 batchlimit      { return BATCHLIMIT; }
 134 fetchlimit      { return FETCHLIMIT; }
 135 fetchsizelimit  { return FETCHSIZELIMIT; }
 136 fastuidl        { return FASTUIDL; }
 137 expunge         { return EXPUNGE; }
 138 properties      { return PROPERTIES; }
 139
 140 is              { SETSTATE(NAME); return IS; }
 141 here            { return HERE; }
 142 there           { return THERE; }
 143 to              { SETSTATE(NAME); return TO; }
 144 =               { SETSTATE(NAME); return MAP; }
 145
 146 nobouncemail    |
 147 nouidl          |
 148 nocheckalias    |
 149 nodns           |
 150 noenvelope      |
 151 nokeep          |
 152 noflush         |
 153 nolimitflush    |
 154 nofetchall      |
 155 norewrite       |
 156 noforcecr       |
 157 nostripcr       |
 158 nopass8(bits)?  |
 159 nodropstatus    |
 160 nodropdelivered |
 161 nomimedec(ode)? |
 162 nospambounce    |
 163 noidle          {
 164                    yyless(2);
 165                    return NO;
 166                 }
 167
 168 no              {return NO;}
 169
 170 keep            { return KEEP; }
 171 flush           { return FLUSH; }
 172 limitflush      { return LIMITFLUSH; }
 173 fetchall        { return FETCHALL; }
 174 rewrite         { return REWRITE; }
 175 forcecr         { return FORCECR; }
 176 stripcr         { return STRIPCR; }
 177 pass8(bits)?    { return PASS8BITS; }
 178 dropstatus      { return DROPSTATUS; }
 179 dropdelivered   { return DROPDELIVERED; }
 180 mimedec(ode)?   { return MIMEDECODE; }
 181 idle            { return IDLE; }
 182 dns             { return DNS; }
 183 uidl            { return UIDL; }
 184 ssl             { return SSL; }
 185 sslkey          { return SSLKEY; }
 186 sslcert         { return SSLCERT; }
 187 sslproto        { return SSLPROTO; }
 188 sslcertck       { return SSLCERTCK; }
 189 sslcertpath     { return SSLCERTPATH; }
 190 sslcommonname   { return SSLCOMMONNAME; }
 191 sslfingerprint  { return SSLFINGERPRINT; }
 192 checkalias      { return CHECKALIAS; }
 193
 194 limit           { return LIMIT; }
 195
 196 with            {/* EMPTY */}
 197 and             {/* EMPTY */}
 198 has             {/* EMPTY */}
 199 wants           {/* EMPTY */}
 200 options         {/* EMPTY */}
 201 [;:,]           {/* EMPTY */}
 202
 203 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 204 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 205 (sdps)|(SDPS)   { return SDPS; }
 206 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 207 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 208 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 209 (rpop)|(RPOP)   { yylval.proto = P_RPOP;  return PROTO; }
 210 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 211 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 212 (kpop)|(KPOP)   { return KPOP; }
 213
 214 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 215
 216 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 217
 218 [^=;:, \t\r\n]+ {
 219                         escapes(yytext, yytext);
 220                         yyleng = strlen(yytext);
 221                         yylval.sval = yytext;
 222                         return STRING;
 223                 }
 224
 225 [ \t\r]+        ;       /* whitespace */
 226
 227 %%
 228
 229 /** process standard C-style escape sequences in a string,
 230  * this can never lengthen the output, so cp and tp may overlap as long
 231  * as cp >= tp. */
 232 void escapes(const char *cp /** source string with escapes */,
 233              char       *tp /** target buffer for digested string */)
 234 {
 235     while (*cp)
 236     {
 237         int     cval = 0;
 238
 239         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 240          * always succeed! */
 241         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 242         {
 243             char *dp;
 244             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 245             int dcount = 0;
 246
 247             if (*++cp == 'x' || *cp == 'X')
 248                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 249                     cval = (cval * 16) + (dp - hex) / 2;
 250             else if (*cp == '0')
 251                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 252                     cval = (cval * 8) + (*cp++ - '0');
 253             else
 254                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 255                     cval = (cval * 10) + (*cp++ - '0');
 256         }
 257         else if (*cp == '\\')           /* C-style character escapes */
 258         {
 259             switch (*++cp)
 260             {
 261             case '\n': cp++; continue;  /* backslash before LF to join lines */
 262             case '\0': goto done;          /* ignore backslash at file end */
 263             case '\\': cval = '\\'; break;
 264             case 'n': cval = '\n'; break;
 265             case 't': cval = '\t'; break;
 266             case 'b': cval = '\b'; break;
 267             case 'r': cval = '\r'; break;
 268             default: cval = *cp;
 269             }
 270             cp++;
 271         }
 272         else
 273             cval = *cp++;
 274         *tp++ = cval;
 275     }
 276 done:
 277     *tp = '\0';
 278 }