Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15 %}
  16
  17 /* this doesn't work with Linux lex, see the INSTALL file */
  18 %o 6000
  19 %a 4000
  20
  21 %%
  22
  23 set             { return SET; }
  24 logfile         { return LOGFILE; }
  25 daemon          { return DAEMON; }
  26 syslog          { return SYSLOG; }
  27 invisible       { return INVISIBLE; }
  28
  29 defaults        { return DEFAULTS; }
  30 server          { return POLL; }
  31 poll            { return POLL; }
  32 skip            { return SKIP; }
  33 via             { return VIA; }
  34 aka             { return AKA; }
  35 local(domains)  { return LOCALDOMAINS; }
  36 proto(col)?     { return PROTOCOL; }
  37 port            { return PORT; }
  38 interval        { return INTERVAL; }
  39 auth(enticate)? { return AUTHENTICATE; }
  40 kerberos_v4     { return KERBEROS4; }
  41 kerberos        { return KERBEROS4; }
  42 timeout         { return TIMEOUT;}
  43 envelope        { return ENVELOPE; }
  44 qvirtual        { return QVIRTUAL; }
  45
  46 user(name)?     { return USERNAME; }
  47 pass(word)?     { return PASSWORD; }
  48 folder(s)?      { return FOLDER; }
  49 smtp(host)?     { return SMTPHOST; }
  50 mda             { return MDA; }
  51 pre(connect)?   { return PRECONNECT; }
  52 post(connect)?  { return POSTCONNECT; }
  53 interface       { return INTERFACE; }
  54 monitor         { return MONITOR; }
  55 batchlimit      { return BATCHLIMIT; }
  56 fetchlimit      { return FETCHLIMIT; }
  57 expunge         { return EXPUNGE; }
  58
  59 is              { return IS; }
  60 here            { return HERE; }
  61 there           { return THERE; }
  62 to              { return TO; }
  63 =               { return MAP; }
  64 "*"             { return WILDCARD; }
  65
  66 no/[kfrsdu \t].*        { return NO;}
  67
  68 keep            { return KEEP; }
  69 flush           { return FLUSH; }
  70 fetchall        { return FETCHALL; }
  71 rewrite         { return REWRITE; }
  72 forcecr         { return FORCECR; }
  73 stripcr         { return STRIPCR; }
  74 pass8(bits)?    { return PASS8BITS; }
  75 dropstatus?     { return DROPSTATUS; }
  76 dns             { return DNS; }
  77 uidl            { return UIDL; }
  78
  79 limit           { return LIMIT; }
  80
  81 with            {/* EMPTY */}
  82 and             {/* EMPTY */}
  83 has             {/* EMPTY */}
  84 wants           {/* EMPTY */}
  85 options         {/* EMPTY */}
  86 [;:,]           {/* EMPTY */}
  87
  88 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
  89 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
  90 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
  91 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
  92 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
  93 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
  94 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
  95 (kpop)|(KPOP)   { return KPOP; }
  96
  97 remote(folder)? {
  98                 fprintf(stderr,
  99                         "fetchmail: `remote' keyword is gone, use `folder'\n");
 100                 }
 101
 102
 103 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 104
 105 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 106
 107 \"[^\"]*\"      {
 108                         char buf[POPBUFSIZE];
 109
 110                         yytext[strlen(yytext)-1] = '\0';
 111                         escapes(yytext+1, buf);
 112                         yylval.sval = (char *) xstrdup(buf);
 113                         return STRING;
 114                 }
 115 [^=;:, \t\r\n]+ {
 116                         char buf[POPBUFSIZE];
 117
 118                         escapes(yytext, buf);
 119                         yylval.sval = (char *) xstrdup(buf);
 120                         return STRING;
 121                 }
 122
 123 [ \t\r]+        ;       /* whitespace */
 124
 125 %%
 126
 127 void escapes(cp, tp)
 128 /* process standard C-style escape sequences in a string */
 129 const char      *cp;    /* source string with escapes */
 130 char            *tp;    /* target buffer for digested string */
 131 {
 132     while (*cp)
 133     {
 134         int     cval = 0;
 135
 136         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 137         {
 138             char *dp, *hex = "00112233445566778899aAbBcCdDeEfF";
 139             int dcount = 0;
 140
 141             if (*++cp == 'x' || *cp == 'X')
 142                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 143                     cval = (cval * 16) + (dp - hex) / 2;
 144             else if (*cp == '0')
 145                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 146                     cval = (cval * 8) + (*cp++ - '0');
 147             else
 148                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 149                     cval = (cval * 10) + (*cp++ - '0');
 150         }
 151         else if (*cp == '\\')           /* C-style character escapes */
 152         {
 153             switch (*++cp)
 154             {
 155             case '\\': cval = '\\'; break;
 156             case 'n': cval = '\n'; break;
 157             case 't': cval = '\t'; break;
 158             case 'b': cval = '\b'; break;
 159             case 'r': cval = '\r'; break;
 160             default: cval = *cp;
 161             }
 162             cp++;
 163         }
 164         else
 165             cval = *cp++;
 166         *tp++ = cval;
 167     }
 168     *tp = '\0';
 169 }
 170