Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15 %}
  16
  17 /* this doesn't work with Linux lex, see the INSTALL file */
  18 %o 7000
  19 %a 4000
  20 %p 3000
  21
  22 %s NAME PREAUTH
  23
  24 %%
  25
  26 \"[^\"]*\"      {
  27                         char buf[MSGBUFSIZE];
  28
  29                         yytext[strlen(yytext)-1] = '\0';
  30                         escapes(yytext+1, buf);
  31                         yylval.sval = (char *) xstrdup(buf);
  32                         BEGIN(0);
  33                         return STRING;
  34                 }
  35 \'[^\']*\'      {
  36                         char buf[MSGBUFSIZE];
  37
  38                         yytext[strlen(yytext)-1] = '\0';
  39                         escapes(yytext+1, buf);
  40                         yylval.sval = (char *) xstrdup(buf);
  41                         BEGIN(0);
  42                         return STRING;
  43                 }
  44
  45 "*"             { BEGIN(0); return WILDCARD; }
  46
  47 <NAME>[^=;:, \t\r\n]+   {
  48                         char buf[MSGBUFSIZE];
  49
  50                         escapes(yytext, buf);
  51                         yylval.sval = (char *) xstrdup(buf);
  52                         BEGIN(0);
  53                         return STRING;
  54                 }
  55
  56 set             { return SET; }
  57 logfile         { return LOGFILE; }
  58 idfile          { return IDFILE; }
  59 daemon          { return DAEMON; }
  60 syslog          { return SYSLOG; }
  61 invisible       { return INVISIBLE; }
  62 postmaster      { return POSTMASTER; }
  63 bouncemail      { return BOUNCEMAIL; }
  64 warnings        { return WARNINGS; }
  65
  66 defaults        { return DEFAULTS; }
  67 server          { return POLL; }
  68 poll            { return POLL; }
  69 skip            { return SKIP; }
  70 via             { return VIA; }
  71 aka             { return AKA; }
  72 local(domains)  { return LOCALDOMAINS; }
  73 proto(col)?     { return PROTOCOL; }
  74 service         { return SERVICE; }
  75 port            { return PORT; }
  76 interval        { return INTERVAL; }
  77 preauth(enticate)?      { BEGIN(PREAUTH); return PREAUTHENTICATE; }
  78 kerberos(_v)?4  { BEGIN(0); return KERBEROS4; }
  79 kerberos(_v)?5  { BEGIN(0); return KERBEROS5; }
  80 kerberos        { BEGIN(0); return KERBEROS; }
  81 <PREAUTH>password { BEGIN(0); return PASSWORD; }
  82 timeout         { return TIMEOUT;}
  83 envelope        { return ENVELOPE; }
  84 qvirtual        { return QVIRTUAL; }
  85
  86 user(name)?     {BEGIN(NAME); return USERNAME; }
  87 pass(word)?     {BEGIN(NAME); return PASSWORD; }
  88 folder(s)?      { return FOLDER; }
  89 smtp(host)?     { return SMTPHOST; }
  90 smtpaddress     { return SMTPADDRESS; }
  91 antispam        { return SPAMRESPONSE; }
  92 mda             { return MDA; }
  93 bsmtp           { return BSMTP; }
  94 lmtp            { return LMTP; }
  95 pre(connect)?   { return PRECONNECT; }
  96 post(connect)?  { return POSTCONNECT; }
  97 netsec          { return NETSEC; }
  98 interface       { return INTERFACE; }
  99 monitor         { return MONITOR; }
 100 plugin          { return PLUGIN; }
 101 plugout         { return PLUGIN; }
 102 batchlimit      { return BATCHLIMIT; }
 103 fetchlimit      { return FETCHLIMIT; }
 104 expunge         { return EXPUNGE; }
 105 properties      { return PROPERTIES; }
 106
 107 is              { BEGIN(NAME); return IS; }
 108 here            { return HERE; }
 109 there           { return THERE; }
 110 to              { BEGIN(NAME); return TO; }
 111 =               { BEGIN(NAME); return MAP; }
 112
 113 nobouncemail    |
 114 nouidl          |
 115 nocheckalias    |
 116 nodns           |
 117 noenvelope      |
 118 nokeep          |
 119 noflush         |
 120 nofetchall      |
 121 norewrite       |
 122 noforcecr       |
 123 nostripcr       |
 124 nopass8(bits)?  |
 125 nodropstatus    |
 126 nomimedec(ode)? {
 127                    yyless(2);
 128                    return NO;
 129                 }
 130
 131 no              {return NO;}
 132
 133 keep            { return KEEP; }
 134 flush           { return FLUSH; }
 135 fetchall        { return FETCHALL; }
 136 rewrite         { return REWRITE; }
 137 forcecr         { return FORCECR; }
 138 stripcr         { return STRIPCR; }
 139 pass8(bits)?    { return PASS8BITS; }
 140 dropstatus      { return DROPSTATUS; }
 141 mimedec(ode)?   { return MIMEDECODE; }
 142 dns             { return DNS; }
 143 uidl            { return UIDL; }
 144 checkalias      { return CHECKALIAS; }
 145
 146 limit           { return LIMIT; }
 147
 148 with            {/* EMPTY */}
 149 and             {/* EMPTY */}
 150 has             {/* EMPTY */}
 151 wants           {/* EMPTY */}
 152 options         {/* EMPTY */}
 153 [;:,]           {/* EMPTY */}
 154
 155 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 156 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 157 (sdps)|(SDPS)   { return SDPS; }
 158 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 159 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
 160 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
 161 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 162 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 163 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 164 (kpop)|(KPOP)   { return KPOP; }
 165
 166 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 167
 168 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 169
 170 [^=;:, \t\r\n]+ {
 171                         char buf[MSGBUFSIZE];
 172
 173                         escapes(yytext, buf);
 174                         yylval.sval = (char *) xstrdup(buf);
 175                         return STRING;
 176                 }
 177
 178 [ \t\r]+        ;       /* whitespace */
 179
 180 %%
 181
 182 void escapes(cp, tp)
 183 /* process standard C-style escape sequences in a string */
 184 const char      *cp;    /* source string with escapes */
 185 char            *tp;    /* target buffer for digested string */
 186 {
 187     while (*cp)
 188     {
 189         int     cval = 0;
 190
 191         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 192         {
 193             char *dp;
 194             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 195             int dcount = 0;
 196
 197             if (*++cp == 'x' || *cp == 'X')
 198                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 199                     cval = (cval * 16) + (dp - hex) / 2;
 200             else if (*cp == '0')
 201                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 202                     cval = (cval * 8) + (*cp++ - '0');
 203             else
 204                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 205                     cval = (cval * 10) + (*cp++ - '0');
 206         }
 207         else if (*cp == '\\')           /* C-style character escapes */
 208         {
 209             switch (*++cp)
 210             {
 211             case '\\': cval = '\\'; break;
 212             case 'n': cval = '\n'; break;
 213             case 't': cval = '\t'; break;
 214             case 'b': cval = '\b'; break;
 215             case 'r': cval = '\r'; break;
 216             default: cval = *cp;
 217             }
 218             cp++;
 219         }
 220         else
 221             cval = *cp++;
 222         *tp++ = cval;
 223     }
 224     *tp = '\0';
 225 }
 226