Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file, to be used with GNU flex.
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "xmalloc.h"
  13 #include "rcfile_y.h"
  14
  15 int prc_lineno = 1;
  16
  17 #ifdef LEXDEBUG
  18 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  19 #else
  20 #define SETSTATE(n)     BEGIN(n)
  21 #endif /* LEXDEBUG */
  22
  23 #define YY_NO_INPUT
  24
  25 %}
  26
  27 %option nounput noyywrap
  28 %option warn nodefault
  29 %option 8bit batch
  30
  31 %s NAME AUTH
  32
  33 %%
  34
  35 \"[^\"]*\"      |
  36 \'[^\']*\'      {
  37                         char *in = xstrndup(yytext+1, yyleng-2);
  38                         escapes(in, in);
  39                         yylval.sval = in;
  40                         SETSTATE(0);
  41                         return STRING;
  42                 }
  43
  44 <NAME>[^=;:, \t\r\n]+   {
  45                         char *in = xstrdup(yytext);
  46                         escapes(in, in);
  47                         yylval.sval = in;
  48                         SETSTATE(0);
  49                         return STRING;
  50                 }
  51
  52 set             { return SET; }
  53 logfile         { return LOGFILE; }
  54 idfile          { return IDFILE; }
  55 pidfile         { return PIDFILE; }
  56 daemon          { return DAEMON; }
  57 syslog          { return SYSLOG; }
  58 invisible       { return INVISIBLE; }
  59 showdots        { return SHOWDOTS; }
  60 postmaster      { return POSTMASTER; }
  61 bouncemail      { return BOUNCEMAIL; }
  62 spambounce      { return SPAMBOUNCE; }
  63 softbounce      { return SOFTBOUNCE; }
  64 warnings        { return WARNINGS; }
  65 tracepolls      { return TRACEPOLLS; }
  66
  67 defaults        { return DEFAULTS; }
  68 server          { return POLL; }
  69 poll            { return POLL; }
  70 skip            { return SKIP; }
  71 via             { return VIA; }
  72 aka             { return AKA; }
  73 local(domains)? { return LOCALDOMAINS; }
  74 proto(col)?     { return PROTOCOL; }
  75 service         { return SERVICE; }
  76 port            { return PORT; }
  77 interval        { return INTERVAL; }
  78 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  79 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  80 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  81 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
  82 kerberos(_v)?4  { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
  83 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  84 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
  85 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
  86 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
  87 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
  88 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
  89 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
  90 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
  91 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
  92 timeout         { return TIMEOUT;}
  93 envelope        { return ENVELOPE; }
  94 qvirtual        { return QVIRTUAL; }
  95 principal       { return PRINCIPAL; }
  96 esmtpname       { return ESMTPNAME; }
  97 esmtppassword   { return ESMTPPASSWORD; }
  98 bad-header      { return BADHEADER; }
  99 accept          { return ACCEPT; }
 100 reject          { return REJECT_; }
 101
 102 user(name)?     {SETSTATE(NAME); return USERNAME; }
 103 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 104 folder(s)?      { return FOLDER; }
 105 smtp(host)?     { return SMTPHOST; }
 106 fetchdomains    { return FETCHDOMAINS; }
 107 smtpaddress     { return SMTPADDRESS; }
 108 smtpname        { return SMTPNAME; }
 109 antispam        { return SPAMRESPONSE; }
 110 mda             { return MDA; }
 111 bsmtp           { return BSMTP; }
 112 lmtp            { return LMTP; }
 113 pre(connect)?   { return PRECONNECT; }
 114 post(connect)?  { return POSTCONNECT; }
 115 interface       { return INTERFACE; }
 116 monitor         { return MONITOR; }
 117 plugin          { return PLUGIN; }
 118 plugout         { return PLUGOUT; }
 119 batchlimit      { return BATCHLIMIT; }
 120 fetchlimit      { return FETCHLIMIT; }
 121 fetchsizelimit  { return FETCHSIZELIMIT; }
 122 fastuidl        { return FASTUIDL; }
 123 expunge         { return EXPUNGE; }
 124 properties      { return PROPERTIES; }
 125
 126 is              { SETSTATE(NAME); return IS; }
 127 here            { return HERE; }
 128 there           { return THERE; }
 129 to              { SETSTATE(NAME); return TO; }
 130 =               { SETSTATE(NAME); return MAP; }
 131
 132 nobouncemail    |
 133 nouidl          |
 134 nocheckalias    |
 135 nodns           |
 136 noenvelope      |
 137 nokeep          |
 138 noflush         |
 139 nolimitflush    |
 140 nofetchall      |
 141 norewrite       |
 142 noforcecr       |
 143 nostripcr       |
 144 nopass8(bits)?  |
 145 nodropstatus    |
 146 nodropdelivered |
 147 nomimedec(ode)? |
 148 nospambounce    |
 149 noidle          {
 150                    yyless(2);
 151                    return NO;
 152                 }
 153
 154 no              {return NO;}
 155
 156 keep            { return KEEP; }
 157 flush           { return FLUSH; }
 158 limitflush      { return LIMITFLUSH; }
 159 fetchall        { return FETCHALL; }
 160 rewrite         { return REWRITE; }
 161 forcecr         { return FORCECR; }
 162 stripcr         { return STRIPCR; }
 163 pass8(bits)?    { return PASS8BITS; }
 164 dropstatus      { return DROPSTATUS; }
 165 dropdelivered   { return DROPDELIVERED; }
 166 mimedec(ode)?   { return MIMEDECODE; }
 167 idle            { return IDLE; }
 168 dns             { return DNS; }
 169 uidl            { return UIDL; }
 170 ssl             { return SSL; }
 171 sslkey          { return SSLKEY; }
 172 sslcert         { return SSLCERT; }
 173 sslproto        { return SSLPROTO; }
 174 sslcertck       { return SSLCERTCK; }
 175 sslcertfile     { return SSLCERTFILE; }
 176 sslcertpath     { return SSLCERTPATH; }
 177 sslcommonname   { return SSLCOMMONNAME; }
 178 sslfingerprint  { return SSLFINGERPRINT; }
 179 checkalias      { return CHECKALIAS; }
 180
 181 limit           { return LIMIT; }
 182
 183 with            {/* EMPTY */}
 184 and             {/* EMPTY */}
 185 has             {/* EMPTY */}
 186 wants           {/* EMPTY */}
 187 options         {/* EMPTY */}
 188 [;:,]           {/* EMPTY */}
 189
 190 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 191 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 192 (sdps)|(SDPS)   { return SDPS; }
 193 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 194 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 195 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 196 (rpop)|(RPOP)   { yylval.proto = P_RPOP;  return PROTO; }
 197 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 198 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 199 (kpop)|(KPOP)   { return KPOP; }
 200
 201 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 202
 203 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 204
 205 [^=;:, \t\r\n]+ {
 206                         char *in = xstrdup(yytext);
 207                         escapes(in, in);
 208                         yylval.sval = in;
 209                         return STRING;
 210                 }
 211
 212 [ \t\r]+        ;       /* whitespace */
 213
 214 %%
 215
 216 /** process standard C-style escape sequences in a string,
 217  * this can never lengthen the output, so cp and tp may overlap as long
 218  * as cp >= tp. */
 219 void escapes(const char *cp /** source string with escapes */,
 220              char       *tp /** target buffer for digested string */)
 221 {
 222     while (*cp)
 223     {
 224         int     cval = 0;
 225
 226         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 227          * always succeed! */
 228         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 229         {
 230             const char *dp;
 231             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 232             int dcount = 0;
 233
 234             if (*++cp == 'x' || *cp == 'X')
 235                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 236                     cval = (cval * 16) + (dp - hex) / 2;
 237             else if (*cp == '0')
 238                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 239                     cval = (cval * 8) + (*cp++ - '0');
 240             else
 241                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 242                     cval = (cval * 10) + (*cp++ - '0');
 243         }
 244         else if (*cp == '\\')           /* C-style character escapes */
 245         {
 246             switch (*++cp)
 247             {
 248             case '\n': cp++; continue;  /* backslash before LF to join lines */
 249             case '\0': goto done;          /* ignore backslash at file end */
 250             case '\\': cval = '\\'; break;
 251             case 'n': cval = '\n'; break;
 252             case 't': cval = '\t'; break;
 253             case 'b': cval = '\b'; break;
 254             case 'r': cval = '\r'; break;
 255             default: cval = *cp;
 256             }
 257             cp++;
 258         }
 259         else
 260             cval = *cp++;
 261         *tp++ = cval;
 262     }
 263 done:
 264     *tp = '\0';
 265 }