Pileus Git - ~andy/fetchmail/blob - rcfile_l.l

   1 %{
   2
   3 /*
   4  * rcfile_l.l -- lexer for the run control file
   5  *
   6  * For license terms, see the file COPYING in this directory.
   7  */
   8 #include <string.h>
   9
  10 #include "config.h"
  11 #include "fetchmail.h"
  12 #include "rcfile_y.h"
  13
  14 int prc_lineno = 1;
  15
  16 #ifdef LEXDEBUG
  17 #define SETSTATE(n)     do {BEGIN(n); if (yydebug) fprintf(stderr, "Entering lexer state %d\n", n);} while (0)
  18 #else
  19 #define SETSTATE(n)     BEGIN(n)
  20 #endif /* LEXDEBUG */
  21
  22 %}
  23
  24 /* this doesn't work with Linux lex, see the INSTALL file */
  25 %o 7000
  26 %a 4000
  27 %p 3000
  28 %option nounput noyywrap
  29
  30 %s NAME AUTH
  31
  32 %%
  33
  34 \"[^\"]*\"      {
  35                         yytext[yyleng-1] = '\0';
  36                         escapes(yytext+1, yytext);
  37                         yyleng = strlen(yytext);
  38                         yylval.sval = yytext;
  39                         SETSTATE(0);
  40                         return STRING;
  41                 }
  42 \'[^\']*\'      {
  43                         yytext[yyleng-1] = '\0';
  44                         escapes(yytext+1, yytext);
  45                         yyleng = strlen(yytext);
  46                         yylval.sval = yytext;
  47                         SETSTATE(0);
  48                         return STRING;
  49                 }
  50
  51 "*"             { BEGIN(0); return WILDCARD; }
  52
  53 <NAME>[^=;:, \t\r\n]+   {
  54                         static char *in;
  55                         static size_t ins;
  56
  57                         if ((size_t)yyleng + 1 > ins) {
  58                             ins = yyleng + 1;
  59                             in = (char *)xrealloc(in, ins);
  60                         }
  61                         memcpy(in, yytext, yyleng);
  62                         in[yyleng] = '\0';
  63                         escapes(in, in);
  64                         yyleng = strlen(in);
  65                         yylval.sval = in;
  66                         SETSTATE(0);
  67                         return STRING;
  68                 }
  69
  70 set             { return SET; }
  71 logfile         { return LOGFILE; }
  72 idfile          { return IDFILE; }
  73 pidfile         { return PIDFILE; }
  74 daemon          { return DAEMON; }
  75 syslog          { return SYSLOG; }
  76 invisible       { return INVISIBLE; }
  77 showdots        { return SHOWDOTS; }
  78 postmaster      { return POSTMASTER; }
  79 bouncemail      { return BOUNCEMAIL; }
  80 spambounce      { return SPAMBOUNCE; }
  81 softbounce      { return SOFTBOUNCE; }
  82 warnings        { return WARNINGS; }
  83 tracepolls      { return TRACEPOLLS; }
  84
  85 defaults        { return DEFAULTS; }
  86 server          { return POLL; }
  87 poll            { return POLL; }
  88 skip            { return SKIP; }
  89 via             { return VIA; }
  90 aka             { return AKA; }
  91 local(domains)? { return LOCALDOMAINS; }
  92 proto(col)?     { return PROTOCOL; }
  93 service         { return SERVICE; }
  94 port            { return PORT; }
  95 interval        { return INTERVAL; }
  96 preauth(enticate)?      { SETSTATE(AUTH); return AUTHENTICATE; }
  97 auth(enticate)? { SETSTATE(AUTH); return AUTHENTICATE; }
  98 any             { SETSTATE(0); yylval.proto = A_ANY; return AUTHTYPE;}
  99 gssapi          { SETSTATE(0); yylval.proto = A_GSSAPI; return AUTHTYPE;}
 100 kerberos(_v)?4  { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
 101 kerberos(_v)?5  { SETSTATE(0); yylval.proto = A_KERBEROS_V5; return AUTHTYPE;}
 102 kerberos        { SETSTATE(0); yylval.proto = A_KERBEROS_V4; return AUTHTYPE;}
 103 ssh             { SETSTATE(0); yylval.proto = A_SSH; return AUTHTYPE;}
 104 external        { SETSTATE(0); yylval.proto = A_EXTERNAL; return AUTHTYPE;}
 105 (otp|opie)      { SETSTATE(0); yylval.proto = A_OTP; return AUTHTYPE;}
 106 cram(-md5)?     { SETSTATE(0); yylval.proto = A_CRAM_MD5; return AUTHTYPE;}
 107 msn             { SETSTATE(0); yylval.proto = A_MSN; return AUTHTYPE;}
 108 ntlm            { SETSTATE(0); yylval.proto = A_NTLM; return AUTHTYPE;}
 109 <AUTH>password  { SETSTATE(0); yylval.proto = A_PASSWORD; return AUTHTYPE;}
 110 timeout         { return TIMEOUT;}
 111 envelope        { return ENVELOPE; }
 112 qvirtual        { return QVIRTUAL; }
 113 principal       { return PRINCIPAL; }
 114 esmtpname       { return ESMTPNAME; }
 115 esmtppassword   { return ESMTPPASSWORD; }
 116 bad-header      { return BADHEADER; }
 117 pass            { return PASS; }
 118 reject          { return REJECT_; }
 119
 120 user(name)?     {SETSTATE(NAME); return USERNAME; }
 121 <INITIAL,NAME>pass(word)?       {SETSTATE(NAME); return PASSWORD; }
 122 folder(s)?      { return FOLDER; }
 123 smtp(host)?     { return SMTPHOST; }
 124 fetchdomains    { return FETCHDOMAINS; }
 125 smtpaddress     { return SMTPADDRESS; }
 126 smtpname        { return SMTPNAME; }
 127 antispam        { return SPAMRESPONSE; }
 128 mda             { return MDA; }
 129 bsmtp           { return BSMTP; }
 130 lmtp            { return LMTP; }
 131 pre(connect)?   { return PRECONNECT; }
 132 post(connect)?  { return POSTCONNECT; }
 133 interface       { return INTERFACE; }
 134 monitor         { return MONITOR; }
 135 plugin          { return PLUGIN; }
 136 plugout         { return PLUGOUT; }
 137 batchlimit      { return BATCHLIMIT; }
 138 fetchlimit      { return FETCHLIMIT; }
 139 fetchsizelimit  { return FETCHSIZELIMIT; }
 140 fastuidl        { return FASTUIDL; }
 141 expunge         { return EXPUNGE; }
 142 properties      { return PROPERTIES; }
 143
 144 is              { SETSTATE(NAME); return IS; }
 145 here            { return HERE; }
 146 there           { return THERE; }
 147 to              { SETSTATE(NAME); return TO; }
 148 =               { SETSTATE(NAME); return MAP; }
 149
 150 nobouncemail    |
 151 nouidl          |
 152 nocheckalias    |
 153 nodns           |
 154 noenvelope      |
 155 nokeep          |
 156 noflush         |
 157 nolimitflush    |
 158 nofetchall      |
 159 norewrite       |
 160 noforcecr       |
 161 nostripcr       |
 162 nopass8(bits)?  |
 163 nodropstatus    |
 164 nodropdelivered |
 165 nomimedec(ode)? |
 166 nospambounce    |
 167 noidle          {
 168                    yyless(2);
 169                    return NO;
 170                 }
 171
 172 no              {return NO;}
 173
 174 keep            { return KEEP; }
 175 flush           { return FLUSH; }
 176 limitflush      { return LIMITFLUSH; }
 177 fetchall        { return FETCHALL; }
 178 rewrite         { return REWRITE; }
 179 forcecr         { return FORCECR; }
 180 stripcr         { return STRIPCR; }
 181 pass8(bits)?    { return PASS8BITS; }
 182 dropstatus      { return DROPSTATUS; }
 183 dropdelivered   { return DROPDELIVERED; }
 184 mimedec(ode)?   { return MIMEDECODE; }
 185 idle            { return IDLE; }
 186 dns             { return DNS; }
 187 uidl            { return UIDL; }
 188 ssl             { return SSL; }
 189 sslkey          { return SSLKEY; }
 190 sslcert         { return SSLCERT; }
 191 sslproto        { return SSLPROTO; }
 192 sslcertck       { return SSLCERTCK; }
 193 sslcertpath     { return SSLCERTPATH; }
 194 sslcommonname   { return SSLCOMMONNAME; }
 195 sslfingerprint  { return SSLFINGERPRINT; }
 196 checkalias      { return CHECKALIAS; }
 197
 198 limit           { return LIMIT; }
 199
 200 with            {/* EMPTY */}
 201 and             {/* EMPTY */}
 202 has             {/* EMPTY */}
 203 wants           {/* EMPTY */}
 204 options         {/* EMPTY */}
 205 [;:,]           {/* EMPTY */}
 206
 207 (auto)|(AUTO)   { yylval.proto = P_AUTO;  return PROTO; }
 208 (pop2)|(POP2)   { yylval.proto = P_POP2;  return PROTO; }
 209 (sdps)|(SDPS)   { return SDPS; }
 210 (pop3)|(POP3)   { yylval.proto = P_POP3;  return PROTO; }
 211 (imap)|(IMAP)   { yylval.proto = P_IMAP;  return PROTO; }
 212 (apop)|(APOP)   { yylval.proto = P_APOP;  return PROTO; }
 213 (rpop)|(RPOP)   { yylval.proto = P_RPOP;  return PROTO; }
 214 (etrn)|(ETRN)   { yylval.proto = P_ETRN;  return PROTO; }
 215 (odmr)|(ODMR)   { yylval.proto = P_ODMR;  return PROTO; }
 216 (kpop)|(KPOP)   { return KPOP; }
 217
 218 (#.*)?\\?\n     { prc_lineno++; }   /* newline is ignored */
 219
 220 -?[0-9]+        { yylval.number = atoi(yytext); return NUMBER; }
 221
 222 [^=;:, \t\r\n]+ {
 223                         escapes(yytext, yytext);
 224                         yyleng = strlen(yytext);
 225                         yylval.sval = yytext;
 226                         return STRING;
 227                 }
 228
 229 [ \t\r]+        ;       /* whitespace */
 230
 231 %%
 232
 233 /** process standard C-style escape sequences in a string,
 234  * this can never lengthen the output, so cp and tp may overlap as long
 235  * as cp >= tp. */
 236 void escapes(const char *cp /** source string with escapes */,
 237              char       *tp /** target buffer for digested string */)
 238 {
 239     while (*cp)
 240     {
 241         int     cval = 0;
 242
 243         /* we MUST check for NUL explicitly, as strchr(string, 0) will
 244          * always succeed! */
 245         if (*cp == '\\' && cp[1] && strchr("0123456789xX", cp[1]))
 246         {
 247             char *dp;
 248             const char *hex = "00112233445566778899aAbBcCdDeEfF";
 249             int dcount = 0;
 250
 251             if (*++cp == 'x' || *cp == 'X')
 252                 for (++cp; *cp && (dp = strchr(hex, *cp)) && (dcount++ < 2); cp++)
 253                     cval = (cval * 16) + (dp - hex) / 2;
 254             else if (*cp == '0')
 255                 while (*cp && strchr("01234567",*cp) != (char*)NULL && (dcount++ < 3))
 256                     cval = (cval * 8) + (*cp++ - '0');
 257             else
 258                 while (*cp && (strchr("0123456789",*cp)!=(char*)NULL)&&(dcount++ < 3))
 259                     cval = (cval * 10) + (*cp++ - '0');
 260         }
 261         else if (*cp == '\\')           /* C-style character escapes */
 262         {
 263             switch (*++cp)
 264             {
 265             case '\n': cp++; continue;  /* backslash before LF to join lines */
 266             case '\0': goto done;          /* ignore backslash at file end */
 267             case '\\': cval = '\\'; break;
 268             case 'n': cval = '\n'; break;
 269             case 't': cval = '\t'; break;
 270             case 'b': cval = '\b'; break;
 271             case 'r': cval = '\r'; break;
 272             default: cval = *cp;
 273             }
 274             cp++;
 275         }
 276         else
 277             cval = *cp++;
 278         *tp++ = cval;
 279     }
 280 done:
 281     *tp = '\0';
 282 }