Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15 %}
  16
  17 /* this doesn't work with Linux lex, see the INSTALL file */
  18 %o 7000
  19 %a 4000
  20 %p 3000
  21
  22 %%
  23
  24 set             { return SET; }
  25 logfile         { return LOGFILE; }
  26 idfile          { return IDFILE; }
  27 daemon          { return DAEMON; }
  28 syslog          { return SYSLOG; }
  29 invisible       { return INVISIBLE; }
  30 postmaster      { return POSTMASTER; }
  31 warnings        { return WARNINGS; }
  32
  33 defaults        { return DEFAULTS; }
  34 server          { return POLL; }
  35 poll            { return POLL; }
  36 skip            { return SKIP; }
  37 via             { return VIA; }
  38 aka             { return AKA; }
  39 local(domains)  { return LOCALDOMAINS; }
  40 proto(col)?     { return PROTOCOL; }
  41 service         { return SERVICE; }
  42 port            { return PORT; }
  43 interval        { return INTERVAL; }
  44 auth(enticate)? { return AUTHENTICATE; }
  45 kerberos(_v)?4  { return KERBEROS4; }
  46 kerberos(_v)?5  { return KERBEROS5; }
  47 kerberos        { return KERBEROS; }
  48 timeout         { return TIMEOUT;}
  49 envelope        { return ENVELOPE; }
  50 qvirtual        { return QVIRTUAL; }
  51
  52 user(name)?     { return USERNAME; }
  53 pass(word)?     { return PASSWORD; }
  54 folder(s)?      { return FOLDER; }
  55 smtp(host)?     { return SMTPHOST; }
  56 smtpaddress     { return SMTPADDRESS; }
  57 antispam        { return SPAMRESPONSE; }
  58 mda             { return MDA; }
  59 bsmtp           { return BSMTP; }
  60 pre(connect)?   { return PRECONNECT; }
  61 post(connect)?  { return POSTCONNECT; }
  62 netsec          { return NETSEC; }
  63 interface       { return INTERFACE; }
  64 monitor         { return MONITOR; }
  65 batchlimit      { return BATCHLIMIT; }
  66 fetchlimit      { return FETCHLIMIT; }
  67 expunge         { return EXPUNGE; }
  68 properties      { return PROPERTIES; }
  69
  70 is              { return IS; }
  71 here            { return HERE; }
  72 there           { return THERE; }
  73 to              { return TO; }
  74 =               { return MAP; }
  75 "*"             { return WILDCARD; }
  76
  77 no/[kfrsduc \t].*       { return NO;}
  78
  79 keep            { return KEEP; }
  80 flush           { return FLUSH; }
  81 fetchall        { return FETCHALL; }
  82 rewrite         { return REWRITE; }
  83 forcecr         { return FORCECR; }
  84 stripcr         { return STRIPCR; }
  85 pass8(bits)?    { return PASS8BITS; }
  86 dropstatus?     { return DROPSTATUS; }
  87 mimedec(ode)?   { return MIMEDECODE; }
  88 dns             { return DNS; }
  89 uidl            { return UIDL; }
  90 checkalias      { return CHECKALIAS; }
  91
  92 limit           { return LIMIT; }
  93
  94 with            {/* EMPTY */}
  95 and             {/* EMPTY */}
  96 has             {/* EMPTY */}
  97 wants           {/* EMPTY */}
  98 options         {/* EMPTY */}
  99 [;:,]           {/* EMPTY */}
 100
 101 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 102 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 103 (sdps)|(SDPS)   { return SDPS; }
 104 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 105 (imap-k4)|(IMAP-K4)   { yylval.proto = P_IMAP_K4;  return PROTO; }
 106 (imap-gss)|(IMAP-GSS) { yylval.proto = P_IMAP_GSS;  return PROTO; }
 107 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 108 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 109 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 110 (kpop)|(KPOP)   { return KPOP; }
 111
 112 remote(folder)? {
 113                 fprintf(stderr,
 114                         "fetchmail: `remote' keyword is gone, use `folder'\n");
 115                 }
 116
 117
 118 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 119
 120 [0-9]+          { yylval.number = atoi(yytext); return NUMBER; }
 121
 122 \"[^\"]*\"      {
 123                         char buf[MSGBUFSIZE];
 124
 125                         yytext[strlen(yytext)-1] = '\0';
 126                         escapes(yytext+1, buf);
 127                         yylval.sval = (char *) xstrdup(buf);
 128                         return STRING;
 129                 }
 130 [^=;:, \t\r\n]+ {
 131                         char buf[MSGBUFSIZE];
 132
 133                         escapes(yytext, buf);
 134                         yylval.sval = (char *) xstrdup(buf);
 135                         return STRING;
 136                 }
 137
 138 [ \t\r]+        ;       /* whitespace */
 139
 140 %%
 141
 142 void escapes(cp, tp)
 143 /* process standard C-style escape sequences in a string */
 144 const char      *cp;    /* source string with escapes */
 145 char            *tp;    /* target buffer for digested string */
 146 {
 147     while (*cp)
 148     {
 149         int     cval = 0;
 150
 151         if (*cp == '\\' && strchr("0123456789xX", cp[1]))
 152         {
 153             char *dp;
 154             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 155             int dcount = 0;
 156
 157             if (*++cp == 'x' || *cp == 'X')
 158                 for (++cp; (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 159                     cval = (cval * 16) + (dp - hex) / 2;
 160             else if (*cp == '0')
 161                 while (strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 162                     cval = (cval * 8) + (*cp++ - '0');
 163             else
 164                 while ((strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 165                     cval = (cval * 10) + (*cp++ - '0');
 166         }
 167         else if (*cp == '\\')           /* C-style character escapes */
 168         {
 169             switch (*++cp)
 170             {
 171             case '\\': cval = '\\'; break;
 172             case 'n': cval = '\n'; break;
 173             case 't': cval = '\t'; break;
 174             case 'b': cval = '\b'; break;
 175             case 'r': cval = '\r'; break;
 176             default: cval = *cp;
 177             }
 178             cp++;
 179         }
 180         else
 181             cval = *cp++;
 182         *tp++ = cval;
 183     }
 184     *tp = '\0';
 185 }
 186