Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21
  22 #define YY_NO_INPUT
  23
  24 %}
  25
  26 /* this doesn't work with Linux lex, see the INSTALL file */
  27 %o 7000
  28 %a 4000
  29 %p 3000
  30 %option nounput noyywrap
  31
  32 %s NAME AUTH
  33
  34 %%
  35
  36 \"[^\"]*\"      {
  37                         yytext[yyleng-1] = '\0';
  38                         escapes(yytext+1, yytext);
  39                         yyleng = strlen(yytext);
  40                         yylval.sval = yytext;
  41                         SETSTATE(0);
  42                         return STRING;
  43                 }
  44 \'[^\']*\'      {
  45                         yytext[yyleng-1] = '\0';
  46                         escapes(yytext+1, yytext);
  47                         yyleng = strlen(yytext);
  48                         yylval.sval = yytext;
  49                         SETSTATE(0);
  50                         return STRING;
  51                 }
  52
  53 "*"             { BEGIN(0); return WILDCARD; }
  54
  55 <NAME>[^=;:, \t\r\n]+   {
  56                         static char *in;
  57                         static size_t ins;
  58
  59                         if ((size_t)yyleng + 1 > ins) {
  60                             ins = yyleng + 1;
  61                             in = (char *)xrealloc(in, ins);
  62                         }
  63                         memcpy(in, yytext, yyleng);
  64                         in[yyleng] = '\0';
  65                         escapes(in, in);
  66                         yyleng = strlen(in);
  67                         yylval.sval = in;
  68                         SETSTATE(0);
  69                         return STRING;
  70                 }
  71
  72 set             { return SET; }
  73 logfile         { return LOGFILE; }
  74 idfile          { return IDFILE; }
  75 pidfile         { return PIDFILE; }
  76 daemon          { return DAEMON; }
  77 syslog          { return SYSLOG; }
  78 invisible       { return INVISIBLE; }
  79 showdots        { return SHOWDOTS; }
  80 postmaster      { return POSTMASTER; }
  81 bouncemail      { return BOUNCEMAIL; }
  82 spambounce      { return SPAMBOUNCE; }
  83 softbounce      { return SOFTBOUNCE; }
  84 warnings        { return WARNINGS; }
  85 tracepolls      { return TRACEPOLLS; }
  86
  87 defaults        { return DEFAULTS; }
  88 server          { return POLL; }
  89 poll            { return POLL; }
  90 skip            { return SKIP; }
  91 via             { return VIA; }
  92 aka             { return AKA; }
  93 local(domains)? { return LOCALDOMAINS; }
  94 proto(col)?     { return PROTOCOL; }
  95 service         { return SERVICE; }
  96 port            { return PORT; }
  97 interval        { return INTERVAL; }
  98 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  99 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
 100 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
 101 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
 102 kerberos(_v)?4  { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
 103 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
 104 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
 105 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
 106 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
 107 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
 108 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
 109 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
 110 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
 111 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
 112 timeout         { return TIMEOUT;}
 113 envelope        { return ENVELOPE; }
 114 qvirtual        { return QVIRTUAL; }
 115 principal       { return PRINCIPAL; }
 116 esmtpname       { return ESMTPNAME; }
 117 esmtppassword   { return ESMTPPASSWORD; }
 118 bad-header      { return BADHEADER; }
 119 accept          { return ACCEPT; }
 120 reject          { return REJECT_; }
 121
 122 user(name)?     {SETSTATE(NAME); return USERNAME; }
 123 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 124 folder(s)?      { return FOLDER; }
 125 smtp(host)?     { return SMTPHOST; }
 126 fetchdomains    { return FETCHDOMAINS; }
 127 smtpaddress     { return SMTPADDRESS; }
 128 smtpname        { return SMTPNAME; }
 129 antispam        { return SPAMRESPONSE; }
 130 mda             { return MDA; }
 131 bsmtp           { return BSMTP; }
 132 lmtp            { return LMTP; }
 133 pre(connect)?   { return PRECONNECT; }
 134 post(connect)?  { return POSTCONNECT; }
 135 interface       { return INTERFACE; }
 136 monitor         { return MONITOR; }
 137 plugin          { return PLUGIN; }
 138 plugout         { return PLUGOUT; }
 139 batchlimit      { return BATCHLIMIT; }
 140 fetchlimit      { return FETCHLIMIT; }
 141 fetchsizelimit  { return FETCHSIZELIMIT; }
 142 fastuidl        { return FASTUIDL; }
 143 expunge         { return EXPUNGE; }
 144 properties      { return PROPERTIES; }
 145
 146 is              { SETSTATE(NAME); return IS; }
 147 here            { return HERE; }
 148 there           { return THERE; }
 149 to              { SETSTATE(NAME); return TO; }
 150 =               { SETSTATE(NAME); return MAP; }
 151
 152 nobouncemail    |
 153 nouidl          |
 154 nocheckalias    |
 155 nodns           |
 156 noenvelope      |
 157 nokeep          |
 158 noflush         |
 159 nolimitflush    |
 160 nofetchall      |
 161 norewrite       |
 162 noforcecr       |
 163 nostripcr       |
 164 nopass8(bits)?  |
 165 nodropstatus    |
 166 nodropdelivered |
 167 nomimedec(ode)? |
 168 nospambounce    |
 169 noidle          {
 170                    yyless(2);
 171                    return NO;
 172                 }
 173
 174 no              {return NO;}
 175
 176 keep            { return KEEP; }
 177 flush           { return FLUSH; }
 178 limitflush      { return LIMITFLUSH; }
 179 fetchall        { return FETCHALL; }
 180 rewrite         { return REWRITE; }
 181 forcecr         { return FORCECR; }
 182 stripcr         { return STRIPCR; }
 183 pass8(bits)?    { return PASS8BITS; }
 184 dropstatus      { return DROPSTATUS; }
 185 dropdelivered   { return DROPDELIVERED; }
 186 mimedec(ode)?   { return MIMEDECODE; }
 187 idle            { return IDLE; }
 188 dns             { return DNS; }
 189 uidl            { return UIDL; }
 190 ssl             { return SSL; }
 191 sslkey          { return SSLKEY; }
 192 sslcert         { return SSLCERT; }
 193 sslproto        { return SSLPROTO; }
 194 sslcertck       { return SSLCERTCK; }
 195 sslcertpath     { return SSLCERTPATH; }
 196 sslcommonname   { return SSLCOMMONNAME; }
 197 sslfingerprint  { return SSLFINGERPRINT; }
 198 checkalias      { return CHECKALIAS; }
 199
 200 limit           { return LIMIT; }
 201
 202 with            {/* EMPTY */}
 203 and             {/* EMPTY */}
 204 has             {/* EMPTY */}
 205 wants           {/* EMPTY */}
 206 options         {/* EMPTY */}
 207 [;:,]           {/* EMPTY */}
 208
 209 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 210 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 211 (sdps)|(SDPS)   { return SDPS; }
 212 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 213 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 214 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 215 (rpop)|(RPOP)   { yylval.proto = P_RPOP;  return PROTO; }
 216 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 217 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 218 (kpop)|(KPOP)   { return KPOP; }
 219
 220 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 221
 222 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 223
 224 [^=;:, \t\r\n]+ {
 225                         escapes(yytext, yytext);
 226                         yyleng = strlen(yytext);
 227                         yylval.sval = yytext;
 228                         return STRING;
 229                 }
 230
 231 [ \t\r]+        ;       /* whitespace */
 232
 233 %%
 234
 235 /** process standard C-style escape sequences in a string,
 236  * this can never lengthen the output, so cp and tp may overlap as long
 237  * as cp >= tp. */
 238 void escapes(const char *cp /** source string with escapes */,
 239              char       *tp /** target buffer for digested string */)
 240 {
 241     while (*cp)
 242     {
 243         int     cval = 0;
 244
 245         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 246          * always succeed! */
 247         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 248         {
 249             const char *dp;
 250             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 251             int dcount = 0;
 252
 253             if (*++cp == 'x' || *cp == 'X')
 254                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 255                     cval = (cval * 16) + (dp - hex) / 2;
 256             else if (*cp == '0')
 257                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 258                     cval = (cval * 8) + (*cp++ - '0');
 259             else
 260                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 261                     cval = (cval * 10) + (*cp++ - '0');
 262         }
 263         else if (*cp == '\\')           /* C-style character escapes */
 264         {
 265             switch (*++cp)
 266             {
 267             case '\n': cp++; continue;  /* backslash before LF to join lines */
 268             case '\0': goto done;          /* ignore backslash at file end */
 269             case '\\': cval = '\\'; break;
 270             case 'n': cval = '\n'; break;
 271             case 't': cval = '\t'; break;
 272             case 'b': cval = '\b'; break;
 273             case 'r': cval = '\r'; break;
 274             default: cval = *cp;
 275             }
 276             cp++;
 277         }
 278         else
 279             cval = *cp++;
 280         *tp++ = cval;
 281     }
 282 done:
 283     *tp = '\0';
 284 }