Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file, to be used with GNU flex.
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8
   9 #include "config.h"
  10 #include "fetchmail.h"
  11 #include "xmalloc.h"
  12 #include "rcfile_y.h"
  13
  14 #include <string.h>
  15
  16 int prc_lineno = 1;
  17
  18 #ifdef LEXDEBUG
  19 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  20 #else
  21 #define SETSTATE(n)     BEGIN(n)
  22 #endif /* LEXDEBUG */
  23
  24 #define YY_NO_INPUT
  25
  26 %}
  27
  28 %option nounput noyywrap
  29 %option warn nodefault
  30 %option 8bit batch
  31
  32 %s NAME AUTH
  33
  34 %%
  35
  36 \"[^\"]*\"      |
  37 \'[^\']*\'      {
  38                         char *in = xstrndup(yytext+1, yyleng-2);
  39                         escapes(in, in);
  40                         yylval.sval = in;
  41                         SETSTATE(0);
  42                         return STRING;
  43                 }
  44
  45 <NAME>[^=;:, \t\r\n]+   {
  46                         char *in = xstrdup(yytext);
  47                         escapes(in, in);
  48                         yylval.sval = in;
  49                         SETSTATE(0);
  50                         return STRING;
  51                 }
  52
  53 set             { return SET; }
  54 logfile         { return LOGFILE; }
  55 idfile          { return IDFILE; }
  56 pidfile         { return PIDFILE; }
  57 daemon          { return DAEMON; }
  58 syslog          { return SYSLOG; }
  59 invisible       { return INVISIBLE; }
  60 showdots        { return SHOWDOTS; }
  61 postmaster      { return POSTMASTER; }
  62 bouncemail      { return BOUNCEMAIL; }
  63 spambounce      { return SPAMBOUNCE; }
  64 softbounce      { return SOFTBOUNCE; }
  65 warnings        { return WARNINGS; }
  66 tracepolls      { return TRACEPOLLS; }
  67
  68 defaults        { return DEFAULTS; }
  69 server          { return POLL; }
  70 poll            { return POLL; }
  71 skip            { return SKIP; }
  72 via             { return VIA; }
  73 aka             { return AKA; }
  74 local(domains)? { return LOCALDOMAINS; }
  75 proto(col)?     { return PROTOCOL; }
  76 service         { return SERVICE; }
  77 port            { return PORT; }
  78 interval        { return INTERVAL; }
  79 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  80 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  81 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  82 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
  83 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  84 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
  85 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
  86 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
  87 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
  88 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
  89 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
  90 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
  91 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
  92 apop            { SETSTATE(0); yylval.proto = A_APOP; return AUTHTYPE;}
  93 timeout         { return TIMEOUT;}
  94 envelope        { return ENVELOPE; }
  95 qvirtual        { return QVIRTUAL; }
  96 principal       { return PRINCIPAL; }
  97 esmtpname       { return ESMTPNAME; }
  98 esmtppassword   { return ESMTPPASSWORD; }
  99 bad-header      { return BADHEADER; }
 100 accept          { return ACCEPT; }
 101 reject          { return REJECT_; }
 102 retrieve-error  { return RETRIEVEERROR; }
 103 abort           { return ABORT; }
 104 continue        { return CONTINUE; }
 105 markseen        { return MARKSEEN; }
 106
 107 user(name)?     {SETSTATE(NAME); return USERNAME; }
 108 pwmd_socket     { return PWMD_SOCKET; }
 109 pwmd_file       { return PWMD_FILE; }
 110 pinentry_timeout        { return PINENTRY_TIMEOUT; }
 111 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 112 folder(s)?      { return FOLDER; }
 113 smtp(host)?     { return SMTPHOST; }
 114 fetchdomains    { return FETCHDOMAINS; }
 115 smtpaddress     { return SMTPADDRESS; }
 116 smtpname        { return SMTPNAME; }
 117 antispam        { return SPAMRESPONSE; }
 118 mda             { return MDA; }
 119 bsmtp           { return BSMTP; }
 120 lmtp            { return LMTP; }
 121 pre(connect)?   { return PRECONNECT; }
 122 post(connect)?  { return POSTCONNECT; }
 123 interface       { return INTERFACE; }
 124 monitor         { return MONITOR; }
 125 plugin          { return PLUGIN; }
 126 plugout         { return PLUGOUT; }
 127 batchlimit      { return BATCHLIMIT; }
 128 fetchlimit      { return FETCHLIMIT; }
 129 fetchsizelimit  { return FETCHSIZELIMIT; }
 130 fastuidl        { return FASTUIDL; }
 131 expunge         { return EXPUNGE; }
 132 properties      { return PROPERTIES; }
 133
 134 is              { SETSTATE(NAME); return IS; }
 135 here            { return HERE; }
 136 there           { return THERE; }
 137 to              { SETSTATE(NAME); return TO; }
 138 =               { SETSTATE(NAME); return MAP; }
 139
 140 nobouncemail    |
 141 nouidl          |
 142 nocheckalias    |
 143 nodns           |
 144 noenvelope      |
 145 nokeep          |
 146 noflush         |
 147 nolimitflush    |
 148 nofetchall      |
 149 norewrite       |
 150 noforcecr       |
 151 nostripcr       |
 152 nopass8(bits)?  |
 153 nodropstatus    |
 154 nodropdelivered |
 155 nomimedec(ode)? |
 156 nospambounce    |
 157 noidle          {
 158                    yyless(2);
 159                    return NO;
 160                 }
 161
 162 no              {return NO;}
 163
 164 keep            { return KEEP; }
 165 flush           { return FLUSH; }
 166 limitflush      { return LIMITFLUSH; }
 167 fetchall        { return FETCHALL; }
 168 rewrite         { return REWRITE; }
 169 forcecr         { return FORCECR; }
 170 stripcr         { return STRIPCR; }
 171 pass8(bits)?    { return PASS8BITS; }
 172 dropstatus      { return DROPSTATUS; }
 173 dropdelivered   { return DROPDELIVERED; }
 174 mimedec(ode)?   { return MIMEDECODE; }
 175 idle            { return IDLE; }
 176 dns             { return DNS; }
 177 uidl            { return UIDL; }
 178 ssl             { return SSL; }
 179 sslkey          { return SSLKEY; }
 180 sslcert         { return SSLCERT; }
 181 sslproto        { return SSLPROTO; }
 182 sslcertck       { return SSLCERTCK; }
 183 sslcertfile     { return SSLCERTFILE; }
 184 sslcertpath     { return SSLCERTPATH; }
 185 sslcommonname   { return SSLCOMMONNAME; }
 186 sslfingerprint  { return SSLFINGERPRINT; }
 187 checkalias      { return CHECKALIAS; }
 188
 189 limit           { return LIMIT; }
 190
 191 with            {/* EMPTY */}
 192 and             {/* EMPTY */}
 193 has             {/* EMPTY */}
 194 wants           {/* EMPTY */}
 195 options         {/* EMPTY */}
 196 [;:,]           {/* EMPTY */}
 197
 198 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 199 (sdps)|(SDPS)   { return SDPS; }
 200 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 201 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 202 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 203 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 204 (kpop)|(KPOP)   { return KPOP; }
 205
 206 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 207
 208 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 209
 210 [^=;:, \t\r\n]+ {
 211                         char *in = xstrdup(yytext);
 212                         escapes(in, in);
 213                         yylval.sval = in;
 214                         return STRING;
 215                 }
 216
 217 [ \t\r]+        ;       /* whitespace */
 218
 219 %%
 220
 221 /** process standard C-style escape sequences in a string,
 222  * this can never lengthen the output, so cp and tp may overlap as long
 223  * as cp >= tp. */
 224 void escapes(const char *cp /** source string with escapes */,
 225              char       *tp /** target buffer for digested string */)
 226 {
 227     while (*cp)
 228     {
 229         int     cval = 0;
 230
 231         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 232          * always succeed! */
 233         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 234         {
 235             const char *dp;
 236             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 237             int dcount = 0;
 238
 239             if (*++cp == 'x' || *cp == 'X')
 240                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 241                     cval = (cval * 16) + (dp - hex) / 2;
 242             else if (*cp == '0')
 243                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 244                     cval = (cval * 8) + (*cp++ - '0');
 245             else
 246                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 247                     cval = (cval * 10) + (*cp++ - '0');
 248         }
 249         else if (*cp == '\\')           /* C-style character escapes */
 250         {
 251             switch (*++cp)
 252             {
 253             case '\n': cp++; continue;  /* backslash before LF to join lines */
 254             case '\0': goto done;          /* ignore backslash at file end */
 255             case '\\': cval = '\\'; break;
 256             case 'n': cval = '\n'; break;
 257             case 't': cval = '\t'; break;
 258             case 'b': cval = '\b'; break;
 259             case 'r': cval = '\r'; break;
 260             default: cval = *cp;
 261             }
 262             cp++;
 263         }
 264         else
 265             cval = *cp++;
 266         *tp++ = cval;
 267     }
 268 done:
 269     *tp = '\0';
 270 }